DisplayObjectContainer  - AS3

Determina se os filhos do objeto são ou não ativados pelo mouse, ou dispositivo de entrada do usuário. Se um objeto estiver ativado,um usuário pode interagir com ele usando um mouse ou dispositivo de entrada do usuário. O padrão é true.

Essa propriedade é útil quando você cria um botão com uma ocorrência da classe Sprite (em vez de usar a classe SimpleButton). Ao usar uma ocorrência de Sprite para criar um botão, você pode optar por decorar esse botão usando o método addChild() para incluir ocorrências adicionais de Sprite. Esse processo pode causar um comportamento inesperado com eventos de mouse, já que as ocorrências de Sprite adicionadas como filhos podem se tornar o objeto de destino de um evento de mouse, quando você espera que a ocorrência-pai seja o objeto de destino. Para garantir que a ocorrência-pai atue como o objeto de destino para eventos de mouse, defina a propriedade mouseChildren dessa ocorrência como false.

Nenhum evento é despachado com o uso dessa propriedade. É necessário usar o método addEventListener() para criar uma funcionalidade interativa.

Elementos da API relacionados

import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
container.name = "container";
addChild(container);

var circle:Sprite = new Sprite();
circle.name = "circle";
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(40, 40, 40);

container.addChild(circle);

container.mouseChildren = false;

container.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace(event.target.name); // container
}

Retorna o número de filhos deste objeto.

import flash.display.Sprite;

var container1:Sprite = new Sprite();
var container2:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(80, 40, 40);

container2.addChild(container1);
container1.addChild(circle1);
container1.addChild(circle2);

trace(container1.numChildren); // 2
trace(container2.numChildren); // 1
trace(circle1.numChildren); // 0
trace(circle2.numChildren); // 0

Determina se os filhos do objeto estão ativados para tabulação. Ativa ou desativa a tabulação para os filhos do objeto. O padrão é true.

Nota: não use a propriedade tabChildren com Flex. Em vez disso, use a propriedade mx.core.UIComponent.hasFocusableChildren.

import flash.display.Sprite;

var container:Sprite = new Sprite();
container.tabChildren = false;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.tabIndex = 1;

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(120, 40, 40);
circle2.tabIndex = 0;

container.addChild(circle1);
container.addChild(circle2);

Retorna um objeto TextSnapshot para essa ocorrência de DisplayObjectContainer.

Elementos da API relacionados

trace(this.textSnapshot.getText(0, this.textSnapshot.charCount));

Chamar o construtor new DisplayObjectContainer() lança uma exceção ArgumentError. Entretanto, você pode chamar construtores para as seguintes subclasses de DisplayObjectContainer:

• new Loader()
• new Sprite()
• new MovieClip()

Adiciona uma ocorrência-filho de DisplayObject a essa ocorrência de DisplayObjectContainer. O filho é adicionado à frente (acima) de todos os outros filhos nessa ocorrência de DisplayObjectContainer. (Para adicionar um filho em uma posição de índice específica, use o método addChildAt().)

Se você adicionar um objeto-filho que já tenha um contêiner de objetos de exibição diferente como pai, o objeto será removido da lista de filhos do outro contêiner de objetos de exibição.

Observação: O comando stage.addChild() pode causar problemas com um arquivo SWF publicado, inclusive problemas de segurança e conflitos com outros arquivos SWF carregados. Há só um Palco dentro de uma instância de tempo de execução de Flash, não importa quantos arquivos SWF você carrega no tempo de execução. Portanto, geralmente, os objetos não devem ser adicionados ao Palco, diretamente. O único objeto que o Palco deve conter é o objeto-raiz. Crie um DisplayObjectContainer para conter todos os itens na lista de exibição. Então, se necessário, adicione essa instância DisplayObjectContainer ao Palco.

Parâmetros

Elementos da API relacionados

import flash.display.Sprite;

var container1:Sprite = new Sprite();
var container2:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(80, 40, 40);

container2.addChild(container1);
container1.addChild(circle1);
container1.addChild(circle2);

trace(container1.numChildren); // 2
trace(container2.numChildren); // 1
trace(circle1.numChildren); // 0
trace(circle2.numChildren); // 0

Adiciona uma ocorrência-filho de DisplayObject a essa ocorrência de DisplayObjectContainer. O filho é adicionado na posição de índice especificada. Um índice de 0 representa o final (parte inferior) da lista de exibição para esse objeto DisplayObjectContainer.

