URLRequest  - AS3

Especifica se as solicitações de autenticação devem ser manipuladas (true) ou não (false) para esta solicitação. Se for false, os desafios de autenticação retornam um erro HTTP.

Os métodos de autenticação com suporte são:

• Windows—HTTP Básico/Compilado, Autenticação Integrada do Windows (incluindo NTLM e Kerberos), Autenticação Certificada SSL.
• Mac—HTTP Básico/Compilação, NTLM, Autenticação Certificada SSL.

Observação: os métodos FileReference.upload(), FileReference.download() e HTMLLoader.load() não oferecem suporte à propriedade URLRequest.authenticate.

O valor padrão é true.

Elementos da API relacionados

Especifica se os dados de resposta bem sucedidos devem ser armazenados em cache para esta solicitação. Ao ser definido como true, o aplicativo AIR usará o cache HTTP do sistema operacional.

Observação: O método HTMLLoader.load() não oferece suporte à propriedade URLRequest.useCacheResponse.

O valor padrão é true.

Elementos da API relacionados

O tipo de conteúdo MIME do conteúdo na propriedade data.

O valor padrão é application/x-www-form-urlencoded.

Observação: os métodos FileReference.upload(), FileReference.download() e HTMLLoader.load() não oferecem suporte à propriedade URLRequest.contentType.

Ao enviar uma solicitação POST, os valores das propriedades contentType e data deverão corresponder adequadamente. O valor da propriedade contentType instrui os servidores sobre como interpretar o valor da propriedade data.

• Se o valor da propriedade data for um objeto URLVariables, o valor de contentType deverá ser application/x-www-form-urlencoded.
• Se o valor da propriedade data for de qualquer outro tipo, o valor de contentType deverá indicar o tipo de dados POST que será despachado (os quais são dados binários ou de string contidos no valor da propriedade data).
• Para FileReference.upload(), o Content-Type da solicitação será definido automaticamente como multipart/form-data e o valor da propriedade contentType será ignorado.

No Flash Player 10 e posterior, se você usar um Content-Type de partes múltiplas (por exemplo, "multipart/form-data") que contém um upload (indicado por um parâmetro "filename" no cabeçalho "content-disposition" do corpo POST), a operação POST ficará sujeita às regras de segurança aplicadas a uploads:

• A operação POST deverá ser executada em resposta a uma ação iniciada pelo usuário, por exemplo, clique de mouse ou pressionamento de tecla.
• Se a operação POST for entre domínios (se o destino de POST não estiver no mesmo servidor do arquivo SWF que está enviando a solicitação POST), o servidor de destino deverá fornecer um arquivo de diretivas de URL que permita o acesso entre domínios.

Além disso, a sintaxe deverá ser válida (de acordo com os padrões RFC2046) para qualquer Content-Type de partes múltiplas. Se a sintaxe for inválida, a operação POST ficará sujeita às regras de segurança aplicadas a uploads.

Elementos da API relacionados

Um objeto contendo dados a serem transmitidos com a solicitação de URL.

Essa propriedade é usada com o método propriedade. Quando o valor de method for GET, o valor de data será acrescentado ao valor de URLRequest.url, usando a sintaxe de string de consulta HTTP. Quando o valor de method for POST (ou qualquer valor que não seja GET), o valor de data será transmitido no corpo da solicitação HTTP.

A API URLRequest oferece suporte para POST binário e variáveis codificadas em URL, bem como para strings. O objeto de dados pode ser do tipo ByteArray, URLVariables ou String.

A forma como os dados são usados depende do tipo de objeto usado:

• Se o objeto for ByteArray, os dados binários do objeto ByteArray serão usados como dados POST. Para GET, não há suporte a dados do tipo ByteArray. Além disso, não a suporte a dados do tipo ByteArray para FileReference.upload() e FileReference.download().
• Se o objeto for um URLVariables e o método for POST, as variáveis serão codificadas com o uso do formato x-www-form-urlencoded e a string resultante será usada como dados POST. Uma exceção é uma chamada a FileReference.upload(), em que as variáveis são enviadas como campos separados em um post multipart/form-data.
• Se o objeto for URLVariables e o método for GET, o objeto URLVariables definirá variáveis a serem enviadas com o objeto URLRequest.
• Caso contrário, o objeto será convertido em string, que será usada como dados POST ou GET.

