LoaderInfo  - AS3

A versão ActionScript do arquivo SWF carregado. A versão de linguagem é especificada com o uso das enumerações na classe ActionScriptVersion, como ActionScriptVersion.ACTIONSCRIPT2 e ActionScriptVersion.ACTIONSCRIPT3.

Observação: Essa propriedade sempre tem um valor de ActionScriptVersion.ACTIONSCRIPT2 ou ActionScriptVersion.ACTIONSCRIPT3. O ActionScript 1.0 e o 2.0 são ambos reportados como ActionScriptVersion.ACTIONSCRIPT2 (versão 2.0). Essa propriedade somente diferencia o ActionScript 1.0 e o 2.0 do ActionScript 3.0.

Elementos da API relacionados

Quando um arquivo SWF externo é carregado, todas as definições do ActionScript 3.0 contidas na classe carregada são armazenadas na propriedade applicationDomain.

Todo código em um arquivo SWF é definido para estar presente em um domínio de aplicativo. O domínio de aplicativo atual é onde seu aplicativo principal é executado. O domínio do sistema contém todos os domínios de aplicativo, incluindo o domínio atual e todas as classes usadas pelo Flash Player ou Adobe AIR.

Todos os domínios de aplicativo, exceto o domínio de sistema, têm um domínio-pai associado. O domínio-pai de applicationDomain do seu aplicativo principal é o domínio de sistema. As classes carregadas só são definidas quando o pai ainda não as definiu. Você não pode substituir uma definição de classe loaded por uma definição mais recente.

Para exemplos de uso de domínios de aplicativo, consulte o capítulo "Ambiente do sistema cliente" em Guia do Desenvolvedor do ActionScript 3.0.

Elementos da API relacionados

Os bytes associados a um objeto LoaderInfo.

O número de bytes carregados para a mídia. Quando esse número equivaler ao valor de bytesTotal, todos os bytes estarão carregados.

O número de bytes compactados no arquivo de mídia inteiro.

Antes que o primeiro evento progress seja despachado pelo objeto Loader correspondente deste objeto LoaderInfo, bytesTotal é 0. Após o primeiro evento progress a partir do objeto Loader, bytesTotal refletirá o número real de bytes a serem baixados.

Observação (apenas iOS): ao executar um aplicativo no iOS, o valor retornado não é o mesmo que nas outras plataformas.

Elementos da API relacionados

Expressa o relacionamento de confiança do conteúdo (filho) com Loader (pai). Se o filho tiver permitido o acesso do pai, true; caso contrário, false. Essa propriedade será definida como true se o objeto-filho tiver chamado o método allowDomain() para conceder permissão ao domínio do pai ou se uma diretiva de URL estiver carregada no domínio do filho, concedendo permissão ao domínio do pai. Se um filho e um pai estiverem no mesmo domínio, essa propriedade será definida como true.

Para obter mais informações relacionadas à segurança, consulte o tópico do Centro dos desenvolvedores do Flash Player Security.

Um objeto que pode ser definido pelo código do conteúdo carregado para expor propriedades e métodos que possam ser acessados pelo código na área de segurança do objeto Loader. Esta sandbox bridge permite que o conteúdo de um domínio de não aplicativo tenha acesso controlado aos scripts na área de segurança do aplicativo e vice-versa. A ponte de área de segurança de conteúdo serve como um gateway entre as caixas de proteção de segurança, oferecendo interação explícita entre as caixas de proteção de segurança de aplicativo e não aplicativo.

Elementos da API relacionados

O objeto carregado associado a este objeto LoaderInfo.

O tipo MIME do arquivo carregado. O valor será null se uma parte insuficiente do arquivo tiver sido carregada para determinar o tipo. A lista a seguir fornecer os valores possíveis:

• "application/x-shockwave-flash"
• "image/jpeg"
• "image/gif"
• "image/png"

A velocidade de projeção nominal, em quadros por segundo, do arquivo SWF carregado. Esse número costuma ser um inteiro, mas isso não é necessário.

