TextBlock  - AS3

Especifica que você deseja aprimorar a aparência da tela em detrimento da fidelidade de impressão de WYSIWYG (what-you-see-is-what-you-get, você tem o que vê). Para plataformas e fontes que não suportam o posicionamento de glifo de subpixel durante a renderização da fonte do dispositivo, mas suportam escala não linear, definir essa propriedade como true ativa o uso daquelas medidas com algum prejuízo à fidelidade de impressão de WYSIWYG, em particular para tamanhos de ponto pequenos. Fonte não linear escalando trabalhos com escala seletiva da larguras dos glifos individuais para ocultar lacunas pouco visíveis causadas por encaixe de pixel.

Em plataformas que suportam o posicionamento de glifo de subpixel, esta marca é ignorada.

Esta marca não tem nenhum efeito na renderização de fontes incorporadas

O valor padrão é true.

A fonte usada para determinar as linhas de base de todas as linhas criadas no bloco, independentemente do conteúdo. As linhas de base dependem da fonte e do tamanho da fonte.

O valor padrão é null. Quando a fonte da linha de base é null, o tamanho da linha de base é ignorado e a linha de base de qualquer linha tem como base a fonte e o tamanho do maior texto da linha. Quando você especifica baselineFontDescription e baselineFontSize, eles determinam as linhas de base de todas as linhas do bloco de texto, independentemente do conteúdo. A combinação costuma ser mais útil na tipografia asiática.

Elementos da API relacionados

O tamanho da fonte usado para calcular as linhas de base para as linhas criadas no bloco. As linhas de base dependem da fonte e do tamanho da fonte.

O valor padrão é 12. Quando a fonte da linha de base é null, o tamanho é ignorado e a linha de base de qualquer linha tem como base a fonte e o tamanho do maior texto da linha.

Elementos da API relacionados

Especifica a linha de base que está em y=0 para as linhas criadas nesse bloco. Valores válidos da propriedade são encontrados nos membros da classe TextBaseline.

O valor padrão é TextBaseline.ROMAN.

Para definir valores para essa propriedade, utilize os seguintes valores de string:

Elementos da API relacionados

Especifica o nível de incorporação do parágrafo bidirecional no nível do bloco de texto. Em geral, use 0 para parágrafos LTR (inglês, japonês etc.) e 1 para parágrafos RTL (árabe, hebraico etc.). O uso de valores diferentes de 0 ou 1 está reservado para casos especiais - consulte UAX#9, "Algoritmo Unicode Bidirecional" (http://www.unicode.org/reports/tr9/) para obter detalhes.

O valor padrão é 0.

Modificar bidiLevel altera a validade de todas as linhas quebradas anteriormente para TextLineValidity.INVALID. Depois de alterar bidiLevel, a propriedade firstInvalidLine se iguala à propriedade firstLine e você deve requebrar todas as linhas em TextBlock.

Elementos da API relacionados

package {
    
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_bidiLevelExample extends Sprite {
        
        public function TextBlock_bidiLevelExample():void {             
            var fontSize:Number = 36;

            var format:ElementFormat = new ElementFormat();        
            format.fontDescription = new FontDescription("Adobe Hebrew");
            format.fontSize = fontSize;
            var y:Number = 0;
            var leading:Number = fontSize * 0.2;
            var text:String = "abc" + String.fromCharCode(0x05D0, 0x05D1, 0x05D2);

            var textBlock:TextBlock = new TextBlock();
            textBlock.content = new TextElement(text, format);
                        
            // bidiLevel even
            textBlock.bidiLevel = 0;
            var textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;
            textLine.y = y;
            y += textLine.descent;
            addChild(textLine);      
            
            // bidiLevel odd
            textBlock.content = new TextElement(text, format);
            textBlock.bidiLevel = 1;
            textLine = textBlock.createTextLine(null, 400);
            y += leading + textLine.ascent;          
            textLine.y = y;
            addChild(textLine);   
        }
    }
}

Mantém o conteúdo do bloco de texto. Porque ContentElement é classe base, atribua content a uma instância de subclasse ContentElement: TextElement, GraphicElement ou GroupElement. Um objeto TextElement contém String; um objeto GraphicElement contém DisplayObject e GroupElement contém um objeto Vector que contém um ou mais objetos TextElement, GraphicElement, ou outros objetos GroupElement. Use TextElement em um parágrafo de texto homogêneo, GraphicElement em um gráfico e GroupElement em uma combinação entre elementos de texto e gráficos ou várias ocorrências desses elementos, bem como outros objetos GroupElement.

O valor padrão é null.

A modificação da propriedade content altera a validade de todas as linhas criadas anteriormente para TextLineValidity.INVALID. Depois de alterar content, a propriedade firstInvalidLine se iguala à propriedade firstLine e você deve quebrar novamente todas as linhas em TextBlock.

