MovieClip  - AS3

Especifica o número do quadro no qual o indicador de reprodução está localizado na linha do tempo da ocorrência de MovieClip. Se o clipe de filme tiver várias cenas, esse valor será o número do quadro na cena atual.

mc1.gotoAndStop(mc1.currentFrame + 5);

O rótulo do quadro atual na linha de tempo da ocorrência de MovieClip. Se o quadro atual não tiver rótulo, currentLabel será null.

O rótulo atual no qual o indicador de reprodução está localizado na linha do tempo da ocorrência de MovieClip. Se o quadro atual não tiver rótulo, currentLabel será definido como o nome do quadro anterior que inclui um rótulo. Se o quadro atual e os quadros anteriores não incluírem um rótulo, currentLabel retornará null.

trace(mc1.currentLabel);

Retorna uma matriz de objetos FrameLabel a partir da cena atual. Se a ocorrência de MovieClip não usar cenas, a matriz incluirá todos os rótulos de quadro dessa ocorrência inteira de MovieClip.

Elementos da API relacionados

import flash.display.FrameLabel;
 
var labels:Array = mc1.currentLabels;

for (var i:uint = 0; i < labels.length; i++) {
    var label:FrameLabel = labels[i];
    trace("frame " + label.frame + ": " + label.name);
}

A cena atual na qual o indicador de reprodução está localizado na linha do tempo da ocorrência de MovieClip.

Elementos da API relacionados

import flash.display.Scene;
 
var scene:Scene = mc1.currentScene;
trace(scene.name + ": " + scene.numFrames + " frames");

Um valor booliano que indica se um clipe de filme está ativado. O valor padrão de enabled é true. Se enabled estiver definida como false, os quadros Sobre, Para baixo e Acima serão desativados. O clipe de filme continuará a receber eventos (por exemplo, mouseDown, mouseUp, keyDown e keyUp).

A propriedade enabled controla apenas as propriedades de botão de um clipe de filme. A propriedade enabled pode ser alterada a qualquer momento; o clipe de filme é imediatamente ativado ou desativado. Se enabled estiver definida como false, o objeto não será incluído na ordenação automática da tabulação.

mc1.enabled = false;

O número de quadros carregados a partir de um arquivo SWF de fluxo. Você pode usar a propriedade framesLoaded para determinar se foram carregados o conteúdo de um quadro específico e de todos os quadros antes dele e estão disponíveis localmente no navegador. Ela também pode ser usada para monitorar o download de arquivos SWF grandes. Por exemplo, é possível exibir uma mensagem aos usuários indicando que o arquivo SWF está sendo carregado até um quadro específico nesse arquivo SWF terminar de ser carregado.

Se o clipe de filme tiver várias cenas, a propriedade framesLoaded retornará o número de quadros carregados para todas as cenas no clipe de filme.

Elementos da API relacionados

if (mc1.framesLoaded == mc1.totalFrames) {
    trace("OK.");
}

Valor booliano que indica se um clipe de filme está sendo reproduzido.

Uma matriz de objetos Scene, cada um listando o nome, o número de quadros e os rótulos de quadro para uma cena na ocorrência de MovieClip.

Elementos da API relacionados

import flash.display.Scene;
 
for (var i:uint = 0; i < mc1.scenes.length; i++) {
    var scene:Scene = mc1.scenes[i];
    trace("scene " + scene.name + ": " + scene.numFrames + " frames");
}

O número total de quadros na ocorrência de MovieClip.

Se o clipe de filme tiver vários quadros, a propriedade totalFrames retornará o número total de quadros carregados em todas as cenas no clipe de filme.

 trace(mc1.totalFrames);

Indica se outros objetos da tela que são objetos de MovieClip ou SimpleButton podem receber eventos de liberação de mouse ou outros eventos de liberação de entrada do usuário. A propriedade trackAsMenu permite criar menus. Você pode definir a propriedade trackAsMenu em qualquer objeto SimpleButton ou MovieClip. O valor padrão da propriedade trackAsMenu é false.

A propriedade trackAsMenu pode ser alterada a qualquer momento; o clipe de filme modificado usa imediatamente o novo comportamento.

 mc1.trackAsMenu = true;

Cria uma nova ocorrência de MovieClip. Depois de criar MovieClip, chame o método addChild() ou addChildAt() de um contêiner de objeto de exibição que esteja no palco.

Inicia a reprodução do arquivo SWF no quadro especificado. Isso acontecerá depois que a execução de todas as ações restantes no quadro tiver terminado. Para especificar uma cena e um quadro, especifique um valor para o parâmetro cena.

Parâmetros

mc1.gotoAndPlay(mc1.currentFrame + 5);

mc1.gotoAndPlay("intro", "Scene 12");

Traz o indicador de reprodução para o quadro especificado do clipe de filme e o interrompe nesse local. Isso acontecerá depois que a execução de todas as ações restantes no quadro tiver terminado. Se você quiser especificar uma cena além de um quadro, especifique um parâmetro cena.

Parâmetros

mc1.gotoAndStop(mc1.currentFrame + 5);

mc1.gotoAndStop("finale", "Scene 12");

Envia o indicador de reprodução ao próximo quadro e o interrompe. Isso acontecerá depois que a execução de todas as ações restantes no quadro tiver terminado.

Elementos da API relacionados

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

Move o indicador de reprodução para a cena seguinte da ocorrência de MovieClip. Isso acontecerá depois que a execução de todas as ações restantes no quadro tiver terminado.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

Move o indicador de reprodução na linha do tempo do clipe de filme.

Elementos da API relacionados

import flash.text.TextField;
import flash.events.MouseEvent;

var continueText:TextField = new TextField();
continueText.text = "Play movie...";
addChild(continueText);

mc1.stop();
continueText.addEventListener(MouseEvent.CLICK, resumeMovie);

function resumeMovie(event:MouseEvent):void {
    mc1.play();
}

Envia o indicador de reprodução ao quando anterior e o interrompe. Isso acontecerá depois que a execução de todas as ações restantes no quadro tiver terminado.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

Move o indicador de reprodução para a cena anterior da ocorrência de MovieClip. Isso acontecerá depois que a execução de todas as ações restantes no quadro tiver terminado.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

Para o indicador de reprodução no clipe de filme.

1. A função de construtor define um campo de texto, que é usado para exibir valores de propriedades do objeto MovieClipExample (que estende MovieClip).
2. O valor de retorno do método getPropertiesString() é usado como texto para o campo de texto outputText. O método getPropertiesString() retorna uma string que é preenchida com valores das seguintes propriedades do clipe de filme: currentFrame, currentLabel, currentScene, framesLoaded, totalFrames e trackAsMenu.
3. Duas linhas de código na função de construtor ajustam as propriedades de largura e altura do campo de texto outputText.
4. A última linha da função de construtor adiciona o campo de texto outputText á lista de exibição.

package {
    import flash.display.MovieClip;
    import flash.text.TextField;

    public class MovieClipExample extends MovieClip {

        public function MovieClipExample() {
            var outputText:TextField = new TextField();
            outputText.text = getPropertiesString();
            outputText.width = stage.stageWidth;
            outputText.height = outputText.textHeight;
            addChild(outputText);
        }

        private function getPropertiesString():String {
            var str:String = ""
                + "currentFrame: " + currentFrame + "\n"
                + "currentLabel: " + currentLabel + "\n"
                + "currentScene: " + currentScene + "\n"
                + "framesLoaded: " + framesLoaded + "\n"
                + "totalFrames: " + totalFrames + "\n"
                + "trackAsMenu: " + trackAsMenu + "\n";
            return str;
        }
    }
}