FileReference  - AS3

A data de criação do arquivo no disco local. Se o objeto não tiver sido preenchido, uma chamada para obter o valor dessa propriedade retornará null.

Observação: caso um sistema operacional não tenha creationDate como sua propriedade, CreationDate será igual a lastModifiedDate.

Elementos da API relacionados

O tipo de criador do arquivo Macintosh, usado somente nas versões do Mac OS anteriores ao Mac OS X. No Windows ou no Linux, essa propriedade é null. Se o objeto FileReference não tiver sido preenchido, uma chamada para obter o valor dessa propriedade retornará null.

Elementos da API relacionados

O objeto ByteArray que representa os dados do arquivo carregado após uma chamada bem-sucedida para o método load().

Elementos da API relacionados

A extensão do nome do arquivo.

A extensão de um arquivo é a parte seguinte ao nome (não incluindo) o ponto final ("."). Se não houver ponto no nome do arquivo, a extensão será null.

Observação: É necessário usar a propriedade extension para determinar o tipo de um arquivo; não use as propriedades creator ou type. As propriedades creator e type devem ser consideradas desaprovadas. Elas se aplicam a versões antigas do Mac OS.

A data da última modificação do arquivo no disco local. Se o objeto FileReference não tiver sido preenchido, uma chamada para obter o valor dessa propriedade retornará null.

Elementos da API relacionados

O nome do arquivo no disco local. Se o objeto FileReference não foi preenchido (por uma chamada válida para FileReference.download() ou para FileReference.browse()), o Flash Player lança um erro ao tentar obter o valor dessa propriedade.

Todas as propriedades de um objeto FileReference são preenchidas por meio da chamada do método browse(). Ao contrário de outras propriedades FileReference, se você chamar o método download(), a propriedade name será preenchida quando o evento select for despachado.

Elementos da API relacionados

Determina se o aplicativo recebeu permissão para acessar o sistema de arquivos.

Elementos da API relacionados

O tamanho do arquivo no disco local, em bytes.

Observação: Na versão inicial do ActionScript 3.0, a propriedade size foi definida como um objeto uint, que suporta arquivos com tamanhos de até 4 GB. É implementado agora como um objeto Number para ser compatível com arquivos maiores.

Elementos da API relacionados

O tipo de arquivo.

No Windows ou Linux, essa propriedade é a extensão do arquivo. No Macintosh, esta propriedade é do tipo de arquivo de quatro caracteres, usada somente nas versões anteriores a Mac OS X. Se o objeto FileReference não foi preenchido, uma chamada para obter o valor dessa propriedade retornará null.

Para o Windows, o Linux e o Mac OS X, a extensão de arquivo, parte da propriedade name que segue a última ocorrência do ponto (.) character — identifica o tipo de arquivo.

Elementos da API relacionados

Cria um novo objeto FileReference. Quando preenchido, um objeto FileReference representa um arquivo no disco local do usuário.

Elementos da API relacionados

Exibe uma caixa de diálogo de navegação de arquivos que permite ao usuário selecionar um arquivo para upload. A caixa de diálogo é nativa para o sistema operacional do usuário. O usuário pode selecionar um arquivo no computador local ou de outros sistemas; por exemplo, através de um caminho UNC no Windows.

Observe: A classe File, disponível no Adobe AIR, inclui métodos para acessar caixas de diálogo de seleção de arquivo do sistema mais específicas. Estes métodos são File.browseForDirectory(), File.browseForOpen(), File.browseForOpenMultiple() e File.browseForSave().

Quando você chamar esse método e o usuário selecionar com êxito um arquivo, as propriedades desse objeto FileReference serão preenchidas com as propriedades desse arquivo. Subsequentemente, sempre que o método FileReference.browse() for chamado, as propriedades do objeto FileReference serão redefinidas para o arquivo selecionado pelo usuário na caixa de diálogo. Apenas uma sessão de browse() ou download() pode ser realizada por vez (porque apenas uma caixa de diálogo pode ser invocada por vez).

