URLLoader  - AS3

Indica o número de bytes que foram carregados até agora durante a operação de carregamento.

Indica o número total de bytes nos dados baixados. Essa propriedade contém 0 enquanto a operação de carregamento está em andamento, sendo preenchida quando a operação é concluída. Além disso, um cabeçalho Content-Length ausente fará com que bytesTotal seja indeterminável.

Os dados recebidos da operação de carregamento. Essa propriedade apenas é preenchida quando a operação de carregamento está concluída. O formato dos dados depende da configuração da propriedade dataFormat:

Se a propriedade dataFormat for URLLoaderDataFormat.TEXT, os dados recebidos serão uma string contendo o texto do arquivo carregado.

Se a propriedade dataFormat for URLLoaderDataFormat.BINARY, os dados recebidos serão um objeto ByteArray contendo os dados binários brutos.

Se a propriedade dataFormat for URLLoaderDataFormat.VARIABLES, os dados recebidos serão um objeto URLVariables contendo as variáveis codificadas em URL.

Elementos da API relacionados

//params.txt is a local file that includes: firstName=Tom&lastName=Jones
var lbl:TextField = new TextField();
var urlRequest:URLRequest = new URLRequest("params.txt");
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.VARIABLES;
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    lbl.text = urlLoader.data.lastName + "," + urlLoader.data.firstName;
    addChild(lbl);
}

Controla se os dados baixados são recebidos como texto (URLLoaderDataFormat.TEXT), dados binários brutos (URLLoaderDataFormat.BINARY) ou variáveis codificadas em URL (URLLoaderDataFormat.VARIABLES).

Se o valor da propriedade dataFormat for URLLoaderDataFormat.TEXT, os dados recebidos serão uma string contendo o texto do arquivo carregado.

Se o valor da propriedade dataFormat for URLLoaderDataFormat.BINARY, os dados recebidos serão um objeto ByteArray contendo os dados binários brutos.

Se o valor da propriedade dataFormat for URLLoaderDataFormat.VARIABLES, os dados recebidos serão um objeto URLVariables contendo as variáveis codificadas em URL.

O valor padrão é URLLoaderDataFormat.TEXT.

Elementos da API relacionados

var PATH:String = "lorem.txt";
var urlRequest:URLRequest = new URLRequest(PATH);
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.TEXT; // default
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    textArea.text = urlLoader.data;
}

Cria um objeto URLLoader.

Elementos da API relacionados

Registra um objeto de ouvinte de evento em um objeto EventDispatcher, de forma que o ouvinte receba a notificação de um evento. Você pode registrar ouvintes de eventos em todos os nós da lista de exibição de um tipo específico de evento, fase e prioridade.

Depois de registrar um ouvinte de evento com êxito, não será possível alterar a respectiva prioridade por meio de chamadas adicionais para o addEventListener(). Para alterar a prioridade de um ouvinte, chame primeiramente o removeListener(). Em seguida, você poderá registrar o ouvinte novamente com o novo nível de prioridade.

Tenha em mente que, após o ouvinte ser registrado, chamadas subsequentes para o addEventListener() com um valor type ou useCapture diferente resultarão na criação de um registro de ouvinte separado. Por exemplo, se você primeiro registrar um ouvinte com o useCapture definido como true, ele escutará apenas durante a fase de captura. Se você chamar o addEventListener() novamente, usando o mesmo objeto de ouvinte, mas com o useCapture definido como false, você terá dois ouvintes distintos: um que escuta durante a fase de captura e outro que escuta durante as fases de destino e de bubbling.

Você não pode registrar um ouvinte de evento apenas para a fase de destino ou a fase de bubbling. Essas fases são emparelhadas durante o registro porque o bubbling se aplica apenas aos ancestral do nó-alvo.

Se você não precisar mais de um ouvinte de evento, remova-o, chamando o removeEventListener(); do contrário, poderão ocorrer problemas de memória. Os ouvintes de evento não são retirados automaticamente da memória porque o coletor de lixo não remove o ouvinte enquanto o objeto de despacho existe (a menos que o parâmetro useWeakReference seja definido para true).