Esses dados apenas serão despachados quando um método, como navigateToURL() ou FileReference.upload(), usar o objeto URLRequest.

Observação: O valor de contentType deve corresponder ao tipo de dados da propriedade data. Consulte a nota contida na descrição da propriedade contentType.

Elementos da API relacionados

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class URLVariablesExample extends Sprite {

        public function URLVariablesExample() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            navigateToURL(request);
        }
    }
}

Uma string que identifica exclusivamente o componente da plataforma Adobe assinado a ser armazenado (ou recuperado) no cache do Flash Player. Um componente da plataforma Adobe é um arquivo assinado (arquivo SWZ) com conteúdo SWF armazenado persistentemente na máquina do usuário. Todos os arquivos SWZ são assinados pela Adobe. Uma compilação corresponde a um único arquivo em cache. Se o arquivo for alterado de algum modo, sua compilação também será alterada de modo imprevisível. Ao usar uma compilação, é possível verificar o arquivo em cache entre vários domínios. Dois arquivos com a mesma compilação são o mesmo arquivo e dois arquivos com compilações diferentes são arquivos diferentes. Um arquivo não pode (praticamente) ser criado para "imitar" uma compilação e fingir ser outra compilação.

A compilação é baseada em um algoritmo de compilação de mensagem SHA-256 (formato hexadecimal com tamanho de 64 caracteres).

Por exemplo, o SDK do Flex inclui um SWZ para a estrutura do Flex (e fornece a string de compilação para esse arquivo SWZ). Você pode publicar esse SWZ no servidor da Web e carregá-lo no arquivo SWF (usando o método load() de um objeto URLLoader). Se a máquina do usuário final já tiver o arquivo SWZ correspondente em cache, o aplicativo usará esse arquivo. (Um arquivo SWZ corresponderá se sua compilação coincidir com a que você fornecer.) Caso contrário, o aplicativo faz download do arquivo SWZ na URL que você especificar.

Somente defina o parâmetro digest em um objeto URLRequest usado na chamada do método URLLoader.load() para carregar um arquivo SWZ. Se a propriedade digest de um objeto URLRequest for definido quando este estiver sendo usado em outros métodos, o aplicativo lançará uma exceção IOError.

 
var myURLReq:URLRequest = new URLRequest();
myURLReq.url = "http://yourdomain/users/jdoe/test01/_rsc/Automated/AssetCaching_rsc/test01/rsl.swz";
myURLReq.digest = "3B0AA28C7A990385E044D80F5637FB036317BB41E044D80F5637FB036317BB41";
var myURLLoader:URLLoader = new URLLoader();
myURLLoader.dataFormat = URLLoaderDataFormat.BINARY;
myURLLoader.addEventListener("complete", onC);

myURLLoad.load(myURLReq);

function onC(e) {
    var someLoader:Loader = new Loader();
    addChild(someLoader);
    someLoader.loadBytes((ByteArray)(myURLLoad.data)); 
}

Especifica se os redirecionamentos devem ser seguidos (true) ou não (false).

Observação: os métodos FileReference.upload(), FileReference.download() e URLRequest.followRedirects não oferecem suporte à propriedade URLRequest.contentType.

O valor padrão é true.

Elementos da API relacionados

Especifica o valor de intervalo ocioso (em milissegundos) para esta solicitação.

O tempo limite ocioso é o período de tempo (em milissegundos) que o cliente espera por uma resposta do servidor, depois que a conexão é estabelecida, antes de abandonar o pedido.

Observação: O método HTMLLoader.load() não oferece suporte à propriedade URLRequest.idleTimeout. A classe HTMLLoader define a sua própria propriedade idleTimeout.

O valor padrão é initialized from the URLRequestDefaults.idleTimeout property.

Elementos da API relacionados

