ElementFormat  - AS3

Especifica o tipo da linha de base no elemento contido para o qual alinhar as linhas de base dominantes dos elementos que têm este formato. Use constantes TextBaseline para essa propriedade.

O maior elemento vertical na linha determina as linhas de base, a menos que TextBlock.baselineFontDescription e TextBlock.baselineFontSize sejam definidos para substituir essa lógica.

O valor padrão é TextBaseline.USE_DOMINANT_BASELINE.

Para definir valores para essa propriedade, utilize os seguintes valores de string:

Elementos da API relacionados

Especifica a transparência dos elementos de linha afetados por este obect. Os valores válidos são de 0 (totalmente transparente) a 1 (totalmente opaco). Objetos exibidos com alpha definida como 0 são ativos, mesmo estando invisíveis.

O valor padrão é 1.

Elementos da API relacionados

Indica o deslocamento da linha de base do elemento em pixels.

O elemento é deslocado de dominantBaseline de acordo com esse valor. O deslocamento é adicionado na posição y dos membros do elemento, logo, em texto não girado, um deslocamento de linha de base positivo move o elemento para baixo e o deslocamento de linha de base negativo, para cima.

O valor padrão é 0,0, o que indica não haver deslocamento.

A oportunidade de quebra de linha aplicada ao texto. Essa propriedade determina os caracteres que podem ser usados na quebra de texto em várias linhas. Use constantes BreakOpportunity para essa propriedade.

O valor padrão é BreakOpportunity.AUTO.

Para definir valores para essa propriedade, utilize os seguintes valores de string:

Elementos da API relacionados

Indica a cor do texto. Um inteiro que contém três componentes RGB de 8 bits; por exemplo, 0xFF0000 é vermelho e 0x00FF00, verde.

O valor padrão é 0x000000 que é o preto.

As maiúsculas/minúsculas do dígito usadas no texto. As maiúsculas/minúsculas de dígitos afetam o estilo e o posicionamento de grupos de caracteres numéricos. Use constantes DigitCase para essa propriedade.

O valor padrão é DigitCase.DEFAULT.

Para definir valores para essa propriedade, utilize os seguintes valores de string:

Elementos da API relacionados

A largura do dígito usada no texto. Use constantes DigitWidth para essa propriedade.

O valor padrão é DigitWidth.DEFAULT.

Para definir valores para essa propriedade, utilize os seguintes valores de string:

Elementos da API relacionados

Especifica o tipo da linha de base para usar como a linha de base dominante. A linha de base dominante está alinhada com a linha de base de alinhamento para determinar a posição vertical do elemento na linha. Use constantes TextBaseline para essa propriedade.

O conteúdo do elemento determina as linhas de base. No caso de um TextElement, a fonte e o tamanho do ponto determinam as linhas de base. No caso de um GraphicElement, a altura do elemento determina as linhas de base.

O valor padrão é TextBaseline.ROMAN.

Para definir valores para essa propriedade, utilize os seguintes valores de string:

Elementos da API relacionados

Um objeto cujas propriedades descrevem uma fonte.

O valor padrão é um objeto FontDescription padrão construído.

Quando a propriedade fontDescription é definido, o objeto FontDescription fornecido é bloqueado: a propriedade locked é definida como true. Um objeto FontDescription bloqueado não pode ser modificado.

Elementos da API relacionados

O tamanho do texto, em pixels.

O valor padrão é 12,0.

O kerning ajusta os pixels entre determinados pares de caracteres para aprimorar a legibilidade. O kerning é suportado por todas as fontes que têm tabelas de kerning.

O valor padrão é Kerning.ON.

Para estabelecer valores desta propriedade, use as seguintes constantes na classe de Kerning de espaço:

Elementos da API relacionados