Usando o parâmetro typeFilter, você pode determinar quais arquivos são exibidos pela caixa de diálogo.

No Flash Player 10 e no Flash Player 9 Update 5, você só pode chamar esse método com êxito em resposta a um evento de usuário (por exemplo, no manipulador de eventos de um clique do mouse ou um evento de pressionamento de tecla). Do contrário, chamar esse método resulta no lançamento de uma exceção de erro pelo Flash Player.

Observe que, em virtude da nova funcionalidade adicionada ao Flash Player, ao publicar no Flash Player 10, somente uma das seguintes operações poderá estar ativa por vez: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Caso contrário, o Flash Player lançará um erro de tempo de execução (código 2174). Use FileReference.cancel() para interromper uma operação em andamento. Essa restrição se aplica apenas ao Flash Player 10. As versões anteriores do Flash Player não são afetadas por essa restrição em operações múltiplas simultâneas.

No Adobe AIR, a caixa de diálogo de navegação no arquivo nem sempre é exibida na frente das janelas subordinadas a outra janela (janelas cuja propriedade owner não é nula). Para evitar problema de ordenação de janelas, oculte as janelas subordinadas antes de chamar este método.

Parâmetros

Elementos da API relacionados

Cancela qualquer operação de upload ou download em andamento neste objeto FileReference. Cancelar esse método não despacha o evento cancel, que somente é despachado quando o usuário cancela a operação descartando a caixa de diálogo de upload ou download de arquivo.

Abre uma caixa de diálogo que permite ao usuário baixar um arquivo a partir de um servidor remoto. Embora o Flash Player não tenha restrição sobre o tamanho dos arquivos que você pode carregar ou baixar, o player oferece suporte oficialmente para uploads ou downloads de até 100 MB.

O método download() abre primeiro uma caixa de diálogo do sistema operacional que solicita que o usuário insira um nome de arquivo e selecione uma localização no computador local para salvar o arquivo. Quando o usuário selecionar uma localização e confirmar a operação de download (por exemplo, clicando em Salvar), o download do servidor remoto será iniciado. Os ouvintes recebem eventos para indicar o progresso, o êxito ou a falha do download. Para avaliar o status da caixa de diálogo e da operação de download depois de chamar download(), seu código deve monitorar eventos como cancel, open, progress e complete.

As funções FileReference.upload() e FileReference.download() são do tipo sem bloqueio. Elas são retornadas depois de serem chamadas, antes da conclusão da transmissão do arquivo. Além disso, se o objeto FileReference sair do escopo, todas as operações de upload ou download ainda não concluídas nesse objeto serão canceladas após a saída do escopo. Certifique-se de que o seu objeto FileReference permaneça em escopo pelo tempo estimado de continuação do upload ou download.

Quando o arquivo for baixado com êxito, as propriedades do objeto FileReference serão preenchidas com as propriedades do arquivo local. O evento complete será despachado se o download for bem-sucedido.

Apenas uma sessão de browse() ou download() pode ser realizada por vez (porque apenas uma caixa de diálogo pode ser invocada por vez).

Esse método oferece suporte ao download de qualquer tipo de arquivo, com HTTP ou HTTPS.

Não é possível conectar-se às portas normalmente reservadas. Para ver uma lista completa de portas bloqueadas, consulte "Restrição de APIs de rede" no Guia do Desenvolvedor do ActionScript 3.0.

Observação: se o seu servidor exigir a autenticação do usuário, apenas os aplicativos Flash em execução em um navegador (ou seja, que utilizam plug-in para navegador ou controle ActiveX), poderão fornecer uma caixa de diálogo para solicitar que o usuário insira um nome e uma senha para autenticação e, então, somente para downloads. No caso de uploads usando o plug-in ou o controle ActiveX, ou de uploads ou downloads usando o player autônomo ou externo, ocorre uma falha na transferência de arquivos.

