LoaderInfo  - AS3

Version ActionScript du fichier SWF chargé. La version du langage est spécifiée par le biais des énumérations de la classe ActionScriptVersion, telles que ActionScriptVersion.ACTIONSCRIPT2 et ActionScriptVersion.ACTIONSCRIPT3.

Remarque : cette propriété possède toujours la valeur ActionScriptVersion.ACTIONSCRIPT2 ou ActionScriptVersion.ACTIONSCRIPT3. ActionScript 1.0 et 2.0 correspondent tous deux à ActionScriptVersion.ACTIONSCRIPT2 (version 2.0). Cette propriété se contente de distinguer ActionScript 1.0 et 2.0 d’ActionScript 3.0.

Eléments de l’API associés

Lorsqu’un fichier SWF externe est chargé, toutes les définitions ActionScript 3.0 que contient la classe chargée sont enregistrées dans la propriété applicationDomain.

L’ensemble du code d’un fichier SWF est défini de sorte à exister dans un domaine d’application. Votre application principale s’exécute dans le domaine d’application en cours. Le domaine du système contient tous les domaines d’application, y compris le domaine actuel et toutes les classes utilisées par Flash Player ou Adobe AIR.

A l’exception du domaine du système, tous les domaines d’application sont associés à un domaine du parent. Le domaine du parent de la propriété applicationDomain de votre application principale est le domaine système. Les classes chargées ne sont définies que si leur parent ne les définit pas encore. Vous ne pouvez pas remplacer une définition de classe chargée par une définition plus récente.

Pour obtenir des exemples d’utilisation de domaines d’application, voir le chapitre « Environnement du système client » du Guide du développeur d’ActionScript 3.0.

Plus d’exemples

Informations complémentaires

Eléments de l’API associés

Octets associés à un objet LoaderInfo.

Nombre d’octets chargés pour le média. Lorsque ce nombre atteint la valeur de bytesTotal, tous les octets sont chargés.

Nombre d’octets compressés du fichier multimédias entier.

Avant la distribution du premier événement progress par l’objet Loader correspondant de cet objet LoaderInfo, bytesTotal est défini sur 0. Après la distribution du premier événement progress par l’objet Loader, bytesTotal reflète le nombre réel d’octets à télécharger.

Remarque (iOS uniquement) : lors de l’exécution d’une application sur iOS, la valeur renvoyée n’est pas la même que sur les autres plates-formes.

Eléments de l’API associés

Exprime la relation de confiance qui lie le contenu (l’enfant) à l’objet Loader (le parent). Renvoie true si l’enfant a autorisé l’accès du parent, false dans le cas contraire. Cette propriété est définie sur true si l’objet enfant a appelé la méthode allowDomain() pour accorder une autorisation d’accès au domaine parent, ou si un fichier de régulation d’URL chargé dans le domaine enfant accorde une autorisation d’accès au domaine parent. Si l’enfant et le parent appartiennent au même domaine, cette propriété est réglée sur true.

Pour plus d’informations sur la sécurité, voir la rubrique « Modifications du fichier de régulation dans Flash Player » dans le Centre des développeurs Flash Player à l’adresse Security.

Un objet qui peut être définir par le code du contenu chargé pour exposer des propriétés et des méthodes auxquelles le code dans le sandbox de l’objet Loader peut accéder. Ce pont de sandbox permet au contenu d’un domaine qui n’est pas un domaine d’application de bénéficier d’un accès contrôlé aux scripts dans le sandbox de l’application, et inversement. Le pont de sandbox sert de passerelle entre les sandboxes, fournissant une interaction explicite entre les sandboxes de sécurité de l’application et les autres.

Eléments de l’API associés

Objet chargé associé à cet objet LoaderInfo.

Type MIME du fichier chargé. Le paramètre est défini sur null si le pourcentage chargé du fichier est insuffisant pour déterminer le type. La liste suivante répertorie les valeurs gérées :

• "application/x-shockwave-flash"
• "image/jpeg"
• "image/gif"
• "image/png"

Cadence nominale, en images par seconde, du fichier SWF chargé. Cette valeur correspond souvent, mais pas nécessairement, à un entier.

