Sound  - AS3

Retorna o número atualmente disponível de bytes neste objeto de som. Geralmente, essa propriedade é útil somente para arquivos carregados externamente.

Retorna o número total de bytes neste objeto de som.

Fornece acesso aos metadados que fazem parte de um arquivo MP3.

Os arquivos de som MP3 podem conter marcas ID3, que fornece metadados sobre o arquivo. Caso um som MP3 que você carregar com o método Sound.load() contiver marcas ID3, você pode pesquisar essas propriedades. Apenas as marcas ID3, que usam o conjunto de caracteres UTF-8, recebem suporte.

O Flash Player 9 e posterior e o AIR oferecem suporte a marcas ID3 2.0, especialmente 2.3 e 2.4. As tabelas a seguir listam as marcas ID3 2.0 padrão e o tipo de conteúdo que elas representam. A propriedade Sound.id3 fornece acesso a essas marcas através do formato my_sound.id3.COMM, my_sound.id3.TIME e assim por diante. A primeira tabela descreve as marcas que podem ser acessadas através do nome da propriedade ID3 2.0 ou do nome da propriedade ActionScript. A segunda tabela descreve as marcas ID3 que recebem suporte, mas não têm propriedade predefinidas no ActionScript.

A tabela a seguir descreve as marcas ID3 suportadas, mas que não têm propriedades pré-definidas na classe Sound. Você as acessa chamando mySound.id3.TFLT, mySound.id3.TIME e assim por diante. NOTA: Nenhuma destas tags é suportada no Flash Lite 4.

Ao usar essa propriedade, considere o modelo de segurança do Flash Player:

• A propriedade id3 de um objeto Sound é sempre permitida pelos arquivos SWF que estão na mesma sandbox de segurança que o arquivo de som. Para os arquivos em outras sandboxes, há verificações de segurança.
• Ao carregar o som, usando o método load() da classe Sound, você pode especificar um parâmetro context, que é um objeto SoundLoaderContext. Se você define a propriedade checkPolicyFile do objeto SoundLoaderContext como true, o Flash Player verifica se há um arquivo de diretivas de URL no servidor do qual o som é carregado. Se existir um arquivo de diretivas que permita o acesso a partir do domínio do arquivo SWF de carregamento, o arquivo poderá acessar a propriedade id3 do objeto Sound; caso contrário, ele não poderá.

Contudo, no Adobe AIR, o conteúdo na caixa de proteção de segurança application (conteúdo instalado com o Adobe AIR) não é restringido por essas limitações de segurança.

Para obter mais informações relacionadas à segurança, consulte o tópico do Centro dos desenvolvedores do Flash Player Security.

Elementos da API relacionados

package {
    import flash.display.Sprite;
    import flash.media.Sound;
    import flash.net.URLRequest;
    import flash.media.ID3Info;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.Event;

    public class Sound_id3Example extends Sprite {
        private var snd:Sound = new Sound();       
        private var myTextField:TextField = new TextField();

        public function Sound_id3Example() {
            snd.addEventListener(Event.ID3, id3Handler);
            snd.load(new URLRequest("mySound.mp3"));
        }
    
        private function id3Handler(event:Event):void {
            var id3:ID3Info = snd.id3;

            myTextField.autoSize = TextFieldAutoSize.LEFT;
            myTextField.border = true;

            myTextField.appendText("Received ID3 Info: \n");
              
            for (var propName:String in id3) {
                myTextField.appendText(propName + " = " + id3[propName] + "\n");
            }
 
            myTextField.appendText("\n" + "Artist: " + id3.artist + "\n");
            myTextField.appendText("Song name: " + id3.songName + "\n");
            myTextField.appendText("Album: " + id3.album + "\n\n"); 
 
            this.addChild(myTextField);
        }
    }
}

Retorna o estado de buffer dos arquivos MP3 externos. Se o valor for true, qualquer reprodução está suspensa no momento, enquanto o objeto aguarda mais dados.

Indica se a propriedade Sound.url foi truncada. Quando o valor isURLInaccessible o é true o valor Sound.url é apenas o domínio do URL final do qual o som carregou. Por exemplo, a propriedade será truncada se o som for carregado de http://www.adobe.com/assets/hello.mp3 e a propriedade Sound.url tiver o valor http://www.adobe.com.br. O valor isURLInaccessible é true somente quando todos os seguintes também são true:

