AccessibilityImplementation  - AS3

Indica um código de erro. Os erros são indicados fora da banda, em vez de em valores de retorno. Para indicar um erro, defina a propriedade errno para um dos códigos de erro documentados no apêndice de Constantes da AccessibilityImplementation. Isto faz que o seu valor de retorno seja ignorado. A propriedade errno da sua AccessibilityImplementation sempre é compensada (definida como zero) pelo player antes que qualquer método AccessibilityImplementation seja invocado.

Elementos da API relacionados

Usado para criar um tronco de acessibilidade do componente. Se um componente for liberado sem uma implementação de acessibilidade ActionScript, a Adobe recomenda que você adicione um tronco de acessibilidade de componente. Este tronco faz que o Flash Player, com objetivos de acessibilidade, trate o componente como um gráfico simples, em vez de expor a estrutura interna de botões, campos de texto, etc., dentro do componente.

Para criar um tronco de acessibilidade componente, subclassifique a classe AccImpl pertinente, sobrescrevendo o tronco de propriedade com um valor true.

Elementos da API relacionados

Construtor estático. Não instancie diretamente AccessibilityImplementation chamando o seu construtor. Em vez disso, crie novas implementações de acessibilidade estendendo a classe mx.accessibility.AccImpl para cada novo componente.

Elementos da API relacionados

Um método IAccessible que executa a ação padrão associada ao componente que esta AccessibilityImplementation representa ou um do seus elementos filho.

Implemente este método apenas se o AccessibilityImplementation representar um elemento de interface do usuário que tenha uma ação padrão no modelo MSAA.

Se você estiver implementando accDoDefaultAction() apenas da própria AccessibilityImplementation ou apenas dos seus elementos filho, precisará em alguns casos indicar que não há nenhuma ação padrão do determinado childID que foi passado. Faça isto configurando a propriedade errno como E_MEMBERNOTFOUND.

Parâmetros

     override public function accDoDefaultAction(childID:uint):void
     {
         if (childID > 0)
             ListBase(master).selectedIndex = childID - 1;
     }

Método de MSAA para retornar um DisplayObject ou Retângulo especificação da caixa delimitadora de um elemento de filho no AccessibilityImplementation.

Este método nunca é invocado com um childID de zero. Se o seu AccessibilityImplementation nunca conterá elementos filho, você não deverá implementar este método. Se o seu AccessibilityImplementation puder conter elementos filho, este método é obrigatório.

Você pode satisfazer normalmente os requisitos deste método retornando um objeto que represente o próprio elemento filho. Isto funciona quando o elemento filho é um DisplayObject. Nestas caixas, simplesmente retorne o DisplayObject que equivale ao nome da instância associada ao objeto visual relevante na lista de exibição.

Se um elemento filho não se qualificar para a técnica descrita acima, você poderá fazer a matemática de caixa delimitadora por si mesmo e retornar um Retangle com as propriedades: x , y , width e height. Os membros x e y especificam o canto superior esquerdo da caixa delimitadora, e os membros width e height especificam o seu tamanho. Os quatro membros devem estar em unidades de pixels de Palco e serem relativos à origem do componente que o AccessibilityImplementation representa. As propriedades x e y podem ter valores negativos, desde que a origem de um DisplayObject não esteja necessariamente no seu canto superior esquerdo.

Se o elemento de filho especificado por childID não é visível (isto é, get_accState daquele filho devolveria um valor inclusive STATE_SYSTEM_INVISIBLE ), você pode retornar nulidade de accLocation . Você também pode retornar um Retangle representando as coordenadas nas quais o elemento filho apareceria se estivesse visível.

Parâmetros

Saiba mais

Elementos da API relacionados

     override public function accLocation(childID:uint):*
     
     {
         var listBase:ListBase = ListBase(master);
     
         var index:uint = childID - 1;
         
         if (index < listBase.verticalScrollPosition ||
             index >= listBase.verticalScrollPosition + listBase.rowCount)
         {
             return null;
         }
         var item:Object = getItemAt(index);
     
         return listBase.itemToItemRenderer(item);
     }
     

