URLLoader  - AS3

Indique le nombre d’octets chargés jusqu’ici au cours du chargement.

Indique le nombre total d’octets dans les données téléchargées. Cette propriété contient 0 lorsque le chargement est en cours et est renseignée au terme de ce dernier. Egalement, si un en-tête Content-Length est manquant, bytesTotal sera indéterminé.

Données reçues par le biais de l’opération de chargement. Cette propriété n’est renseignée qu’à la fin du chargement. Le format des données varie en fonction du paramétrage de la propriété dataFormat :

Si la propriété dataFormat est URLLoaderDataFormat.TEXT, les données reçues représentent une chaîne qui contient le texte du fichier chargé.

Si la propriété dataFormat est URLLoaderDataFormat.BINARY, les données reçues représentent un objet ByteArray qui contient des données binaires brutes.

Si la propriété dataFormat est URLLoaderDataFormat.VARIABLES, les données reçues représentent un objet URLVariables qui contient des variables d’URL codées.

Eléments de l’API associés

//params.txt is a local file that includes: firstName=Tom&lastName=Jones
var lbl:TextField = new TextField();
var urlRequest:URLRequest = new URLRequest("params.txt");
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.VARIABLES;
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    lbl.text = urlLoader.data.lastName + "," + urlLoader.data.firstName;
    addChild(lbl);
}

Contrôle si les données téléchargées sont reçues sous forme de texte (URLLoaderDataFormat.TEXT), de données binaires brutes (URLLoaderDataFormat.BINARY) ou de variables d’URL codées (URLLoaderDataFormat.VARIABLES).

Si la valeur de la propriété dataFormat est URLLoaderDataFormat.TEXT, les données reçues représentent une chaîne qui contient le texte du fichier chargé.

Si la valeur de la propriété dataFormat est URLLoaderDataFormat.BINARY, les données reçues représentent un objet ByteArray qui contient les données binaires brutes.

Si la valeur de la propriété dataFormat est URLLoaderDataFormat.VARIABLES, les données reçues représentent un objet URLVariables qui contient les variables d’URL codées.

La valeur par défaut est URLLoaderDataFormat.TEXT.

Eléments de l’API associés

var PATH:String = "lorem.txt";
var urlRequest:URLRequest = new URLRequest(PATH);
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.TEXT; // default
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    textArea.text = urlLoader.data;
}

Crée un objet URLLoader.

Eléments de l’API associés

Enregistre un objet écouteur d’événement auprès d’un objet EventDispatcher afin que l’écouteur soit averti d’un événement. Vous pouvez enregistrer les écouteurs d’événement dans tous les nœuds de la liste d’affichage pour un type spécifique d’événement, de phase et de priorité.

Après l’enregistrement d’un écouteur d’événement, vous ne pouvez plus modifier sa priorité par d’autres appels de addEventListener(). Pour modifier la priorité d’un écouteur, vous devez d’abord appeler removeListener(). Vous pouvez ensuite réenregistrer l’écouteur avec le nouveau niveau de priorité.

N’oubliez pas qu’une fois l’écouteur enregistré, tous les prochains appels de addEventListener() avec une valeur type ou useCapture différente entraîneront la création d’un autre enregistrement d’écouteur. Si, par exemple, vous enregistrez un écouteur dans lequel la propriété useCapture est définie sur true, il écoute uniquement pendant la phase de capture. Si vous appelez addEventListener() à l’aide du même objet écouteur, mais en définissant useCapture sur false, vous obtenez deux écouteurs distincts : l’un qui écoute pendant la phase de capture et l’autre qui écoute pendant les phases cible et de propagation vers le haut (bubbling).

Il est impossible d’enregistrer un écouteur d’événement uniquement pour la phase cible ou la phase de propagation vers le haut. Ces deux phases sont associées pendant l’enregistrement car la propagation vers le haut s’applique uniquement aux ancêtres du nœud cible.

Si vous n’avez plus besoin d’un écouteur d’événements, supprimez-le en appelant removeEventListener(), afin d’éviter tout problème de mémoire. Les écouteurs d’événement ne sont pas automatiquement supprimés de la mémoire, car le nettoyeur de mémoire ne supprime pas l’écouteur tant que l’objet de distribution existe (à moins que le paramètre useWeakReference ne soit défini sur true).

