Loader  - AS3

Contient l’objet d’affichage racine du fichier SWF ou du fichier d’image (JPG, PNG ou GIF) qui a été chargé à l’aide de la méthode load() ou loadBytes().

Eléments de l’API associés

Renvoie un objet LoaderInfo qui correspond à l’objet en cours de chargement. Les objets LoaderInfo sont partagés entre l’objet Loader et l’objet chargé. L’objet LoaderInfo fournit des informations relatives à la progression du déroulement du chargement et des statistiques sur le fichier chargé.

Les événements liés au chargement sont distribués par l’objet LoaderInfo qui est référencé par la propriété contentLoaderInfo de l’objet Loader. La propriété contentLoaderInfo est définie sur un objet LoaderInfo valide, y compris avant le chargement du contenu, ce qui permet d’ajouter des écouteurs d’événement à l’objet avant l’opération de chargement.

Pour détecter les erreurs non interceptées qui se produisent dans un fichier SWF, utilisez la propriété Loader.uncaughtErrorEvents et non la propriété Loader.contentLoaderInfo.uncaughtErrorEvents.

Eléments de l’API associés

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";
var urlRequest:URLRequest = new URLRequest(url);
var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loader_complete);
loader.load(urlRequest);
addChild(loader);
 
function loader_complete(evt:Event):void {
    var target_mc:Loader = evt.currentTarget.loader as Loader;
    target_mc.x = (stage.stageWidth - target_mc.width) / 2;
    target_mc.y = (stage.stageHeight - target_mc.height) / 2;
}

Objet qui distribue un événement uncaughtError lorsqu’une erreur non interceptée se produit dans le fichier SWF chargé par cet objet Loader. Une erreur non interceptée se produit lorsqu’une erreur est renvoyée en dehors de tout bloc try..catch ou lorsqu’un objet ErrorEvent est distribué avec aucun écouteur enregistré.

Notez que la propriété uncaughtErrorEvents d’un objet Loader distribue les événements qui se propagent vers le haut au sein de celle-ci et non les événements qu’elle distribue directement. Elle ne distribue jamais d’événement uncaughtErrorEvent dans la phase cible. Elle distribue l’événement uniquement dans les phases de capture et de propagation. Pour détecter une erreur non interceptée dans le fichier SWF actuel (fichier SWF dans lequel l’objet Loader est défini), utilisez plutôt la propriété LoaderInfo.uncaughtErrorEvents.

Si le contenu chargé par l’objet Loader est un fichier SWF AVM1 (ActionScript 2), les erreurs non interceptées dans le fichier SWF AVM1 n’entraînent pas un événement uncaughtError.

Eléments de l’API associés

package
{
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.ErrorEvent;
    import flash.events.UncaughtErrorEvent;
    import flash.net.URLRequest;

    public class LoaderUncaughtErrorEventExample extends Sprite
    {
        private var ldr:Loader;
        
        public function LoaderUncaughtErrorEventExample()
        {
            ldr = new Loader();
            ldr.load(new URLRequest("child.swf"));
            ldr.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
        }
        
        private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
        {
            if (event.error is Error)
            {
                var error:Error = event.error as Error;
                // do something with the error
            }
            else if (event.error is ErrorEvent)
            {
                var errorEvent:ErrorEvent = event.error as ErrorEvent;
                // do something with the error
            }
            else
            {
                // a non-Error, non-ErrorEvent type was thrown and uncaught
            }
        }
    }
}

Crée un objet Loader qui permet de charger des fichiers (SWF, JPEG, GIF ou PNG). Appelez la méthode load() pour charger l’actif en tant qu’enfant de l’occurrence de Loader. Vous pouvez alors ajouter l’objet Loader à la liste d’affichage (par le biais de la méthode addChild() d’une occurrence de DisplayObjectContainer, par exemple). L’actif apparaît sur la scène au fur et à mesure de son chargement.

Vous pouvez également utiliser une occurrence de Loader sans l’intégrer à un conteneur d’objet d’affichage de la liste d’affichage. Si ce mode est activé, l’occurrence de Loader peut être utilisée pour charger un fichier SWF contenant d’autres modules d’une application.

Pour détecter la fin du chargement du fichier SWF, vous disposez des événements de l’objet LoaderInfo associés à la propriété contentLoaderInfo de l’objet Loader. A ce stade, vous pouvez exécuter le code du fichier SWF du module pour initialiser et démarrer ce dernier. En mode hors liste, l’occurrence de Loader peut également être utilisée pour charger un fichier SWF contenant des composants ou des actifs multimédias. Il est également possible d’utiliser les notifications d’événement associées à l’objet LoaderInfo pour détecter la fin du chargement des composants. L’application peut alors commencer à utiliser les composants et les actifs multimédias intégrés à la bibliothèque du fichier SWF en instanciant les classes ActionScript 3.0 qui représentent ces composants et ces actifs.