O nível de ligatura usado no texto. Ocorre uma ligatura quando duas ou mais letras são unidas como um único glifo. As ligaturas geralmente substituem caracteres consecutivos que compartilham componentes comuns, como os pares de letras 'fi', 'fl' ou 'ae'. Elas são usadas com conjuntos de caracteres latinos e não latinos. Use constantes LigatureLevel para essa propriedade.

O valor padrão é LigatureLevel.COMMON.

Para definir valores para essa propriedade, utilize os seguintes valores de string:

Elementos da API relacionados

O local do texto. Controla as transformações de maiúsculas/minúsculas e forma. São usados identificadores de localidade padrão. Por exemplo, "en", "en_US" e "en-US" são todos inglês e "ja", japonês. Ver iso639-2 lista de códigos de uma lista de códigos de localidade.

O valor padrão é "en".

Indica se o objeto ElementFormat está bloqueado. Se for true, o ElementFormat não poderá ser modificado. Chame ElementFormat.clone() para obter uma cópia desbloqueada do objeto ElementFormat.

Define o giro aplicado a glifos individuais. Use constantes definidas na classe TextRotation para esta propriedade.

O valor padrão é TextRotation.AUTO.

O giro final de qualquer glifo é a soma de ElementFormat.textRotation, ContentElement.textRotation e TextBlock.lineRotation.

Você normalmente usa esta propriedade do texto asiático onde os caracteres devem ser girados para exibir propriamente no layout vertical. Usar TextRotation. AUTO em combinação com TextBlock.lineRotation = TextRotation. ROTATE_90 para realizar isto.

A definição dessa propriedade em fontes que não contêm informações de layout vertical pode apresentar resultados indesejáveis. Fontes que contêm uma tabela vmtx ou VORG, por exemplo, a fonte em japonês "MS Mincho", e funcionam corretamente porque as tabelas fornecem os dados de que o mecanismo de layout precisa para conseguir o layout correto. As fontes, como Verdana, não funcionam porque não contêm as informações necessárias.

Para definir valores para essa propriedade, utilize os seguintes valores de string:

Elementos da API relacionados

O espaçamento ou kerning manual aplicados à esquerda de cada glifo, em pixels. Se kerning for ativado, o valor trackingLeft será adicionado aos valores na tabela de kerning da fonte. Se kerning for desativado, o valor trackingLeft será usado como valor de kerning manual. Oferece suporte a valores positivos e negativos.

Geralmente, o valor de espaçamento desejado é dividido entre trackingRight e trackingLeft. Caso contrário, em texto de direção mista, haverá o dobro de espaçamento em um limite bidirecional e nenhum no outro.

O valor padrão é 0,0.

Exemplo:

          //positive tracking added to kerning
          var ef1:ElementFormat = new ElementFormat();
          ef1.kerning = flash.text.engine.Kerning.ON;
          ef1.trackingLeft = 0.5;
     
          //negative manual kerning
          var ef2:ElementFormat = new ElementFormat();
          ef2.kerning = flash.text.engine.Kerning.OFF;
          ef2.trackingLeft = -1.0;
     

O espaçamento ou kerning manual aplicados à direita de cada glifo, em pixels. Se kerning for ativado, o valor trackingRight será adicionado aos valores na tabela de kerning da fonte. Se kerning for desativado, o valor trackingRight será usado como valor de kerning manual. Oferece suporte a valores positivos e negativos.

Geralmente, o valor de espaçamento desejado é dividido entre trackingRight e trackingLeft. Caso contrário, em texto de direção mista, haverá o dobro de espaçamento em um limite bidirecional e nenhum no outro.

O valor padrão é 0,0.

Exemplo:

          //positive tracking added to kerning
          var ef1:ElementFormat = new ElementFormat();
          ef1.kerning = flash.text.engine.Kerning.ON;
          ef1.trackingRight = 0.5;
     
          //negative manual kerning
          var ef2:ElementFormat = new ElementFormat();
          ef2.kerning = flash.text.engine.Kerning.OFF;
          ef2.trackingRight = -1.0;
     

