NumericStepper  - AS3 Flash

Récupère ou définit une valeur indiquant si le composant peut accepter une interaction de l’utilisateur. La valeur true indique que le composant peut accepter une interaction de l’utilisateur ; la valeur false indique qu’il ne le peut pas.

Si vous définissez la propriété enabled sur false, la couleur du conteneur est grisée et la saisie de l’utilisateur est bloquée (sauf pour les composants Label et ProgressBar).

La valeur par défaut est true.

Lit ou définit le mode de l’éditeur de méthode d’entrée (IME). L’IME permet aux utilisateur d’utiliser un clavier AZERTY pour saisir des caractères chinois, japonais ou coréens.

Flash définit l’IME sur le mode spécifié lorsque le composant obtient le focus et restaure sa valeur d’origine lorsque ce composant perd le focus.

La classe flash.system.IMEConversionMode définit des constantes pour les valeurs possibles de cette propriété. Définissez cette propriété sur null pour empêcher l’utilisation de l’éditeur IME avec le composant.

Lit ou définit la valeur maximale de la séquence de valeurs numériques.

La valeur par défaut est 10.

Lit ou définit la valeur minimale de la séquence de valeurs numériques.

La valeur par défaut est 0.

Lit la valeur suivante dans la séquence de valeurs.

Lit la valeur précédente dans la séquence de valeurs.

Récupère ou définit un nombre non nul qui décrit l’unité de modification entre les différentes valeurs. La propriété value est un multiple de ce nombre moins le minimum. Le composant NumericStepper arrondit la valeur résultante à la taille la plus proche.

La valeur par défaut est 1.

Lit une référence au composant TextInput contenu dans le composant NumericStepper. Utilisez cette propriété pour accéder au composant TextInput sous-jacent et le manipuler. Par exemple, vous pouvez utiliser cette propriété pour modifier la sélection actuelle de la zone de texte ou pour restreindre les caractères acceptés par cette dernière.

Lit ou définit la valeur actuelle du composant NumericStepper.

La valeur par défaut est 1.

Crée une nouvelle occurrence du composant NumericStepper.

Affiche ou masque l’indicateur de focus dans ce composant.

La classe UIComponent implémente cette méthode en créant et en positionnant une occurrence de la classe spécifiée par le style focusSkin.

Paramètres

Récupère la texture de style par défaut du composant actif. La texture de style contient le type adapté au composant, qui dépend du style utilisé par ce dernier. Par exemple, le style disabledTextFormat contient la valeur null ou un objet TextFormat. Vous pouvez utiliser ces styles et appeler setStyle() pour le composant actif. Le code suivant ignore le style par défaut disabledTextFormat dans le composant spécifié :

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Eléments de l’API associés

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Attribue le focus à l’occurrence de composant.

Distribué lorsque l’utilisateur change la valeur du composant NumericStepper.

Remarque : cet événement n’est pas distribué si vous utilisez du code ActionScript pour modifier la valeur.

Les propriétés de cet événement sont les suivantes :

1. Ajoutez le composant NumericStepper à votre bibliothèque.
2. Enregistrez ce code sous le nom NumericStepperExample.as dans le même répertoire que votre fichier FLA.
3. Dans le fichier FLA, définissez DocumentClass sur NumericStepperExample.

package 
{
    import flash.display.Sprite
    import flash.text.TextField;
    import flash.events.Event;
    import fl.controls.NumericStepper;
    
    public class NumericStepperExample extends Sprite
    {
        private var ns1:NumericStepper;
        private var ns2:NumericStepper;
        private var tf1:TextField;
        private var tf2:TextField;
        private var rowHeight1:Number = 10;
        private var rowHeight2:Number = 50;
        
        public function NumericStepperExample() {        
            setupSteppers();
            setupTextFields();
        }
        private function setupTextFields():void {
            tf1 = new TextField();
            tf1.text = "This stepper increments by 1 between 0 and 5. Disables if it reaches 0.";
            tf1.autoSize = "left";
            tf1.x = 100;
            tf1.y = rowHeight1;
            addChild(tf1);
            
            tf2 = new TextField();
            tf2.text = "This stepper increments by 0.01 between 0 and 20. Disables if it reaches 0.";
            tf2.autoSize = "left";
            tf2.x = 100;
            tf2.y = rowHeight2;
            addChild(tf2);
        }
        private function setupSteppers():void {    
            ns1 = new NumericStepper();
            ns1.stepSize = 1;
            ns1.maximum = 5;
            ns1.minimum = 0;
            ns1.addEventListener(Event.CHANGE,changeOccurred);
            ns1.move(10,rowHeight1);
            addChild(ns1);

            ns2 = new NumericStepper();
            ns2.stepSize = 0.01;
            ns2.maximum = 20;
            ns2.minimum = 0;
            ns2.value = 10;
            ns2.addEventListener(Event.CHANGE,changeOccurred);
            ns2.move(10,rowHeight2);
            addChild(ns2);
        }
        private function changeOccurred(e:Event):void {
            var nsTarget:NumericStepper = e.target as NumericStepper;
            if(nsTarget.value == 0) nsTarget.enabled = false;
        }
    }
}