ProgressEvent  - AS3

O número de itens ou bytes carregados no momento em que o ouvinte processa o evento.

O número total de itens ou bytes que serão carregados se o processo de carregamento for bem-sucedido. Se o evento de progresso for despachado/anexado a um objeto Socket, bytesTotal será sempre 0 a menos que um valor seja especificado no parâmetro bytesTotal do construtor. O número real de bytes despachados para trás ou para frente não é definido e é para o desenvolvedor de aplicativos.

Cria um objeto Event que contém informações sobre eventos progress. Objetos Event são transmitidos como parâmetros para ouvintes de eventos.

Cria uma copia de um objeto ProgressEvent e define o valor de cada propriedade para corresponder ao valor do original.

Retorna uma string que contém todas as propriedades do objeto ProgressEvent. A string está no seguinte formato:

[ProgressEvent type=value bubbles=value cancelable=value bytesLoaded=value bytesTotal=value]

Define o valor da propriedade type de um objeto de evento progress.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Define o valor da propriedade type de um objeto de evento socketData.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Define o valor da propriedade type de um objeto de evento standardErrorData.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Define o valor da propriedade type de um objeto de evento standardInputProgress.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Define o valor da propriedade type de um objeto de evento standardOutputData.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

1. As propriedades downloadURL e fileName são criadas, o que indica o local e o nome do arquivo de download.
2. No construtor ProgressEventExample, um novo objeto FileReference de nome file é criado e transferido para o método configureOuvintes().
3. As propriedades downloadURL e fileName são então transferidas para o file.download(), que solicita o local para baixar o arquivo.
4. O método configureOuvintes() adiciona sete ouvintes de evento e os métodos de assinante associados:
   1. cancel/cancelHandler() será despachado se o download de arquivo for cancelado.
   2. complete/complereHandler() será despachado quando o processo de download de arquivo for concluído.
   3. ioError/ioErrorHandler() será despachado se o arquivo de download estiver indisponível ou inacessível.
   4. open/openHandler() será despachado quando a operação de download tiver iniciado.
   5. progress/progressHandler() será despachado quando o processo de download iniciar e novamente quando ele terminar.
   6. securityError/securityErrorHandler será despachado se a configuração de segurança de reprodução local não corresponder ao tipo de acesso de dados para o arquivo de download (local versus rede); consulte as notas a seguir.
   7. select/selectHandler() será despachado quando o objeto download for selecionado.

Observações:

• Você precisa compilar o arquivo SWF com Segurança de reprodução local definida para Acessar somente arquivos de rede.
• Este exemplo requer um arquivo de nome SomeFile.pdf.
• Embora este exemplo faça uso de todos os eventos disponíveis para o objeto FileReference, a maioria das situações requer apenas um subconjunto.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class ProgressEventExample extends Sprite {
        private var downloadURL:String = "http://www.[yourDomain].com/SomeFile.pdf";
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function ProgressEventExample() {
            var request:URLRequest = new URLRequest(downloadURL);
            file = new FileReference();
            configureListeners(file);
            file.download(request, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL);
        }
    }
}