String  - AS3

Um inteiro que especifica o número de caracteres no objeto String especificado.

Como todos os índices de string são baseados em zero, o índice do último caractere de qualquer string x é x.length - 1.

Cria um novo objeto String inicializado para a string especificada.

Nota: a menos que haja um forte motivo, use literais de string ao invés de objetos String, pois as literais carregam menos o sistema e geralmente são mais fáceis de usar.

Retorna o caractere na posição especificada pelo parâmetro index. Se index não for um número de 0 a string.length - 1, uma string vazia será retornada.

Esse método é semelhante a String.charCodeAt(), exceto pelo fato de que o valor retornado é um caractere e não um código de caractere de inteiro de 16 bits.

Parâmetros

Elementos da API relacionados

Retorna o código de caractere Unicode numérico do caractere no index especificado. Se index não for um número de 0 a string.length - 1, NaN será retornado.

Esse método é semelhante a String.charAt(), exceto pelo fato de que o valor retornado é um código de caractere de inteiro de 16 bits e não o número real.

Parâmetros

Elementos da API relacionados

Acrescenta os argumentos fornecidos ao final do objeto String, convertendo-os em strings se necessário, e retorna a string resultante. O valor original do objeto String de origem permanece inalterado.

Parâmetros

Retorna uma string que compreende os caracteres representados pelos códigos de caracteres Unicode nos parâmetros.

Parâmetros

Pesquisa a string e retorna a posição da primeira ocorrência de val encontrada em ou após startIndex na string de chamada. Esse índice é baseado em zero, significando que o primeiro caractere em uma string é considerado como estando no índice 0 e não no índice 1. Se val não for encontrado, o método retornará -1.

Parâmetros

Elementos da API relacionados

Pesquisa a string da direita para a esquerda e retorna o índice da última ocorrência de val encontrada antes de startIndex. O índice é baseado em zero, significando que o primeiro caractere está no índice 0 e o último, em string.length - 1. Se val não for encontrado, o método retornará -1.

Parâmetros

Elementos da API relacionados

Compara a ordem de classificação de duas ou mais strings e retorna o resultado da comparação como um inteiro. Embora esse método sirva para manipular a comparação de forma específica para cada caso, a implementação ActionScript 3.0 não gera um resultado diferente de outras comparações de string, como os operadores de igualdade (==) ou desigualdade (!=). Se as strings forem equivalentes, o valor de retorno será 0. Se o valor de string original preceder o valor de string especificado por other, o valor de retorno será um inteiro negativo cujo valor absoluto representa o número de caracteres que separa os dois valores de string. Se o valor de string original vier depois de other, o valor de retorno será um inteiro positivo cujo valor absoluto representa o número de caracteres que separa os dois valores de string.

Parâmetros

Corresponde o pattern especificado com base na string.

Parâmetros

Elementos da API relacionados

Corresponde o pattern especificado com base na string e retorna uma nova string na qual a primeira correspondência de pattern é substituída pelo conteúdo especificado por repl. O parâmetro pattern pode ser uma string ou uma expressão regular. O parâmetro repl pode ser uma string ou uma função; se for uma função, a string retornada pela função é inserida no lugar da correspondência. A string original não é modificada.

No exemplo a seguir, apenas a primeira ocorrência de "sh" (com distinção entre maiúsculas e minúsculas) é substituída:

    var myPattern:RegExp = /sh/;  
    var str:String = "She sells seashells by the seashore.";
    trace(str.replace(myPattern, "sch"));  
       // She sells seaschells by the seashore.

No exemplo a seguir, todas as ocorrências de "sh" (com distinção entre maiúsculas e minúsculas) são substituídas porque o sinalizador g (global) está definido na expressão regular.

    var myPattern:RegExp = /sh/g;  
    var str:String = "She sells seashells by the seashore.";
    trace(str.replace(myPattern, "sch"));  
       // She sells seaschells by the seaschore.