Copiar uma ocorrência do EventDispatcher não copia os ouvintes de eventos a ele anexados. (Se o seu recém-criado nó precisar de um ouvinte de evento, anexe o ouvinte após criar o nó). Entretanto, se você mover uma ocorrência do EventDispatcher, os ouvintes de evento anexados se movimentarão com ele.

Se o ouvinte de evento estiver sendo registrado em um nó enquanto um evento estiver sendo processado nesse nó, o ouvinte de evento não será disparado durante a fase atual, mas poderá ser disparado durante uma fase posterior no fluxo de eventos, como a fase de bubbling.

Se um ouvinte de evento for removido de um nó enquanto um evento estiver sendo processado no nó, ele ainda será disparado pelas ações atuais. Depois de removido, o ouvinte de evento nunca mais é chamado novamente (a menos que registrado mais uma vez para processamento futuro).

Parâmetros

function(evt:Event):void

Encerra a operação de carregamento em andamento. Qualquer operação de carregamento em andamento é imediatamente terminada. Se nenhuma URL estiver sendo enviada por fluxo no momento, um erro de fluxo inválido será lançado.

Envia e carrega dados da URL especificada. Os dados podem ser recebidos como texto, dados binários brutos ou variáveis codificadas em URL, dependendo do valor definido para a propriedade dataFormat. Observe que o valor padrão da propriedade dataFormat é texto. Se você quiser enviar dados à URL especificada, poderá definir a propriedade data no objeto URLRequest.

Observação: Se um arquivo que está sendo carregado contiver caracteres não ASCII (como é o caso de muitos idiomas que não são o inglês), convém salvar o arquivo com codificação UTF-8 ou UTF-16, em contraste com um formato não Unicode, como ASCII.

Um arquivo SWF da caixa de proteção local com sistema de arquivos não pode carregar dados de um recurso que está na caixa de proteção da rede nem fornecer dados para ele.

Por padrão, a URL e o arquivo SWF da chamada que você carrega precisam estar exatamente no mesmo domínio. Por exemplo, um arquivo SWF em www.adobe.com pode carregar dados apenas de fontes que também estejam em www.adobe.com. Para carregar dados de outro domínio, coloque um arquivo de diretivas de URL no servidor que está hospedando os dados.

Não é possível conectar-se às portas normalmente reservadas. Para ver uma lista completa de portas bloqueadas, consulte "Restrição de APIs de rede" no Guia do Desenvolvedor do ActionScript 3.0.

No Flash Player 10 e posterior, se você usar um Content-Type de partes múltiplas (por exemplo, "multipart/form-data") que contém um upload (indicado por um parâmetro "filename" no cabeçalho "content-disposition" do corpo POST), a operação POST ficará sujeita às regras de segurança aplicadas a uploads:

• A operação POST deverá ser executada em resposta a uma ação iniciada pelo usuário, por exemplo, clique de mouse ou pressionamento de tecla.
• Se a operação POST for entre domínios (se o destino de POST não estiver no mesmo servidor do arquivo SWF que está enviando a solicitação POST), o servidor de destino deverá fornecer um arquivo de diretivas de URL que permita o acesso entre domínios.

Além disso, a sintaxe deverá ser válida (de acordo com os padrões RFC2046) para qualquer Content-Type de partes múltiplas. Se a sintaxe for inválida, a operação POST ficará sujeita às regras de segurança aplicadas a uploads.

Para obter mais informações relacionadas à segurança, consulte o tópico do Centro dos desenvolvedores do Flash Player Security.

Parâmetros