Elle peut être différente de la cadence utilisée. Flash Player ou Adobe AIR utilise la même cadence pour tous les fichiers SWF chargés. Cette valeur est déterminée par la cadence nominale du fichier SWF principal. De même, la cadence principale risque de ne pas pouvoir être atteinte, selon le matériel, la synchronisation du son, et d’autres facteurs.

Hauteur nominale du fichier chargé. Elle peut être différente de la hauteur réelle du contenu affiché, car le contenu chargé ou ses objets d’affichage parent risquent d’avoir été redimensionnés.

Indique si la propriété LoaderInfo.url a été tronquée. Lorsque la valeur isURLInaccessible est définie sur true, la valeur LoaderInfo.url correspond uniquement au domaine de l’URL finale à partir de laquelle le contenu a été chargé. Par exemple, la propriété est tronquée si le contenu est chargé depuis http://www.adobe.com/assets/hello.swf, et la propriété LoaderInfo.url a la valeur http://www.adobe.com. La valeur isURLInaccessible est définie sur true uniquement lorsque toutes les affirmations suivantes sont également vraies :

• Une redirection HTTP s’est produite lors du chargement du contenu.
• Le fichier SWF qui appelle Loader.load() provient d’un domaine différent de celui de l’URL finale du contenu.
• Le fichier SWF qui appelle Loader.load() n’est pas autorisé à accéder au contenu. L’autorisation d’accéder au contenu s’obtient de la même façon que l’autorisation d’accéder à BitmapData.draw() : appelez Security.allowDomain() pour accéder à un fichier SWF (ou pour le contenu des fichiers non SWF, créez un fichier de régulation et utilisez la propriété LoaderContext.checkPolicyFile).

Remarque : la propriété isURLInaccessible a été ajoutée à Flash Player 10.1 et AIR 2.0. Toutefois, cette propriété est disponible pour les fichiers SWF de toutes les versions lorsque le moteur d’exécution de Flash la prend en charge. Ainsi, l’utilisation de certains outils de création en « mode strict » entraîne une erreur de compilation. Pour contourner cette erreur, utilisez la syntaxe indirecte myLoaderInfo["isURLInaccessible"] ou désactivez le mode strict. Si vous utilisez Flash Professional CS5 ou le kit SDK Flex version 4.1, vous pouvez utiliser et compiler cette API pour les moteurs d’exécution publiés avant Flash Player 10.1 et AIR 2.

Pour le contenu de l’application dans AIR, la valeur de cette propriété est toujours false.

Eléments de l’API associés

Objet Loader associé à cet objet LoaderInfo. Si cet objet LoaderInfo figure dans la propriété loaderInfo de l’occurrence de la classe principale du fichier SWF, il n’est associé à aucun objet Loader.

URL du fichier SWF qui a initié le chargement du média décrit par l’objet LoaderInfo. Pour l’occurrence de la classe principale du fichier SWF, cette URL correspond à l’URL du fichier SWF.

Objet contenant des paires nom-valeur qui représentent les paramètres fournis au fichier SWF chargé.

L’utilisation d’une boucle for-in vous permet d’extraire tous les noms et toutes les valeurs de l’objet parameters.

Les deux sources de paramètres sont : la chaîne de requête que contient l’URL du fichier SWF principal et la valeur du paramètre HTML FlashVars (qui n’affecte que le fichier SWF principal).

La propriété parameters remplace la technique ActionScript 1.0 et 2.0 qui consistait à utiliser des paramètres de fichier SWF en tant que propriétés du scénario principal.

La valeur de la propriété parameters est null pour les objets Loader qui contiennent des fichiers SWF qui utilisent ActionScript 1.0 ou 2.0. Elle est différente de null pour les objets Loader qui contiennent des fichiers SWF ayant recours à ActionScript 3.0.

Exprime la relation de confiance qui lie l’objet Loader (le parent) au contenu (l’enfant). Renvoie true si le parent a autorisé l’accès de l’enfant, false dans le cas contraire. Cette propriété est définie sur true si l’objet parent a appelé la méthode allowDomain() pour accorder une autorisation d’accès au domaine enfant, ou si un fichier de régulation d’URL chargé dans le domaine parent accorde une autorisation d’accès au domaine enfant. Si l’enfant et le parent appartiennent au même domaine, cette propriété est réglée sur true.

Pour plus d’informations sur la sécurité, voir la rubrique « Modifications du fichier de régulation dans Flash Player » dans le Centre des développeurs Flash Player à l’adresse Security.

