UIComponent  - AS3 Flash

Obtém ou define um valor que indica se o componente pode aceitar a interação do usuário. O valor true indica que o componente pode aceitar interação do usuário; o valor false indica que ele não pode aceitar.

Se você definir a propriedade enabled como false, a cor do contêiner ficará esmaecia e a entrada do usuário será bloqueada (com exceção dos componentes Label e ProgressBar).

O valor padrão é true.

Obtém ou define um valor booliano que indica se o componente pode receber foco depois que o usuário clicar nele. O valor true indica que ele pode receber foco; o valor false indica que ele não pode receber.

Se esta propriedade for false, o foco será transferido ao primeiro pai cuja propriedade mouseFocusEnabled esteja definida como true.

O valor padrão é true.

Elementos da API relacionados

Obtém ou define o FocusManager que controla o foco para este componente e seus semelhantes. Cada componente pop-up mantém seu próprio loop de foco e ocorrência FocusManager. Use esta propriedade para acessar o FocusManager correto para este componente.

Obtém ou define a altura do componente, em pixels.

Definir esta propriedade faz com que um evento resize seja despachado. Consulte o evento resize para obter informações detalhadas sobre quando ele é despachado.

Se a propriedade scaleY do componente não for 1.0, a altura do componente que é obtido das coordenadas internas não corresponderá ao valor da altura das coordenadas pai. Por exemplo, um componente com uma largura de 100 pixels e scaleY de 2 tem o valor de 100 pixels no pai, mas armazena internamente um valor indicando que a altura é de 50 pixels.

Obtém ou define um valor que indica se o componente pode receber foco depois que o usuário clicar nele. O valor true indica que ele pode receber foco; o valor false indica que ele não pode receber.

Se esta propriedade for false, o foco será transferido ao primeiro pai cuja propriedade mouseFocusEnabled esteja definida como true.

O valor padrão é true.

Elementos da API relacionados

Multiplica a largura atual do componente por um fator escalar.

Elementos da API relacionados

Multiplica a altura atual do componente por um fator escalar.

Elementos da API relacionados

Obtém ou define um valor que indica se a ocorrência do componente atual é visível. O valor true indica que a barra indeterminada é visível; o valor false indica que ela não é visível.

Quando esta propriedade é definida como true, o objeto despacha um evento show. Quando esta propriedade é definida como false, o objeto despacha um evento hide. Em qualquer um dos casos, os filhos de um objeto não geram um evento show ou hide, a não ser que o objeto grave uma implementação específica para que isso seja feito.

O valor padrão é true.

Elementos da API relacionados

Obtém ou define a largura do componente, em pixels.

Definir esta propriedade faz com que um evento resize seja despachado. Consulte o evento resize para obter informações detalhadas sobre quando ele é despachado.

Se a propriedade scaleX do componente não for 1.0, a largura do componente que é obtido das coordenadas internas não corresponderá ao valor da largura das coordenadas pai. Por exemplo, um componente com uma largura de 100 pixels e scaleX de 2 tem o valor de 100 pixels no pai, mas armazena internamente um valor indicando que a largura é de 50 pixels.

Elementos da API relacionados

Obtém ou define a coordenada x que representa a posição do componente ao longo do eixo x em seu contêiner-pai. Este valor é descrito em pixels e é calculado da esquerda para a direita.

Definir esta propriedade faz com que o evento ComponentEvent.MOVE seja despachado.

O valor padrão é 0.

Elementos da API relacionados

Obtém ou define a coordenada y que representa a posição do componente ao longo do eixo y em seu contêiner-pai. Este valor é descrito em pixels e é calculado de cima para baixo.

Definir esta propriedade faz com que o evento move seja despachado.

Elementos da API relacionados

Cria uma nova ocorrência do componente UIComponent.

Exclui uma propriedade de estilo desta ocorrência do componente.

Isto não faz com que o método getStyle() retorne necessariamente um valor undefined.

Parâmetros

Elementos da API relacionados

Mostra ou oculta o indicador de foco neste componente.

A classe UIComponent implementa este método criando e posicionando uma ocorrência da classe que é especificada pelo estilo focusSkin.

Parâmetros

Inicia uma operação imediata de desenho, sem invalidar nada como faz invalidateNow.

