File  - AS3

A pasta contendo os arquivos instalados do aplicativo.

A propriedade url desse objeto utiliza o esquema de URL app (não o esquema de URL file). Isso significa que a string url é especificada iniciando com "app:" (não "file:"). Além disso, se você cria um objeto File relativo ao diretório File.applicationDirectory (usando o método resolvePath()), a propriedade url do objeto File também usa o esquema de URL app.

Observação: não é possível gravar em arquivos ou diretórios que tenham caminhos que usam o esquema de URL app:. Além disso, não é possível excluir ou criar arquivos ou pastas que tenham caminhos que usem o esquema de URL app:. Modificar conteúdo no diretório do aplicativo é uma prática recriminável por motivos de segurança, sendo bloqueada pelo sistema operacional em algumas plataformas. Se desejar armazenar dados específicos ao aplicativo, considere usar o diretório de armazenamento do aplicativo (File.applicationStorageDirectory). Se desejar que algum conteúdo do diretório de armazenamento do aplicativo tenha acesso à funcionalidade privilegiada do aplicativo (APIs do AIR), você pode expor essa funcionalidade usando uma ponte de área de segurança.

A propriedade applicationDirectory permite fazer referência ao diretório do aplicativo que funciona entre plataformas. Se você definir um objeto File para fazer referência ao diretório do aplicativo usando a propriedade nativePath ou url, ele só funcionará na plataforma para a qual o caminho é válido.

No Android, a propriedade nativePath de um objeto File que aponte para o diretório do aplicativo é uma string vazia. Use a propriedade url para acessar arquivos do aplicativo.

Elementos da API relacionados

O diretório de armazenamento particular do aplicativo.

Cada aplicativo AIR tem um diretório de armazenamento de aplicativo persistente, criado quando o File.applicationStorageDirectory é acessado pela primeira vez. O diretório é exclusivo para cada aplicativo e usuário. Esse diretório é um local conveniente para armazenar dados específicos do usuário ou do aplicativo.

Quando você desinstala um aplicativo AIR, a exclusão ou não do diretório de armazenamento de aplicativo e seus arquivos pelo desinstalador depende da plataforma.

A propriedade url desse objeto utiliza o esquema de URL app-storage (não o esquema de URL file). Isso significa que a string url é especificada iniciando com "app-storage:" (não "file:"). Além disso, se você cria um objeto File relativo ao diretório File.applicationStoreDirectory (usando o método resolvePath()), a url do objeto File também usa o esquema de URL app-storage (como no exemplo).

A propriedade applicationStorageDirectory permite fazer referência ao diretório de armazenamento do aplicativo que funciona entre plataformas. Se você definir um objeto File para fazer referência ao diretório de armazenamento do aplicativo usando a propriedade nativePath ou url, ele só funcionará na plataforma para a qual o caminho é válido.

Observação (apenas Mac OS): para estar em conformidade com os requisitos da Mac App Store, a localização física deste diretório foi alterada entre o AIR 3.2 e o AIR 3.3:

• 3.2 namespace and earlier: ~/Library/Preferences/appid/Local Store/
• namespace 3.3 e posterior: path/Library/Application Support/appid/Local Store/, onde path é ~/Library/Containers/bundle-id/Data (ambiente seguro) ou ~ (ao executar fora de um ambiente seguro)

import flash.filesystem.File;

var tempFiles:File = File.applicationStorageDirectory;
tempFiles = tempFiles.resolvePath("images/");
trace(tempFiles.url); // app-storage:/images

Diretório de cache do aplicativo.

A propriedade cacheDirectory fornece uma forma de fazer referência ao diretório de cache. Seu aplicativo deve usar o diretório de cache para armazenar arquivos que são baixados de um servidor ou que são, de algum modo, gerados novamente. Os exemplos de arquivos que devem ser inseridos no diretório de cache inclui os arquivos do cache do banco de dados e conteúdo para download, como os usados por aplicativos de revistas, jornais e mapas.

Se você definir o objeto File para referência do diretório de cache usando a propriedade nativePath ou url, isso irá funcionar apenas em plataformas para as quais este caminho é válido.

Se o sistema operacional não suportar um diretório de cache, o cacheDirectory é nulo

O diretório da área de trabalho do usuário.

A propriedade desktopDirectory permite fazer referência ao diretório de área de trabalho que funciona entre plataformas. Se você definir um objeto File para fazer referência ao diretório de área de trabalho usando a propriedade nativePath ou url, ele só funcionará na plataforma para a qual o caminho é válido.

Se um sistema operacional não oferecer suporte a um diretório de área de trabalho, um diretório apropriado no sistema de arquivos será usado em vez dele.