Un objet qui peut être défini par le code dans le sandbox de l’objet Loader pour exposer les propriétés et les méthodes auxquelles le code du contenu chargé peut accéder. Ce pont de sandbox permet au contenu d’un domaine qui n’est pas un domaine d’application de bénéficier d’un accès contrôlé aux scripts dans le sandbox de l’application, et inversement. Le pont de sandbox sert de passerelle entre les sandboxes, fournissant une interaction explicite entre les sandboxes de sécurité de l’application et les autres.

Eléments de l’API associés

Exprime la relation entre les domaines de l’objet loader et du contenu : true s’ils proviennent du même domaine ; false dans tous les autres cas.

Occurrence de EventDispatcher permettant d’échanger des événements hors des limites de sécurité. Même lorsque l’objet Loader et le contenu chargé proviennent de domaines de sécurité qui ne s’approuvent pas, ils peuvent accéder à sharedEvents ainsi qu’envoyer et recevoir des événements via cet objet.

Version du format du fichier SWF chargé. Le format du fichier est spécifié par le biais des énumérations de la classe SWFVersion, telles que SWFVersion.FLASH7 et SWFVersion.FLASH9.

Eléments de l’API associés

Objet qui distribue un événement uncaughtError lorsqu’une erreur non interceptée se produit dans le code du fichier SWF de cet objet LoaderInfo. Une erreur non interceptée se produit lorsqu’une erreur est renvoyée en dehors de tout bloc try..catch ou lorsqu’un objet ErrorEvent est distribué avec aucun écouteur enregistré.

Par exemple, si dans un bloc try, un diffuseur d’événements appelle son gestionnaire d’événements, le bloc catch n’intercepte pas l’erreur si elle est renvoyée dans le gestionnaire d’événements. Toute erreur renvoyée peut être interceptée en écoutant LoaderInfo.uncaughtErrorEvents

Cette propriété est créée à la fin du chargement du fichier SWF associé à cet objet LoaderInfo. Tant que la propriété uncaughtErrorEvents n’est pas définie sur null, Dans un projet ActionScript uniquement, vous pouvez accéder à cette propriété pendant ou après l’exécution de la fonction constructeur de la classe principale du fichier SWF. Pour un projet Flex, la propriété uncaughtErrorEvents n’est disponible qu’une fois l’événement applicationComplete distribué.

Eléments de l’API associés

package
{
    import flash.display.Sprite;
    import flash.events.ErrorEvent;
    import flash.events.MouseEvent;
    import flash.events.UncaughtErrorEvent;

    public class UncaughtErrorEventExample extends Sprite
    {
        public function UncaughtErrorEventExample()
        {
            loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
            
            drawUI();
        }
        
        private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
        {
            if (event.error is Error)
            {
                var error:Error = event.error as Error;
                // do something with the error
            }
            else if (event.error is ErrorEvent)
            {
                var errorEvent:ErrorEvent = event.error as ErrorEvent;
                // do something with the error
            }
            else
            {
                // a non-Error, non-ErrorEvent type was thrown and uncaught
            }
        }
        
        private function drawUI():void
        {
            var btn:Sprite = new Sprite();
            btn.graphics.clear();
            btn.graphics.beginFill(0xFFCC00);
            btn.graphics.drawRect(0, 0, 100, 50);
            btn.graphics.endFill();
            addChild(btn);
            btn.addEventListener(MouseEvent.CLICK, clickHandler);
        }
        
        private function clickHandler(event:MouseEvent):void
        {
            throw new Error("Gak!");
        }
    }
}

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
                       xmlns:s="library://ns.adobe.com/flex/spark" 
                       xmlns:mx="library://ns.adobe.com/flex/halo"
                       applicationComplete="applicationCompleteHandler();">
    
    <fx:Script>
        <![CDATA[
            import flash.events.ErrorEvent;
            import flash.events.MouseEvent;
            import flash.events.UncaughtErrorEvent;
            
            private function applicationCompleteHandler():void
            {
                loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
            }
    
            private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
            {
                if (event.error is Error)
                {
                    var error:Error = event.error as Error;
                    // do something with the error
                }
                else if (event.error is ErrorEvent)
                {
                    var errorEvent:ErrorEvent = event.error as ErrorEvent;
                    // do something with the error
                }
                else
                {
                    // a non-Error, non-ErrorEvent type was thrown and uncaught
                }
            }
            
            private function clickHandler(event:MouseEvent):void
            {
                throw new Error("Gak!");
            }
        ]]>
    </fx:Script>
      
    <s:Button label="Cause Error" click="clickHandler(event);"/>