Ao usar esse método, considere o modelo de segurança do Flash Player:

• Operações de carregamento não serão permitidas se o arquivo SWF de chamada estiver em uma caixa de proteção local não confiável.
• O comportamento padrão é negar o acesso entre caixas de proteção. Um site da Web pode permitir o acesso a um recurso adicionando um arquivo de diretivas de URL.
• Você pode impedir o arquivo SWF de usar esse método configurando o parâmetro allowNetworking das marcas object e embed na página HTML com o conteúdo SWF.
• No Flash Player 10 e no Flash Player 9 Update 5, você só pode chamar esse método com êxito em resposta a um evento de usuário (por exemplo, no manipulador de eventos de um clique do mouse ou um evento de pressionamento de tecla). Do contrário, chamar esse método resulta no lançamento de uma exceção de erro pelo Flash Player.

Contudo, no Adobe AIR, o conteúdo na área de segurança do aplicativo (conteúdo instalado com o aplicativo AIR) não é restrito por essas limitações de segurança.

Para obter mais informações relacionadas à segurança, consulte o tópico do Centro dos desenvolvedores do Flash Player Security.

Quando você baixa um arquivo que usa este método, ele é marcado como baixado em sistemas operacionais que sinalizam arquivos baixados:

• Windows XP Service Pack 2 e versões posteriores e no Windows Vista
• SO Mac 10.5 e posterior

Alguns sistemas operacionais, como Linux, não sinalizam arquivos baixados.

Observe que, em virtude da nova funcionalidade adicionada ao Flash Player, ao publicar no Flash Player 10, somente uma das seguintes operações poderá estar ativa por vez: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Caso contrário, o Flash Player lançará um erro de tempo de execução (código 2174). Use FileReference.cancel() para interromper uma operação em andamento. Essa restrição se aplica apenas ao Flash Player 10. As versões anteriores do Flash Player não são afetadas por essa restrição em operações múltiplas simultâneas.

No Adobe AIR, a caixa de diálogo de download nem sempre é exibida na frente das janelas subordinadas a outra janela (janelas cuja propriedade owner não é nula). Para evitar problema de ordenação de janelas, oculte as janelas subordinadas antes de chamar este método.

Parâmetros

Elementos da API relacionados

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Inicia o carregamento de um arquivo local selecionado por um usuário. Embora o Flash Player não tenha restrição sobre o tamanho dos arquivos que você pode carregar, baixar ou salvar, ele oferece suporte oficialmente até 100 MB. Para o conteúdo em execução no Flash Player, você deve chamar o método FileReference.browse() ou FileReferenceList.browse() antes de chamar o método load(). No entanto, o conteúdo em execução no AIR na área de segurança do aplicativo pode chamar o método load() de um objeto File sem antes chamar o método browse(). (A classe File do AIR estende a classe FileReference.)

Os ouvintes recebem eventos para indicar o andamento, o êxito ou a falha do carregamento. Embora possa usar o objeto FileReferenceList para permitir que os usuários selecionem vários arquivos a serem carregados, você deve carregar os arquivos um a um. Para carregar os arquivos um a um, itere a matriz FileReferenceList.fileList dos objetos FileReference.

O Adobe AIR também inclui a classe FileStream que fornece mais opções para ler arquivos.

As funções FileReference.upload(), FileReference.download(), FileReference.load() e FileReference.save() não são bloqueadoras. Elas são retornadas depois de serem chamadas, antes da conclusão da transmissão do arquivo. Além disso, se o objeto FileReference sair do escopo, todas as transações ainda não concluídas nesse objeto serão canceladas depois que ele sair do escopo. Certifique-se de que o objeto FileReference permaneça no escopo enquanto as ações de salvar, carregar, fazer upload e download estiverem sendo executadas.