Por exemplo, o exemplo a seguir mostra três objetos de exibição, com os rótulos a, b e c, nas posições de índice 0, 2 e 1, respectivamente:

Se você adicionar um objeto-filho que já tenha um contêiner de objetos de exibição diferente como pai, o objeto será removido da lista de filhos do outro contêiner de objetos de exibição.

Parâmetros

Elementos da API relacionados

import flash.display.Sprite;

var container:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
var circle2:Sprite = new Sprite();

container.addChild(circle1);
container.addChildAt(circle2, 0);

trace(container.getChildAt(0) == circle2); // true
trace(container.getChildAt(1) == circle1); // true

Indica se restrições de segurança fariam com que qualquer objeto de exibição fosse omitido da lista retornada com a chamada do método DisplayObjectContainer.getObjectsUnderPoint() junto com o ponto especificado. Por padrão, o conteúdo de um domínio não pode acessar objetos de outro domínio, a não ser isso seja permitido com uma chamada ao método Security.allowDomain(). Para obter mais informações relacionadas à segurança, consulte o tópico do Centro do desenvolvedor do Flash Player: Security.

O parâmetro ponto está no espaço de coordenadas do Palco, que pode ser diferente do espaço de coordenadas do contêiner de objetos de exibição (a menos que o contêiner de objetos de exibição seja o Palco). Você pode usar os métodos globalToLocal() e localToGlobal() para converter pontos entre esses espaços de coordenadas.

Parâmetros

Elementos da API relacionados

import flash.display.Sprite;
import flash.display.Loader;
import flash.system.LoaderContext;
import flash.net.URLRequest;
import flash.events.Event;
import flash.geom.Point;

var container:Sprite = new Sprite();

var urlReq:URLRequest = new URLRequest("http://localhost/RemoteFile.swf");
var ldr:Loader = new Loader();
var context:LoaderContext = new LoaderContext();
context.checkPolicyFile = false;
ldr.load(urlReq, context);

ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, loaded);
ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, urlNotFound);

function loaded(event:Event):void {
    var pt:Point = new Point(1, 1);
    trace(container.areInaccessibleObjectsUnderPoint(pt)); // true
}

function urlNotFound(event:Event):void {
    trace("The URL was not found."); 
}

Determina se o objeto de exibição especificado é um filho da ocorrência de DisplayObjectContainer ou se é a própria ocorrência. A pesquisa inclui a lista de exibição inteira, incluindo essa ocorrência de DisplayObjectContainer. Netos, bisnetos e assim por diante retornam true cada.

Parâmetros

import flash.display.Sprite;

var sprite1:Sprite = new Sprite();
var sprite2:Sprite = new Sprite();
var sprite3:Sprite = new Sprite();
var sprite4:Sprite = new Sprite();

sprite1.addChild(sprite2);
sprite2.addChild(sprite3);

trace(sprite1.contains(sprite1)); // true
trace(sprite1.contains(sprite2)); // true
trace(sprite1.contains(sprite3)); // true
trace(sprite1.contains(sprite4)); // false

Retorna a ocorrência do objeto de exibição-filho que existe no índice especificado.

Parâmetros

Elementos da API relacionados

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
var sprite2:Sprite = new Sprite();
var sprite3:Sprite = new Sprite();

container.addChild(sprite1);
container.addChild(sprite2);
container.addChildAt(sprite3, 0);

trace(container.getChildAt(0) == sprite3); // true
trace(container.getChildAt(1) == sprite1); // true
trace(container.getChildAt(2) == sprite2); // true

Retorna o objeto de exibição-filho que existe com o nome especificado. Se mais de um objeto de exibição-filho tiver o nome especificado, o método retornará o primeiro objeto na lista de filhos.

O método getChildAt() é mais rápido do que o método getChildByName(). O método getChildAt() acessa um filho a partir de uma matriz em cache, enquanto o método getChildByName() precisa atravessar a lista vinculada para acessar um filho.

Parâmetros

Elementos da API relacionados

import flash.display.Sprite;
import flash.display.DisplayObject;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

var target:DisplayObject = container.getChildByName("sprite1"); 
trace(container.getChildIndex(target)); // 0

Retorna a posição de índice de uma ocorrência-filho de DisplayObject.