Pour déterminer le statut d’un objet Loader, supervisez les événements suivants que l’objet LoaderInfo a associé à la propriété contentLoaderInfo de l’objet Loader :

• L’événement open est distribué lorsque le chargement commence.
• L’événement ioError ou securityError est distribué s’il est impossible de charger le fichier ou s’il se produit une erreur lors du processus de chargement.
• L’événement progress est déclenché continuellement lors du chargement du fichier.
• L’événement complete est distribué lorsque le chargement d’un fichier est terminé, mais avant la mise à disposition des méthodes et des propriétés du clip qui vient d’être chargé.
• L’événement init est distribué après la mise à disposition des méthodes et des propriétés du fichier SWF chargé, afin de vous permettre de commencer à manipuler ce dernier. Cet événement est distribué avant le gestionnaire complete. Dans les fichiers SWF en diffusion continue, l’événement init risque de se produire bien avant l’événement complete. Dans la plupart des cas, utilisez le gestionnaire init.

Remarques (pour iOS uniquement) : dans les applications AIR sur iOS, vous ne pouvez charger un fichier SWF contenant du code ActionScript qu’à partir du package de l’application. Cette restriction inclut tous les scripts ActionScript, tels que les actifs comportant des noms de classe exportés pour ActionScript. Pour charger un fichier SWF, vous devez utiliser le même domaine d’application que le fichier SWF parent.

Dans les versions antérieures à AIR 3.6, seuls les fichiers ne contenant aucun bytecode ActionScript peuvent être chargés, que ce soit à partir d’un package d’application ou d’un réseau. Pour éviter l’utilisation d’un fichier SWF externe avec ActionScript, créez une bibliothèque SWC et associez-la à votre SWF principal.

Ces restrictions ne s’appliquent pas lorsqu’une application est en cours d’exécution dans le simulateur iOS (ipa-test-interpreter-simulator ou ipa-debug-interpreter-simulator) ou en mode interpréteur (ipa-test-interpreter ou ipa-debug-interpreter).

Eléments de l’API associés

Annule une opération associée à la méthode load() qui est en cours d’exécution pour l’occurrence de Loader.

Eléments de l’API associés

Charge un fichier SWF, JPEG, JPEG progressif, GIF non animé ou PNG dans un objet enfant de l’objet Loader. Si vous chargez un fichier GIF animé, seule la première image est affichée. Puisque l’objet Loader ne peut contenir qu’un seul enfant, générer une nouvelle requête load() met fin à la requête précédente si elle est en attente et démarre un autre chargement.

Remarque : dans AIR 1.5 et Flash Player 10, la taille maximale d’une image chargée est de 8 191 pixels en largeur ou en hauteur, et le nombre total de pixels ne peut pas excéder 16 777 215 pixels (ainsi, si la largeur d’une image chargée est de 8 191 pixels, sa hauteur maximale doit être de 2 048 pixels). Dans Flash Player 9 et les versions antérieures, ainsi que dans AIR 1.1 et les versions antérieures, la limite est de 2 880 pixels de haut sur 2 880 pixels de large.

Un fichier SWF ou une image chargé(e) dans un objet Loader hérite des propriétés position, rotation et scale (échelle) des objets d’affichage parent de l’objet Loader.

Utilisez unload() pour supprimer des animations ou des images chargées à l’aide de cette méthode ou pour annuler une opération de chargement en cours.

Vous pouvez empêcher un fichier SWF d’utiliser cette méthode en définissant le paramètre allowNetworking des balises object et embed dans la page HTML qui comporte le contenu SWF.

Remarques iOS

Dans les applications AIR sur iOS, vous ne pouvez charger un fichier SWF contenant du code ActionScript qu’à partir du package de l’application. Cette restriction inclut tous les scripts ActionScript, tels que les actifs comportant des noms de classe exportés pour ActionScript. Pour charger un fichier SWF, vous devez utiliser le même domaine d’application que le fichier SWF parent, comme illustré dans l’exemple suivant :

     var loader:Loader = new Loader();
     var url:URLRequest = new URLRequest("swfs/SecondarySwf.swf");
     var loaderContext:LoaderContext = new LoaderContext(false, ApplicationDomain.currentDomain, null);
     loader.load(url, loaderContext);

En outre, iOS ne vous permet pas de charger un fichier SWF contenant du code ActionScript ByteCode (ABC), puis de le décharger et le recharger. Si vous essayez cette opération, le moteur d’exécution renvoie une erreur 3764.

Dans les versions antérieures à AIR 3.6, seuls les fichiers ne contenant aucun bytecode ActionScript peuvent être chargés, que ce soit à partir d’un package d’application ou d’un réseau. Pour éviter l’utilisation d’un fichier SWF externe avec ActionScript, créez une bibliothèque SWC et associez-la à votre SWF principal.

