Sprite  - AS3

Especifica o modo de botão desta entidade gráfica. Se true, essa entidade gráfica se comportará como um botão, o que significa que ela aciona a exibição do cursor de mão quando o mouse passa sobre a entidade gráfica e poderá receber um evento click se as teclas Enter ou barra de espaço forem pressionadas quando o foco estiver na entidade gráfica. É possível suprimir a exibição do cursor de mão definindo a propriedade useHandCursor como false, em cujo caso o ponto é exibido.

Embora seja melhor usar a classe SimpleButton para criar botões, você pode usar a propriedade buttonMode para fornecer a uma entidade gráfica uma funcionalidade de botão. Para incluir uma entidade gráfica na ordem de tabulação, defina a propriedade tabEnabled (herdada da classe InteractiveObject e false por padrão) como true. Além disso, considere se você deseja que os filhos da entidade gráfica sejam ativados pelo usuário. A maioria dos botões não permitem a interatividade do usuário para seus objetos-filho, já que isso confunde o fluxo de eventos. Para desativar a interatividade para todos os objetos-filho, é necessário definir a propriedade mouseChildren (herdada da classe DisplayObjectContainer) como false.

Se você usar a propriedade buttonMode com a classe MovieClip (que é uma subclasse da classe Sprite), o botão poderá ter uma certa funcionalidade adicionada. Se você incluir quadros com os rótulos _up, _over e _down, o Flash Player fornecerá alterações automáticas de estado (funcionalidade semelhante à fornecida nas versões anteriores do ActionScript para clipes de filme usados como botões). Essas alterações automáticas de estado não estão disponíveis para entidades gráficas, que não têm linha do tempo e, portanto, não têm quadros a serem rotulados.

Elementos da API relacionados

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace ("Click!");
}

addChild(circle1);
addChild(circle2);

Especifica o objeto de exibição sobre o qual a entidade gráfica está sendo arrastada ou no qual a entidade gráfica foi solta.

Elementos da API relacionados

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Especifica o objeto Graphics pertencente a esta entidade gráfica em que comandos de desenho de vetor podem ocorrer.

import flash.display.Sprite;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(40, 40, 40);
addChild(circle);

Designa outra entidade gráfica para atuar como área de ocorrência para uma entidade gráfica. Se a propriedade hitArea não existir ou o valor for null ou undefined, a própria entidade gráfica será usada como área de ocorrência. O valor da propriedade hitArea pode ser uma referência a um objeto Sprite.

A propriedade hitArea pode ser alterada a qualquer momento; a entidade gráfica modificada usa imediatamente o novo comportamento da área de ocorrência. A entidade gráfica designada como área de ocorrência não precisa estar visível; sua forma gráfica, embora invisível, ainda é detectada como a área de ocorrência.

Observação: é necessário definir como false a propriedade mouseEnabled da entidade gráfica designada como área de ocorrência. Caso contrário, o botão de entidade gráfica não funcionará porque a entidade gráfica designada como área de acerto receberá os eventos da entrada de usuário no lugar desse botão de entidade gráfica.

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var square:Sprite = new Sprite();
square.graphics.beginFill(0xCCFF00);
square.graphics.drawRect(200, 0, 100, 100);

circle.hitArea = square;
square.mouseEnabled = false;

circle.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void{
    trace(event.target == circle); // true
    trace(event.target == square); // false
}

addChild(circle);
addChild(square);

Controla o som nesta entidade gráfica.

Observação: Esta propriedade não afeta o conteúdo de HTML em um objeto HTMLControl (no Adobe AIR).

Elementos da API relacionados

import flash.display.Sprite;
import flash.display.Loader;
import flash.events.IOErrorEvent;
import flash.events.MouseEvent;
import flash.net.URLRequest;
import flash.text.TextField;
import flash.media.SoundTransform;

var container:Sprite = new Sprite();
addChild(container);

var ldr:Loader = new Loader;
var urlReq:URLRequest = new URLRequest("SoundPlayer.swf");
ldr.load(urlReq);

container.addChild(ldr);
ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, urlNotFound);
            
var tf:TextField = new TextField();
tf.htmlText = "<a href = 'event:Mute'>Mute / Unmute</a>";
addChild(tf);

var mySoundTransform:SoundTransform = new SoundTransform();
mySoundTransform.volume = 1;

tf.addEventListener(MouseEvent.CLICK, mute);

function mute(event:MouseEvent):void {    
    if (mySoundTransform.volume == 0) {
        mySoundTransform.volume = 1;
    } else {
        mySoundTransform.volume = 0;        
    }
    container.soundTransform = mySoundTransform;
}

function urlNotFound(event:IOErrorEvent):void {
    trace("The URL was not found."); 
}

Um valor booliano que indica se a mão que aponta (cursor de mão) aparece quando o mouse passa sobre uma entidade gráfica em que a propriedade buttonModeesteja definida como true. O valor padrão da propriedade useHandCursor é true. Se useHandCursor está definida como true, a mão que aponta usada para botões aparecerá quando o mouse rolar sobre uma entidade gráfica de botão. Se useHandCursor for false, o ponteiro de seta será usado.

A propriedade useHandCursor pode ser alterada a qualquer momento; a entidade gráfica modificada usa imediatamente a nova aparência do cursor.

Observação: No Flex ou no Flash Builder, se o seu fantasma tiver fantasmas filhos, talvez convenha definir a propriedade mouseChildren como false. Por exemplo, se desejar que o cursor de mão seja exibido sobre um controle Flex<mx:Label>, defina as propriedades useHandCursor e buttonMode como true, e a propriedade mouseChildren como false.

