TextLine  - AS3

Especifica o número de pixels da linha de base até a parte superior dos caracteres mais altos da linha. Para um TextLine que contenha apenas um elemento gráfico, ascent é definido como 0.

O número de átomos da linha, que é o número de elementos indivisíveis, inclusive espaços e elementos gráficos.

Especifica o número de pixels da linha de base até a parte inferior dos caracteres mais baixos da linha. Para um TextLine que contenha apenas um elemento gráfico, descent é definido como 0.

Indica se a linha de texto contém algum elemento gráfico.

Elementos da API relacionados

Indica se a linha de texto contém alguma guia.

Vector que contém os objetos TextLineMirrorRegion associados à linha, ou null caso não haja nenhum.

Elementos da API relacionados

O TextLine seguinte no TextBlock, ou null caso a linha atual seja a última do bloco, ou a validade da linha seja TextLineValidity.STATIC.

Elementos da API relacionados

O TextLine anterior noTextBlock, ou null caso a linha seja a primeira do bloco ou a validade da linha seja TextLineValidity.STATIC.

Elementos da API relacionados

O comprimento do texto bruto do bloco de texto que se tornou a linha, inclusive os caracteres U+FDEF que representam elementos gráficos e todos os espaços à esquerda, que fazem parte da linha mas que não são exibidos.

Elementos da API relacionados

A largura especificada para o método TextBlock.createTextLine() quando ele criou a linha. O valor é útil quando se decide se uma alteração exige uma nova quebra da linha.

Elementos da API relacionados

O TextBlock que contém esta linha de texto, ou nulo se a validade da linha é TextLineValidity.STÁTIC, significar que a conexão entre a linha e o TextBlock foi separada.

Elementos da API relacionados

O índice do primeiro caractere da linha no texto bruto do bloco de texto.

Elementos da API relacionados

A altura lógica da linha de texto é igual a ascent + descent. Para obter a altura pintada, acesse a propriedade height herdada.

O valor é calculado com base na diferença entre as linhas de base que formam a linha, de cima para baixo ou de subida e descida, dependendo de TextBlock.baselineZero ser ideo ou não. Os elementos gráficos não são considerados durante a computação dessas linhas de base.

Elementos da API relacionados

A largura lógica da linha de texto, que é a largura que o mecanismo de texto usa para posicionar a linha. Acesse a propriedade width herdada para obter a largura real da caixa delimitadora de todos os pixels desenhados.

Elementos da API relacionados

 
package {
import flash.display.Sprite;
import flash.text.engine.TextBlock;
import flash.text.engine.TextElement;
import flash.text.engine.TextLine;
import flash.text.engine.FontDescription;
import flash.text.engine.ElementFormat;
import flash.text.engine.FontPosture;

    public class TextLine_textWidthExample extends Sprite {
        
        public function TextLine_textWidthExample() {
            
            var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
            var yPos:Number = 20;
            var fontDescription:FontDescription = new FontDescription();
            var textBlock:TextBlock = new TextBlock();
            fontDescription.fontPosture = FontPosture.NORMAL;
            var format:ElementFormat = new ElementFormat(fontDescription, 12);
            var textElement:TextElement = new TextElement(str, format);
            textBlock.content = textElement;
            createLine(textBlock, yPos);
            var fontDescriptionItalic = fontDescription.clone();
            fontDescriptionItalic.fontPosture = FontPosture.ITALIC;
            var formatItalic = new ElementFormat(fontDescriptionItalic, 12);
            textElement = new TextElement(str, formatItalic);
            textBlock.content = textElement;
            createLine(textBlock, yPos + 20);
        }

        private function createLine(textBlock:TextBlock, yPos:Number):void {
            var textLine:TextLine = textBlock.createTextLine (null, 500);
            trace("specifiedWidth is: " + textLine.specifiedWidth);
            trace("textWidth is: " + textLine.textWidth);
            trace("width is: " + textLine.width);
            addChild(textLine);
            textLine.x = 15;
            textLine.y = yPos;     
        }
    }
}

Especifica o número de pixels desde a linha de base até a parte superior do caractere ou gráfico mais alto na linha.

Especifica o número de pixels desde a linha de base até a parte inferior do caractere ou gráfico descendente mais baixo na linha.

A altura lógica total da linha de texto, igual a totalAscent + totalDescent.