Os dispositivos AIR for TV não têm o conceito de diretório de área de trabalho do usuário. Por isso, a propriedade desktopDirectory faz referência ao mesmo local de diretório que a propriedade File.userDirectory. O diretório de usuário é exclusivo ao aplicativo.

import flash.filesystem.File;
var desktop:File = File.desktopDirectory;

var files:Array = desktop.getDirectoryListing();

for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

O diretório de documentos do usuário.

No Windows, esse é o diretório Meus Documentos (por exemplo, C:\Documents and Settings\userName\Meus Documentos). No Mac OS, o local padrão é /Users/userName/Documents. No Linux, o local padrão é /home/userName/Documents (em um sistema em inglês), e a propriedade observa a configuração xdg-user-dirs.

A propriedade documentsDirectory permite fazer referência ao diretório de documentos que funciona entre plataformas. Se você definir um objeto File para fazer referência ao diretório de documentos usando a propriedade nativePath ou url, ele só funcionará na plataforma para a qual o caminho é válido.

Se um sistema operacional não oferecer suporte a um diretório de documentos, um diretório apropriado no sistema de arquivos será usado em vez dele.

Os dispositivos AIR for TV não têm o conceito de diretório de documentos do usuário. Por isso, a propriedade documentsDirectory faz referência ao mesmo local de diretório que a propriedade File.userDirectory. O diretório de usuário é exclusivo ao aplicativo.

import flash.filesystem.File;

var directory:File = File.documentsDirectory;
directory = directory.resolvePath("AIR Test");

File.createDirectory(directory);
trace(directory.exists); // true

Indica se o arquivo ou o diretório mencionados foram baixados (da Internet) ou não.

Esta propriedade só é significativa em sistemas operacionais em que os arquivos podem ser marcados como baixados:

• Windows XP Service Pack 2 e versões posteriores e no Windows Vista
• SO Mac 10.5 e posterior

Em sistemas que não marcam arquivos baixados, como Linux, a propriedade não é significativa (e ele é definido para false).

Elementos da API relacionados

Indica se o arquivo ou diretório referenciado existe. O valor é true se o objeto File apontar para um arquivo ou diretório existente; caso contrário, é false.

import flash.filesystem.*;

var temp:File = File.createTempFile();
trace(temp.exists); // true
temp.deleteFile();
trace(temp.exists); // false

Um objeto Icon que contém os ícones definidos para o arquivo. Um objeto Icon é uma matriz de objetos BitmapData que correspondem aos vários estados do ícone. No Linux, o objeto Icon não contém nenhum ícone. No Android, a propriedade icon é null.

import flash.filesystem.File;
import flash.display.*;

var directory:File = File.documentsDirectory;
var bitmaps:Array = directory.icon.bitmaps;
var bmpData:BitmapData = new BitmapData(1, 1);
for (var i:uint = 0; i < bitmaps.length; i++) {
    if (bitmaps[i].height > bmpData.height) {
        bmpData = directory.icon.bitmaps[i];
    }
}
var iconBmp:Bitmap = new Bitmap(bmpData);

Indica se a referência é um diretório. O valor é true se o objeto File apontar para um diretório; caso contrário, é false.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isDirectory) {
        trace(userDirFiles[i].nativePath);
    }
}    

Indica se o arquivo ou diretório referenciado está "oculto". O valor é true se o arquivo ou diretório referenciado estiver oculto; caso contrário, é false.

import flash.filesystem.*;

var userDirFiles:Array = File.userDirectory.getDirectoryListing();
for (var i:uint = 0; i < userDirFiles.length; i++) {
    if (userDirFiles[i].isHidden) {
        trace(userDirFiles[i].nativePath);
    }
}    

Indica se o diretório referenciado é um pacote.

O valor é true se o diretório referenciado for um pacote; caso contrário, é false. Observe que a classe File não permite criar pacotes diretamente.

• No Mac OS, diretórios podem ser designados como pacotes e aparecerão no Localizador como um arquivo único, em vez de um diretório. Essa propriedade será definida como true se o diretório referenciado for um pacote; se o arquivo não for um diretório, não existir ou não for um pacote, será definida como false.
• Em outros sistemas operacionais, essa propriedade é sempre definida como false.

Indica se a referência é um link simbólico.

O valor é true se o objeto File for um link simbólico; caso contrário, é false. Observe que a classe File não permite criar links simbólicos diretamente.