Lors de la copie d’une occurrence d’EventDispatcher, les écouteurs d’événement qui lui sont associés ne sont pas pris en compte (si le nouveau nœud nécessite un écouteur d’événement, vous devez associer celui-ci après la création du nœud). Toutefois, si vous déplacez une occurrence d’EventDispatcher, les écouteurs d’événement qui lui sont associés la suivent.

Si un écouteur d’événement est enregistré sur un nœud alors qu’un événement est en cours de traitement sur ce nœud, l’écouteur n’est pas déclenché pendant la phase actuelle, mais il peut l’être pendant une phase ultérieure du flux d’événements, telle que la phase de propagation vers le haut (bubbling).

Si un écouteur d’événement est supprimé d’un nœud sur lequel un événement est en cours de traitement, il est cependant déclenché par les actions en cours. Une fois supprimé, l’écouteur d’événement n’est plus jamais appelé (à moins d’être réenregistré à des fins de traitement ultérieur).

Paramètres

function(evt:Event):void

Ferme l’opération de chargement en cours. Toute opération de chargement en cours prend immédiatement fin. Si aucune URL n’est en cours de transmission, une erreur de flux non valide est renvoyée.

Envoie et charge les données à partir de l’URL spécifiée. Les données peuvent être reçues sous forme de texte, de données binaires brutes ou de variables d’URL codées, selon la valeur définie pour la propriété dataFormat. Vous remarquerez que la valeur par défaut de la propriété dataFormat correspond à text. Si vous souhaitez envoyer des données à l’URL spécifiée, définissez la propriété data dans l’objet URLRequest.

Remarque : si un fichier en cours de chargement contient des caractères non-ASCII (comme dans les langues autres que l’anglais), nous vous recommandons d’enregistrer le fichier avec codage UTF-8 ou UTF-16, plutôt que sous un format non-Unicode, ASCII par exemple.

Un fichier SWF du sandbox local avec système de fichiers risque de ne pas charger des données depuis une ressource située dans le sandbox réseau, ni lui en fournir.

Par défaut, le fichier SWF appelant et l’URL chargée doivent se trouver dans le même domaine. Par exemple, un fichier SWF à l’adresse www.adobe.com peut charger uniquement des données provenant de sources situées aussi à l’adresse www.adobe.com. Pour charger des données à partir d’un autre domaine, placez un fichier de régulation d’URL sur le serveur hébergeant les données.

Vous ne pouvez pas vous connecter aux ports généralement réservés. Pour obtenir une liste complète des ports bloqués, voir la rubrique « Restriction des API de réseau » dans le Guide du développeur d’ActionScript 3.0.

Dans Flash Player versions 10 et ultérieures, si vous utilisez un Content-Type en plusieurs parties (par exemple « multipart/form-data ») qui contient un chargement (indiqué par un paramètre « filename » dans un en-tête « content-disposition » au sein du corps POST), l’opération POST est soumise aux règles de sécurité appliquées aux chargements :

• L’opération POST doit être effectuée en réponse à l’action d’un utilisateur, comme un clic de souris ou la pression d’une touche.
• Si l’opération POST se fait entre plusieurs domaines (la cible POST ne se trouve pas sur le même serveur que le fichier SWF qui envoie la demande POST), le serveur cible doit fournir un fichier de régulation d’URL qui permette l’accès interdomaines.

Par ailleurs, la syntaxe de tous les Content-Type en plusieurs parties doit être correcte (selon la norme RFC2046). Si la syntaxe s’avère incorrecte, l’opération POST est soumise aux règles de sécurité appliquées aux chargements.

Pour plus d’informations concernant la sécurité, voir la rubrique du Pôle de développement Flash Player : Sécurité (disponible en anglais uniquement).

Paramètres

Informations complémentaires