As maiúsculas/minúsculas tipográficas usadas no texto. Use constantes definidas na classe TypographicCase para esta propriedade.

O valor padrão é true.

Para definir valores para essa propriedade, utilize os seguintes valores de string:

Elementos da API relacionados

Cria um objeto ElementFormat.

Constrói uma cópia clonada desbloqueada de ElementFormat.

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class ElementFormat_cloneExample extends Sprite {
        private var ef1:ElementFormat;
        private var ef2:ElementFormat;
        
        public function ElementFormat_cloneExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontLookup = flash.text.engine.FontLookup.DEVICE;
            fd.fontName = "Palatino";

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize=20;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            
            ef2 = (ef1.locked) ? ef1.clone() : ef1;    
            ef2.fontSize = 32;

            tb.content.elementFormat=ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            
        }
    }    
}

Retorna um objeto FontMetrics com propriedades que descrevem emBox, a posição do tachado, a espessura do tachado, a posição do sublinhado e a espessura do sublinhado da fonte especificada por fontDescription e fontSize.

Elementos da API relacionados

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class FontMetricsExample extends Sprite {
        
        public function FontMetricsExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontName = "Garamond";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize = 24;            
            var fm1:FontMetrics = ef1.getFontMetrics();

            trace(fm1.emBox);
            trace(fm1.strikethroughOffset);
            trace(fm1.strikethroughThickness);
            trace(fm1.subscriptScale);
            trace(fm1.subscriptOffset);
            trace(fm1.superscriptScale);
            trace(fm1.superscriptOffset);
            trace(fm1.underlineOffset);
            trace(fm1.underlineThickness);
            
            
        }
    }    
}

O exemplo cria dois objetos ElementFormat e define várias propriedades. Ele atribui o novo ElementFormats a um objeto TextElement, que foi atribuído como conteúdo de TextBlock. Observe que alterar ElementFormat de TextElement não afeta TextLines criado anteriormente pelo TextBlock pai.

package {

    import flash.display.Sprite;
    import flash.text.engine.*;

    
    public class ElementFormatExample extends Sprite {
        
        public function ElementFormatExample():void {
            var fd:FontDescription = new FontDescription();
            fd.fontName = "Garamond";
            fd.fontWeight = flash.text.engine.FontWeight.BOLD;

            var ef1:ElementFormat = new ElementFormat(fd);
            ef1.fontSize = 30;
            ef1.color = 0xFF0000;
            ef1.alpha = 100;
            ef1.kerning = flash.text.engine.Kerning.ON;
            ef1.trackingRight = 2;
            ef1.typographicCase = flash.text.engine.TypographicCase.UPPERCASE;
            ef1.alignmentBaseline = flash.text.engine.TextBaseline.DESCENT;
            ef1.ligatureLevel = flash.text.engine.LigatureLevel.EXOTIC;
            
            var ef2:ElementFormat = new ElementFormat(fd);
            ef2.fontSize = 30;
            ef2.color = 0xFF0000;
            ef2.alpha = 0.3;
            ef2.kerning = flash.text.engine.Kerning.OFF;
            ef2.typographicCase = flash.text.engine.TypographicCase.LOWERCASE;
            ef2.digitCase = flash.text.engine.DigitCase.OLD_STYLE;
            ef2.textRotation = flash.text.engine.TextRotation.ROTATE_180;
            
            var str:String = "This is flash text 0123456789";
            var tb:TextBlock = new TextBlock();
            var te1:TextElement = new TextElement(str, ef1);
            tb.content = te1;
            var line1:TextLine = tb.createTextLine(null, 600);
            addChild(line1);
            line1.x = 15;
            line1.y = 30;

            tb.content.elementFormat = ef2;
            var line2:TextLine = tb.createTextLine(null, 600);
            addChild(line2);
            line2.x = 15;
            line2.y = 60;
            
        }
    }    
}