Caso a conclusão do arquivo seja concluída com êxito, o conteúdo é armazenado como uma matriz de bytes na propriedade data do objeto FileReference.

As considerações de segurança a seguir se aplicam:

• Operações de carregamento não serão permitidas se o arquivo SWF de chamada estiver em uma caixa de proteção local não confiável.
• O comportamento padrão é negar o acesso entre caixas de proteção. Um site da Web pode permitir o acesso a um recurso adicionando um arquivo de diretivas entre domínios.
• Você pode impedir o arquivo de usar esse método configurando o parâmetro allowNetworking das marcas object e embed na página HTML com o conteúdo SWF.

No entanto, essas considerações não se aplicam ao conteúdo do AIR na área de segurança do aplicativo.

Observe que, ao publicar no Flash Player 10 ou no AIR 1.5, você pode ter apenas uma das seguintes operações ativas por vez: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Do contrário, o aplicativo lança um erro de tempo de execução (código 2174). Use FileReference.cancel() para interromper uma operação em andamento. Essa restrição se aplica apenas ao Flash Player 10 e ao AIR 1.5. As versões anteriores do Flash Player ou do AIR não são afetadas por essa restrição em operações múltiplas simultâneas.

No Adobe AIR, a caixa de diálogo de navegação no arquivo nem sempre é exibida na frente das janelas subordinadas a outra janela (janelas cuja propriedade owner não é nula). Para evitar problema de ordenação de janelas, oculte as janelas subordinadas antes de chamar este método.

Elementos da API relacionados

var buttonShape:Shape = new Shape();
buttonShape.graphics.beginFill(0x336699);
buttonShape.graphics.drawCircle(50, 50, 25);
var button = new SimpleButton(buttonShape, buttonShape, buttonShape, buttonShape);
addChild(button);

var fileRef:FileReference= new FileReference();
button.addEventListener(MouseEvent.CLICK, onButtonClick);

function onButtonClick(e:MouseEvent):void {
fileRef.browse([new FileFilter("Images", "*.jpg;*.gif;*.png")]);
fileRef.addEventListener(Event.SELECT, onFileSelected);
}

function onFileSelected(e:Event):void {
fileRef.addEventListener(Event.COMPLETE, onFileLoaded);
fileRef.load();
}

function onFileLoaded(e:Event):void {
var loader:Loader = new Loader();
loader.loadBytes(e.target.data);
addChild(loader);
}

Solicita permissão para acessar o sistema de arquivos.

Abre uma caixa de diálogo que permite ao usuário salvar um arquivo no sistema de arquivos local. Embora o Flash Player não tenha restrições sobre o tamanho dos arquivos que você pode salvar, carregar, fazer upload e download, o player oferece suporte oficialmente a tamanhos de até 100 MB.

O método save() abre primeiro uma caixa de diálogo do sistema operacional que solicita que o usuário insira um nome de arquivo e selecione uma localização no computador local para salvar o arquivo. Quando o usuário selecionar uma localização e confirmar a operação de salvamento (por exemplo, clicando em Salvar), o processo será iniciado. Os ouvintes recebem eventos para indicar o andamento, o êxito ou a falha da operação de salvamento. Para avaliar o status da caixa de diálogo e da operação de salvamento depois de chamar save(), o código deve monitorar eventos como cancel, open, progress e complete.

O Adobe AIR também inclui a classe FileStream que fornece mais opções de salvar arquivos localmente.

As funções FileReference.upload(), FileReference.download(), FileReference.load() e FileReference.save() não são bloqueadoras. Elas são retornadas depois de serem chamadas, antes da conclusão da transmissão do arquivo. Além disso, se o objeto FileReference sair do escopo, todas as transações ainda não concluídas nesse objeto serão canceladas depois que ele sair do escopo. Certifique-se de que o objeto FileReference permaneça no escopo enquanto as ações de salvar, carregar, fazer upload e download estiverem sendo executadas.