Eléments de l’API associés

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.xml.*;
    import flash.events.IOErrorEvent;
  
    public class URLLoader_loadExample extends Sprite {
        private var xmlTextField:TextField = new TextField();
        private var externalXML:XML;    
        private var loader:URLLoader;

        public function URLLoader_loadExample() {
            var request:URLRequest = new URLRequest("xmlFile.xml");

            loader = new URLLoader();
            
            try {
                loader.load(request);
            }
            catch (error:SecurityError)
            {
                trace("A SecurityError has occurred.");
            }

             loader.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            loader.addEventListener(Event.COMPLETE, loaderCompleteHandler);

            xmlTextField.x = 10;
            xmlTextField.y = 10;
            xmlTextField.background = true;
            xmlTextField.autoSize = TextFieldAutoSize.LEFT;

            addChild(xmlTextField);
        }

        private function loaderCompleteHandler(event:Event):void {

                try {
                    externalXML = new XML(loader.data);
                    readNodes(externalXML);    
                } catch (e:TypeError) {
                    trace("Could not parse the XML file.");
                }
        }

        private function readNodes(node:XML):void {

                for each (var element:XML in node.elements()) {
                    xmlTextField.appendText(element.attributes()[0] + "\n");

                    readNodes(element);
                }    
        }

        private function errorHandler(e:IOErrorEvent):void {
            xmlTextField.text = "Had problem loading the XML File.";
        }
    }
}

Distribué après le décodage de toutes les données reçues et leur placement dans la propriété data de l’objet URLLoader. Il est possible d’accéder aux données reçues une fois cet événement distribué.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Distribué si un appel de la méthode load() tente d’accéder aux données via HTTP, et si Adobe AIR est capable de détecter et de renvoyer le code d’état de la requête.

La constante HTTPStatusEvent.HTTP_RESPONSE_STATUS définit la valeur de la propriété type d’un objet événement httpResponseStatus.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Distribué si un appel de la méthode URLLoader.load() tente d’accéder aux données via HTTP. Dans le cas de contenu s’exécutant dans Flash Player, cet événement n’est distribué que si l’environnement Flash Player actif est capable de détecter et de renvoyer le code d’état de la requête (certains environnements de navigateur ne sont pas capables de fournir cette information). Vous remarquerez que l’événement httpStatus (le cas échéant) est envoyé avant (et en complément de) tout événement complete ou error.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Distribué si un appel de la méthode URLLoader.load() provoque une erreur fatale qui met fin au téléchargement.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Distribué lorsque l’opération de téléchargement commence suite à un appel de la méthode URLLoader.load().

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Distribué à la réception des données au fur et à mesure du téléchargement.

Notez qu’avec un objet URLLoader, il est impossible d’accéder aux données avant la fin de leur téléchargement. L’événement progress indique donc uniquement la progression du téléchargement. Pour accéder aux données avant la fin de leur téléchargement, utilisez un objet URLStream.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Distribué si un appel de la méthode URLLoader.load() tente de charger des données d’un serveur en dehors d’un sandbox de sécurité. Egalement distribué si un appel de la méthode URLLoader.load() tente de charger un fichier SWZ, si le certificat n’est pas valide ou si la chaîne digest ne correspond pas au composant.

Les propriétés de cet événement sont les suivantes :

Eléments de l’API associés

Remarque : pour exécuter cet exemple, placez un fichier nommé urlLoaderExample.txt dans le même répertoire que votre fichier SWF. Ce fichier ne doit contenir que la ligne de texte suivante : answer=42&question=unknown

Le code de l’exemple effectue les opérations suivantes :

1. La fonction constructeur crée une occurrence d’URLLoader nommée loader et une occurrence d’URLRequest nommée request, qui contient l’emplacement et le nom du fichier à charger.
2. L’objet loader est transmis à la méthode configureListeners(), qui ajoute des écouteurs à chacun des événements URLLoader pris en charge.
3. L’objet request est ensuite transmis à la méthode loader.load(), qui charge le fichier texte.
4. Lorsque l’URLLoader a terminé de chargé le fichier texte, l’événement Event.COMPLETE se produit et déclenche la méthode completeHandler(). La méthode completeHandler() crée un objet URLVariables à partir du texte chargé depuis le fichier. L’objet URLVariables convertit les paires nom/valeur d’URL codées en propriétés ActionScript pour faciliter la manipulation des données chargées.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLLoaderExample extends Sprite {
        
        private loader:URLoader;
        public function URLLoaderExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("urlLoaderExample.txt");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
    
            var vars:URLVariables = new URLVariables(loader.data);
            trace("The answer is " + vars.answer);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}