A largura da linha, caso não esteja justificada. Para o texto não justificado, esse valor é igual ao textWidth. Para o texto justificado, esse valor é o comprimento sem justificação, e textWidth representa a largura real da linha. Por exemplo, quando a seguinte string é justificada e enviada para o TextBlock.createTextLine() com uma largura de 500, ela tem uma largura real de 500 e uma largura não justificada de 268.9921875.

Elementos da API relacionados

     import flash.display.Sprite;
     import flash.text.engine.TextBlock;
     import flash.text.engine.TextElement;
     import flash.text.engine.TextLine;
     import flash.text.engine.FontDescription;
     import flash.text.engine.ElementFormat;
     import flash.text.engine.SpaceJustifier;
     import flash.text.engine.LineJustification;

     var str:String = "Lorem ipsum dolor sit amet, consectetur adipisicing elit, ";
     var fontDescription:FontDescription = new FontDescription();
     var textBlock:TextBlock = new TextBlock();
     var format:ElementFormat = new ElementFormat(fontDescription, 12);
     var textElement:TextElement = new TextElement(str, format);
     textBlock.content = textElement;
     var spaceJustifier:SpaceJustifier = new SpaceJustifier("en", LineJustification.ALL_INCLUDING_LAST);
     textBlock.textJustifier = spaceJustifier;
     var textLine:TextLine = textBlock.createTextLine(null, 500);
     textLine.y = 20;

     addChild(textLine);
     trace("textWidth value is: " + textLine.textWidth);        // 500.00244140625
     trace("unjustifiedTextWidth is: " + textLine.unjustifiedTextWidth); // 268.9921875
     

Fornece uma maneira de o aplicativo associar dados arbitrários à linha de texto.

Especifica a validade atual da linha de texto. Valores para esta propriedade são encontrados nos membros da classe TextLineValidity. As regras para definir essa propriedade são as seguintes:

Uma linha é considerada USER_INVALID caso validity seja definida como uma string que não são membros de TextLineValidity. USER_INVALID é uma abstração usada aqui para representar qualquer valor desse tipo.

Quando o conteúdo de TextBlock é modificado, as marcas de tempo de execução do Flash afetam linhas de texto, a linha anterior e todas estas linhas como INVALID. A linha anterior deve ser considerada inválida quando uma alteração permite que a linha anterior absorva parte do conteúdo originalmente na primeira linha afetada.

Linhas recém-quebradas são sempre VALID. O tempo de execução do Flash pode alterar as linhas que seguem de VALID para POSSIBLY_INVALID ou INVALID. Ele pode alterar linhas POSSIBLY_INVALID para VALID caso as quebras de linha sejam correspondentes, ou para INVALID caso não correspondam.

O código do aplicativo pode marcar linhas VALID como INVALID ou USER_INVALID, além de marcar linhas USER_INVALID como VALID. O código do aplicativo do não pode marcar linhas POSSIBLY_INVALID.

O código do aplicativo pode marcar qualquer linha STATIC. Isso faz com que o membro block se torne null. Todos os elementos gráficos em uma linha de texto STATIC são removidos e refeitos caso façam parte de uma nova linha de texto quebrada do bloco de texto do qual a linha de texto STATIC foi derivada originalmente.

Elementos da API relacionados

Descarta o conteúdo subjacente da TextLine como uma string XML. Isso pode ser útil no teste automático e inclui texto, formatação e informações de layout.

O seguinte descreve a saída:

	 [LINE]
	 <line ascent=[Number] descent=[Number] rotation=[int]>
	 	<elements>
	 		[0-N ELEMENT]
	 	</elements>
	 	<clusters>
	 		[0-N CLUSTER]
	 	</clusters>
	 </line>
	 
	 [ELEMENT]
	 <glyph isEmbedded=[Boolean] fontName=[String] isBold=[Boolean] isItalic=[Boolean] gid=[int] pointSize=[Number] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <graphic child=[int] x=[Number] y=[Number] rotation=[int]/>
	 or
	 <embeddedRun x=[Number] y=[Number]>
	 	[LINE]
	 </embeddedRun>
	 
	 [CLUSTER]
	 <cluster xLeft=[Number] xCenter=[Number] xRight=[Number] cursorOnLeft=[Boolean] cursorOnRight=[Boolean] wordBoundaryOnLeft=[Boolean] wordBoundaryOnRight=[Boolean]/>
	 