Elementos da API relacionados

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.xml.*;
    import flash.events.IOErrorEvent;
  
    public class URLLoader_loadExample extends Sprite {
        private var xmlTextField:TextField = new TextField();
        private var externalXML:XML;    
        private var loader:URLLoader;

        public function URLLoader_loadExample() {
            var request:URLRequest = new URLRequest("xmlFile.xml");

            loader = new URLLoader();
            
            try {
                loader.load(request);
            }
            catch (error:SecurityError)
            {
                trace("A SecurityError has occurred.");
            }

             loader.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            loader.addEventListener(Event.COMPLETE, loaderCompleteHandler);

            xmlTextField.x = 10;
            xmlTextField.y = 10;
            xmlTextField.background = true;
            xmlTextField.autoSize = TextFieldAutoSize.LEFT;

            addChild(xmlTextField);
        }

        private function loaderCompleteHandler(event:Event):void {

                try {
                    externalXML = new XML(loader.data);
                    readNodes(externalXML);    
                } catch (e:TypeError) {
                    trace("Could not parse the XML file.");
                }
        }

        private function readNodes(node:XML):void {

                for each (var element:XML in node.elements()) {
                    xmlTextField.appendText(element.attributes()[0] + "\n");

                    readNodes(element);
                }    
        }

        private function errorHandler(e:IOErrorEvent):void {
            xmlTextField.text = "Had problem loading the XML File.";
        }
    }
}

Despachado depois que todos os dados recebidos são decodificados e inseridos na propriedade "data" do objeto URLLoader. Os dados recebidos poderão ser acessados quando esse evento tiver sido despachado.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado se uma chamada para o método load() tentar acessar dados via HTTP e o Adobe AIR atual for capaz de detectar e retornar o código de status da solicitação.

A constante HTTPStatusEvent.HTTP_RESPONSE_STATUS define o valor da propriedade type de um objeto de evento httpResponseStatus.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado se uma chamada ao URLLoader.load() tentar acessar os dados via HTTP. Para o conteúdo em execução no Flash Player, este evento somente será despachado se o ambiente atual do Flash Player puder detectar e executar o código de status para a solicitação. (Alguns ambientes de navegador podem não ser capazes de fornecer essas informações.) Observe que o evento httpStatus (se houver) será despachado antes (e além de) qualquer evento complete ou error.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado se uma chamada para URLLoader.load() resultar em um erro fatal que finaliza o download.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado quando a operação de download é iniciada após uma chamada para o método URLLoader.load().

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado quando os dados são recebidos ao longo do progresso da operação de download.

Observe que com um objeto URLLoader, não é possível acessar os dados até que eles tenham sido totalmente recebidos. Portanto, o evento "progress" apenas serve como notificação do nível de andamento do download. Para acessar os dados antes que eles sejam totalmente baixados, use um objeto URLStream.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado se uma chamada para URLLoader.load() tentar carregar dados de um servidor fora da área de segurança. Também despachado se uma chamada para URLLoader.load() tentar carregar um arquivo SWZ e o certificado for inválido ou a string de compilação não corresponder ao componente.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Observação: Para executar esse exemplo, insira um arquivo com nome urlLoaderExample.txt no mesmo diretório do seu arquivo SWF. Esse arquivo deve conter apenas a seguinte linha de texto: answer=42&question=unknown

O código de exemplo faz o seguinte:

1. A função de construtor cria uma ocorrência de URLLoader denominada loader e uma ocorrência de URLRequest denominada request, que contém a localização e o nome do arquivo a ser carregado.
2. O objeto loader é transmitido ao método configureListeners(), que adiciona ouvintes para cada um dos eventos URLLoader suportados.
3. O objeto request é então transmitido a loader.load(), que carrega o arquivo de texto.
4. Quando URLLoader tiver terminado de carregar o arquivo de texto, o evento Event.COMPLETE será acionado, disparando o método completeHandler(). O método completeHandler() cria um objeto URLVariables a partir do texto carregado do arquivo. O objeto URLVariables converte pares de nome/valor codificados em URL em propriedades ActionScript para facilitar a manipulação dos dados carregados.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLLoaderExample extends Sprite {
        
        private loader:URLoader;
        public function URLLoaderExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("urlLoaderExample.txt");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
    
            var vars:URLVariables = new URLVariables(loader.data);
            trace("The answer is " + vars.answer);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}