Elementos da API relacionados

Identifica a primeira linha do bloco de texto em que TextLine.validity não é igual a TextLineValidity.VALID.

O valor padrão é null.

Elementos da API relacionados

O primeiro TextLine no TextBlock, se houver.

O valor padrão é null.

Elementos da API relacionados

O último TextLine no TextBlock, se houver.

O valor padrão é null.

Elementos da API relacionados

Gira as linhas de texto do bloco como uma unidade. Chame o método createTextLine() depois de definir lineRotation para que ele entre em vigor. O valor padrão é TextRotation.ROTATE_0.

O giro final de qualquer glifo depende dos valores de ElementFormat.textRotation, ContentElement.textRotation e TextBlock.lineRotation.

TextBlock.lineRotation costuma ser usado em texto asiático. Para criar um parágrafo de texto vertical em japonês, siga este procedimento:

1. Defina a propriedade TextBlock.lineRotation como TextRotation.ROTATE_90.
2. Deixe a propriedade ElementFormat.textRotation do conteúdo como o padrão, TextRotation.AUTO.

Use as seguintes constantes, definidas na classe TextRotation, para definir o valor como esta propriedade:

Elementos da API relacionados

package {
    import flash.display.Sprite;
    import flash.text.engine.FontDescription;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.TextRotation;
    import flash.text.engine.ElementFormat;
    
    public class TextBlock_lineRotationExample extends Sprite {
        
        public function TextBlock_lineRotationExample():void {
            var Japanese:String = String.fromCharCode(
                0x5185, 0x95A3, 0x5E9C, 0x304C, 0x300C, 0x653F, 0x5E9C, 0x30A4,
                0x30F3, 0x30BF, 0x30FC, 0x30CD, 0x30C3, 0x30C8, 0x30C6, 0x30EC, 
                0x30D3, 0x300D, 0x306E, 0x52D5, 0x753B, 0x914D, 0x4FE1, 0x5411, 
                0x3051, 0x306B, 0x30A2, 0x30C9, 0x30D3, 0x30B7, 0x30B9, 0x30C6, 
                0x30E0, 0x30BA, 0x793E, 0x306E
            ) +
            "FMS 2" +
            String.fromCharCode(0x3092, 0x63A1, 0x7528, 0x3059, 0x308B, 0x3068, 
                0x767a, 0x8868, 0x3057, 0x307e, 0x3057, 0x305F, 0x3002);

            var fontDescription:FontDescription = new FontDescription("MS Mincho");
            var format:ElementFormat = new ElementFormat();
            format.fontSize = 15;
            format.fontDescription = fontDescription;
                        
            var textElement:TextElement = new TextElement(Japanese, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement;
            textBlock.lineRotation = TextRotation.ROTATE_90;

            var linePosition:Number = this.stage.stageWidth - 120;
            var previousLine:TextLine = null;
        
            while (true) {
                var textLine:TextLine = textBlock.createTextLine(
                    previousLine, 
                    300);
                if (textLine == null) 
                    break;
                textLine.y = 30;    
                textLine.x = linePosition;
                linePosition -= 24;
                addChild(textLine);                
                previousLine = textLine;
            }        
        }
    }
}

Especifica as paradas de tabulação do texto no bloco de texto, na forma de um Vector de objetos TabStop.

O valor padrão é null, o que significa que não há paradas de tabulação ativas. Quando nenhuma parada de tabulação é especificada (ou o ponto de inserção está além da última parada de tabulação especificada), o tempo de execução cria tabulações de meia-polegada por padrão.

Quando a propriedade tabStops é definida, o TextBlock cria uma cópia do objeto Vector para uso interno. A modificação do Vector original ou do seu conteúdo não afeta o TextBlock. Quando a propriedade tabStops é consultada, é retornada uma cópia do Vector interno. Novamente, a modificação do Vector retornado ou do seu conteúdo não afeta o TextBlock.

Elementos da API relacionados

Especifica o TextJustifier a ser usado durante a criação de linha.

O valor padrão é um objeto TextJustifier padrão construído.

Quando a propriedade textJustifier é definida, o TextBlock cria uma cópia do objeto para uso interno. A modificação do objeto original não afeta o TextBlock. Quando a propriedade textJustifier é consultada, é retornada uma cópia do objeto interno. Novamente, a modificação do objeto retornado não afeta o TextBlock.

Elementos da API relacionados

Indica o resultado de uma operação createTextLine(). Alterar o conteúdo do bloco invalida linhas quebradas anteriormente e redefine a propriedade como null.

O valor padrão é null.

Valores da propriedade são encontrados em TextLineCreationResult

Elementos da API relacionados

Fornece uma maneira de o aplicativo associar dados arbitrários ao bloco de texto. Os dados podem ser informações referentes ao conteúdo, por exemplo, uma data de revisão ou o nome do autor, ou podem ser dados armazenados em cache que são usados durante o processamento.

Cria um objeto TextBlock

Elementos da API relacionados

Instrui o bloco de texto a criar uma linha de texto a partir de seu conteúdo, começando no ponto especificado pelo parâmetro previousLine e quebrando no ponto especificado pelo parâmetro largura. A linha de texto é um objeto TextLine, que você pode adicionar à lista de exibição.

A quebra de linhas em um intervalo de um bloco de texto que já tenha sido quebrado pode alterar a validade das linhas na área em que ocorre a quebra e além dela. O status das linhas pode mudar de VALID para INVALID ou POSSIBLY_INVALID. Caso uma linha recém-quebrada se alinhe perfeitamente com uma linha quebrada anteriormente cujo status é POSSIBLY_INVALID, o status dessa linha quebrada anteriormente e de todas as linhas POSSIBLY_INVALID seguintes é restaurado como VALID. A validade das linhas que foram definidas como valores que não são membros de TextLineValidity não é alterada para VALID, mas pode ser alterada para INVALID. Verifique a propriedade firstInvalidLine depois de qualquer alteração feita no bloco de texto para ver onde começar ou continuar quebrando linhas de texto.

Você pode criar quebras de linha artificiais incluindo o caractere ZWSP (Unicode Zero Width Space, Espaço de Largura Zero Unicode) no texto. Isso pode ser útil para idiomas como tailandês, que precisam de um dicionário para quebras de linha corretas. O tempo de execução do Flash não inclui esse dicionário.

Para reduzir a sobrecarga da memória, quando todas as linhas desejadas foram criadas, a menos que se espere que as linhas precisem ser repetidamente requebradas, devido a, por exemplo, redimensão do container, o usuário deve chamar o método releaseLineCreationData() permitindo ao bloco de texto desfazer-se dos dados temporários associados à quebra de linha.

Parâmetros

Elementos da API relacionados

package {
    import flash.display.Sprite;
    import flash.text.engine.TextBlock;
    import flash.text.engine.TextElement;
    import flash.text.engine.TextLine;
    import flash.text.engine.ElementFormat;
    import flash.text.engine.FontDescription;
    
    public class TextBlock_createTextLineExample extends Sprite {
        
        public function TextBlock_createTextLineExample():void {
            
            var str:String = "I am a TextElement, created from a String and assigned " +
            "to the content property of a TextBlock. The createTextLine() method " +
            "then created these lines, 300 pixels wide, for display." ;
            
            var fontDescription:FontDescription = new FontDescription("Arial");
            var format:ElementFormat = new ElementFormat(fontDescription);
            format.fontSize = 16;
            var textElement:TextElement = new TextElement(str, format); 
            var textBlock:TextBlock = new TextBlock();
            textBlock.content = textElement; 
            createLines(textBlock); 
        }
        
        private function createLines(textBlock:TextBlock):void 
        {            
            var lineWidth:Number = 300;
            var xPos:Number = 15.0;
            var yPos:Number = 20.0;
            
            var textLine:TextLine = textBlock.createTextLine (null, lineWidth);
            while (textLine)
            {
                textLine.x = xPos;
                textLine.y = yPos;
                yPos += textLine.height + 2;
                addChild (textLine);
                textLine = textBlock.createTextLine (textLine, lineWidth);
            }
        }
    }
}

Descarta o conteúdo subjacente de TextBlock como uma string XML. Isso pode ser útil no teste automático e inclui texto, formatação e informações de layout.

O seguinte descreve a saída:

	 >block<
	 	[0-N LINE]
	 >/block<
	 

Para uma descrição da saída de cada linha, consulte o método TextLine.dump().

Observação: o conteúdo e o formato da saída pode ser alterado no futuro. A Adobe não garante a compatibilidade do método com versões anteriores.

Elementos da API relacionados

Localiza o índice do próximo limite de átomo usando o índice do caractere especificado sem incluir o caractere no índice especificado. Os caracteres entre limites de átomo são combinados para formar um só átomo em TextLine como, por exemplo, um "e" e uma combinação de acento agudo.

Parâmetros

Elementos da API relacionados

Localiza o índice do próximo limite de palavra usando o índice do caractere especificado sem incluir o caractere no índice especificado. Os limites de palavra são determinados com base nas propriedades Unicode dos caracteres.

Parâmetros

Localiza o índice do limite de núcleo anterior do índice do caractere especificado sem incluir o caractere no índice especificado. Os caracteres entre limites de átomo são combinados para formar um só átomo em TextLine como, por exemplo, um "e" e uma combinação de acento agudo.

Parâmetros

Elementos da API relacionados

Localiza o índice do limite de palavra anterior do índice do caractere especificado sem incluir o caractere no índice especificado. Os limites de palavra são determinados com base nas propriedades Unicode dos caracteres.

Parâmetros

Retorna o TextLine contendo o caractere especificado pelo parâmetro charIndex.

Parâmetros

Instrui o bloco de texto a reutilizar uma linha de texto existente a partir de seu conteúdo, começando no ponto especificado pelo parâmetro previousLine e quebrando-a no ponto especificado pelo parâmetro width. A linha de texto é um objeto TextLine, que você pode adicionar à lista de exibição. Com a reutilização de uma linha de texto existente, o desempenho é melhorado por causa da redução na criação de objetos.

A textLine a ser recriado será liberada de qualquer bloco de texto em que estiver, se houver algum. Além disso, todas as propriedades, inclusive propriedades herdadas de DisplayObjectContainer, InteractiveObject e DisplayObject são redefinidas com seus valores padrão. Finalmente, todos os filhos da linha são removidos, inclusive elementos gráficos e outras decorações, e todos os ouvintes de evento na linha são removidos. Para melhorar o desempenho, a única exceção a esta redefinição completa é que a própria linha não seja removida do seu pai.

A quebra de linhas em um intervalo de um bloco de texto que já tenha sido quebrado pode alterar a validade das linhas na área em que ocorre a quebra e além dela. O status das linhas pode mudar de VALID para INVALID ou POSSIBLY_INVALID. Caso uma linha recém-quebrada se alinhe perfeitamente com uma linha quebrada anteriormente cujo status é POSSIBLY_INVALID, o status dessa linha quebrada anteriormente e de todas as linhas POSSIBLY_INVALID seguintes é restaurado como VALID. A validade das linhas que foram definidas como valores que não são membros de TextLineValidity não é alterada para VALID, mas pode ser alterada para INVALID. Verifique a propriedade firstInvalidLine depois de qualquer alteração feita no bloco de texto para ver onde começar ou continuar quebrando linhas de texto.

Você pode criar quebras de linha artificiais incluindo o caractere ZWSP (Unicode Zero Width Space, Espaço de Largura Zero Unicode) no texto. Isso pode ser útil para idiomas como tailandês, que precisam de um dicionário para quebras de linha corretas. O tempo de execução do Flash não inclui esse dicionário.

Para reduzir a sobrecarga da memória, quando todas as linhas desejadas foram criadas, a menos que se espere que as linhas precisem ser repetidamente requebradas, devido a, por exemplo, redimensão do container, o usuário deve chamar o método releaseLineCreationData() permitindo ao bloco de texto desfazer-se dos dados temporários associados à quebra de linha.

Parâmetros

Elementos da API relacionados

var elementFormat:ElementFormat = new ElementFormat();
elementFormat.fontDescription = new FontDescription("Arial");
elementFormat.fontSize = 48;

var textElement:TextElement = new TextElement("Text you'll never see", elementFormat)
var textBlock:TextBlock = new TextBlock(textElement);
var textLine:TextLine = textBlock.createTextLine();
textLine.x = 50;
textLine.y = 50;
addChild(textLine);

// Reuse the element format to preserve the text formatting
var elementTwo:TextElement = new TextElement("Text you see", elementFormat);  
textBlock.content = elementTwo;
textBlock.recreateTextLine(textLine);

// Set the position (and any other display object properties like alpha, children, etc.)
// otherwise, they're all set to default properties.
textLine.x = 50;  
textLine.y = 50;

Instrui que o bloco de texto a liberar todos os dados temporários associados com a criação de linhas de texto. Para minimizar a impressão de um aplicativo, você deve chamar o método releaseLineCreationData() quando estiver criando linhas de texto de um bloco de texto. Contudo, para maximizar o desempenho para requebrar as linhas (por exemplo quando o container é redimensionado) o método releaseLineCreationData() não deve ser invocado. Ele está pronto para o aplicativo equilibrar memória versus desempenho.

O processo recomendado para o texto que não é esperado modificar é: inicialize um bloco de texto, chame o métodocreateTextLine() tantas vezes quanto necessário para criar a saída desejada, e a seguir chame o método releaseLineCreationData().

Elementos da API relacionados

Remove uma faixa de linhas de texto da lista de linhas mantidas por TextBlock. Isso permite que o lixo das linhas seja coletado caso não existam outras referências.

Define os membros textBlock, nextLine e previousLine das linhas removidas como null. Defina a validity das linhas removidas e de todas as linhas posteriores às linhas removidas em TextBlock como TextLineValidity.INVALID.

Parâmetros

Elementos da API relacionados