No exemplo a seguir, todas as ocorrências de "sh" são substituídas porque o sinalizador g (global) está definido na expressão regular e as correspondências não fazem distinção entre maiúsculas e minúsculas porque o sinalizador i (ignoreCase) está definido.

    var myPattern:RegExp = /sh/gi;  
    var str:String = "She sells seashells by the seashore.";
    trace(str.replace(myPattern, "sch"));  
       // sche sells seaschells by the seaschore.

Parâmetros

var str:String = "flip-flop";
    var pattern:RegExp = /(\w+)-(\w+)/g;
    trace(str.replace(pattern, "$2-$1")); // flop-flip

    var str1:String = "abc12 def34";
    var pattern:RegExp = /([a-z]+)([0-9]+)/;
    var str2:String = str1.replace(pattern, replFN);
    trace (str2);   // 12abc 34def
    
    function replFN():String {
      return arguments[2] + arguments[1];
    }

    {"abc12", "abc", "12", 0, "abc12 def34"}

    {"def34", "def", "34", 6, "abc123 def34"}

Elementos da API relacionados

Procura o pattern especificado e retorna o índice da primeira substring correspondente. Se não houver substring correspondente, o método retornará -1.

Parâmetros

Elementos da API relacionados

Retorna uma string que inclui o caractere de startIndex e todos os caracteres até, mas não incluindo, o caractere de startIndex. O objeto String original não é modificado. Se o parâmetro endIndex não for especificado, o final da substring será também o final da string. Se o caractere indexado por startIndex for igual ou à direita do caractere indexado por endIndex, o método retornará uma string vazia.

Parâmetros

Elementos da API relacionados

Divide um objeto String em uma matriz de substrings, dividindo-se sempre que o parâmetro delimiter especificado ocorrer.

Se o parâmetro delimiter for uma expressão regular, apenas a primeira correspondência em uma determinada posição da string será considerada, mesmo que a operação de retrocesso pudesse localizar uma correspondência de substring não vazia nessa posição. Por exemplo:

     var str:String = "ab";
     var results:Array = str.split(/a*?/); // results == ["","b"]
     
     results = str.split(/a*/); // results == ["","b"].)

Se o parâmetro delimiter for uma expressão regular contendo parênteses de agrupamento, sempre que o delimiter for correspondido, os resultados (incluindo qualquer resultado indefinido) desses parênteses de agrupamento serão unidos na matriz de saída. Por exemplo

     var str:String = "Thi5 is a tricky-66 example.";
     var re:RegExp = /(\d+)/;
     var results:Array = str.split(re);
         // results == ["Thi","5"," is a tricky-","66"," example."]

Se o parâmetro limit for especificado, a matriz retornada não terá mais do que o número especificado de elementos.

Se o delimiter for uma string vazia, uma expressão regular vazia ou uma expressão regular que possa corresponder uma string vazia, cada caractere da string será processado como um elemento na matriz.

Se o parâmetro delimiter for indefinido, a string inteira será inserida no primeiro elemento da matriz retornada.

Parâmetros

Elementos da API relacionados

Retorna uma substring que consiste nos caracteres que começam no startIndex especificado e com um comprimento especificado por com. A string original não é modificada.

Parâmetros

Retorna uma string que consiste no caractere especificado por startIndex e todos os caracteres até endIndex - 1. Se endIndex não for especificado, String.length será usado. Se o valor de startIndex for igual ao valor de endIndex, o método retornará uma string vazia. Se o valor de startIndex for maior do que o valor de endIndex, os parâmetros serão automaticamente alternados antes que a função seja executada. A string original não é modificada.

Parâmetros

Retorna uma cópia desta string, com todos os caracteres em maiúsculas convertidos em minúsculas. A string original não é modificada. Embora este método sirva para manipular a conversão de forma específica para cada caso, a implementação ActionScript 3.0 não gera um resultado diferente do método toLowerCase().

Elementos da API relacionados

Retorna uma cópia desta string, com todos os caracteres em minúsculas convertidos em maiúsculas. A string original não é modificada. Embora este método sirva para manipular a conversão de forma específica para cada caso, a implementação ActionScript 3.0 não gera um resultado diferente do método toUpperCase().