Observação: o conteúdo e o formato da saída do método podem ser alterados no futuro. A Adobe não garante a compatibilidade do método com versões anteriores.

Elementos da API relacionados

Este método é desaprovado e não tem nenhum efeito. O dado de átomo é comprimido e não é um fator no gerenciamento eficiente de memória.

Elementos da API relacionados

Obtém o nível bidirecional do núcleo no índice especificado. Determinado por uma combinação de TextBlock.bidiLevel e propriedades bidirecionais Unicode dos caracteres que formam a linha.

Por exemplo, se você iniciar um bloco de texto com texto em hebraico, defina TextBlock.bidiLevel como 1, estabelecendo um padrão da direita para a esquerda. Se há no texto uma parte em inglês (da esquerda para a direita), esse texto tem um AtomBidiLevel de valor 2. Se no texto em inglês houver um trecho em árabe (da direita para a esquerda), o AtomBidiLevel passará a ser 3. Se no texto em árabe houver um número (da esquerda para a direita), a definição de AtomBidiLevel do número será 4. Não importa em que linha os núcleos terminem; os núcleos em hebraico são AtomBidiLevel 1, os núcleos em inglês são AtomBidiLevel 2, os núcleos em árabe são AtomBidiLevel 3 e os núcleos de número são AtomBidiLevel 4.

Parâmetros

Elementos da API relacionados

Obtém os limites do núcleo no índice especificado em relação à linha do texto. Os limites do átomo especificado consistem na posição horizontal (x) da linha, na posição vertical da linha (y), na largura (w) e na altura (h). Todos os valores são em pixels.

Parâmetros

Obtém o centro do núcleo conforme medido na linha de base do índice especificado.

Parâmetros

Obtém o gráfico do núcleo no índice especifico, ou null caso o núcleo seja um caractere.

Parâmetros

Retorna o índice do núcleo que contém o caractere especificado pelo parâmetro charIndex ou -1 se o caractere não contribuir com qualquer núcleo na linha. O charIndex é relativo a todo o conteúdo do bloco de texto que contém a linha.

Parâmetros

Retorna o índice do núcleo no ponto especificado pelos parâmetros x e y, ou -1 caso não haja núcleo a essa altura.

Esse método usa coordenadas globais para que você possa usá-lo facilmente com MouseEvent.stageX e MouseEvent.stageY.

Parâmetros

Obtém o índice inicial do bloco de texto do núcleo no índice especificado.

Parâmetros

Obtém o índice final do bloco de texto do núcleo no índice especificado.

Parâmetros

Obtém o giro do núcleo no índice especificado. Constantes TextRotation são usadas na propriedade. O giro do núcleo são os giros cumulativos do elemento e da linha. É usado principalmente para definir a orientação do circunflexo (cursor) ao interagir com um TextLine.

Parâmetros

Elementos da API relacionados

Indica se ocorre um limite de palavra à esquerda do núcleo no índice especificado. Os limites de palavra são determinados com base nas propriedades Unicode dos caracteres que contribuem com a linha.

Parâmetros

Obtém a posição da linha de base especificada, em relação a TextBlock.baselineZero.

Parâmetros

Elementos da API relacionados

Retorna o primeiro TextLineMirrorRegion na linha cuja propriedade mirror corresponde ao especificado pelo parâmetro mirror, ou null caso não haja correspondência.

Mesmo um TextElement único pode produzir vários objetos TextLineMirrorRegion em uma ou mais linhas, dependendo da quebra de linha e do nível bidirecional. As propriedades nextRegion e previousRegion vinculam todas as regiões de espelho geradas a partir de um elemento de texto.

Parâmetros

Elementos da API relacionados

A largura solicitada máxima de uma linha de texto, em pixels. O método TextBlock.createTextLine() usa essa constante como o valor padrão do parâmetro width, caso você não especifique um valor.

Elementos da API relacionados