Quando o arquivo for salvo com êxito, as propriedades do objeto FileReference serão preenchidas com as propriedades do arquivo local. O evento complete será despachado se o salvamento for bem-sucedido.

Só é possível realizar uma sessão de browse() ou save() por vez (pois só é possível chamar uma caixa de diálogo por vez).

No Flash Player, você só pode chamar esse método com êxito em resposta a um evento de usuário (por exemplo, no manipulador de eventos de um clique do mouse ou um evento de pressionamento de tecla). Do contrário, chamar esse método resulta no lançamento de uma exceção de erro pelo Flash Player. Essa limitação não se aplica ao conteúdo do AIR na área de segurança do aplicativo.

No Adobe AIR, a caixa de diálogo Salvar nem sempre é exibida na frente das janelas subordinadas a outra janela (janelas cuja propriedade owner não é nula). Para evitar problema de ordenação de janelas, oculte as janelas subordinadas antes de chamar este método.

Parâmetros

Elementos da API relacionados

var MyTextField:TextField = new TextField();
var MyButtonField:TextField = new TextField();
var MyFile:FileReference = new FileReference();

MyTextField.border = true;
MyTextField.type = TextFieldType.INPUT;

MyButtonField.background = true;
MyButtonField.backgroundColor = 0x339933;
MyButtonField.x = 150;
MyButtonField.height = 20;
MyButtonField.text = "Click here to save";

addChild(MyTextField);
addChild(MyButtonField);
MyButtonField.addEventListener(MouseEvent.CLICK, clickhandler);

function clickhandler(e:MouseEvent): void {
    MyFile.save(MyTextField.text);
}

Inicia o upload do arquivo para um servidor remoto. Embora o Flash Player não tenha restrição sobre o tamanho dos arquivos que você pode carregar ou baixar, o player oferece suporte oficialmente para uploads ou downloads de até 100 MB. É necessário chamar o método FileReference.browse() ou FileReferenceList.browse() antes de chamar esse método.

Para a classe de Arquivo de Adobe AIR, que estende a classe FileReference, você pode usar o método upload() para transferir qualquer arquivo. Para a classe FileReference (usado em Flash Player), o usuário deve selecionar primeiro um arquivo.

Os ouvintes recebem eventos para indicar o progresso, o êxito ou a falha do upload. Embora você possa usar o objeto FileReferenceList para permitir que os usuários selecionem vários arquivos para upload, esses arquivos precisam ser carregados um por um. Para tanto, faça uma iteração por meio da matriz FileReferenceList.fileList de objetos FileReference.

As funções FileReference.upload() e FileReference.download() são do tipo sem bloqueio. Elas são retornadas depois de serem chamadas, antes da conclusão da transmissão do arquivo. Além disso, se o objeto FileReference sair do escopo, todas as operações de upload ou download ainda não concluídas nesse objeto serão canceladas após a saída do escopo. Certifique-se de que o seu objeto FileReference permaneça em escopo pelo tempo estimado de continuação do upload ou download.

O arquivo é carregado para a URL transmitida no parâmetro url. Essa URL deve ser um script de servidor configurado para aceitar uploads. O Flash Player carrega arquivos usando o método HTTP POST. O script de servidor que manipula o upload deve esperar uma solicitação POST com os seguintes elementos:

• Content-Type de multipart/form-data
• Content-Disposition com um atributo name definido como "Filedata" por padrão e um atributo filename definido como o nome do arquivo original
• O conteúdo binário do arquivo

Não é possível conectar-se às portas normalmente reservadas. Para ver uma lista completa de portas bloqueadas, consulte "Restrição de APIs de rede" no Guia do Desenvolvedor do ActionScript 3.0.

Para ver uma amostra de solicitação POST, consulte a descrição do parâmetro uploadNomeCampoDados. Você pode enviar parâmetros POST ou GET ao servidor com o método upload(); consulte a descrição do parâmetro request.