Os links simbólicos permitem que um arquivo aponte para outro arquivo ou diretório no disco. Embora semelhantes, os links simbólicos não são o mesmo que os aliases no Mac OS e os atalhos no Windows. O alias ou atalho é sempre reportado como um arquivo (em vez de diretório) e ler ou gravar em um alias ou atalho nunca afeta o diretório ou arquivo original para o qual ele aponta. Por outro lado, o link simbólico se comporta normalmente como o arquivo ou diretório para o qual aponta. Ele pode ser reportado como um arquivo ou diretório, e ler ou gravar em um link simbólico afetará o arquivo ou diretório para o qual ele aponta, não o link simbólico propriamente dito. No entanto, excluir um link simbólico exclui o link, e não o destino do link.

O Mac^® OS^®, o Linux e o Windows^® Vista^® oferecem suporte a links simbólicos. Além disso, no Windows, a propriedade isSymbolicLink de um objeto File que faça referência a um ponto de junção (usado no sistema de arquivos NTFS) é definido como true.

A string de final de linha usada pelo sistema operacional de hospedagem.

No Mac OS e no Linux, esse é o caractere de feed de linha (código de caractere hexadecimal 0x0A). No Windows, esse é o caractere de retorno de carro (código de caractere hexadecimal 0x0D) seguido pelo caractere de feed de linha (código de caractere hexadecimal 0x0A).

import flash.filesystem.*;

var str:String = "Hello\n" + 
        "World\n";
str = str.replace(/\n/g, File.lineEnding);
var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.WRITE);
fileStream.writeUTF(str);
fileStream.close();

O caminho completo na representação do sistema operacional de hospedagem. No Mac OS e no Linux, o caractere de barra (/) é usado como o separador de caminho. Entretanto, no Windows, você pode definir a propriedade nativePath usando o caractere de barra ou o caractere de barra invertida (\) como o separador de caminho. O AIR substitui automaticamente as barras pelos caracteres de barra invertida apropriados.

Antes de gravar código para definir a propriedade nativePath diretamente, analise se isso pode resultar em código específico de plataforma. Por exemplo, um caminho nativo como "C:\\Documents and Settings\\bob\\Desktop" só é válido no Windows. É bem melhor usar as seguintes propriedades estáticas, que representam diretórios usados com frequência e são válidas em todas as plataformas:

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Você pode usar o método resolvePath() para obter um caminho relativo a esses diretórios.

Algumas APIs flexíveis, tal como a propriedade origem a da classe SWFLoader, usam um URL (a propriedade url de um objeto Arquivo), não um caminho nativo (a propriedade nativePath).

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

O diretório que contém o arquivo ou o diretório referenciado por esse objeto File.

Se o arquivo ou diretório não existir, a propriedade parent ainda retornará o objeto File que aponta para o diretório que o contém, mesmo se esse diretório não existir.

Essa propriedade é idêntica ao valor de retorno de resolvePath("..") exceto se o pai de um diretório raiz for null.

import flash.filesystem.File;

var tempFile:File = File.createTempDirectory();
trace(tempFile.parent.nativePath);
tempFile.deleteFile();

Determina se o aplicativo recebeu permissão para acessar o sistema de arquivos.

Elementos da API relacionados

Indica se o runtime o impede que o backup desse objeto File seja salvo na nuvem.

Se esta propriedade for definida como true, ela não é copiada automaticamente para a nuvem nas plataformas que fornecem este serviço. O valor padrão dessa propriedade é false.

O caractere separador de componente do caminho do sistema operacional de hospedagem.

No Mac OS e no Linux, ele é o caractere de barra (/). No Windows, ele é o caractere de barra invertida (\).

Observação: Ao usar o caractere de barra invertida em uma literal de String, lembre-se de digitar o caractere duas vezes (como em "directory\\file.ext"). Cada par de barras invertidas em uma literal de String representa uma única barra invertida na String.

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Apollo Test");
var file:File = File.documentsDirectory.resolvePath("Apollo Test/employees/bob/test.txt");