1. Adicione o componente NumericStepper à biblioteca.
2. Salve o código como TextLineExample.as no mesmo diretório de FLA.
3. Defina a Classe na janela Propriedades do FLA como TextLineExample.

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    import flash.text.engine.FontPosture;
    import flash.text.engine.FontWeight;
    import fl.controls.NumericStepper;
    import flash.events.Event;
    import flash.geom.Rectangle;
    
    public class TextLineExample extends Sprite {
        
        private var atomStepper:NumericStepper = new NumericStepper();
        private var atomDataContainer:Sprite;
        private var fontDescriptionItalic:FontDescription = new FontDescription("Arial", FontWeight.NORMAL, FontPosture.ITALIC);
        private var fontDescriptionNormal:FontDescription = new FontDescription("Arial", FontWeight.NORMAL , FontPosture.NORMAL);
        private var textBlock:TextBlock = new TextBlock();
        private var textLine:TextLine;
        
        public function TextLineExample():void {
            
            var myText:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. From the text block, " +
            "the createTextLine() method created these lines, 300 pixels wide, "  +
            "for display." ;
            
            atomStepper.minimum = 0;
            atomStepper.value = 0;
            atomStepper.width = 50;
            addChild(atomStepper);
            atomStepper.x = 20;
            atomStepper.y = 120;
            atomStepper.addEventListener(Event.CHANGE, nsChange);
            
            var directions:String = "Click up / down arrows to frame atoms in text block above.";
            
            var formatItalic:ElementFormat = new ElementFormat(fontDescriptionItalic);
            formatItalic.fontSize = 12;
            var textElement1:TextElement = new TextElement(directions, formatItalic);
            textBlock.content = textElement1;
            createLines(textBlock, 15, 160, 400, this);
            
            var formatNormal:ElementFormat = new ElementFormat(fontDescriptionNormal);
            formatNormal.fontSize = 16;
            var textElement2:TextElement = new TextElement(myText, formatNormal);
            textBlock.content = textElement2;
            createLines(textBlock, 15.0, 20.0, 300, this);
            textLine = textBlock.firstLine;
            atomStepper.maximum = textLine.atomCount - 1;
            showAtom(textLine, 0);
        }
            
        private function nsChange(event:Event):void
        {
            removeAtom(textLine);
            if (atomStepper.value == textLine.atomCount - 1)
            {
                if(textLine != textBlock.lastLine)
                {
                    textLine = textLine.nextLine;
                    atomStepper.maximum = textLine.atomCount - 1;
                    atomStepper.value = 0;
                }
            }
            showAtom(textLine, atomStepper.value);
        }
            
        private function createLines(textBlock, startX, startY, width, container)
        {
            var textLine:TextLine = textBlock.createTextLine (null, width);
            while (textLine)
            {
                textLine.x = startX;
                textLine.y = startY;
                startY += textLine.height + 2;
                container.addChild(textLine);
                textLine = textBlock.createTextLine (textLine, width);
            }
        }
            
        private function showAtom(textLine, i):void
        {
            var box:Sprite = new Sprite();
            var mcGraphics = box.graphics;
            var bounds:Rectangle = textLine.getAtomBounds(i);
            mcGraphics.lineStyle(1, 0xFF0000, 1.0);
            mcGraphics.drawRect(bounds.left, bounds.top, bounds.width, bounds.height);
            textLine.userData = textLine.addChild(box);
            displayAtomData(textLine,i);
        }
            
        private function displayAtomData(textLine, i)
        {
            if(atomDataContainer != null)
                removeChild(atomDataContainer);
            atomDataContainer=new Sprite();
            var format = new ElementFormat(fontDescriptionNormal);
            format.color = 0x00000FF;
            var n:int = 0;
            var nxtY:Number = 0;
            var atomInfo:String = "value of getAtomBidiLevel() is: " + textLine.getAtomBidiLevel(i)+"\n"
            +"value of getAtomCenter() is: " + textLine.getAtomCenter(i)+"\n"
            +"value of getAtomIndexAtCharIndex() is: " + textLine.getAtomIndexAtCharIndex(i)+"\n"
            +"value of getAtomTextBlockBeginIndex() is: " + textLine.getAtomTextBlockBeginIndex(i)+"\n"
            +"value of getAtomTextBlockEndIndex() is: " + textLine.getAtomTextBlockEndIndex(i)+"\n"
            +"value of getAtomTextRotation() is: " + textLine.getAtomTextRotation(i)+"\n";
            var atomtextBlock:TextBlock = new TextBlock();
            var textElement3:TextElement = new TextElement(atomInfo, format);
            atomtextBlock.content = textElement3;
            createLines(atomtextBlock,20,200,500, atomDataContainer)
            addChild(atomDataContainer);
        }
            
        private function removeAtom(textLine):void
        {
            textLine.removeChild(textLine.userData);
        }
    }    
}