Ces restrictions ne s’appliquent pas lorsqu’une application est en cours d’exécution dans le simulateur iOS (ipa-test-interpreter-simulator ou ipa-debug-interpreter-simulator) ou en mode interpréteur (ipa-test-interpreter ou ipa-debug-interpreter).

Sécurité de l’objet Loader

Si vous utilisez cette méthode, tenez compte du modèle de sécurité de Flash Player, expliqué dans la description de la classe Loader.

Dans Flash Player versions 10 et ultérieures, si vous utilisez un Content-Type en plusieurs parties (par exemple « multipart/form-data ») qui contient un chargement (indiqué par un paramètre « filename » dans un en-tête « content-disposition » au sein du corps POST), l’opération POST est soumise aux règles de sécurité appliquées aux chargements :

• L’opération POST doit être effectuée en réponse à l’action d’un utilisateur, comme un clic de souris ou la pression d’une touche.
• Si l’opération POST se fait entre plusieurs domaines (la cible POST ne se trouve pas sur le même serveur que le fichier SWF qui envoie la demande POST), le serveur cible doit fournir un fichier de régulation d’URL qui permette l’accès interdomaines.

Par ailleurs, la syntaxe de tous les Content-Type en plusieurs parties doit être correcte (selon la norme RFC2046). Si la syntaxe s’avère incorrecte, l’opération POST est soumise aux règles de sécurité appliquées aux chargements.

Pour plus d’informations concernant la sécurité, voir la rubrique du Pôle de développement Flash Player : Sécurité (disponible en anglais uniquement).

Paramètres

Plus d’exemples

Informations complémentaires

Eléments de l’API associés

Charge des données binaires stockées dans un objet ByteArray.

La méthode loadBytes() est asynchrone. Vous devez attendre l’événement « init » avant d’accéder aux propriétés d’un objet chargé.

Si vous utilisez cette méthode, tenez compte du modèle de sécurité de Flash Player, expliqué dans la description de la classe Loader.

Remarque (pour iOS uniquement) : dans les applications AIR sur iOS, vous ne pouvez charger un fichier SWF contenant du code ActionScript qu’à partir du package de l’application. Cette restriction inclut tous les scripts ActionScript, tels que les actifs comportant des noms de classe exportés pour ActionScript. Pour charger un fichier SWF, vous devez utiliser le même domaine d’application que le fichier SWF parent.

Dans les versions antérieures à AIR 3.6, l’appel de cette méthode n’a aucun effet sur iOS.

Paramètres

Informations complémentaires

Eléments de l’API associés

Charge une occurrence d’IFilePromise.

La méthode loadFilePromise prend un objet IFilePromise et charge les données binaires. Si les données sont un flux progressif, par exemple une vidéo, attendez les événements "init" ou progress avant d’accéder aux propriétés de l’objet chargé. Dans le cas contraire, attendez l’événement complete pour vous assurer que les données sont entièrement chargées.

Si vous utilisez cette méthode, tenez compte du modèle de sécurité de Flash Player, expliqué dans la description de la classe Loader.

Paramètres

Eléments de l’API associés

Supprime un enfant de l’objet Loader chargé à l’aide de la méthode load(). La valeur property de la propriéténull de l’objet LoaderInfo associé est réinitialisée. L’enfant n’est pas nécessairement détruit, car d’autres objets risquent de s’y référer. Il n’est cependant plus un enfant de l’objet Loader.

Lorsque vous appelez la méthode unload(), la propriété contentLoaderInfo de l’objet Loader est définie sur null. Tous les actifs visuels qui ont été chargés avec le fichier SWF ont été déchargés de la mémoire. Les définitions de classe ActionScript dans le fichier SWF chargé restent en mémoire et le code se trouvant dans le même domaine d’application que le SWF chargé peut accéder aux occurrences de ces classes et créer de nouvelles occurrences.

Remarque (iOS uniquement) : dans les versions antérieures à AIR 3.6, cette méthode n’a aucun effet sur iOS.

Avant de décharger un fichier SWF enfant, il est recommandé de fermer explicitement tout flux continu dans les objets enfant du fichier SWF, tels que les objets LocalConnection, NetConnection, NetStream et Sound. Si vous n’effectuez pas cette opération, la lecture de l’audio risque de continuer dans le fichier SWF enfant, bien que ce dernier soit déchargé. Pour fermer les flux continus dans le fichier SWF enfant, ajoutez un écouteur d’événement à l’enfant qui écoute l’événement unload. Lorsque le parent appelle Loader.unload(), l’événement unload est distribué à l’enfant. L’exemple suivant illustre cette opération :