Especifica se a pilha de protocolo HTTP deve gerenciar cookies para esta solicitação. Quando for true, cookies serão adicionados à solicitação e cookies de resposta serão memorizados. Se for false, os cookies não são adicionados à solicitação e os cookies de resposta não são memorizados, mas os próprios usuários podem gerenciar os cookies por meio da manipulação direta do cabeçalho. Nota: no Windows, não é possível adicionar cookies a um pedido de URL manualmente quando manageCookies é definido como true. Em outros sistemas operacionais, adicionar cookies a um pedido é permitido, independentemente de manageCookies ser definido como true ou false. Quando permitido, você poderá adicionar cookies a um pedido manualmente, adicionando um objeto URLRequestHeader que contenha os dados do cookie à matriz requestHeaders.

No Mac OS, os cookies são compartilhados com o Safari. Para apagar os cookies no Mac OS:

1. Abra o Safari.
2. Selecione Safari > Preferências e clique no painel Segurança.
3. Clique no botão Exibir cookies.
4. Clique no botão Remover todos.

Para apagar os cookies no Windows:

1. Abra o painel de controle Propriedades da Internet e clique na guia Geral.
2. Clique no botão Excluir cookies.

O valor padrão é true.

Elementos da API relacionados

Controla o método de envio de formulário HTTP.

Para o conteúdo SWF em execução no Flash Player (no navegador), essa propriedade é limitada à operação GET ou POST, e os valores válidos são URLRequestMethod.GET ou URLRequestMethod.POST.

Para o conteúdo em execução no Adobe AIR, você poderá usar qualquer valor de string se o conteúdo estiver na área de segurança do aplicativo. Caso contrário, como no conteúdo executado no Flash Player, você estará restrito ao uso da operação GET ou POST.

Para conteúdo em execução no Adobe AIR, ao usar a função navigateToURL(), o tempo de execução trata um URLRequest que usa o método POST (um com a propriedade method definida como URLRequestMethod.POST ) por meio do método GET.

Observação: Se estiver executando no Flash Player e o formulário referenciado não tiver corpo, o Flash Player usará automaticamente uma operação GET, mesmo que o método esteja definido como URLRequestMethod.POST. Por esse motivo, é recomendável sempre incluir um corpo "fictício" para garantir o uso do método correto.

O valor padrão é URLRequestMethod.GET.

Elementos da API relacionados

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequest_method extends Sprite {

        public function URLRequest_method() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            request.method = URLRequestMethod.POST;
            
            navigateToURL(request);
        }
    }
}

A matriz de cabeçalhos de solicitação HTTP a ser acrescentada à solicitação de HTTP. A matriz é composta de objetos URLRequestHeader. Cada objeto na matriz deve ser um objeto URLRequestHeader que contenha uma string de nome e uma string de valor, desta maneira:

     var rhArray:Array = new Array(new URLRequestHeader("Content-Type", "text/html"));
     

O tempo de execução do Flash Player e do AIR impõe algumas restrições nos cabeçalhos de solicitação; para obter mais informações, consulte a descrição da classe URLRequestHeader.

Nem todos os métodos que aceitam parâmetros de URLRequest suportam a propriedade requestHeaders; consulte a documentação para verificar o método que você está chamando. Por exemplo, os métodos FileReference.upload() e FileReference.download() não suportam a propriedade URLRequest.requestHeaders.

Em virtude de limitações do navegador, os cabeçalhos personalizados de solicitação HTTP são suportados somente para solicitações POST, não para solicitações GET.

Elementos da API relacionados

A URL a ser solicitada.

