| Pacote | flash.media |
| Classe | public final class SoundTransform |
| Herança | SoundTransform  Object |
| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Elementos da API relacionados
flash.display.SimpleButton.soundTransform
flash.display.Sprite.soundTransform
flash.media.Microphone.soundTransform
flash.media.SoundChannel.soundTransform
flash.media.SoundMixer.soundTransform
flash.net.NetStream.soundTransform
flash.display.Sprite.soundTransform
flash.media.Microphone.soundTransform
flash.media.SoundChannel.soundTransform
flash.media.SoundMixer.soundTransform
flash.net.NetStream.soundTransform
Propriedades públicas
Ocultar propriedades públicas herdadas
Mostrar propriedades públicas herdadas| Propriedade | Definido por | ||
|---|---|---|---|
 | constructor : Object
Uma referência ao objeto de classe ou à função de construtor de uma determinada ocorrência de objeto. | Object | |
| leftToLeft : Number
Um valor, de 0 (nenhum) to 1 (tudo), especificando o quanto da entrada esquerda será reproduzido no alto-falante esquerdo. | SoundTransform | ||
| leftToRight : Number
Um valor, de 0 (nenhum) to 1 (tudo), especificando o quanto da entrada esquerda será reproduzido no alto-falante direito. | SoundTransform | ||
| pan : Number
O panorama do som da esquerda para a direita, variando de -1 (panorama total à esquerda) a 1 (panorama total à direita). | SoundTransform | ||
| rightToLeft : Number
Um valor, de 0 (nenhum) to 1 (tudo), especificando o quanto da entrada direita será reproduzido no alto-falante esquerdo. | SoundTransform | ||
| rightToRight : Number
Um valor, de 0 (nenhum) to 1 (tudo), especificando o quanto da entrada direita será reproduzido no alto-falante direito. | SoundTransform | ||
| volume : Number
O volume, variando de 0 (silêncio) a 1 (volume total). | SoundTransform | ||
Métodos públicos
| Método | Definido por | ||
|---|---|---|---|
Cria um objeto SoundTransform. | SoundTransform | ||
|
Indica se um objeto tem uma propriedade especificada definida. | Object | |
|
Indica se uma ocorrência da classe Object está na cadeia de protótipos do objeto especificado como o parâmetro. | Object | |
|
Indica se a propriedade especificada existe e é enumerável. | Object | |
|
Define a disponibilidade de uma propriedade dinâmica para operações de repetição. | Object | |
|
Retorna a representação da string deste objeto, formatado segundo as convenções específicas para a localidade. | Object | |
|
Retorna a representação de string do objeto especificado. | Object | |
|
Retorna o valor primitivo do objeto especificado. | Object | |
Detalhes da propriedade
leftToLeft | propriedade |
leftToLeft:Number| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Um valor, de 0 (nenhum) to 1 (tudo), especificando o quanto da entrada esquerda será reproduzido no alto-falante esquerdo.
Implementação
public function get leftToLeft():Number public function set leftToLeft(value:Number):voidleftToRight | propriedade |
leftToRight:Number| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Um valor, de 0 (nenhum) to 1 (tudo), especificando o quanto da entrada esquerda será reproduzido no alto-falante direito.
Implementação
public function get leftToRight():Number public function set leftToRight(value:Number):voidpan | propriedade |
pan:Number| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | AIR 1.0, Flash Player 9, Flash Lite 4 |
O panorama do som da esquerda para a direita, variando de -1 (panorama total à esquerda) a 1 (panorama total à direita). O valor 0 representa sem panorama (centro equilibrado entre a direita e a esquerda).
Implementação
public function get pan():Number public function set pan(value:Number):voidrightToLeft | propriedade |
rightToLeft:Number| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Um valor, de 0 (nenhum) to 1 (tudo), especificando o quanto da entrada direita será reproduzido no alto-falante esquerdo.
Implementação
public function get rightToLeft():Number public function set rightToLeft(value:Number):voidrightToRight | propriedade |
rightToRight:Number| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Um valor, de 0 (nenhum) to 1 (tudo), especificando o quanto da entrada direita será reproduzido no alto-falante direito.
Implementação
public function get rightToRight():Number public function set rightToRight(value:Number):voidvolume | propriedade |
Detalhes do construtor
SoundTransform | () | Construtor |
public function SoundTransform(vol:Number = 1, panning:Number = 0)| Versão da linguagem: | ActionScript 3.0 |
| Versões de runtime: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Cria um objeto SoundTransform.
Parâmetrosvol:Number (default = 1) | |
panning:Number (default = 0) |
Exemplo ( Como usar este exemplo )
No exemplo a seguir, o som é reproduzido do canal direito e o volume é ajustado em 50 por cento.
No construtor, o som é carregado e atribuído a um canal de som (canal). Também é criado um objeto SoundTransform (transform). Seu primeiro argumento ajusta o volume em 50 por cento (o intervalo é 0.0 a 1.0). O segundo argumento configura o panorama. Neste exemplo, o panorama é ajustado em 1.0, significando que o som vem do alto-falante direito. Para que essa configuração tenha efeito, o objeto transform SoundTranform é atribuído à propriedade soundTransform do canal de som.
Observação: Há um manuseio de erro limitado escrito para este exemplo.
package {
import flash.display.Sprite;
import flash.net.URLRequest;
import flash.media.Sound;
import flash.media.SoundChannel;
import flash.media.SoundTransform;
import flash.events.IOErrorEvent;
public class SoundTransform_constructorExample extends Sprite
{
public function SoundTransform_constructorExample() {
var mySound:Sound = new Sound();
var url:URLRequest = new URLRequest("mySound.mp3");
var channel:SoundChannel;
var transform:SoundTransform = new SoundTransform(0.5, 1.0);
mySound.load(url);
channel = mySound.play();
channel.soundTransform = transform;
mySound.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
}
private function errorHandler(errorEvent:IOErrorEvent):void {
trace("The sound could not be loaded: " + errorEvent.text);
}
}
}
Exemplos Como usar este exemplo
SoundTransformExample.as
O exemplo a seguir carrega e reproduz um arquivo MP3. À medida que o arquivo MP3 toca, mova o mouse ou outro dispositivo de entrada do usuário; o volume e os valores mudam à medida que você move o dispositivo de entrada do usuários sobre a Etapa. Para usar este exemplo, coloque um arquivo chamado MySound.mp3 no mesmo diretório que o seu arquivo SWF.
package {
import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageScaleMode;
import flash.events.*;
import flash.media.Sound;
import flash.media.SoundChannel;
import flash.media.SoundTransform;
import flash.net.URLRequest;
import flash.utils.Timer;
public class SoundTransformExample extends Sprite {
private var url:String = "MySound.mp3";
private var soundFactory:Sound;
private var channel:SoundChannel;
private var positionTimer:Timer;
public function SoundTransformExample() {
stage.align = StageAlign.TOP_LEFT;
stage.scaleMode = StageScaleMode.NO_SCALE;
var request:URLRequest = new URLRequest(url);
soundFactory = new Sound();
soundFactory.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
soundFactory.load(request);
channel = soundFactory.play();
stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
}
private function ioErrorHandler(event:Event):void {
trace("ioErrorHandler: " + event);
}
private function setPan(pan:Number):void {
trace("setPan: " + pan.toFixed(2));
var transform:SoundTransform = channel.soundTransform;
transform.pan = pan;
channel.soundTransform = transform;
}
private function setVolume(volume:Number):void {
trace("setVolume: " + volume.toFixed(2));
var transform:SoundTransform = channel.soundTransform;
transform.volume = volume;
channel.soundTransform = transform;
}
private function mouseMoveHandler(event:MouseEvent):void {
var halfStage:uint = Math.floor(stage.stageWidth / 2);
var xPos:uint = event.stageX;
var yPos:uint = event.stageY;
var value:Number;
var pan:Number;
if (xPos > halfStage) {
value = xPos / halfStage;
pan = value - 1;
} else if (xPos < halfStage) {
value = (xPos - halfStage) / halfStage;
pan = value;
} else {
pan = 0;
}
var volume:Number = 1 - (yPos / stage.stageHeight);
setVolume(volume);
setPan(pan);
}
}
}
Wed Jun 13 2018, 11:10 AM Z