</s:WindowedApplication>

URL du média en cours de chargement.

Avant la distribution du premier événement progress par l’objet Loader correspondant associé à cet objet LoaderInfo, la valeur de la propriété url risque de ne refléter que l’URL initiale spécifiée par l’appel de la méthode load() de l’objet Loader. Après la distribution du premier événement progress, la propriété url reflète l’URL finale du média, suite à la résolution de toute redirection et URL relative.

Dans certains cas, la valeur de la propriété url est tronquée. Voir la propriété isURLInaccessible pour plus d’informations.

Eléments de l’API associés

Largeur nominale du contenu chargé. Elle peut être différente de la largeur réelle du contenu affiché, car le contenu chargé ou ses objets d’affichage parent risquent d’avoir été redimensionnés.

Renvoie l’objet LoaderInfo associé à un fichier SWF défini sous forme d’objet.

Paramètres

Distribué lorsque le chargement de données aboutit. En d’autres termes, il est distribué lorsque tout le contenu a été téléchargé et une fois le chargement terminé. L’événement complete est toujours distribué après l’événement init. L’événement init est distribué lorsque vous pouvez accéder à l’objet, même si le contenu est en cours de téléchargement.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Distribué lorsqu’une requête réseau est effectuée sur HTTP et qu’un code d’état HTTP peut être détecté.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Distribué lorsqu’il est possible d’accéder aux propriétés et aux méthodes d’un fichier SWF chargé et de les utiliser. Il est néanmoins toujours possible de télécharger le contenu. Un objet LoaderInfo distribue l’événement init lorsque les conditions suivantes sont remplies :

• Il est possible d’accéder à toutes les propriétés et méthodes associées à l’objet chargé et celles associées à l’objet LoaderInfo.
• L’exécution des constructeurs de tous les objets enfant est terminée.
• Le code ActionScript contenu dans la première image du scénario principal du fichier SWF chargé a été exécuté.

Par exemple, un événement Event.INIT est distribué lorsque la première image d’un clip ou d’une animation est chargée. Vous pouvez alors accéder au clip et l’ajouter à la liste d’affichage. Il est toutefois possible que le téléchargement du clip complet soit un peu plus long. L’événement Event.COMPLETE n’est distribué que lorsque le clip complet est chargé.

L’événement init précède toujours l’événement complete.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Distribué lorsqu’il se produit une erreur d’entrée ou de sortie entraînant l’échec d’une opération de chargement.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Distribué lors du démarrage d’une opération de chargement.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Distribué à la réception des données au fur et à mesure du téléchargement.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Distribué par un objet LoaderInfo lorsqu’un objet chargé est supprimé à l’aide de la méthode unload() de l’objet Loader ou lorsqu’un second chargement est effectué par le même objet Loader et que le contenu d’origine est supprimé avant le début du chargement.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

1. Une propriété url est créée pour désigner l’emplacement et le nom de l’image.
2. Le constructeur de classe crée un objet Loader appelé loader.
3. L’objet loader crée une occurrence d’écouteur d’événements pour s’assurer que l’image se charge correctement.
4. Le constructeur crée une occurrence d’objet URLRequest, request, et transmet le paramètre url de façon à identifier le nom de fichier et son emplacement.
5. L’objet request est ensuite transmis à la méthode load() de l’objet loader, qui charge l’image dans la liste d’affichage.

Important : cet exemple implique l’ajout d’un fichier appelé Image.gif dans le même répertoire que le fichier SWF compilé. Utilisez une image dont la zone corresponde aux dimensions du fichier SWF principal.

package {
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderInfoExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderInfoExample() {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.INIT, initHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            var request:URLRequest = new URLRequest(url);
            loader.load(request);
            addChild(loader);
        }

        private function initHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var info:LoaderInfo = LoaderInfo(loader.contentLoaderInfo);
            trace("initHandler: loaderURL=" + info.loaderURL + " url=" + info.url);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}