var relativePath:String = directory.getRelativePath(file); // employees/bob/test.txt
relativePath = relativePath.replace(/\//g, File.separator);
trace(relativePath); 

O espaço disponível para uso nesse local de arquivo, em bytes.

Se o objeto File fizer referência a um diretório, spaceAvailable indicará o espaço no diretório que os arquivos podem usar. Se o objeto File fizer referência a um arquivo, spaceAvailable indicará o espaço no qual o arquivo poderá crescer. Se o local do arquivo não existir, spaceAvailable será definido como 0. Se o objeto File fizer referência a um link simbólico, spaceAvailable indicará o espaço disponível no local para o qual o link simbólico aponta.

Geralmente o espaço disponível para um diretório ou arquivo é igual ao espaço disponível no volume de contém o diretório ou o arquivo. No entanto, o espaço disponível pode levar em conta os limites por cotas e por diretório.

A adição de um arquivo ou diretório a um volume geralmente requer mais espaço que o tamanho real do arquivo ou o tamanho do conteúdo do diretório. Por exemplo, o sistema operacional pode exigir mais espaço para armazenar informações sobre índice. Ou os setores de disco necessários podem usar espaço adicional. Além disso, o espaço disponível muda dinamicamente. Dessa forma, você não poderá alocar todo o espaço informado para o armazenamento de arquivos.

A codificação padrão usada pelo sistema operacional de hospedagem.

Os valores possíveis incluem "windows-1252" "shift-jis", "cn-gb", "iso-8859-1" e outros. Para obter uma lista completa, consulte Conjuntos de caracteres suportados.

Você pode usar esse valor quando usar os métodos readMultiByte() e writeMultiByte() da classe FileStream.

Elementos da API relacionados

import flash.filesystem.File;

var file:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var fileStream:FileStream = new FileStream();
fileStream.open(file, FileMode.READ);
var str:String = fileStream.readMultiByte(file.size, File.systemCharset);
trace(str);    

A URL desse caminho de arquivo.

Se isso for uma referência a um caminho no diretório de armazenamento de aplicativo, o esquema de URL será "app-storage"; se for uma referência a um caminho no diretório de aplicativo, o esquema de URL será "app"; caso contrário, o esquema será "file".

Você pode usar caracteres de espaço em branco (em vez de "%20") quando atribuir um valor à propriedade url; o AIR decodifica as strings automaticamente (por exemplo, convertendo espaços em "%20").

Elementos da API relacionados

import flash.filesystem.File;

var docs:File = File.documentsDirectory;
trace(docs.nativePath); // C:\Documents and Settings\turing\My Documents
trace(docs.url); // file:///C:/Documents%20and%20Settings/turing/My%20Documents

O diretório do usuário.

No Windows, esse é o pai do diretório Meus Documentos (por exemplo, C:\Documents and Settings\userName). No Mac OS, é /Users/userName. No Linux, é /home/userName.

A propriedade userDirectory permite fazer referência ao diretório de usuário que funciona entre plataformas. Se você definir a propriedade nativePath ou url de um objeto File diretamente, ele só funcionará na plataforma para a qual o caminho é válido.

Se um sistema operacional não oferecer suporte a um diretório do usuário, um diretório apropriado no sistema de arquivos será usado em vez dele.

Em dispositivos AIR for TV, a propriedade userDirectory faz referência a um diretório de usuário exclusivo ao aplicativo.

import flash.filesystem.File;

var files:Array = File.userDirectory.listDirectory();
for (var i:uint = 0; i < files.length; i++) {
    trace(files[i].nativePath);
}

A função de construtor da classe File.

Se você passar um argumento path, o objeto File apontará para o caminho específico, e as propriedades nativePath e url serão definidas para refletir esse caminho.

Embora você possa passar um argumento path para especificar um caminho de arquivo, analise se isso pode resultar em código específico de plataforma. Por exemplo, um caminho nativo como "C:\\\\Documents and Settings\\bob\\Desktop" ou uma URL como "file:///C:/Documents%20and%20Settings/bob/Desktop" só tem validade no Windows. É bem melhor usar as seguintes propriedades estáticas, que representam diretórios usados com frequência e são válidas em todas as plataformas:

• File.applicationDirectory
• File.applicationStorageDirectory
• File.desktopDirectory
• File.documentsDirectory
• File.userDirectory

Em seguida, você pode usar o método resolvePath() para obter um caminho relativo a esses diretórios. Por exemplo, o código a seguir configura um objeto File de maneira que aponte para o arquivo settings.xml no diretório de armazenamento do aplicativo:

var file:File = File.applicationStorageDirectory.resolvePath("settings.xml");

Importante: se você enviar uma string de URL no parâmetro path, o URL será decodificado para resolver o caminho do arquivo. Por exemplo, a instrução, new File("file:///c:/test/demo%20file%201%2e0.txt") cria um objeto File com um caminho nativo, "c:\test\demo file 1.0.txt". (Um URL usa prefixos com os esquemas file:, app:, ou app-storage:.) Contudo, se os prefixos de URL válidos forem omitidos, a string do caminho será tratada como um caminho nativo e nenhuma decodificação ocorrerá. Você deve levar este comportamento em conta ao validar caminhos derivados de fontes potencialmente não confiáveis. Se você simplesmente validar a string de entrada, a decodificação de URL poderá permitir que um invasor burle suas verificações de validação. Valide sempre o caminho final do objeto File não instanciado.

     var file:File = new File( taintedString );
     validate( file.nativePath ); //where validate() is your path validation function
     

Elementos da API relacionados

Exibe uma caixa de diálogo seletora de diretórios, que permite ao usuário selecionar um diretório. Quando o usuário seleciona o diretório, o evento select é despachado. A propriedade target do evento select é o objeto File apontando para o diretório selecionado.

A caixa de diálogo do seletor de diretório nem sempre é exibida na frente das janelas subordinadas a outra janela (janelas cuja propriedade owner não é nula). Para evitar problema de ordenação de janelas, oculte as janelas subordinadas antes de chamar este método.

Note: não há suporte para browseForDirectory() em dispositivos com o Android. O objeto File despacha um evento Cancel imediatamente.

Parâmetros

Elementos da API relacionados

import flash.filesystem.File;
import flash.events.Event;

var directory:File = File.documentsDirectory;

try
{
    directory.browseForDirectory("Select Directory");
    directory.addEventListener(Event.SELECT, directorySelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function directorySelected(event:Event):void 
{
    directory = event.target as File;
    var files:Array = directory.getDirectoryListing();
    for(var i:uint = 0; i < files.length; i++)
    {
        trace(files[i].name);
    }
}

Exibe a caixa de diálogo Abrir arquivo, que permite ao usuário selecionar um arquivo para abrir.

Quando o usuário seleciona o arquivo, o evento select é despachado. A propriedade target do evento select é o objeto File apontando para o arquivo selecionado.

A caixa de diálogo Abrir arquivo nem sempre é exibida na frente das janelas subordinadas a outra janela (janelas cuja propriedade owner não é nula). Para evitar problema de ordenação de janelas, oculte as janelas subordinadas antes de chamar este método.

Nota: em dispositivos com o Android, o título da caixa de diálogo de arquivo não pode ser definido. O parâmetro title é ignorado.

Parâmetros

Elementos da API relacionados

import flash.filesystem.*;
import flash.events.Event;
import flash.net.FileFilter;

var fileToOpen:File = new File();
var txtFilter:FileFilter = new FileFilter("Text", "*.as;*.css;*.html;*.txt;*.xml");

try 
{
    fileToOpen.browseForOpen("Open", [txtFilter]);
    fileToOpen.addEventListener(Event.SELECT, fileSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function fileSelected(event:Event):void 
{
    var stream:FileStream = new FileStream();
    stream.open(event.target, FileMode.READ);
    var fileData:String = stream.readUTFBytes(stream.bytesAvailable);
    trace(fileData);
}

Exibe a caixa de diálogo Abrir arquivo, que permite ao usuário selecionar um ou mais arquivos para abrir.

Quando o usuário seleciona o arquivo, o evento selectMultiple é despachado. A propriedade target do evento select é esse objeto File. Ao contrário do browseForOpen(), com o método browseForOpenMultiple(), este objeto File não é atualizado para fazer referência a nenhum dos arquivos escolhidos. Em vez disso, o evento selectMultiple resultante contém uma matriz dos arquivos escolhidos.

A caixa de diálogo Abrir arquivo nem sempre é exibida na frente das janelas subordinadas a outra janela (janelas cuja propriedade owner não é nula). Para evitar problema de ordenação de janelas, oculte as janelas subordinadas antes de chamar este método.

Nota: em dispositivos com o Android, o título da caixa de diálogo de arquivo não pode ser definido. O parâmetro title é ignorado.

Parâmetros

Elementos da API relacionados

import flash.filesystem.*;
import flash.events.FileListEvent;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForOpenMultiple("Select Files");
    docsDir.addEventListener(FileListEvent.SELECT_MULTIPLE, filesSelected);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function filesSelected(event:FileListEvent):void 
{
    for (var i:uint = 0; i < event.files.length; i++) 
    {
        trace(event.files[i].nativePath);
    }
}

Exibe a caixa de diálogo Salvar arquivo, que permite ao usuário selecionar um destino de arquivo.

Quando o usuário seleciona o arquivo, o evento select é despachado. A propriedade target do evento select é o objeto File apontando para o destino selecionado para Salvar.

A caixa de diálogo Salvar arquivo nem sempre é exibida na frente das janelas que são subordinadas a outra janela (janelas cuja propriedade owner não é nula). Para evitar problema de ordenação de janelas, oculte as janelas subordinadas antes de chamar este método.

Nota: em dispositivos com o Android, o título da caixa de diálogo de arquivo não pode ser definido. O parâmetro title é ignorado.

Parâmetros

Elementos da API relacionados

import flash.filesystem.*;
import flash.events.Event;

var docsDir:File = File.documentsDirectory;
try
{
    docsDir.browseForSave("Save As");
    docsDir.addEventListener(Event.SELECT, saveData);
}
catch (error:Error)
{
    trace("Failed:", error.message);
}

function saveData(event:Event):void 
{
    var newFile:File = event.target as File;
    var str:String = "Hello.";
    if (!newFile.exists)
    {
        var stream:FileStream = new FileStream();
        stream.open(newFile, FileMode.WRITE);
        stream.writeUTFBytes(str);
        stream.close();
    }
}

Cancela alguma operação assíncrona pendente.

Canonicaliza o caminho File.

Se o objeto File representa um arquivo ou diretório existente, a canonicalização ajusta o caminho para que ele coincida com a minúscula ou a maiúscula do nome de arquivo ou diretório. Se o objeto File for um link simbólico, a canonicalização ajustará o caminho para que ele coincida com a minúscula ou a maiúscula do nome de arquivo ou diretório para o qual o link aponta, independentemente de o arquivo ou diretório apontado existir. Em sistemas que diferenciam maiúsculas de minúsculas (como o Linux), quando há vários arquivos com nomes diferentes apenas em maiúsculas e minúsculas, o método canonicalize() ajusta o caminho de acordo com o primeiro arquivo encontrado (em uma ordem determinada pelo sistema de arquivos).

Além disso, a canonicalização converte nomes de arquivos curtos em nomes de arquivos longos no Windows.

import flash.filesystem.*;

var path:File = File.desktopDirectory.resolvePath("air test");
trace(path.nativePath); 
path.canonicalize();
trace(path.nativePath); // ...\AIR Test

import flash.filesystem.*;

var path:File = new File();
path.nativePath = "C:\\AIR~1";
path.canonicalize();
trace(path.nativePath); // C:\AIR Test

Retorna uma cópia desse objeto File. Registros de eventos não são copiados.

Observação: Este método não copia o arquivo propriamente dito. Ele simplesmente faz uma cópia da ocorrência do objeto File ActionScript. Para copiar um arquivo, use o método copyTo().

Copia o arquivo ou diretório no local especificado por esse objeto File no local especificado pelo parâmetro newLocation. O processo de cópia cria qualquer diretório-pai necessário (se possível). Ao substituir arquivos usando o copyTo(), os atributos do arquivo também serão substituídos.

Parâmetros

Elementos da API relacionados

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:FileReference = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:FileReference = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

if (sourceFile.copyTo(destination, true)) {
    trace("Done.");
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

try 
{
    sourceFile.copyTo(destination, true);
}
catch (error:Error)
{
    trace("Error:", error.message);
}

Começa a copiar o arquivo ou diretório do local especificado pelo objeto File no local especificado pelo parâmetro destination.

Ao concluir, um evento complete (bem-sucedido) ou um evento ioError (mal-sucedido) é despachado. O processo de cópia cria qualquer diretório-pai necessário (se possível).

Parâmetros

Elementos da API relacionados

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/test2.txt");

sourceFile.copyToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileCopiedHandler);

function fileCopiedHandler(event:Event):void {
    trace("Done.");
}

Cria o diretório especificado e qualquer diretório pai necessário. Se o diretório já existir, nenhuma ação será executada.

import flash.filesystem.*;

var source:File = File.desktopDirectory.resolvePath("test.txt");
var target:File = File.documentsDirectory.resolvePath("AIR Test/test.txt");
var targetParent:File = target.parent;
targetParent.createDirectory();
source.moveTo(target, true);

Retorna uma referência a um novo diretório temporário. Este é um novo diretório no caminho de diretório temporário do sistema.

Este método permite identificar um diretório novo e exclusivo sem ter que consultar o sistema para ver se o diretório é novo e exclusivo.

Pode ser conveniente excluir o diretório temporário antes de fechar o aplicativo, pois em alguns dispositivos ele não é excluído automaticamente.

Elementos da API relacionados

import flash.File;

var temp:File = File.createTempDirectory();
trace(temp.nativePath);

Retorna uma referência a um novo arquivo temporário. Este é um novo arquivo no caminho de diretório temporário do sistema.

Este método permite identificar um arquivo novo e exclusivo sem ter que consultar o sistema para ver se o arquivo é novo e exclusivo.

Pode ser conveniente excluir o arquivo temporário antes de fechar o aplicativo, pois ele não é excluído automaticamente.

Elementos da API relacionados

import flash.File;

var temp:File = File.createTempFile();
trace(temp.nativePath);

Exclui o diretório. Caso esse arquivo seja um link simbólico para um diretório, o link, e não o diretório, é removido.

Parâmetros

Elementos da API relacionados

import flash.filesystem.File;

var directory:File = File.documentsDirectory.resolvePath("Empty Junk Directory/");
File.createDirectory(directory);
trace(directory.exists); // true
directory.deleteDirectory();
trace(directory.exists); // false

Exclui o diretório assincronamente. Caso esse arquivo seja um link simbólico para um diretório, o link, e não o diretório, é removido.

Parâmetros

Elementos da API relacionados

Exclui o arquivo. Caso esse arquivo seja um link simbólico, o link, e não o arquivo de destino, é removido.

Elementos da API relacionados

import flash.filesystem.*;

var file:File = File.createTempFile();
trace(file.exists); // true
file.deleteFile();
trace(file.exists); // false

Exclui o arquivo assincronamente. Caso esse arquivo seja um link simbólico, o link, e não o arquivo de destino, é removido.

Elementos da API relacionados

Retorna uma matriz de objetos File correspondente aos arquivos e diretórios no diretório representado por esse objeto File. Esse método não explora o conteúdo de subdiretórios.

Elementos da API relacionados

import flash.filesystem.File;

var directory:File = File.userDirectory;
var list:Array = directory.getDirectoryListing();
for (var i:uint = 0; i < list.length; i++) {
    trace(list[i].nativePath);
}

Recupera assincronamente uma matriz de objetos File correspondente ao conteúdo do diretório representado por esse objeto File.

Elementos da API relacionados

import flash.filesystem.File;
import flash.events.FileListEvent;

var directory:File = File.userDirectory;
directory.getDirectoryListingAsync();
directory.addEventListener(FileListEvent.DIRECTORY_LISTING, directoryListingHandler);

function directoryListingHandler(event:FileListEvent):void {
    var list:Array = event.files;
    for (var i:uint = 0; i < list.length; i++) {
        trace(list[i].nativePath);
    }
}

Localiza o caminho relativo entre dois caminhos de arquivo.

O caminho relativo é a lista de componentes que podem ser acrescentados a essa referência (resolvidos em relação a ela) para localizar a segunda referência (parâmetro). O caminho relativo é retornado usando o caractere separador "/".

Opcionalmente, caminhos relativos podem incluir referências ".." referências, mas tais caminhos não cruzam limites de volumes evidentes.

Parâmetros

Retorna uma matriz de objetos File, relacionando os diretórios raiz do sistema de arquivos.

Por exemplo, no Windows isso é uma lista de volumes, como as unidades C: e D:. Uma unidade vazia, como uma unidade de CD ou DVD, sem nenhum disco inserido, não é incluída nessa matriz. No Mac OS e no Linux, esse método sempre retorna para o diretório raiz exclusivo do computador (o diretório "/").

Em sistemas de arquivos cuja raiz não é legível, como o sistema de arquivos do Android, as propriedades do objeto File retornado nem sempre refletem o valor verdadeiro. Por exemplo, no Android, a propriedade spaceAvailable informa 0.

import flash.filesystem.File;
var rootDirs:Array = File.getRootDirectories();

for (var i:uint = 0; i < rootDirs.length; i++) {
    trace(rootDirs[i].nativePath);
}

Move o arquivo ou diretório do local especificado por esse objeto File para o local especificado pelo parâmetro destination.

Para renomear um arquivo, defina o parâmetro destination para apontar para um caminho que esteja no diretório do arquivo, mas com um nome de arquivo diferente.

O processo de transferência cria qualquer diretório-pai necessário (se possível).

Parâmetros

Elementos da API relacionados

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

try  
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

import flash.filesystem.File;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("AIR Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("AIR Test/Results/test1.txt");

try 
{
    sourceFile.moveTo(destination, true);
}
catch (error:Error)
{
    trace("Error:" + error.message);
}

Começa a mover o arquivo ou diretório no local especificado por esse objeto File para o local especificado pelo parâmetro newLocation.

Para renomear um arquivo, defina o parâmetro destination para apontar para um caminho que esteja no diretório do arquivo, mas com um nome de arquivo diferente.

O processo de transferência cria qualquer diretório-pai necessário (se possível).

Parâmetros

Elementos da API relacionados

import flash.filesystem.File;
import flash.events.Event;

var sourceFile:File = File.documentsDirectory;
sourceFile = sourceFile.resolvePath("Apollo Test/test1.txt");
var destination:File = File.documentsDirectory;
destination = destination.resolvePath("Apollo Test/test2.txt");

sourceFile.moveToAsync(destination, true);
sourceFile.addEventListener(Event.COMPLETE, fileMoveCompleteHandler);

function fileMoveCompleteHandler(event:Event):void 
{
    trace("Done.")
}

Move um arquivo ou diretório para a lixeira.

Nota: em sistemas operacionais que não oferecem suporte ao conceito de uma pasta de lixeira recuperável, os arquivos são removidos imediatamente.

Elementos da API relacionados

Move um arquivo ou diretório assincronamente para a lixeira.

Nota: em sistemas operacionais que não oferecem suporte ao conceito de uma pasta de lixeira recuperável, os arquivos são removidos imediatamente.

Elementos da API relacionados

Abre o arquivo no aplicativo registrado pelo sistema operacional para abrir este tipo de arquivo.

O AIR impede que você use o método File.openWithDefaultApplication() para abrir certos arquivos. No Windows, o AIR impede que você abra arquivos com certos tipos de arquivo (arquivos com extensões específicas, enumeradas abaixo). Nos sistemas operacionais Mac e Linux, o AIR não permite abrir arquivos que serão lançados em aplicativos específicos, discriminados abaixo. A tentativa de abrir um destes arquivos que usam o método openWithDefaultApplication() resultará em uma exceção. Contudo, os aplicativos de AIR instalados com um instalador nativo (aplicativos de perfil de desktop extensos) não são restringidos por estas limitações; eles podem abrir arquivos de qualquer tipo.

Você não pode abrir documentos a partir do diretório de aplicativo.

As tabelas abaixo enumeram extensões de arquivo que são proibidas no Windows, bem como os aplicativos prevenidos no Mac OS e Linux:

Elementos da API relacionados

import flash.filesystem.File;
import flash.net.FileFilter;

var file:File = File.documentsDirectory; 
var mp3Filter:FileFilter = new FileFilter("MP3 Files", "*.mp3"); 
file.browseForOpen("Open", [mp3Filter]); 
file.addEventListener(Event.SELECT, fileSelected); 
 
function fileSelected(e:Event):void 
{ 
    file.openWithDefaultApplication(); 
}

Solicita permissão para acessar o sistema de arquivos.

Cria um novo objeto File com um caminho relativo a esse caminho do objeto File, com base no parâmetro path (uma string).

Você pode usar um caminho relativo ou absoluto como o parâmetro path.

Se você especificar um caminho relativo, o path fornecido será "acrescentado" ao caminho do objeto File. No entanto, o uso de ".." no path pode retornar um caminho resultante que não seja filho do objeto File. A referência resultante não precisa fazer referência a um local de sistema de arquivos real.

Se você especificar uma referência de arquivo absoluta, o método retornará o objeto File apontando para esse caminho. A referência de arquivo absoluta deverá usar uma sintaxe válida de caminho nativo para o sistema operacional do usuário ("C:\\test" no Windows). Não use uma URL (por exemplo, "file:///c:/test") como o parâmetro path.

Todos os caminhos resultantes são normalizados da seguinte maneira:

• Qualquer elemento "." é ignorado.
• Qualquer elemento ".." consuma sua entrada pai.
• Nenhuma referência ".." que alcança a raiz do sistema de arquivos ou a raiz do armazenamento persistente do aplicativo transmite esse nó; ele é ignorado.

Sempre use o caractere de barra (/) como separador de caminho. Em Windows, você também pode usar o caractere de barra oblíqua invertida (\), mas você não deve. O uso do caractere de barra oblíqua invertida pode levar a aplicativos que não funcionam em outras plataformas.

Nomes de arquivo e de diretório diferenciam maiúsculas de minúsculas no Linux.

Parâmetros

Despachado quando uma operação assíncrona pendente é cancelada.

Esse evento tem as seguintes propriedades:

Despachado quando uma operação assíncrona é concluída.

Esse evento tem as seguintes propriedades:

Despachado quando uma lista de diretórios está disponível como resultado de uma chamada para o método getDirectoryListingAsync().

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Despachado quando ocorre um erro durante uma operação de arquivo assíncrona.

Esse evento tem as seguintes propriedades:

Será despachado quando o aplicativo solicitar permissão para acessar o sistema de arquivos. Verifique o valor da propriedade status para determinar se a permissão for concedida ou recusada

Elementos da API relacionados

Despachado quando uma operação viola uma restrição de segurança.

Esse evento tem as seguintes propriedades:

Despachado quando o usuário seleciona um arquivo ou diretório na caixa de diálogo de navegação de arquivo ou diretório.

Esse evento tem as seguintes propriedades:

Despachado quando o usuário seleciona arquivos na caixa de diálogo aberta por uma chamada para o método browseForOpenMultiple().

Elementos da API relacionados