Recupera o objeto que possui foco no momento.

Observe que este método não retorna necessariamente o componente que possui foco. Ele pode retornar o subcomponente interno do componente que possui foco. Para obter o componente que possui foco, utilize a propriedade focusManager.focus.

Recupera uma propriedade de estilo definida na cadeia de pesquisa de estilo do componente.

O tipo retornado por este método varia de acordo com a propriedade de estilo que o método recupera. Os tipos possíveis incluem Boolean; String; Number; int; uint para uma cor RGB; Class para uma capa ou qualquer tipo de objeto.

Se você chamar este método para recuperar uma propriedade de estilo particular, ele será de um tipo conhecido que você pode armazenar em uma variável do mesmo tipo. Não é necessário projetar o tipo. Basta uma simples instrução de atribuição como a seguir:

var backgroundColor:uint = getStyle("backgroundColor");

Se a propriedade de estilo não for definida na cadeia de pesquisa de estilo, este método retornará o valor undefined. Observe que undefined é um valor específico que não é igual a false, "", NaN, 0 ou null. O valor de um estilo válido nunca é undefined. Você pode usar o método estático StyleManager.isValidStyleValue() para testar se um valor foi definido.

Parâmetros

Elementos da API relacionados

import fl.controls.ComboBox;
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var myComboBox:ComboBox = new ComboBox();
myComboBox.setStyle("textPadding", 6);
myComboBox.setStyle("disabledAlpha", 0.8);

var styleObject:Object = ComboBox.getStyleDefinition();
var styleDP:DataProvider = new DataProvider();
var styleName:String;
var styleDefaultValue:String;
var styleCurrentValue:String;

for (styleName in styleObject) {
    styleDefaultValue = String(styleObject[styleName]);
    styleCurrentValue = String(myComboBox.getStyle(styleName));
    styleDP.addItem({name:styleName, defaultValue:styleDefaultValue, currentValue:styleCurrentValue});
}
styleDP.sortOn("name", Array.CASEINSENSITIVE);

var c1:DataGridColumn = new DataGridColumn("name");
c1.headerText = "Style name:";
var c2:DataGridColumn = new DataGridColumn("defaultValue");
c2.headerText = "Default style value:";
var c3:DataGridColumn = new DataGridColumn("currentValue");
c3.headerText = "Current style value:"

var styleDataGrid:DataGrid = new DataGrid();
styleDataGrid.addColumn(c1); // name
styleDataGrid.addColumn(c2); // defaultValue
styleDataGrid.addColumn(c3); // currentValue
styleDataGrid.dataProvider = styleDP;
styleDataGrid.setSize(stage.stageWidth - 20, stage.stageHeight - 20);
styleDataGrid.move(10, 10);
addChild(styleDataGrid);

Recupera o mapa de estilos padrão do componente atual. O mapa de estilos contém o tipo que é apropriado para o componente, de acordo com o estilo que o componente usa. Por exemplo, o estilo disabledTextFormat contém o valor null ou um objeto TextFormat. Você pode usar estes estilos e chamar setStyle() no componente atual. O código a seguir substitui o estilo disabledTextFormat padrão no componente especificado:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Elementos da API relacionados

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Retorna o estilo especificado para um componente, considerando todos os estilos definidos nos níveis global, de componente e de ocorrência.

Por exemplo, se um componente tiver um estilo definido no nível global como myStyle e você chamar getStyle("myStyle") em uma ocorrência que não tenha uma definição de ocorrência, retornará null. Se você chamar getStyleValue("myStyle"), ele retornará "myStyle", pois está ativo no nível global.

Parâmetros

Marca uma propriedade como inválida e redesenha o componente no quadro seguinte, a não ser que especificado de outra forma.

Parâmetros

Mescla os estilos de várias classes em um objeto. Se um estilo for definido em vários objetos, a primeira ocorrência encontrada será utilizada.

Parâmetros

Move o componente até a posição especificada em seu pai. O efeito é o mesmo de quando se altera o local do componente definindo suas propriedades x e y. Chamar este método dispara o evento ComponentEvent.MOVE a ser exibido.