Elementos da API relacionados

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.useHandCursor = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = true;
circle2.useHandCursor = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace ("Click!");
}

addChild(circle1);
addChild(circle2);

Cria uma nova ocorrência de Sprite. Depois de criar a ocorrência de Sprite, chame o método DisplayObjectContainer.addChild() ou DisplayObjectContainer.addChildAt() para adicionar Sprite a um DisplayObjectContainer-pai.

Permite ao usuário arrastar a entidade gráfica especificada. A entidade gráfica permanece arrastável até ser explicitamente interrompida por meio de uma chamada ao método Sprite.stopDrag() ou até que outra entidade gráfica se torne arrastável. Apenas uma entidade gráfica por vez pode ser arrastável.

Os objetos de exibição tridimensional seguem o mouse e Sprite.startDrag() move o objeto dentro do plano tridimensional definido pelo objeto de exibição. Ou, se o objeto de exibição for um objeto bidimensional e filho de um objeto tridimensional, esse objeto bidimensional se moverá dentro do plano tridimensional definido pelo objeto pai tridimensional.

Parâmetros

Elementos da API relacionados

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Deixa o usuário arrastar o sprite especificado em um dispositivo ativado pelo toque. O sprite permanece arrastável até ser explicitamente interrompido por meio de uma chamada ao método Sprite.stopTouchDrag() ou até que outro sprite se torne arrastável. Apenas uma entidade gráfica por vez pode ser arrastável.

Os objetos de exibição tridimensionais seguem o ponteiro e Sprite.startTouchDrag() move o objeto dentro do plano tridimensional definido pelo objeto de exibição. Ou, se o objeto de exibição for um objeto bidimensional e filho de um objeto tridimensional, esse objeto bidimensional se moverá dentro do plano tridimensional definido pelo objeto pai tridimensional.

Parâmetros

Elementos da API relacionados

MySprite.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
MySprite.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);

function onTouchBegin(e:TouchEvent) {
     e.target.startTouchDrag(e.touchPointID, false, bg.getRect(this));
     trace("touch begin");
 
 }
function onTouchEnd(e:TouchEvent) {
     e.target.stopTouchDrag(e.touchPointID);
     trace("touch end");
}

Finaliza o método startDrag(). Uma entidade gráfica que se tornou arrastável com o método startDrag() permanecerá nesse estado até que um método stopDrag() seja adicionado ou até que outra entidade gráfica se torne arrastável. Apenas uma entidade gráfica por vez pode ser arrastável.

Elementos da API relacionados

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Finaliza o método startTouchDrag() para uso com dispositivos ativados pelo toque. Um Sprite que se tornou arrastável com o método startTouchDrag() permanecerá nesse estado até que um método stopTouchDrag() seja adicionado ou até que outro sprite se torne arrastável. Apenas uma entidade gráfica por vez pode ser arrastável.

Parâmetros

Elementos da API relacionados

MySprite.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
MySprite.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);

function onTouchBegin(e:TouchEvent) {
     e.target.startTouchDrag(e.touchPointID, false, bg.getRect(this));
     trace("touch begin");
 
 }
function onTouchEnd(e:TouchEvent) {
     e.target.stopTouchDrag(e.touchPointID);
     trace("touch end");
}

1. Declare a propriedade size (100 x 100 pixels) e a cor do plano de fundo (laranja) para uso posterior no desenho do quadrado.
2. Em seguida, o construtor cria um novo objeto-filho Sprite e o usa para adicionar dois ouvintes de eventos e seus métodos associados: mouseDownHandler() e mouseUpHandler().
3. O objeto-filho Sprite é então transmitido ao método draw(), que desenha o quadrado laranja.
4. O filho é inserido na lista de exibição por uma chamada ao método addChild().
5. Os listeners de evento funcionam como se segue:
   • mouseDownHandler(): quando o usuário clica no objeto Sprite, esse método adiciona um ouvinte de evento mouseMove, o método mouseDownHandler() que processa os movimentos do mouse. Em seguida, o método startDrag() é chamado, o que permite que o objeto Sprite seja arrastado.
   • mouseUpHandler(): quando o botão do mouse é solto, o ouvinte de eventos mouseMove é removido e o método stopDrag() é chamado, congelando o quadrado laranja no lugar.
   • mouseMoveHandler: enquanto o botão esquerdo do mouse estiver pressionado, esse método instrui o player a redesenhar continuamente o quadrado laranja.

Observação: Cada um dos métodos do ouvinte de eventos declara uma variável sprite local, que recebe a propriedade target do evento.

package {
    import flash.display.Sprite;
    import flash.events.*;

    public class SpriteExample extends Sprite {
        private var size:uint    = 100;
        private var bgColor:uint = 0xFFCC00;

        public function SpriteExample() {
            var child:Sprite = new Sprite();
            child.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            child.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
            draw(child);
            addChild(child);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            trace("mouseDownHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.startDrag();
        }

        private function mouseUpHandler(event:MouseEvent):void {
            trace("mouseUpHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.stopDrag();
        }

        private function mouseMoveHandler(event:MouseEvent):void {
            trace("mouseMoveHandler");
            event.updateAfterEvent();
        }

        private function draw(sprite:Sprite):void {
            sprite.graphics.beginFill(bgColor);
            sprite.graphics.drawRect(0, 0, size, size);
            sprite.graphics.endFill();
        }
    }
}