function closeAllStreams(evt:Event) { 
    myNetStream.close();
    mySound.close();
    myNetConnection.close();
    myLocalConnection.close();
}

myMovieClip.loaderInfo.addEventListener(Event.UNLOAD, closeAllStreams);

Eléments de l’API associés

Tente de décharger le contenu du fichier SWF enfant et interrompt l’exécution des commandes des fichiers SWF chargés. Cette méthode tente de décharger les fichiers SWF qui ont été chargés à l’aide de la méthode Loader.load() ou Loader.loadBytes() en supprimant les références aux objets EventDispatcher, NetConnection, Timer, Sound ou Video du fichier SWF enfant. Par conséquent, les actions suivantes sont effectuées dans le fichier SWF enfant et la liste d’affichage du fichier SWF enfant :

• Les sons sont arrêtés.
• Les écouteurs d’événement sont supprimés de la scène.
• Les écouteurs d’événement des événements enterFrame, frameConstructed, exitFrame, activate et deactivate sont supprimés.
• Les horloges sont arrêtées.
• Les occurrences Camera et Microphone sont détachées.
• Les clips sont arrêtés.

Lorsque vous appelez la méthode unloadAndStop(), la propriété contentLoaderInfo de l’objet Loader est définie sur null. Tous les actifs visuels qui ont été chargés avec le fichier SWF ont été déchargés de la mémoire. Les définitions de classe ActionScript dans le fichier SWF chargé restent en mémoire et le code se trouvant dans le même domaine d’application que le SWF chargé peut accéder aux occurrences de ces classes et créer de nouvelles occurrences.

Remarque (pour iOS uniquement) : dans les versions antérieures à AIR 3.6, cette méthode n’a aucun effet sur iOS.

Paramètres

Eléments de l’API associés

1. Une propriété url est créée pour désigner l’emplacement et le nom du fichier d’image.
2. Dans le constructeur LoaderExample, un nouvel objet Loader appelé loader est créé, qui est ensuite transmis à la méthode configureListeners(), décrite à l’étape 3.
3. Le constructeur crée une occurrence d’objet URLRequest, request, et transmet le paramètre url de façon à identifier le nom de fichier et son emplacement.
4. L’objet request est ensuite transmis à la méthode load() de l’objet loader, qui charge l’image dans la liste d’affichage.
5. Un écouteur d’événement clickHandler est enregistré pour l’événement click sur l’objet loader. Lorsque l’utilisateur clique avec la souris, l’image chargée est déchargée.
6. La méthode configureListeners() ajoute sept écouteurs d’événement à l’aide des méthodes suivantes :
   • La méthode completeHandler() s’exécute lorsque l’image termine son chargement.
   • La méthode httpStatusHandler() s’exécute lorsque l’image n’est pas chargée de façon locale et uniquement lorsque la requête réseau est rendue disponible et lorsque Flash Player peut la détecter.
   • La méthode initHandler() s’exécute avant la méthode completeHandler() et après la méthode progressHandler(). En général, l’événement init est plus utile lors du chargement des fichiers SWF.
   • La méthode ioErrorHandler() s’exécute si le fichier d’image n’est pas disponible ou n’est pas accessible.
   • La méthode openHandler() s’exécute lorsque le fichier d’image est ouvert en premier.
   • La méthode progressHandler() s’exécute lorsque le fichier d’image commence son chargement et s’exécute de nouveau à la fin de cette procédure.
   • La méthode unLoadHandler() s’exécute lorsque l’image est déchargée à l’aide de la méthode unload() lorsque l’utilisateur clique sur l’image.

N’oubliez pas les spécifications suivantes :

• Cet exemple implique le placement d’un fichier appelé Image.gif dans le même répertoire que le fichier SWF compilé. Utilisez une image dont la zone corresponde aux dimensions du fichier SWF principal.
• Cet exemple couvre tous les événements disponibles pour l’objet LoaderInfo. Cependant, la plupart des situations n’en nécessite qu’un sous-ensemble. En particulier, lors du chargement d’un fichier d’image unique, l’événement complete (voire l’événement ioError) suffisent lors du chargement d’une image locale.

package {
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderExample() {
            var loader:Loader = new Loader();
            configureListeners(loader.contentLoaderInfo);
            loader.addEventListener(MouseEvent.CLICK, clickHandler);

            var request:URLRequest = new URLRequest(url);
            loader.load(request);

            addChild(loader);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(Event.INIT, initHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(Event.UNLOAD, unLoadHandler);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function initHandler(event:Event):void {
            trace("initHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler: bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function unLoadHandler(event:Event):void {
            trace("unLoadHandler: " + event);
        }

        private function clickHandler(event:MouseEvent):void {
            trace("clickHandler: " + event);
            var loader:Loader = Loader(event.target);
            loader.unload();
        }
    }
}