Esse valor pode diferir da velocidade de projeção real em uso. O Flash Player ou o Adobe AIR usa somente uma taxa de quadros para todos os arquivos SWF carregados a qualquer momento, e essa taxa de quadros é determinada pela taxa de quadros nominal do arquivo SWF principal. Além disso, talvez a taxa de quadros principal não possa ser alcançada, dependendo do hardware, da sincronização de som e de outros fatores.

A altura nominal do arquivo carregado. Esse valor pode diferir da altura real na qual o conteúdo é exibido, já que o conteúdo carregado ou seus objetos de exibição-pai podem estar dimensionados.

Indica se a propriedade LoaderInfo.url foi truncada. Quando o isURLInaccessible o valor é verdadeiro o LoaderInfo.url o valor é apenas o domínio do URL final do qual o conteúdo carregou. Por exemplo, a propriedade será truncada se o conteúdo for carregado de http://www.adobe.com/assets/hello.swf e a propriedade LoaderInfo.url tiver o valor http://www.adobe.com . O valor isURLInaccessible é true somente quando todos os seguintes também são true:

• Um redirecionameno de HTTP ocorreu ao carregar o conteúdo.
• O arquivo SWF que está chamando Loader.load() é de um domínio diferente do domínio do URL final do conteúdo.
• O arquivo SWF que está chamando Loader.load() não tem permissão para acessar o conteúdo. A permissão é dada para acessar o conteúdo da mesma forma que permissão é dada para BitmapData.draw() : invoque Security.allowDomain() para acessar um arquivo SWF (ou, para o conteúdo de um arquivo que não seja SWF, estabeleça um arquivo de política e use a propriedade LoaderContext.checkPolicyFile ).

Observação: A propriedade isURLInaccessible foi adicionada para o Flash Player 10.1 e o AIR 2.0. Contudo, esta propriedade está disponível para arquivos SWF de todas as versões quando o tempo de execução do Flash a suporta. Desta maneira, usar algumas ferramentas de autoria no "modo estrito" causa um erro de compilação. Para trabalhar em retorna do erro usam a sintaxe indireta myLoaderInfo ("isURLInaccessible") , ou desativam o modo estrito. Se você estiver usando Flash Professional CS5 ou Flex SDK 4.1, você pode usar e compilar este API para tempos de execução lançados antes do Flash Player 10.1 e AIR 2.

Para conteúdo de aplicativo no AIR, o valor desta propriedade é sempre false.

Elementos da API relacionados

O objeto Loader associado a este objeto LoaderInfo. Se esse objeto this for a propriedade loaderInfo da ocorrência da classe principal do arquivo SWF, nenhum objeto Loader será associado.

A URL do arquivo SWF que iniciou o carregamento da mídia descrita por este objeto LoaderInfo. Para a instância da classe principal do arquivo SWF, essa URL é igual à URL do própria arquivo SWF.

Um objeto que contém pares de nome e valor que representam os parâmetros fornecidos ao arquivo SWF carregado.

Você pode usar uma repetição for-in para extrair todos os nomes e valores do objeto parameters.

As duas origens de parâmetros são: As duas origens de parâmetros são: a string de consulta na URL do arquivo SWF principal e o valor do parâmetro HTML FlashVars (isso afeta apenas o arquivo SWF principal).

A propriedade parameters substitui a técnica do ActionScript 1.0 e 2.0 de fornecer parâmetros de arquivo SWF como propriedades da linha do tempo principal.

O valor da propriedade parameters é nulo para objetos Loader que contêm arquivos SWF que usam o ActionScript 1.0 ou 2.0. Ele apenas é não nulo para objetos Loader que contêm arquivos SWF que usam o ActionScript 3.0.

Expressa o relacionamento de confiança de Loader (pai) com o conteúdo (filho). Se o pai tiver permitido o acesso do filho, true; caso contrário, false. Essa propriedade será definida como true se o objeto-pai tiver chamado o método allowDomain() para conceder permissão ao domínio do filho ou se um arquivo de diretivas de URL estiver carregado no domínio do pai, concedendo permissão ao domínio do filho. Se um filho e um pai estiverem no mesmo domínio, essa propriedade será definida como true.

