SimpleButton  - AS3

Especifica um objeto de exibição que é usado como objeto visual para o estado "Down" do botão - o estado no qual o botão se encontra quando o usuário clica no objeto hitTestState.

Elementos da API relacionados

Um valor booliano que especifica se um botão está ativado. Quando um botão está desativado (a propriedade "enabled" está definida como false), o botão fica visível, mas não pode ser clicado. O valor padrão é true. Essa propriedade será útil se você quiser desativar parte da navegação; por exemplo, é possível desativar um botão na página atualmente exibida para que ele não possa ser clicado e a página não possa ser recarregada.

Observação: Para impedir cliques de mouse em um botão, defina as propriedades enabled e mouseEnabled como false.

Especifica um objeto de exibição usado como objeto de testes de pressionamento para o botão. Para um botão básico, a propriedade hitTestState para o mesmo objeto de exibição que a propriedade overState. Se você não definir a propriedade hitTestState, SimpleButton estará inativo - não responderá a eventos de entrada do usuário.

Elementos da API relacionados

Especifica um objeto de exibição que é usado como objeto visual para o estado "over" do botão - o estado no qual o botão se encontra quando o mouse está posicionado sobre ele.

Elementos da API relacionados

O objeto SoundTransform atribuído a esse botão. O objeto SoundTransform inclui propriedades para configurar o volume, o panorama, a atribuição do alto-falante esquerdo e a atribuição do alto-falante direito. Esse objeto SoundTransform aplica-se a todos os estados do botão. Esse objeto SoundTransform afeta somente os sons incorporados.

Elementos da API relacionados

Indica se outros objetos de exibição que são objetos SimpleButton ou MovieClip podem receber eventos de soltar de entrada. A propriedade trackAsMenu permite criar menus. Você pode definir a propriedade trackAsMenu em qualquer objeto SimpleButton ou MovieClip. Se a propriedade trackAsMenu não existir, o comportamento padrão será false.

A propriedade trackAsMenu pode ser alterada a qualquer momento; o botão modificado usa imediatamente o novo comportamento.

Especifica um objeto de exibição que é usado como objeto visual para o estado "up" do botão — o estado no qual o botão se encontra quando o mouse não está posicionado sobre ele.

Elementos da API relacionados

Um valor booliano que, quando definido como true, indica se o cursor de mão é exibido quando o mouse rola sobre um botão. Se essa propriedade for definida como false, o cursor com ponteiro de seta será exibido como alternativa. O padrão é true.

A propriedade useHandCursor pode ser alterada a qualquer momento; o botão modificado usa imediatamente o novo comportamento de cursor.

Cria uma nova ocorrência de SimpleButton. Quaisquer ou todos os objetos de exibição que representam os vários estados de botão podem ser definidos como parâmetros no construtor.

1. No construtor SimpleButtonExample(), um novo objeto CustomSimpleButton do tipo SimpleButton, chamado button, é criado, chamando o método do construtor CustomSimpleButton. O objeto button é adicionado à lista de exibição. A cor e o tamanho do botão são determinados nas etapas a seguir.
2. Na classe CustomSimpleButton, as propriedades da ocorrência são declaradas e, mais tarde, são usadas para controlar o tamanho e a cor do plano de fundo de button, com base no estado em que ele se encontra (laranja no estado normal, amarelo escuro no estado de mouse sobre e azul claro no estado de mouse abaixo). Em todos os estados de button, o tamanho do quadrado é definido como 80 usando a propriedade size.
3. A função do construtor para a classe CustomSimpleButton define as propriedades downState, overState, upState, hitTestState e useHandCursor com quatro ocorrências da classe ButtonDisplayState.
4. Na classe ButtonDisplayState, o construtor define o valor do tamanho e da cor do plano de fundo do quadrado e chama o método draw().
5. O método draw() redesenha o quadrado com o tamanho e a cor de plano de fundo definidos no construtor, com base no estado do botão.

package {
    import flash.display.Sprite;

    public class SimpleButtonExample extends Sprite {
        public function SimpleButtonExample() {
            var button:CustomSimpleButton = new CustomSimpleButton();
            addChild(button);
        }
    }
}

import flash.display.DisplayObject;
import flash.display.Shape;
import flash.display.SimpleButton;

class CustomSimpleButton extends SimpleButton {
    private var upColor:uint   = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;
    private var size:uint      = 80;

    public function CustomSimpleButton() {
        downState      = new ButtonDisplayState(downColor, size);
        overState      = new ButtonDisplayState(overColor, size);
        upState        = new ButtonDisplayState(upColor, size);
        hitTestState   = new ButtonDisplayState(upColor, size * 2);
        hitTestState.x = -(size / 4);
        hitTestState.y = hitTestState.x;
        useHandCursor  = true;
    }
}

class ButtonDisplayState extends Shape {
    private var bgColor:uint;
    private var size:uint;

    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size    = size;
        draw();
    }

    private function draw():void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}