Se o parâmetro testarUpload for true e o arquivo a ser carregado for maior do que aproximadamente 10 KB, o Flash Player no Windows enviará primeiro uma operação POST de upload de teste sem conteúdo antes de carregar o arquivo real, para verificar se há chances de êxito na transmissão. O Flash Player enviará então uma segunda operação POST que inclui o conteúdo do arquivo real. Para arquivos com menos de 10 KB, o Flash Player realiza um único POST de upload com o conteúdo do arquivo real a ser carregado. O Flash Player no Macintosh não realiza operações POST de upload de teste.

Observação: se o seu servidor exigir a autenticação do usuário, apenas os aplicativos Flash em execução em um navegador (ou seja, que utilizam plug-in para navegador ou controle ActiveX), poderão fornecer uma caixa de diálogo para solicitar que o usuário insira um nome e uma senha para autenticação e, então, somente para downloads. No caso de uploads usando o plug-in ou o controle ActiveX, ou de uploads ou downloads usando o player autônomo ou externo, ocorre uma falha na transferência de arquivos.

Ao usar esse método, considere o modelo de segurança do Flash Player:

• Operações de carregamento não serão permitidas se o arquivo SWF de chamada estiver em uma caixa de proteção local não confiável.
• O comportamento padrão é negar o acesso entre caixas de proteção. Um site da Web pode permitir o acesso a um recurso adicionando um arquivo de diretivas de URL.
• Você pode impedir o arquivo SWF de usar esse método configurando o parâmetro allowNetworking das marcas object e embed na página HTML com o conteúdo SWF.

Contudo, no Adobe AIR, o conteúdo na caixa de proteção de segurança application (conteúdo instalado com o Adobe AIR) não é restringido por essas limitações de segurança.

Para obter mais informações relacionadas à segurança, consulte o tópico do Centro dos desenvolvedores do Flash Player Security.

Observe que, em virtude da nova funcionalidade adicionada ao Flash Player, ao publicar no Flash Player 10, somente uma das seguintes operações poderá estar ativa por vez: FileReference.browse(), FileReference.upload(), FileReference.download(), FileReference.load(), FileReference.save(). Caso contrário, o Flash Player lançará um erro de tempo de execução (código 2174). Use FileReference.cancel() para interromper uma operação em andamento. Essa restrição se aplica apenas ao Flash Player 10. As versões anteriores do Flash Player não são afetadas por essa restrição em operações múltiplas simultâneas.

Parâmetros

    Content-Type: multipart/form-data; boundary=AaB03x
    --AaB03x 
    Content-Disposition: form-data; name="Filedata"; filename="example.jpg" 
    Content-Type: application/octet-stream
    ... contents of example.jpg ... 
    --AaB03x-- 
    

Elementos da API relacionados

Inicia um upload de arquivo para um URL sem qualquer codificação. Independentemente de o método upload() codificar um arquivo em um form-data envelope, o método uploadUnencoded() passa o conteúdo do arquivo como um corpo de solicitação HTTP. Use o método uploadUnencoded() caso os dados a serem despachados estejam já codificados em um formato que possa ser compreendido pelo servidor receptor. Normalmente, o método uploadeUnencoded() é usado com o método HTTP/WebDAV PUT.

Parâmetros

Elementos da API relacionados

Despachado quando uma operação de upload ou download de arquivo é cancelada pelo usuário na caixa de diálogo de navegação de arquivos. O Flash Player não despachará esse evento se o usuário cancelar um upload ou download de outras maneiras (fechando o navegador ou interrompendo o aplicativo atual).

Esse evento tem as seguintes propriedades:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_cancel extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_cancel() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(Event.CANCEL, cancelHandler);
            file.download(downloadURL, fileName);
        }
        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }
    }
}