Método IAccessible para alterar a seleção no componente que esta AccessibilityImplementation representa.

O parâmetro childID sempre será diferente de zero. Este método sempre se aplica a um elemento de filho em vez de ao componente total; o próprio Flash Player gerencia a seleção do componente total.

O parâmetro selFlag é um campo de bit composto de uma ou várias constantes de indicador de seleção, que permite a um cliente MSAA indicar como o item referido pelo childID deve ser selecionado ou tomar o foco. O que segue são as descrições das constantes de indicador de seleção e o que elas comunicam à implementação de acessibilidade. Por uma questão prática, a maior parte das implementações deste método nas implementações de acessibilidade que herdam do Flex mx.accessibility. A classe ListBaseAccImpl não ignora a constante selFlag e, em vez disso, confia no comportamento de seleção de teclado do componente para processar a multisseleção.

O parâmetro selFlag pode conter ou não o indicador SELFLAG_TAKEFOCUS. Se contiver, você deverá definir o foco do filho no childID especificado e, a menos que SELFLAG_EXTENDSELECTION também esteja presente, tornar aquele elemento filho a âncora de seleção. De outra maneira, o foco do filho e a âncora de seleção deverão permanecer inalterados, apesar de que os indicadores adicionais descritos abaixo possam modificar a seleção.

O argumento selFlag sempre conterá um dos quatro indicadores, que indicam que tipo de modificação de seleção é desejada:

• SELFLAG_TAKESELECTION: Limpa qualquer seleção existente e define a seleção para o childID especificado.

• SELFLAG_EXTENDSELECTION: calcule o intervalo de elementos filho entre e inclusive a âncora de seleção e o especificado childID. Se SELFLAG_ADDSELECTION está presente, adicionar todos destes elementos filho à seleção. Se SELFLAG_REMOVESELECTION está presente, remover tudo destes elementos filho da seleção. Se nenhum SELFLAG_ADDSELECTION nem SELFLAG_REMOVESELECTION está presente, todos destes elementos filho devem empreender a estatal de seleção de âncora de seleção: se a âncora de seleção for selecionada, adicione estes elementos filho à seleção; de outra maneira retire-os da seleção.

• SELFLAG_ADDSELECTION (sem SELFLAG_EXTENDSELECTION): Adicione o childID especificado à seleção.

• SELFLAG_REMOVESELECTION (sem SELFLAG_EXTENDSELECTION): Remova childID especificado da seleção.

Observe isto para um não componente não multisselecionável. os únicos valores de parâmetro selFlag válidos são SELFLAG_TAKEFOCUS e SELFLAG_TAKESELECTION. Teoricamente, você também poderia escolher suportar SELFLAG_REMOVESELECTION para um componente não multisselecionável que permitiu ao usuário forçar uma seleção null, mas, na prática, a maior parte dos componentes não multisselecionáveis não funciona desta maneira, e os clientes MSAA podem não tentar este tipo da operação.

Se você encontrar indicadores que pareçam inválidos, defina errnocomoE_INVALIDARG.

Finalmente, observe que quando accSelect é invocado, o Flash Player assegura que ele tenha host focus (o foco da janela do seu aplicativo de contêiner), e que o seu componente tenha o foco dentro do Flash Player.

Parâmetros

Saiba mais

Elementos da API relacionados

override public function accSelect(selFlag:uint, childID:uint):void
     {
         
         var listBase:ListBase = ListBase(master);
         
         var index:uint = childID - 1;
         
         if (index >= 0 && index < listBase.dataProvider.length)
             listBase.selectedIndex = index;
     }
     

Método de MSAA para retornar a ação de padrão do componente que este AccessibilityImplementation representa ou de um dos seus elementos de filho.