Para obter mais informações relacionadas à segurança, consulte o tópico do Centro dos desenvolvedores do Flash Player Security.

Um objeto pode ser definido pelo código na área de segurança do objeto Loader para expor propriedades e métodos que possam ser acessados pelo código do conteúdo carregado. Esta sandbox bridge permite que o conteúdo de um domínio de não aplicativo tenha acesso controlado aos scripts na área de segurança do aplicativo e vice-versa. A ponte de área de segurança de conteúdo serve como um gateway entre as caixas de proteção de segurança, oferecendo interação explícita entre as caixas de proteção de segurança de aplicativo e não aplicativo.

Elementos da API relacionados

Expressa o relacionamento de domínio entre o carregador e o conteúdo: true se tiverem os mesmo domínio de origem; false caso contrário.

Uma ocorrência de EventDispatcher que pode ser usada para trocar eventos entre limites de segurança. Mesmo quando o objeto Loader e o conteúdo carregado se originam de domínios de segurança que não confiam um no outro, ambos podem acessar o sharedEvents e enviar e receber eventos por meio deste objeto.

A versão de formato de arquivo do arquivo SWF carregado. O formato de arquivo é especificado com o uso das enumerações na classe SWFVersion, como SWFVersion.FLASH7 e SWFVersion.FLASH9.

Elementos da API relacionados

Um objeto que despacha um evento uncaughtError quando um erro não controlado ocorre no código no arquivo SWF deste objeto LoaderInfo. Um erro não capturado acontece quando um erro é lançado fora de qualquer try..catch ou quando um objeto ErrorEvent é despachado sem ouvintes registrados.

Por exemplo: se, em um bloco try, há um distribuidor de eventos que chama o manipulador de eventos, o bloco catch não identifica o erro caso seja inserido no manipulador de eventos. Qualquer erro inserido depois disso poderá ser identificado em LoaderInfo.uncaughtErrorEvents

Esta propriedade é criada quando o SWF associado a este LoaderInfo terminar de carregar. Até lá, a propriedade uncaughtErrorEvents é null. Em um projeto somente para ActionScript, você pode acessar esta propriedade durante ou depois da execução da função do construtor da classe principal no arquivo SWF. Para um projeto de Flex, a propriedade uncaughtErrorEvents está disponível depois que o evento applicationComplete é despachado.

Elementos da API relacionados

package
{
    import flash.display.Sprite;
    import flash.events.ErrorEvent;
    import flash.events.MouseEvent;
    import flash.events.UncaughtErrorEvent;

    public class UncaughtErrorEventExample extends Sprite
    {
        public function UncaughtErrorEventExample()
        {
            loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
            
            drawUI();
        }
        
        private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
        {
            if (event.error is Error)
            {
                var error:Error = event.error as Error;
                // do something with the error
            }
            else if (event.error is ErrorEvent)
            {
                var errorEvent:ErrorEvent = event.error as ErrorEvent;
                // do something with the error
            }
            else
            {
                // a non-Error, non-ErrorEvent type was thrown and uncaught
            }
        }
        
        private function drawUI():void
        {
            var btn:Sprite = new Sprite();
            btn.graphics.clear();
            btn.graphics.beginFill(0xFFCC00);
            btn.graphics.drawRect(0, 0, 100, 50);
            btn.graphics.endFill();
            addChild(btn);
            btn.addEventListener(MouseEvent.CLICK, clickHandler);
        }
        
        private function clickHandler(event:MouseEvent):void
        {
            throw new Error("Gak!");
        }
    }
}

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
                       xmlns:s="library://ns.adobe.com/flex/spark" 
                       xmlns:mx="library://ns.adobe.com/flex/halo"
                       applicationComplete="applicationCompleteHandler();">
    
    <fx:Script>
        <![CDATA[
            import flash.events.ErrorEvent;
            import flash.events.MouseEvent;
            import flash.events.UncaughtErrorEvent;
            
            private function applicationCompleteHandler():void
            {
                loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
            }
    
            private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
            {
                if (event.error is Error)
                {
                    var error:Error = event.error as Error;
                    // do something with the error
                }
                else if (event.error is ErrorEvent)
                {
                    var errorEvent:ErrorEvent = event.error as ErrorEvent;
                    // do something with the error
                }
                else
                {
                    // a non-Error, non-ErrorEvent type was thrown and uncaught
                }
            }
            
            private function clickHandler(event:MouseEvent):void
            {
                throw new Error("Gak!");
            }
        ]]>
    </fx:Script>
      
    <s:Button label="Cause Error" click="clickHandler(event);"/>