• Um redirecionamento de HTTP ocorreu ao carregar o arquivo de som.
• A chamada de arquivo SWF Sound.load() é de um domínio diferente do que o URL final do arquivo sólido.
• A chamada de arquivo SWF Sound.load() não tem permissão para acessar o arquivo sólido. A permissão é dada para acessar o arquivo de som da mesma forma que é dada para a propriedade Sound.id3: estabeleça um arquivo de política e use a propriedadeSoundLoaderContext.checkPolicyFile.

Observação: A propriedade isURLInaccessible foi adicionada para o Flash Player 10.1 e o AIR 2.0. Contudo, esta propriedade está disponível para arquivos SWF de todas as versões quando o tempo de execução do Flash a suporta. Desta maneira, usar algumas ferramentas de autoria no "modo estrito" causa um erro de compilação. Para trabalhar em retorna do erro usam a sintaxe indireta mySound ("isURLInaccessible") , ou desativam o modo estrito. Se você estiver usando Flash Professional CS5 ou Flex SDK 4.1, você pode usar e compilar este API para tempos de execução lançados antes do Flash Player 10.1 e AIR 2.

Para conteúdo de aplicativo no AIR, o valor desta propriedade é sempre false.

Elementos da API relacionados

A duração do som atual em milésimos de segundo.

A URL a partir da qual esse som foi carregado. Essa propriedade é aplicável apenas aos objetos Sound que foram carregados usando o método Sound.load(). Para os objetos Sound que estão associados com um ativo de som de uma biblioteca do SWF, o valor da propriedade url é null.

Quando você chama primeiro Sound.load(), a propriedade url inicialmente tem o valor null, pois a URL final ainda não é conhecida. A propriedade url terá um valor não null tão logo seja despachado um evento open do objeto Sound.

A propriedade url contém a URL final e absoluta a partir da qual foi carregado um som. O valor de url é geralmente igual ao valor passado para o parâmetro streamde Sound.load(). No entanto, se você passou uma URL relativa para Sound.load(), o valor da propriedade url vai representar a URL absoluta. Além disso, se a solicitação da URL original foi redirecionada por um servidor HTTP, o valor da propriedade url reflete a URL final a partir da qual o arquivo de som foi realmente baixado. Esse relatório de uma URL final absoluta é equivalente ao comportamento de LoaderInfo.url.

Em alguns casos, o valor da propriedade url é truncado; consulte a propriedade isURLInaccessible para obter detalhes.

Elementos da API relacionados

Cria um novo objeto Sound. Se você passar um objeto URLRequest válido para o construtor Sound, o construtor chama automaticamente a função load() para o objeto Sound. Se você não passar um objeto URLRequest válido para o construtor Sound, você mesmo deve chamar a função load() para o objeto Sound, ou o fluxo não será carregado.

Depois que load() é chamado em um objeto Sound, você não pode carregar mais tarde um arquivo de som diferente naquele objeto Sound. Para carregar um arquivo de som diferente, crie um objeto Sound.

Fecha o fluxo, resultando no encerramento de qualquer download de dados. Não é possível ler dados do fluxo depois que se chama o método close().

 
package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;    
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.errors.IOError;
    import flash.events.IOErrorEvent;

    public class Sound_closeExample extends Sprite {
        private var snd:Sound = new Sound();
        private var button:TextField = new TextField();
        private var req:URLRequest = new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3");
        
        public function Sound_closeExample() {
            button.x = 10;
            button.y = 10;
            button.text = "START";
            button.border = true;
            button.background = true;
            button.selectable = false;
            button.autoSize = TextFieldAutoSize.LEFT;

            button.addEventListener(MouseEvent.CLICK, clickHandler);

            this.addChild(button);
        }

        private function clickHandler(e:MouseEvent):void {

            if(button.text == "START") {

                snd.load(req);
                snd.play();        

                snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);

                button.text = "STOP";
            }
            else if(button.text == "STOP") {
                    
                try {
                    snd.close();
                    button.text = "Wait for loaded stream to finish.";
                }
                catch (error:IOError) {
                    button.text = "Couldn't close stream " + error.message;    
                }
            }
        }
        
        private function errorHandler(event:IOErrorEvent):void {
                button.text = "Couldn't load the file " + event.text;
        }
    }
}