Implemente este método só se o AccessibilityImplementation representar um elemento UI que tem uma ação de padrão no modelo MSAA; esteja seguro de retornar a string exata que o modelo MSAA especifica. Por exemplo, a string de ação padrão de um Componente de botão é "Prensa".

Se você está implementando get_accDefaultAction apenas do próprio AccessibilityImplementation, ou apenas dos seus elementos filho, você precisará em alguns casos indicar que não há nenhuma ação padrão para o childID específico que foi passado. Faça isto retornando simplesmente null .

Parâmetros

Saiba mais

Elementos da API relacionados

override public function get_accDefaultAction(childID:uint):String
     {
         if (childID == 0)
             return null;
     
         return "Double Click";
     }

Método MSAA para retornar o ID do inteiro sem sinal do elemento filho, se houver, que este filho focaliza no componente. Se nenhum filho fizer o filho enfoque, o método retorna o zero.

Saiba mais

Elementos da API relacionados

override public function get_accFocus():uint
     {
     var index:uint = ListBase(master).selectedIndex;
     
     return index >= 0 ? index + 1 : 0;
     }

Método de MSAA para retornar o nome do componente que este AccessibilityImplementation representa ou para um dos seus elementos de filho.

No caso do próprio AccessibilityImplementation (childID == 0), se este método não for implementado ou não retornar um valor, o Flash Player usará o valor de propriedade AccessibilityProperties.name , se houver.

Para AccessibilityImplementations que pode ter elementos filho, este método deve ser implementado e deve retornar um valor de sequência quando childID é diferente de zero.

Dependendo do tipo do elemento da interface do usuário, os nomes em MSAA significam uma de duas coisas diferentes: um nome atribuído pelo autor ou conteúdo de texto real do elemento. Normalmente, uma própria AccessibilityImplementation cairá na categoria anterior. Sua propriedade name é um nome atribuído pelo autor. Os elementos filho sempre caem na segunda categoria. Seus nomes indicam o seu conteúdo de texto.

Quando a propriedade name de uma AccessibilityImplementation tem o significado de um nome atribuído pelo autor, há dois caminhos dos quais os componentes podem obter nomes dos autores. O primeiro significa nomes presentes no próprio componente; por exemplo, um componente da caixa de seleção poderia incluir um rótulo de texto que servisse como seu nome. A segunda-a retirada do primeiro — implica nomes especificados no interface do usuário e terminando em AccessibilityProperties.name. Esta opção de retirada permite aos usuários especificar nomes exatamente como seriam para qualquer outra entidade gráfica ou MovieClip.

Isto deixa três possibilidades para a própria AccessibilityImplementation ( childID == zero ):

• nome atribuído pelo autor dentro de componente. O método get_accName deve ser implementado e retornar um valor de sequência que contenha o nome da AccessibilityImplementation quando childID for zero. Se childID for zero, mas AccessibilityImplementation não tiver nenhum nome, get_accName deverá retornar uma string vazia para impedir o player de recorrer à propriedade AccessibilityProperties.name.

• Nome atribuído pelo autor na interface do usuário. Se o AccessibilityImplementation pode ter elementos de filho, o get_accName o método deve ser implementado mas não deve retornar um valor quando childID é zero. Se o AccessibilityImplementation nunca terá elementos filho, get_accName não deve ser implementado.

• Nome significando conteúdo. O método get_accName deve ser implementado e retornar um valor de string apropriado quando childID é zero. Se childId for zero, mas AccessibilityImplementation não tiver nenhum conteúdo, get_accName deverá retornar uma string vazia para impedir o player de recorrer à propriedade AccessibilityProperties.name .

Observe que para elementos filho (se o AccessibilityImplementation puder tê-los), a terceira caixa sempre se aplica. O get_accName o método deve ser implementado e deve retornar um valor de sequência apropriado quando childID é não zero.

Parâmetros

Saiba mais

Elementos da API relacionados