Elementos da API relacionados

Retorna uma cópia desta string, com todos os caracteres em maiúsculas convertidos em minúsculas. A string original não é modificada.

Esse método converte todos os caracteres (e não simplesmente A-Z) para os quais existem equivalentes Unicode em minúsculas:

     var str:String = " JOSÉ BARÇA";
     trace(str.toLowerCase()); // josé barça

Estes mapeamentos de caixa são definidos na especificação do Banco de dados de Caractere de Unicode.

Elementos da API relacionados

Retorna uma cópia desta string, com todos os caracteres em minúsculas convertidos em maiúsculas. A string original não é modificada.

Este método converte todos os caracteres (e não simplesmente a-z) para os quais existem equivalentes Unicode em maiúsculas:

     var str:String = "José Barça";
     trace(str.toUpperCase()); // JOSÉ BARÇA

Estes mapeamentos de caixa são definidos na especificação do Banco de dados de Caractere de Unicode.

Elementos da API relacionados

Retorna o valor primitivo da ocorrência de String. Esse método foi desenvolvido para converter um objeto String em um valor de string primitivo. Como os tempos de execução do Flash chama valueOf() automaticamente quando necessário, raramente você precisará chamar esse método explicitamente.

1. O construtor para StringExample declara várias ocorrências locais de String, que são inicializadas com várias strings e um novo objeto StringHelper.
2. A classe StringHelper tem os seguintes métodos:
   • replace(): chama os métodos split() e join() de String para remover uma substring da string transmitida com uma nova.
   • trim(): chama trimBack() e trimFront() usando as strings transmitidas e retorna a string atualizada.
   • trimFront(): remove recursivamente todos os caracteres que correspondem ao parâmetro char, começando pela frente da string e seguindo em direção ao fim, até que o primeiro caractere na string não corresponda a char, e retorna a string atualizada.
   • trimBack(): remove recursivamente todos os caracteres que correspondem ao parâmetro char, começando pelo fim da string e seguindo em regressão, até que o último caractere na string não corresponda a char, e retorna a string atualizada.
   • stringToCharacter(): retorna o primeiro caractere da string a ele transmitida.
3. Três strings são então geradas com o uso das variáveis de string declaradas, com uma chamada ao método replace() usada para gerar a segunda string e trim() para gerar a terceira string.

package {
    import flash.display.Sprite;

    public class StringExample extends Sprite {
        public function StringExample() {
            var companyStr:String = new String("     Company X");
            var productStr:String = "Product Z Basic     ";
            var emptyStr:String = " ";
            var strHelper:StringHelper = new StringHelper();

            var companyProductStr:String = companyStr + emptyStr + productStr;
            trace("'" + companyProductStr + "'");    // '     Company X Product Z Basic     '

            companyProductStr = strHelper.replace(companyProductStr, "Basic", "Professional");
            trace("'" + companyProductStr + "'");    // '     Company X Product Z Professional     '

            companyProductStr = strHelper.trim(companyProductStr, emptyStr);
            trace("'" + companyProductStr + "'");    // 'Company X Product Z Professional'
        }
    }
}

class StringHelper {
    public function StringHelper() {
    }

    public function replace(str:String, oldSubStr:String, newSubStr:String):String {
        return str.split(oldSubStr).join(newSubStr);
    }

    public function trim(str:String, char:String):String {
        return trimBack(trimFront(str, char), char);
    }

    public function trimFront(str:String, char:String):String {
        char = stringToCharacter(char);
        if (str.charAt(0) == char) {
            str = trimFront(str.substring(1), char);
        }
        return str;
    }

    public function trimBack(str:String, char:String):String {
        char = stringToCharacter(char);
        if (str.charAt(str.length - 1) == char) {
            str = trimBack(str.substring(0, str.length - 1), char);
        }
        return str;
    }

    public function stringToCharacter(str:String):String {
        if (str.length == 1) {
            return str;
        }
        return str.slice(0, 1);
    }
}