</s:WindowedApplication>

A URL da mídia que está sendo carregada.

Antes que o evento progress seja despachado pelo objeto Loader correspondente do objeto LoaderInfo, o valor da propriedade url pode refletir apenas a URL inicial especificada na chamada ao método load() do objeto Loader. Após o primeiro evento progress, a propriedade url reflete a URL final da mídia, após a resolução de redirecionamentos e URLs relativas.

Em alguns casos, o valor da propriedade url é truncado; consulte a propriedade isURLInaccessible para obter detalhes.

Elementos da API relacionados

A largura nominal do conteúdo carregado. Esse valor pode diferir da largura real na qual o conteúdo é exibido, já que o conteúdo carregado ou seus objetos de exibição-pai podem estar dimensionados.

Retorna o objeto LoaderInfo associado a um arquivo SWF definido como um objeto.

Parâmetros

Despachado quando os dados foram carregados com êxito. Em outras palavras, ele será despachado quando todo o conteúdo tiver sido baixado e o carregamento estiver finalizado. O evento complete é sempre despachado após o evento init. O evento init é despachado quando o objeto está pronto para acesso, embora o conteúdo ainda esteja sendo baixado.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado quando uma solicitação de rede for feita em HTTP e um código de status HTTP puder ser detectado.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado quando as propriedades e os métodos de um arquivo SWF carregado estão acessíveis e prontos para uso. O conteúdo, entretanto, ainda pode estar sendo baixado. Um objeto LoaderInfo despacha o evento init quando existem as seguintes condições:

• Todas as propriedades e métodos associados ao objeto carregado e ao objeto LoaderInfo estão acessíveis.
• Os construtores para todos os objetos-filho foram concluídos.
• Todos os códigos ActionScript do primeiro quadro da linha de tempo principal do SWF carregado foram executados.

Por exemplo, um Event.INIT é despachado quando o primeiro quadro de um filme ou animação é carregado. O filme fica acessível e pode ser adicionado à lista de exibição. No entanto, o filme completo pode levar mais tempo para ser baixado. O Event.COMPLETE é despachado somente quando o filme todo está carregado.

O evento init sempre precede o evento complete.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado quando ocorre um erro de entrada ou saída que resulta na falha de uma operação de carregamento.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado quando uma operação de carregamento é iniciada.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado quando os dados são recebidos ao longo do progresso da operação de download.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado por um objeto LoaderInfo sempre que um objeto carregado é removido com o uso do método unload() do objeto Loader ou quando um segundo carregamento é realizado pelo mesmo objeto Loader e o conteúdo original é removido antes do início do carregamento.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

1. Uma propriedade url é criada, representando a localização e o nome da imagem.
2. O construtor da classe cria um objeto Loader denominado loader.
3. O objeto loader instancia um ouvinte de evento para garantir que a imagem seja carregada corretamente.
4. O construtor cria uma nova ocorrência de um objeto URLRequest, request, com a url transmitida para que o nome e a localização do arquivo sejam conhecidos.
5. O objeto request é transmitido ao método load() do objeto loader, que carrega a imagem na lista de exibição.

Importante: Esse exemplo requer que um arquivo denominado Image.gif seja inserido no mesmo diretório que o arquivo SWF compilado. Use uma imagem com uma área que se encaixe nas dimensões do arquivo SWF principal.

package {
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderInfoExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderInfoExample() {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.INIT, initHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            var request:URLRequest = new URLRequest(url);
            loader.load(request);
            addChild(loader);
        }

        private function initHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var info:LoaderInfo = LoaderInfo(loader.contentLoaderInfo);
            trace("initHandler: loaderURL=" + info.loaderURL + " url=" + info.url);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}