SoundMixer  - AS3

Especifica o modo de reprodução de áudio de todos os objetos Sound. Em dispositivos móveis, essa propriedade define prioridades de áudio e padrões conforme os idiomas da plataforma. Em ambientes da área de trabalho e de televisão, nenhuma diferença funcional existe entre os modos de reprodução de áudio.

Os valores válidos desta propriedade são definidos na classe AudioPlaybackMode.

Observação Em iOS, se um aplicativo definir audioPlaybackMode=AudioPlaybackMode.VOICE, outros aplicativos não podem alterá-lo para AudioPlaybackMode.MEDIA.

Faça o uso mínimo do modo AudioPlaybackMode.VOICE, e tente alternar para o modo AudioPlaybackMode.MEDIA assim que puder, depois que a chamada de voz terminar para permitir que outros aplicativos sejam executados no modo mídia.

Quando você altera o modo de reprodução de áudio no iOS, os aplicativos nativos que estão reproduzindo música pausam rapidamente.

O valor padrão é AudioPlaybackMode.MEDIA.

Elementos da API relacionados

O número de segundos para pré-carregar um som de streaming incorporado em um buffer antes que ele inicie o streaming. Os dados em um som carregado, incluindo o tempo de buffer, não podem ser acessados por um arquivo SWF em um domínio diferente, a menos que você implemente um arquivo de política de vários domínios. Para obter mais informações sobre segurança e som, consulte a descrição da classe Sound. Os dados em um som carregado, incluindo o tempo de buffer, não podem ser acessados por um código em um arquivo em um domínio diferente, a menos que você implemente um arquivo de política de vários domínios. Contudo, na caixa de proteção do aplicativo no aplicativo AIR o código pode acessar os dados no arquivo de som a partir de qualquer fonte. Para obter mais informações sobre segurança e som, consulte a descrição da classe Sound.

A propriedade SoundMixer.bufferTime só afeta o tempo de buffer para os sons de streaming incorporados em um SWF e é independente dos objetos Sound criados dinamicamente (ou seja, objetos Sound criados no ActionScript). O valor de SoundMixer.bufferTime não pode substituir ou configurar o padrão do tempo de buffer especificado no objeto SoundLoaderContext que é transmitido para o método Sound.load().

Elementos da API relacionados

O objeto SoundTransform que controla propriedades de som globais. O objeto SoundTransform inclui propriedades para configurar o volume, o panorama, a atribuição do alto-falante esquerdo e a atribuição do alto-falante direito. O objeto SoundTransform usado nesta propriedade fornece configurações finais de som que são aplicadas a todos os sons depois que são aplicadas as configurações individuais do som.

Elementos da API relacionados

Alterna o speakerphone quando o dispositivo está no modo de voz. Por padrão, os smartphones utilizarão o receptor do telefone como saída de áudio quando SoundMixer.audioPlaybackMode for definido para AudioPlaybackMode.VOICE. A propriedade useSpeakerphoneForVoice permite que você substitua a saída de padrão para que possa implementar um botão speakerphone em um aplicativo telefônico. Esta propriedade não tem nenhum efeito em outros modos, exceto emAudioPlaybackMode.VOICE. Em ambientes de área de trabalho e de televisão, esta propriedade não tem nenhum efeito.

Observação No iOS, se o seu aplicativo definiu audioPlaybackMode=VOICE e outro aplicativo também está sendo executado no modo de voz, não é possível definir useSpeakerphoneForVoice=true.

Observe no Andróide, deve estabelecer o android.permission. MODIFY_AUDIO_SETTINGS no descritor de aplicativo de AIR ou alterar este valor não tem nenhum efeito. Além disso, a configuração é a configuração de dispositivo global. Outros aplicativos que executam no dispositivo podem alterar a configuração dispositivo subjacente em qualquer momento.

O valor padrão é false.

Elementos da API relacionados

Determina se os sons não são acessíveis devido a restrições de segurança. Por exemplo, um som carregado de um domínio diferente daquele do conteúdo chamando este método não pode ser acessado se o servidor do som não tiver um arquivo de política de URL que concede acesso àquele domínio. O som ainda pode ser carregado e reproduzido, mas operações de baixo nível, como obter metadados ID3 para o som, não podem ser realizadas em sons inacessíveis.

Para o conteúdo AIR na área de segurança do aplicativo, o chamado deste método sempre retorna false. Todos os sons, incluindo aqueles carregados de outros domínios, estão acessíveis para o conteúdo na área de segurança.

Elementos da API relacionados

Tira um instantâneo da onda sonora atual e o coloca no objeto ByteArray especificado. Os valores são formatados como valores normalizados de ponto flutuante, no intervalo –1,0 a 1,0. O objeto ByteArray transmitido para o parâmetro outputArray é substituído pelos novos valores. O tamanho do objeto ByteArray criado é fixado em 512 valores de ponto flutuante, nos quais os primeiros 256 valores representam o canal esquerdo, e os 256 valores seguintes representam o canal direito.

Observação: esse método está sujeito às restrições locais de segurança de arquivo e às restrições no carregamento entre vários domínios. Se você estiver trabalhando com arquivos locais ou sons carregados de um servidor em um domínio diferente do que o conteúdo de chamada, talvez seja necessário tratar das restrições da caixa de proteção através de um arquivo de política entre vários domínios. Para obter mais informações, consulte a descrição da classe Sound. Além disso, este método não pode ser usado para extrair dados de fluxos RTMP, mesmo que seja chamado pelo conteúdo residente no mesmo domínio que o servidor RTMP.