Extrai dados de som brutos de um objeto Sound.

Este método deve ser usado quando você estiver trabalhando com áudio gerado dinamicamente, usando uma função atribuída ao evento sampleData de um objeto Sound diferente. Ou seja, você pode usar esse método para extrair dados de som de um objeto Sound. Em seguida, grave os dados na matriz de bytes que um outro objeto Sound está usando para transmitir áudio dinâmico.

Os dados de áudio são colocados na matriz de bytes de destino, começando na posição atual da matriz de bytes. Os dados de áudio são sempre expostos como 44100 Hz Stereo. O tipo de amostra é um valor de ponto de flutuação de 32 bits que pode ser convertido em número usando a função ByteArray.readFloat().

Parâmetros

Elementos da API relacionados

var sourceSnd:Sound = new Sound();
var outputSnd:Sound = new Sound();
var urlReq:URLRequest = new URLRequest("test.mp3");

sourceSnd.load(urlReq);
sourceSnd.addEventListener(Event.COMPLETE, loaded);

function loaded(event:Event):void
{
    outputSnd.addEventListener(SampleDataEvent.SAMPLE_DATA, processSound);
    outputSnd.play();
}

function processSound(event:SampleDataEvent):void
{
    var bytes:ByteArray = new ByteArray();
    sourceSnd.extract(bytes, 4096);
    event.data.writeBytes(upOctave(bytes));
}

function upOctave(bytes:ByteArray):ByteArray
{
    var returnBytes:ByteArray = new ByteArray();
    bytes.position = 0;
    while(bytes.bytesAvailable > 0)
    {
        returnBytes.writeFloat(bytes.readFloat());
        returnBytes.writeFloat(bytes.readFloat());
        if (bytes.bytesAvailable > 0)
        {
            bytes.position += 8;
        }
    }
    return returnBytes;
}

Inicia o carregamento de um arquivo MP3 externo a partir da URL especificada. Se você fornecer um objeto URLRequest válido ao construtor Sound, o construtor chama Sound.load() para você. Você mesmo só precisa chamar Sound.load() se você não passar um objeto URLRequest válido para o construtor Sound ou passar um valor null.

Depois que load() é chamado em um objeto Sound, você não pode carregar mais tarde um arquivo de som diferente naquele objeto Sound. Para carregar um arquivo de som diferente, crie um objeto Sound.

Ao usar esse método, considere o seguinte modelo de segurança:

• A chamada de Sound.load() não é permitida se a chamada do arquivo encontra-se na caixa de proteção local com sistema de arquivo e o som está na sandbox de rede.
• O acesso da caixa de proteção local confiável ou local com rede exige permissão de um site através de um arquivo de diretivas de URL.
• Não é possível conectar-se às portas normalmente reservadas. Para ver uma lista completa de portas bloqueadas, consulte "Restrição de APIs de rede" no Guia do Desenvolvedor do ActionScript 3.0.
• Você pode impedir o arquivo SWF de usar esse método definindo o parâmetro allowNetworking das tags object e embed na página HTML com o conteúdo SWF.

No Flash Player 10 e posterior, se você usar um Content-Type de partes múltiplas (por exemplo, "multipart/form-data") que contém um upload (indicado por um parâmetro "filename" no cabeçalho "content-disposition" do corpo POST), a operação POST ficará sujeita às regras de segurança aplicadas a uploads:

• A operação POST deverá ser executada em resposta a uma ação iniciada pelo usuário, por exemplo, clique de mouse ou pressionamento de tecla.
• Se a operação POST for entre domínios (se o destino de POST não estiver no mesmo servidor do arquivo SWF que está enviando a solicitação POST), o servidor de destino deverá fornecer um arquivo de diretivas de URL que permita o acesso entre domínios.

Além disso, a sintaxe deverá ser válida (de acordo com os padrões RFC2046) para qualquer Content-Type de partes múltiplas. Se a sintaxe for inválida, a operação POST ficará sujeita às regras de segurança aplicadas a uploads.

No Adobe AIR, o conteúdo na caixa de proteção de segurança application (conteúdo instalado com o aplicativo AIR) não é restringido por essas limitações de segurança.