override public function get_accName(childID:uint):String
     {
         // Start with the name of the component's parent form 
          // if the component is contained within a form
         var accName:String = UIComponentAccImpl.getFormName(master);
     
         // If the element requested is the component itself, 
         // append the value of any assigned accessibilityProperties.name    
         if (childID == 0 && master.accessibilityProperties 
             && master.accessibilityProperties.name 
                 && master.accessibilityProperties.name != "")
             accName += master.accessibilityProperties.name + " ";
     
         // Append the value of the childIDs name 
     // returned by the component-specific override 
     // of the mx.accessibility.AccImpl.getName() utility function,
         // and append the component's status returned by the 
     // component-specific override of the 
     // mx.accessibility.AccImpl.getStatusName() utility function
         accName += getName(childID) + getStatusName();
     
     // Return the assembled String if it is neither empty nor null, 
     // otherwise return null
         return (accName != null && accName != "") ? accName : null;
     }

Método MSAA para retornar a função do sistema para o componente que esta AccessibilityImplementation representa ou um do seus elementos filho. As funções do sistema são predefinidas para todos os componentes no MSAA.

Parâmetros

Saiba mais

Elementos da API relacionados

Método MSAA para retornar uma matriz que contém os IDs de todos os elementos filho que foram selecionados. A matriz retornada pode conter zero, um ou mais IDs, todos inteiros sem sinal.

Saiba mais

Elementos da API relacionados

     override public function get_accSelection():Array
     {
         var accSelection:Array = [];
     
         var selectedIndices:Array = ListBase(master).selectedIndices;
         
         var n:int = selectedIndices.length;
         for (var i:int = 0; i < n; i++)
         {
             accSelection[i] = selectedIndices[i] + 1;
         }
         
         return accSelection;
     }
     

O método de IAccessible para retornar a estatal em tempo de execução atual do componente que este AccessibilityImplementation representa ou de um dos seus elementos de filho.

Este método deve retornar uma combinação do zero, um, ou mais dos predestinados objetam constantes estatais de componentes em MSAA. Quando mais de um estado se aplica, as constantes de estado devem ser combinadas em um campo de bit que use |, o operador de bitwise OR.

Para indicar que nenhum das constantes estatais atualmente se aplica, este método deve retornar o zero.

Você não deve ter a necessidade de rastrear ou reportar o estado STATE_SYSTEM_FOCUSED ou STATE_SYSTEM_FOCUSABLE. O Flash Player trata estes estados automaticamente.

Parâmetros

Saiba mais

Elementos da API relacionados

     override public function get_accState(childID:uint):uint
     {
         var accState:uint = getState(childID);
     
         if (childID > 0) 
         {
             var listBase:ListBase = ListBase(master);
     
             var index:uint = childID - 1;
     
             // For returning states (OffScreen and Invisible)
             // when the list Item is not in the displayed rows.
             if (index < listBase.verticalScrollPosition ||
                 index >= listBase.verticalScrollPosition + listBase.rowCount)
             {
                 accState |= (STATE_SYSTEM_OFFSCREEN |
                              STATE_SYSTEM_INVISIBLE);
             }
             else
             {
                 accState |= STATE_SYSTEM_SELECTABLE;
     
                 var item:Object = getItemAt(index);
     
                 var renderer:IListItemRenderer =
                     listBase.itemToItemRenderer(item);
     
                 if (renderer != null && listBase.isItemSelected(renderer.data))
                     accState |= STATE_SYSTEM_SELECTED | STATE_SYSTEM_FOCUSED;
             }
         }
     
         return accState;
     }

Método de MSAA para retornar o valor em tempo de execução do componente que este AccessibilityImplementation representa ou de um dos seus elementos de filho.

Implemente este método apenas se o seu AccessibilityImplementation representar um elemento interface do usuário que tem um valor no modelo MSAA. Esteja sabendo que alguns elementos de interface do usuário que têm 'um valor' evidente de fato expõem este valor por meios diferentes, tal como get_accName (texto, por exemplo), get_accState (caixas de seleção, por exemplo), ou get_accSelection (caixas de lista, por exemplo).