Parâmetros

import flash.display.Sprite;
import flash.display.DisplayObject;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

var target:DisplayObject = container.getChildByName("sprite1"); 
trace(container.getChildIndex(target)); // 0

Retorna uma matriz de objetos que estão dispostos no ponto especificado e são filhos (ou netos e assim por diante) desta ocorrência de DisplayObjectContainer. Os objetos-filho que não puderem ser acessados por questões de segurança serão omitidos da matriz retornada. Para determinar se essa restrição de segurança afeta a matriz retornada, chame o método areInaccessibleObjectsUnderPoint().

O parâmetro ponto está no espaço de coordenadas do Palco, que pode ser diferente do espaço de coordenadas do contêiner de objetos de exibição (a menos que o contêiner de objetos de exibição seja o Palco). Você pode usar os métodos globalToLocal() e localToGlobal() para converter pontos entre esses espaços de coordenadas.

Parâmetros

Elementos da API relacionados

import flash.display.Sprite;
import flash.geom.Point;

var container:Sprite = new Sprite();

var square1:Sprite = new Sprite();
square1.graphics.beginFill(0xFFCC00);
square1.graphics.drawRect(0, 0, 40, 40);

var square2:Sprite = new Sprite();
square2.graphics.beginFill(0x00CCFF);
square2.graphics.drawRect(20, 0, 30, 40);

container.addChild(square1);
container.addChild(square2);

var pt:Point = new Point(10, 20);
var objects:Array = container.getObjectsUnderPoint(pt); 
trace(objects.length); // 1

pt = new Point(35, 20);
objects = container.getObjectsUnderPoint(pt);
trace(objects.length);  // 2

Remove uma ocorrência-filho de DisplayObject especificada da lista de filhos da ocorrência de DisplayObjectContainer. A propriedade parent do filho removido é definida como null e o objeto será coletado como lixo se não houver outras referências ao filho. As posições de índice de qualquer objeto de exibição acima do filho em DisplayObjectContainer são diminuídas em 1.

O coletor de lixo realoca o espaço de memória não utilizado. Quando uma variável ou objeto deixa de ser ativamente referenciado ou é armazenado em outro local, o coletor de lixo faz uma varredura e limpa o espaço de memória que essa variável ou objeto costumava ocupar, se nenhuma outra referência existir.

Parâmetros

 
import flash.display.DisplayObject;
import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
addChild(container);

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(120, 40, 40);

container.addChild(circle1);
container.addChild(circle2);

container.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    container.removeChild(DisplayObject(event.target)); 
}

Remove um DisplayObject filho da posição de index especificada na lista de filhos de DisplayObjectContainer. A propriedade parent do filho removido é definida como null e o objeto será coletado como lixo se não houver outras referências ao filho. As posições de índice de qualquer objeto de exibição acima do filho em DisplayObjectContainer são diminuídas em 1.

O coletor de lixo realoca o espaço de memória não utilizado. Quando uma variável ou objeto deixa de ser ativamente referenciado ou é armazenado em outro local, o coletor de lixo faz uma varredura e limpa o espaço de memória que essa variável ou objeto costumava ocupar, se nenhuma outra referência existir.

Parâmetros

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

trace(container.numChildren) // 2
container.removeChildAt(0); 
trace(container.numChildren) // 1
trace(container.getChildAt(0).name); // sprite2

Remove todas as instâncias child de DisplayObject especificadas na lista de filhos da instância DisplayObjectContainer. A propriedade parent do filho removido é definida como null e o objeto será coletado como lixo se não houver outras referências ao filho.

O coletor de lixo realoca o espaço de memória não utilizado. Quando uma variável ou objeto deixa de ser ativamente referenciado ou é armazenado em outro local, o coletor de lixo faz uma varredura e limpa o espaço de memória que essa variável ou objeto costumava ocupar, se nenhuma outra referência existir.

Parâmetros

Altera a posição de um filho existente no contêiner de objetos de exibição. Isso afeta a disposição de objetos-filho em camadas. Por exemplo, o exemplo a seguir mostra três objetos de exibição, com os rótulos a, b e c, nas posições de índice 0, 1 e 2, respectivamente:

Quando você usa o método setChildIndex() e especifica uma posição de índice que já está ocupada, as únicas posições alteradas são aquelas entre a posição nova e a anterior do objeto de exibição. Todos as demais permanecem da mesma maneira. Se um filho for movido para um índice INFERIOR ao índice atual respectivo, todos os filhos entre eles AUMENTARÃO em 1 na respectiva referência de índice. Se um filho for movido para um índice SUPERIOR ao índice atual respectivo, todos os filhos entre eles DIMINUIRÃO em 1 na respectiva referência de índice. Por exemplo, se o contêiner de objetos de exibição no exemplo anterior se chamar container, você poderá alternar a posição dos objetos de exibição com os rótulos a e b, chamando o seguinte código:

container.setChildIndex(container.getChildAt(1), 0);

Esse código resulta na seguinte disposição de objetos:

Parâmetros

Elementos da API relacionados

import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
addChild(container);

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFF0000);
circle1.graphics.drawCircle(40, 40, 40);
circle1.addEventListener(MouseEvent.CLICK, clicked);
 
var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00FF00);
circle2.graphics.drawCircle(100, 40, 40);
circle2.addEventListener(MouseEvent.CLICK, clicked);
 
var circle3:Sprite = new Sprite();
circle3.graphics.beginFill(0x0000FF);
circle3.graphics.drawCircle(70, 80, 40);
circle3.addEventListener(MouseEvent.CLICK, clicked);
 
container.addChild(circle1);
container.addChild(circle2);
container.addChild(circle3);
addChild(container);
 
function clicked(event:MouseEvent):void {
    var circle:Sprite = Sprite(event.target);
    var topPosition:uint = container.numChildren - 1;
    container.setChildIndex(circle, topPosition);
}

Interrompe repetitivamente a execução da linha de tempo de todos os MovieClips enraizados neste objeto.

Os objetos de exibição filhos que pertence a uma caixa de proteção à qual o código em execução não tem acesso são ignorados.

Observação: o fluxo de reprodução de mídia gerenciado por um objeto NetStream não será interrompido.

Alterna a ordem z (ordem da frente para trás) dos dois objetos filhos especificados. Todos os outros objetos-filho no contêiner de objetos de exibição permanecem nas mesmas posições de índice.

Parâmetros

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

trace(container.getChildAt(0).name); // sprite1
trace(container.getChildAt(1).name); // sprite2

container.swapChildren(sprite1, sprite2);

trace(container.getChildAt(0).name); // sprite2
trace(container.getChildAt(1).name); // sprite1

Alterna a ordem z (ordem da frente para trás) dos objetos-filho nas duas posições de índice especificadas na lista de filhos. Todos os outros objetos-filho no contêiner de objetos de exibição permanecem nas mesmas posições de índice.

Parâmetros

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";
var sprite3:Sprite = new Sprite();
sprite3.name = "sprite3";

container.addChild(sprite1);
container.addChild(sprite2);
container.addChild(sprite3);

trace(container.getChildAt(0).name); // sprite1
trace(container.getChildAt(1).name); // sprite2
trace(container.getChildAt(2).name); // sprite3

container.swapChildrenAt(0, 2);

trace(container.getChildAt(0).name); // sprite3
trace(container.getChildAt(1).name); // sprite2
trace(container.getChildAt(2).name); // sprite1

1. O construtor chama o método configureAssets().
2. O método configureAssets() cria objetos Sprite child e lastChild.
3. Uma repetição for cria os cinco quadrados laranja e os posiciona um depois do outro.
4. Sempre que um objeto CustomSprite for criado, seu construtor chamará o método draw() do objeto CustomSprite, que cria um quadrado de 50 por 50 pixels chamando os métodos beginFill(), drawRect() e endFill() da classe Graphics. O método addChild() adiciona cada quadrado à lista de exibição.

package {
    import flash.display.DisplayObject;
    import flash.display.Sprite;

    public class DisplayObjectContainerExample extends Sprite {
        private var gutter:uint     = 5;
        private var childCount:uint = 5;

        public function DisplayObjectContainerExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var child:Sprite = new CustomSprite();
            var lastChild:Sprite = child;
            for (var i:uint = 1; i <= childCount; i++) {
                child = new CustomSprite();
                child.x = lastChild.x + lastChild.width + gutter;
                addChild(child);
                lastChild = child;
            }
        }
    }
}

import flash.display.Sprite;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0xFFCC00;

    public function CustomSprite() {
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }
}