Para obter mais informações relacionadas à segurança, consulte o tópico do Centro dos desenvolvedores do Flash Player Security.

Parâmetros

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.ProgressEvent;
    import flash.events.IOErrorEvent;
    
    public class Sound_loadExample extends Sprite {
        private var snd:Sound = new Sound();
        private var statusTextField:TextField  = new TextField();

        public function Sound_loadExample(){

            statusTextField.autoSize = TextFieldAutoSize.LEFT;
            var req:URLRequest = new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3");
            
            try {
            snd.load(req);
            
            snd.play();
            }
            catch (err:Error) {
                trace(err.message);
            }
 
            snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            snd.addEventListener(ProgressEvent.PROGRESS, progressHandler);
                     
            this.addChild(statusTextField);
        }
    
        private function progressHandler(event:ProgressEvent):void {
            var loadTime:Number = event.bytesLoaded / event.bytesTotal;
            var LoadPercent:uint = Math.round(100 * loadTime);
              
            statusTextField.text = "Sound file's size in bytes: " + event.bytesTotal + "\n" 
                                 + "Bytes being loaded: " + event.bytesLoaded + "\n" 
                                 + "Percentage of sound file that is loaded " + LoadPercent + "%.\n";
        }
 
        private function errorHandler(errorEvent:IOErrorEvent):void {
            statusTextField.text = "The sound could not be loaded: " + errorEvent.text;
        }
    }
}

carrega dados de áudio MP3 a partir de um objeto ByteArray em um objeto Sound. Os dados serão lidos na posição de ByteArray atual e deixarão a posição ByteArray no fim do comprimento de bytes especificado, após o término. Se os dados de áudio de MP3 contiverem dados ID3, os eventos de ID3 serão despachados durante estas chamadas de função. Essa função irá gerar uma exceção se o objeto ByteArray não contiver dados suficientes.

Parâmetros

Carrega dados de áudio do ponto flutuante PCM de 32 bits de um objeto ByteArray para um objeto Sound. Os dados serão lidos na posição de ByteArray atual e deixarão a posição ByteArray no fim do comprimento de amostra especificado, multiplicado por 1 canal ou por 2 canais, se o sinalizador estéreo for definido, após o término.

A partir do Flash Player 11.8, a quantidade de dados de áudio que podem ser transmitidos para essa função é limitada. Em versões SWF >= 21, essa função lançará uma exceção se a quantidade de dados de áudio transmitidos nessa função for acima de 1800 segundos. Isto é, as amostras / sampleRate deve ser menor ou igual a 1800. Em versões swf < 21, o tempo de execução falha silenciosamente se a quantidade de dados de áudio transmitidos for mais de 12000 segundos. Isso é fornecido somente para compatibilidade retroativa.

Essa função gera uma exceção se o objeto ByteArray não contiver dados suficientes.

Parâmetros

Gera um novo objeto SoundChannel para reproduzir o som. Esse método retorna um objeto SoundChannel, que você acessa para parar o som e monitorar o volume. (Para controlar o volume, o panorama e o equilíbrio, acesse o objeto SoundTransform atribuído ao canal de som.)

Parâmetros

Elementos da API relacionados

 
package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.MouseEvent;
    import flash.media.Sound;;
    import flash.net.URLRequest;
    import flash.media.SoundChannel;
    import flash.events.ProgressEvent;
    import flash.events.Event;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.IOErrorEvent;
    
    public class Sound_playExample1 extends Sprite {
        private var snd:Sound = new Sound();
        private var channel:SoundChannel = new SoundChannel();
        private var infoTextField:TextField = new TextField();
    
        public function Sound_playExample1() {

            var req:URLRequest = new URLRequest("MySound.mp3");
            
            infoTextField.autoSize = TextFieldAutoSize.LEFT;
            infoTextField.text = "Please wait for the file to be loaded.\n" 
                                + "Then select from the bar to decide where the file should start.";
            
            snd.load(req);               
            channel = snd.play();

            snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            snd.addEventListener(Event.COMPLETE, completeHandler);


            this.addChild(infoTextField);
        }

        private function completeHandler(event:Event):void {                
            infoTextField.text = "File is ready.";

            var bar:Sprite = new Sprite();

            bar.graphics.lineStyle(5, 0xFF0000);
            bar.graphics.moveTo(100, 100);
            bar.graphics.lineTo(200, 100);

            bar.addEventListener(MouseEvent.CLICK, clickHandler);

            this.addChild(bar);
        }
    
        private function clickHandler(event:MouseEvent):void {
            
                var position:uint = event.localX;
                var percent:uint = Math.round(position) - 100;   
                var cue:uint = (percent / 100) * snd.length;

                channel.stop();
                channel = snd.play(cue);    
        }

        private function errorHandler(errorEvent:IOErrorEvent):void {
            infoTextField.text = "The sound could not be loaded: " + errorEvent.text;
        }
    }
}