Para substituir o método updateDisplayList() em um componente personalizado, utilize o método move() em vez de definir as propriedades x e y. Isso ocorre porque chamar o método move() faz com que um objeto de evento move seja despachado imediatamente após a operação de movimento ser concluída. Por outro lado, quando você altera o local do componente definindo as propriedades x e y, o objeto de evento é despachado na próxima atualização da tela.

Parâmetros

Elementos da API relacionados

Define o foco para este componente. O componente pode, sucessivamente, passar o foco para um subcomponente.

Observação: apenas os componentes TextInput e TextArea mostram um indicador de foco quando este método define o foco. Todos os componentes mostram um indicador de foco quando o usuário especifica o componente.

Define o componente para a largura e altura especificadas.

Parâmetros

Define uma propriedade de estilo nesta ocorrência do componente. Este estilo pode substituir um estilo definido globalmente.

Chamar este método pode reduzir o desempenho. Utilize-o apenas quando necessário.

Parâmetros

Elementos da API relacionados

import fl.controls.Button;

var myFormat:TextFormat = new TextFormat();
myFormat.font = "Georgia";

var b:Button = new Button();
b.label = "Hello World";
b.setStyle("textFormat", myFormat);
addChild(b);

import fl.controls.Button;

var flashIcon:Loader = new Loader();
flashIcon.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
flashIcon.load(new URLRequest("http://www.helpexamples.com/flash/images/logo.png"));

var myButton:Button = new Button();
myButton.label = "Flash";
myButton.move(10, 10);
addChild(myButton);

function completeHandler(event:Event):void {
    flashIcon.width = 16;
    flashIcon.height = 16;
    myButton.setStyle("icon", flashIcon);
}

Valida e atualiza as propriedades e o layout deste objeto, redesenhando-o se necessário.

As propriedades que exigem cálculo substancial normalmente não são processadas até o script terminar de ser executado. Isso ocorre porque a definição de uma propriedade pode exigir o processamento de outras propriedades. Por exemplo, a definição da propriedade width pode exigir que as larguras dos filhos ou pai do objeto também sejam recalculadas. E se o script recalcular a largura do objeto mais de uma vez, estas propriedades interdependentes também poderão exigir um novo cálculo. Use este método para substituir manualmente este comportamento.

Despachado depois que a visibilidade do componente muda de visível para invisível.

Esse evento tem as seguintes propriedades:

import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

Elementos da API relacionados

Despachado após a movimentação do componente.

Esse evento tem as seguintes propriedades:

import fl.controls.Slider;
import fl.containers.UILoader;
import fl.events.ComponentEvent;
import fl.events.SliderEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
myUILoader.move(10, 20); 
myUILoader.addEventListener(ComponentEvent.MOVE, moveHandler);
addChild(myUILoader);

var mySlider:Slider = new Slider();
mySlider.liveDragging = true;
mySlider.minimum = myUILoader.x;
mySlider.maximum = myUILoader.x + 200;
mySlider.snapInterval = 1;
mySlider.tickInterval = 10;
mySlider.move(10, 10);
mySlider.addEventListener(SliderEvent.CHANGE, changeHandler);
addChild(mySlider);

function changeHandler(event:SliderEvent):void {
    myUILoader.x = event.value;
}

function moveHandler(event:ComponentEvent):void {
    trace("[move] x:" + event.currentTarget.x + ", y:" + event.currentTarget.y);
}

Despachado após o redimensionamento do componente.

Esse evento tem as seguintes propriedades:

import fl.containers.UILoader;
import fl.events.ComponentEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.scaleContent = false;
myUILoader.addEventListener(ComponentEvent.RESIZE, resizeHandler);
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
addChild(myUILoader);

function resizeHandler(event:ComponentEvent):void {
    var myImg:UILoader = event.currentTarget as UILoader;
    var newX:uint = (stage.stageWidth - myImg.width) / 2;
    var newY:uint = (stage.stageHeight - myImg.height) / 2;
    myImg.move(newX, newY);
}

Despachado depois que a visibilidade do componente muda de invisível para visível.

Esse evento tem as seguintes propriedades:

import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

Elementos da API relacionados

O número de versão dos componentes.

import fl.controls.CheckBox;

var myCheckBox:CheckBox = new CheckBox();
trace(myCheckBox.version);