Despachado quando o download é concluído ou quando o upload gera um código de status HTTP de 200. No caso do download de arquivos, esse evento é despachado quando o Flash Player ou o Adobe AIR finaliza o download do arquivo inteiro em disco. No caso do upload de arquivos, esse evento é despachado depois que o Flash Player ou o Adobe AIR recebe um código de status HTTP de 200 do servidor que recebe a transmissão.

Esse evento tem as seguintes propriedades:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_complete extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_complete() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Elementos da API relacionados

Despachado se uma chamada ao método upload() ou uploadUnencoded() tentar acessar os dados através de HTTP e o Adobe AIR for capaz de detectar e retornar o código de status para a solicitação.

A constante HTTPStatusEvent.HTTP_RESPONSE_STATUS define o valor da propriedade type de um objeto de evento httpResponseStatus.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado quando ocorre uma falha de upload e um código de status HTTP está disponível para descrever a falha. O evento httpStatus é despachado, seguido de um evento ioError.

O evento httpStatus é exibido apenas para falhas de upload. Para o conteúdo em execução no Flash Player, este evento não é aplicado em falhas de download. Se um download falhar devido a um erro HTTP, esse erro será reportado como um erro de E/S.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado quando ocorre uma falha na operação de upload ou download. Um transferência de arquivo pode falhar por um dos seguintes motivos:

• Um erro de entrada/saída ocorre enquanto o player está lendo, gravando ou transmitindo o arquivo.
• O arquivo SWF tenta carregar um arquivo em um servidor que exige autenticação (como um nome de usuário e senha). Durante o upload, o Flash Player ou o Adobe AIR não fornece um meio para os usuários inserirem senhas. Se um arquivo SWF tentar carregar um arquivo em um servidor que exige autenticação, o upload falhará.
• O arquivo SWF tenta baixar um arquivo de um servidor que exige autenticação, no player autônomo ou externo. Durante o download, os players autônomos e externos não fornecem um meio de os usuários inserirem senhas. Se um arquivo SWF desses players tentar baixar um arquivo de um servidor que exige autenticação, o download falhará. O download do arquivo somente será bem sucedido em players com controle ActiveX, plug-in e no tempo de execução do Adobe AIR.
• O valor transmitido ao parâmetro url no método upload() contém um protocolo inválido. Os protocolos válidos são HTTP e HTTPS.

Importante: apenas os aplicativos em execução em um navegador (ou seja, que utilizam plug-in para navegador ou controle ActiveX) e o conteúdo em execução no Adobe AIR podem fornecer uma caixa de diálogo para solicitar que o usuário insira um nome e uma senha para autenticação e somente para downloads. No caso de uploads usando o plug-in ou uma versão do Flash Player para o controle ActiveX, ou do upload ou download usando o player autônomo ou externo, ocorre uma falha na transferência de arquivos.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado quando uma operação de upload ou download é iniciada.

Esse evento tem as seguintes propriedades:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Elementos da API relacionados

Será despachado quando o aplicativo solicitar permissão para acessar o sistema de arquivos. Verifique o valor da propriedade status para determinar se a permissão for concedida ou recusada

Elementos da API relacionados

Despachado periodicamente durante a operação de upload ou download de arquivos. O evento progress é despachado enquanto o Flash Player transmite bytes a um servidor e é periodicamente despachado durante a transmissão, mesmo que ela não venha a ser bem-sucedida. Para determinar se a transmissão de arquivos foi bem-sucedida e está concluída, e quando isso ocorreu, monitore o evento complete.

Em alguns casos, eventos progress não são recebidos. Por exemplo, quando o arquivo que está sendo transmitido for muito pequeno ou o upload ou o download acontecer muito rapidamente, talvez um evento progress não seja despachado.

O progresso de upload de arquivos não pode ser determinado em plataformas Macintosh anteriores ao OS X 10.3. O evento progress é chamado durante a operação de upload, mas o valor da propriedade bytesLoaded do evento "progress" é -1, indicando que não é possível determinar o progresso.