package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.media.Sound;
    import flash.net.URLRequest;

    public class Sound_playExample2 extends Sprite {
        private var button:Sprite = new Sprite(); 
        private var snd:Sound = new Sound();
            
        public function Sound_playExample2() {

            var req:URLRequest = new URLRequest("click.mp3");
            snd.load(req);               
     
            button.graphics.beginFill(0x00FF00);
            button.graphics.drawRect(10, 10, 50, 30);
            button.graphics.endFill();
     
            button.addEventListener(MouseEvent.CLICK, clickHandler);
            button.addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
     
            this.addChild(button);
        }

        private function clickHandler(event:MouseEvent):void {
            snd.play();            
        }

        private function doubleClickHandler(event:MouseEvent):void {
            snd.play(0, 2);        
        }
    }
}

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    
    public class Sound_playExample3 extends Sprite {
        private var snd:Sound = new Sound();
        private var channel:SoundChannel;
        private var statusTextField:TextField  = new TextField();

        public function Sound_playExample3(){

            statusTextField.autoSize = TextFieldAutoSize.LEFT;

           var req:URLRequest = new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3");
            
            try {
                snd.load(req);
            
                channel = snd.play();
            }
            catch (err:Error) {
                trace(err.message);
            }
                    
            snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            addEventListener(Event.ENTER_FRAME, enterFrameHandler);
            channel.addEventListener(Event.SOUND_COMPLETE, soundCompleteHandler);
                    
            this.addChild(statusTextField);
        }
    
        private function enterFrameHandler(event:Event):void {    
            var loadTime:Number = snd.bytesLoaded / snd.bytesTotal;
            var loadPercent:uint = Math.round(100 * loadTime);
            var estimatedLength:int = Math.ceil(snd.length / (loadTime));
            var playbackPercent:uint = Math.round(100 * (channel.position / estimatedLength));
      
            statusTextField.text = "Sound file's size is " + snd.bytesTotal + " bytes.\n" 
                                   + "Bytes being loaded: " + snd.bytesLoaded + "\n" 
                                   + "Percentage of sound file that is loaded " + loadPercent + "%.\n"
                                   + "Sound playback is " + playbackPercent + "% complete.";     
        }
 
        private function errorHandler(errorEvent:IOErrorEvent):void {
            statusTextField.text = "The sound could not be loaded: " + errorEvent.text;
        }

        private function soundCompleteHandler(event:Event):void {
            statusTextField.text = "The sound has finished playing.";
            removeEventListener(Event.ENTER_FRAME, enterFrameHandler);
        }
    }
}

Despachado quando os dados foram carregados com êxito.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado por um objeto Sound quando dados ID3 estão disponíveis para sons MP3.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado quando ocorre um erro de entrada/saída que resulta na falha de uma operação de carregamento.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado quando uma operação de carregamento é iniciada.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado quando os dados são recebidos ao longo do progresso de uma operação de carregamento.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado quando o tempo de execução solicita novos dados de áudio.

Esse evento tem as seguintes propriedades:

var mySound:Sound = new Sound();
function sineWaveGenerator(event:SampleDataEvent):void {
    for ( var c:int=0; c<8192; c++ ) {
        event.data.writeFloat(Math.sin((Number(c+event.position)/Math.PI/2))*0.25);
        event.data.writeFloat(Math.sin((Number(c+event.position)/Math.PI/2))*0.25);
    }
}

mySound.addEventListener(SampleDataEvent.SAMPLE_DATA,sineWaveGenerator);
mySound.play();

Elementos da API relacionados