Este método é suportado pelo RTMP no Flash Player 9.0.115.0 e posterior e no Adobe AIR. Você pode controlar o acesso a fluxos no Flash Media Server em um script do lado do servidor. Para obter mais informações, consulte as propriedades Client.audioSampleAccess e Client.videoSampleAccess na Referência de lado do servidor do ActionScript para Adobe Flash Media Server.

Parâmetros

Elementos da API relacionados

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.Event;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.net.URLRequest;
    import flash.utils.ByteArray;
    import flash.text.TextField;

    public class SoundMixer_computeSpectrumExample extends Sprite {

        public function SoundMixer_computeSpectrumExample() {
            var snd:Sound = new Sound();
            var req:URLRequest = new URLRequest("Song1.mp3");
            snd.load(req);
            
            var channel:SoundChannel;
            channel = snd.play();
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
            channel.addEventListener(Event.SOUND_COMPLETE, onPlaybackComplete);
        }

        private function onEnterFrame(event:Event):void {
            var bytes:ByteArray = new ByteArray();
            const PLOT_HEIGHT:int = 200;
            const CHANNEL_LENGTH:int = 256;

            SoundMixer.computeSpectrum(bytes, false, 0);
            
            var g:Graphics = this.graphics;
            
            g.clear();
       
            g.lineStyle(0, 0x6600CC);
            g.beginFill(0x6600CC);
            g.moveTo(0, PLOT_HEIGHT);
            
            var n:Number = 0;
            
            for (var i:int = 0; i < CHANNEL_LENGTH; i++) {
                n = (bytes.readFloat() * PLOT_HEIGHT);
                g.lineTo(i * 2, PLOT_HEIGHT - n);
            }

            g.lineTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
            g.endFill();
 
            g.lineStyle(0, 0xCC0066);
            g.beginFill(0xCC0066, 0.5);
            g.moveTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
            
            for (i = CHANNEL_LENGTH; i > 0; i--) {
                n = (bytes.readFloat() * PLOT_HEIGHT);
                g.lineTo(i * 2, PLOT_HEIGHT - n);
            }
  
            g.lineTo(0, PLOT_HEIGHT);
            g.endFill();
        }
        
        private function onPlaybackComplete(event:Event):void {
            removeEventListener(Event.ENTER_FRAME, onEnterFrame);
        }
    }
}

Para todos os sons em reprodução atualmente.

>No Flash Professional, este método não para a cabeça de reprodução. Os sons configurados para stream vão retomar a reprodução à medida que o indicador de reprodução se move sobre os quadros nos quais se localizam.

Ao usar essa propriedade, considere o seguinte modelo de segurança:

• Por padrão, chamar o método SoundMixer.stopAll() interrompe apenas os sons na mesma sandbox de segurança que o objeto que está chamando o método. O som cuja reprodução não foi iniciada da mesma sandbox que o objeto que chama não é interrompido.
• Ao carregar o som, usando o método load() da classe Sound, você pode especificar um parâmetro context, que é um objeto SoundLoaderContext. Se você definir a propriedade checkPolicyFile do objeto SoundLoaderContext como true, o Flash Player ou o Air verifica se há um arquivo de política de vários domínios no servidor do qual o som é carregado. Se o servidor tiver um arquivo de política de vários domínios, e o arquivo permitir o domínio do conteúdo de chamada, então o arquivo pode interromper o som carregado usando o método SoundMixer.stopAll(); do contrário, ele não pode interromper.

Contudo, no Adobe AIR, o conteúdo na caixa de proteção de segurança application (conteúdo instalado com o Adobe AIR) não é restringido por essas limitações de segurança.

Para obter mais informações relacionadas à segurança, consulte o tópico do Centro dos desenvolvedores do Flash Player Security.

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.media.SoundLoaderContext;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.events.IOErrorEvent;

    public class SoundMixer_stopAllExample extends Sprite  {
        private var firstSound:Sound = new Sound();
        private var secondSound:Sound = new Sound();
        private var muteButton:TextField = new TextField();
        private var channel1:SoundChannel = new SoundChannel();
        
        public function SoundMixer_stopAllExample() {
            firstSound.load(new URLRequest("mySound.mp3"));
            secondSound.load(new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3"));

            firstSound.addEventListener(IOErrorEvent.IO_ERROR, firstSoundErrorHandler);
            secondSound.addEventListener(IOErrorEvent.IO_ERROR, secondSoundErrorHandler);
            
            channel1 = firstSound.play();
            secondSound.play();
            
            muteButton.autoSize = TextFieldAutoSize.LEFT;
            muteButton.border = true;
            muteButton.background = true;
            muteButton.text = "MUTE";
        
            muteButton.addEventListener(MouseEvent.CLICK, muteButtonClickHandler);         
        
            this.addChild(muteButton);
        }

        private function muteButtonClickHandler(event:MouseEvent):void {

            if(muteButton.text == "MUTE") {        
  
                if(SoundMixer.areSoundsInaccessible() == false) {
                    SoundMixer.stopAll();
                    muteButton.text = "click to play only one of sound.";
                }
                else {
                    muteButton.text = "The sounds are not accessible.";
                }
            }
           else {
                firstSound.play();        
                muteButton.text = "MUTE";
           }
        } 

        private function firstSoundErrorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }

        private function secondSoundErrorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }
    }
}