Esse evento tem as seguintes propriedades:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_progress extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_progress() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.download(downloadURL, fileName);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
        
        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Elementos da API relacionados

Despachado quando uma chamada ao método FileReference.upload() ou FileReference.download() tenta carregar um arquivo em um servidor ou obter um arquivo a partir de um servidor que está fora da área de segurança do chamador. O valor da propriedade de texto que descreve o erro específico ocorrido é normalmente "securitySandboxError". O arquivo SWF de chamada pode ter tentado acessar um arquivo SWF fora do seu domínio, mas não tem permissão para tanto. Você pode tentar solucionar esse erro usando um arquivo do diretivas de URL.

No Adobe AIR, essas restrições de segurança não se aplicam ao conteúdo na caixa de proteção do aplicativo.

No Adobe AIR, essas restrições de segurança não se aplicam ao conteúdo na caixa de proteção do aplicativo.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado quando o usuário seleciona um arquivo para upload ou download a partir da caixa de diálogo de navegação de arquivos. (Essa caixa de diálogo é aberta quando você chama o método FileReferenceList.browse(), FileReference.browse() ou FileReference.download().) Quando o usuário selecionar um arquivo e confirmar a operação (por exemplo, clicando em OK), as propriedades do objeto FileReference serão preenchidas.

Para o conteúdo em execução no Flash Player ou fora da caixa de proteção do aplicativo no tempo de execução do Adobe AIR, a seleção de eventos funciona um pouco diferente, dependendo do método invocado. Quando o evento select é despachado depois de uma chamada browse(), o Flash Player ou o Adobe AIR consegue ler todas as propriedades do objeto FileReference, uma vez que o arquivo selecionado pelo usuário está no sistema de arquivos local. Quando o evento select ocorre depois de uma chamada download(), o Flash Player ou o Adobe AIR apenas pode ler a propriedade name, uma vez que o arquivo ainda não foi baixado para o sistema de arquivos local no momento em que o evento select é despachado. Quando o arquivo for baixado e o evento complete for despachado, o Flash Player ou o Adobe AIR poderá ler todas as outras propriedades do objeto FileReference.

Esse evento tem as seguintes propriedades:

 
package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_select extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReference_event_select() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            file.addEventListener(Event.SELECT, selectHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.browse();
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Despachado quando os dados são recebidos do servidor após um upload bem-sucedido. Esse evento não será despachado se os dados não forem retornados do servidor.

Esse evento tem as seguintes propriedades:

Observação: Para executar esse exemplo, altere a propriedade uploadURL.url de forma que ela aponte para uma URL real, em vez de a URL fictícia no exemplo. A URL deve apontar para um arquivo denominado yourUploadHandlerScript.cfm, no diretório da Web raiz da URL especificada. Com base na sua configuração, talvez também seja necessário compilar o arquivo SWF com a Segurança de reprodução local definida como Acessar somente a rede ou atualizar as configurações de segurança do Flash Player para permitir esse acesso de rede ao arquivo.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileFilter;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReferenceExample extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReferenceExample() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            configureListeners(file);
            file.browse(getTypes());
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
            dispatcher.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA,uploadCompleteDataHandler);
        }

        private function getTypes():Array {
            var allTypes:Array = new Array(getImageTypeFilter(), getTextTypeFilter());
            return allTypes;
        }

        private function getImageTypeFilter():FileFilter {
            return new FileFilter("Images (*.jpg, *.jpeg, *.gif, *.png)", "*.jpg;*.jpeg;*.gif;*.png");
        }

        private function getTextTypeFilter():FileFilter {
            return new FileFilter("Text Files (*.txt, *.rtf)", "*.txt;*.rtf");
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function uploadCompleteDataHandler(event:DataEvent):void {
            trace("uploadCompleteData: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }
    }
}