Certifique-se de codificar quaisquer caracteres descritos como não seguros na especificação Uniform Resource Locator (consulte http://www.faqs.org/rfcs/rfc1738.html) ou aqueles reservados no esquema URL do objeto URLRequest (quando não usados para a finalidade a qual foram reservados). Por exemplo, use "%25" para o símbolo de porcentagem (%) e "%23" para o sinal de número (#), como em "http://www.example.com/orderForm.cfm?item=%23B-3&discount=50%25".

Por padrão, a URL precisa estar no mesmo domínio do arquivo de chamada, a menos que o conteúdo esteja em execução na área de segurança do Adobe AIR . Se for necessário carregar dados de um domínio diferente, insira um arquivo de diretivas de URL no servidor que está hospedando os dados.. Para obter mais informações, consulte a descrição da classe URLRequest.

Para o conteúdo em execução no Adobe AIR, os arquivos na área de segurança do aplicativo (instalados com o aplicativo AIR) podem acessar URLs usando qualquer um dos seguintes esquemas de URL:

• http e https
• file
• app-storage
• aplic

Observação: O IPv6 (Protocolo de Internet versão 6) é suportado no AIR e no Flash Player 9.0.115.0 e posterior. O IPv6 é uma versão do Internet Protocol que oferece suporte a endereços de 128 bits (um aprimoramento do protocolo IPv4 anterior, que oferece suporte a endereços de 32 bits). Talvez seja necessário ativar o IPv6 nas suas interfaces de rede. Para obter mais informações, consulte a Ajuda do sistema operacional que está hospedando os dados. Se o IPv6 for suportado no sistema host, será possível especificar endereços literais IPv6 numéricos em URLs entre parênteses ([]), como a seguir.

     rtmp://[2001:db8:ccc3:ffff:0:444d:555e:666f]:1935/test
     

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";
var urlRequest:URLRequest = new URLRequest(url);
var loader:Loader = new Loader();
loader.load(urlRequest);
addChild(loader);

Especifica se o cache local deve ser consultado antes que URLRequest saia em busca dos dados.

Observação: O método HTMLLoader.load() não oferece suporte para a propriedade URLRequest.useCache.

O valor padrão é true.

Elementos da API relacionados

Especifica a string user-agent a ser usada na solicitação HTTP.

O valor padrão é a mesma string user-agent usada pelo Flash Player, que é diferente no Mac, no Linux e no Windows.

Observação: Esta propriedade não afeta a string user-agent quando o objeto URLRequest object é usado com o método load() de um objeto HTMLLoader. Para definir a string user-agent para o objeto HTMLLoader, defina a propriedade userAgent do objeto ou defina a propriedade estática URLRequestDefaults.userAgent.

Elementos da API relacionados

Cria um objeto URLRequest. Se System.useCodePage for true, a solicitação será codificada com o uso da página de códigos do sistema em vez de Unicode. Se System.useCodePage for false, a solicitação será codificada com o uso de Unicode em vez da página de códigos do sistema.

Elementos da API relacionados

// Requires
// - Button symbol on Stage (or a display object, such as a MovieClip) with instance name "buttonSymbol"
//
buttonSymbol.addEventListener(MouseEvent.CLICK, buttonSymbol_click);
 
function buttonSymbol_click(evt:MouseEvent):void {
    var req:URLRequest = new URLRequest("http://www.adobe.com/");
    navigateToURL(req, "_blank");
}

Permite a substituição de um URL redirecionado de uma fonte URLRequest para uma parte do URL em um novo URLRequest. Depois que uma solicitação inicial foi redirecionada, isso permite que as solicitações subsequentes sejam enviadas diretamente para o local do servidor redirecionado.

Depois que o URLRequest for concluído, se HTTPStatusEvent.redirected for verdadeiro, esse método pode ser aplicado usando a solicitação inicial como o sourceRequest. Por padrão, o domínio do URL redirecionado será usado no lugar do domínio no URL desse URLRequest. URLRequest.url deve ser definido antes de aplicar este método. O método deve ser aplicado antes de esse URLRequest ser carregado. Como opção, se o parâmetro wholeURL for verdadeiro, o URL completo, sem o nome de arquivo, do URLRequest de origem será substituído para o URL completo sem o nome do arquivo final nesse URLRequest. Além de isso, aquele que aplicar esse método pode fornecer um string ou uma expressão regular no parâmetro pattern. O padrão é pesquisado e substituído pelo string do parâmetroreplace. Esta busca e substituição ocorrem após a substituição do URL.

Parâmetros

Elementos da API relacionados

Para executar este exemplo, insira um arquivo denominado XMLFile.xml no mesmo diretório que o seu arquivo SWF.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestExample extends Sprite {
        private var loader:URLLoader;
        
        public function URLRequestExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("XMLFile.xml");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}