Se você está implementando get_accValue apenas da próprio AccessibilityImplementation ou apenas dos seus elementos filho, precisará em alguns casos indicar que não há nenhum conceito do valor para o childID específico que foi passado. Faça isto retornando simplesmente null .

Parâmetros

Saiba mais

Elementos da API relacionados

override public function get_accValue(childID:uint):String
     {
         var accValue:String;
         
         var listBase:ListBase = ListBase(master);
         
         var index:int = listBase.selectedIndex;
         if (childID == 0)
         {
             if (index > -1)
             {
                 var item:Object = getItemAt(index);
     
                 if (item is String)
                 {
                     accValue = item + " " + (index + 1) + " of " + listBase.dataProvider.length;
                 }
                 else
                 {
                     accValue = listBase.itemToLabel(item) + " " + (index + 1) +
                                " of " + listBase.dataProvider.length;
                 }
             }
         }
     
         return accValue;
     }

Retorna uma matriz que contém as IDs dos inteiros sem sinal de todos os elementos filho na AccessibilityImplementation.

O comprimento da matriz pode ser zero. O IDs na matriz deve aparecer na mesma ordem lógica que os elementos filho que eles representam. Se o seu AccessibilityImplementation puder conter elementos filho, este método é obrigatório; de outra maneira, não o implemente.

Na designação de filho IDs aos seus elementos filho, use qualquer esquema que preserva a singularidade dentro de cada ocorrência do seu AccessibilityImplementation. O Filho IDs não tem de ser contíguo, e o seu encomendar não tem de combinar com lógico encomendar dos elementos filho. Você deve organizar isso de maneira a não reutilizar IDs filho; se um elemento filho for excluído, o seu ID nunca deverá ser usado novamente durante a vida útil desta instância de AccessibilityImplementation. Esteja ciente de que, devido a seleções de implementação no código do Flash Player, um comportamento indesejável poderá resultar se você usar mais de um milhão de IDs filho.

     override public function getChildIDArray():Array
     {
         var childIDs:Array = [];
     
         if (ListBase(master).dataProvider)
         {
             var n:uint = ListBase(master).dataProvider.length;
             for (var i:int = 0; i < n; i++)
             {
                 childIDs[i] = i + 1;
             }
         }
         return childIDs;
     }
     

Retorna true ou false para indicar se um objeto de texto que tem a caixa delimitadora especificada por um x, y, width eheight deve ser considerado um rótulo do componente que esta AccessibilityImplementation representa.

As coordenadas x e y são relativas ao canto superior esquerdo do componente ao qual a AccessibilityImplementation se aplica e podem ser negativas. Todas as coordenadas estão nas unidades de pixels de Palco.

Este método permite que os componentes acessíveis ajustem-se à busca do Flash de relações de rotulagem automática, que permitem que o texto externo de um objeto forneça o nome do objeto. Este método é fornecido porque se espera que os critérios para reconhecer rótulos sejam diferentes de componente para componente. Se você implementar este método, deverá ter como objetivo usar critérios geométricos semelhantes àqueles em uso no código do player para botões e campos de texto. Aqueles critérios são os seguintes:

• No caso dos botões, qualquer texto que fique inteiramente dentro do botão é considerado um rótulo.
• No caso dos campos de texto, qualquer texto que apareça próximo, acima ou alinhado à esquerda, ou próximo à esquerda, é considerado um rótulo.

Se o componente que a AccessibilityImplementation representa nunca dever participar em relações de rotulagem automática, não implemente isLabeledBy. Isto é equivalente a retornar sempre false. Um caso em que isLabeledBy não deve ser implementado é quando a AccessibilityImplementation cai no caso de "nome atribuído pelo autor dentro do componente", descrito abaixo de get_accName acima.

Observe que este método não se baseia em nenhum método IAccessible, mas é específico do Flash.

Parâmetros