Label  - AS3 Flash

Obtém ou define uma string que indica como um rótulo é dimensionado e alinhado para se ajustar ao valor de sua propriedade text. Os seguintes valores são válidos:

• TextFieldAutoSize.NONE: o rótulo não é redimensionado ou alinhado para se ajustar ao texto.
• TextFieldAutoSize.LEFT: os lados direito e esquerdo do rótulo são redimensionados para se ajustarem ao texto. Os lados esquerdo e superior não são redimensionados.
• TextFieldAutoSize.CENTER: os lados esquerdo e direito do rótulo são redimensionados para se ajustarem ao texto. O centro horizontal do rótulo permanece ancorado a sua posição central horizontal original.
• TextFieldAutoSize.RIGHT: os lados esquerdo e inferior do rótulo são redimensionados para se ajustarem ao texto. Os lados superior e direito não são redimensionados.

O valor padrão é TextFieldAutoSize.NONE.

Elementos da API relacionados

import flash.text.TextFieldAutoSize;
import fl.controls.Label;

var testString:String = "Lorem ipsum dolor sit amet.";
var label1:Label = new Label();
var label2:Label = new Label();
var label3:Label = new Label();
label1.move(10,10);
label2.move(10,50);
label3.move(10,90);
label1.width = stage.stageWidth - 20;
label2.width = stage.stageWidth - 20;
label3.width = stage.stageWidth - 20;
label1.text = testString;
label2.text = testString;
label3.text = testString;
label1.autoSize = TextFieldAutoSize.LEFT;
label2.autoSize = TextFieldAutoSize.CENTER;
label3.autoSize = TextFieldAutoSize.RIGHT;
addChild(label1);
addChild(label2);
addChild(label3);

Obtém ou define um valor que indica se o espaço em branco extra, como espaços e quebras de linha, deve ser removido de um componente Label que contém texto HTML. Um valor true indica que o espaço em branco deve ser removido; um valor false indica que o espaço em branco permanece.

A propriedade condenseWhite property afeta apenas o texto que foi definido com o uso da propriedade htmlText, e não da propriedade text. Se você definir o texto usando a propriedade text, a propriedade condenseWhite é ignorada.

Se você definir a propriedade condenseWhite como verdadeira, é necessário usar comandos HTML padrão, como <br> e <p>, para inserir quebras de linha no campo de texto.

O valor padrão é false.

Elementos da API relacionados

import fl.controls.Label;

var testString:String = "   Hello World";

var label1:Label = new Label();
label1.move(10,10);
label1.htmlText = testString;
addChild(label1);

var label2:Label = new Label();
label2.move(10,40);
label2.condenseWhite = true;
label2.htmlText = testString;
addChild(label2);

Obtém ou define a altura do componente, em pixels.

Definir esta propriedade faz com que um evento resize seja despachado. Consulte o evento resize para obter informações detalhadas sobre quando ele é despachado.

Se a propriedade scaleY do componente não for 1.0, a altura do componente que é obtido das coordenadas internas não corresponderá ao valor da altura das coordenadas pai. Por exemplo, um componente com uma largura de 100 pixels e scaleY de 2 tem o valor de 100 pixels no pai, mas armazena internamente um valor indicando que a altura é de 50 pixels.

Elementos da API relacionados

Obtém ou define o texto a ser exibido pelo componente Label, incluindo a marcação HTML que expressa os estilos desse texto. É possível especificar o texto HTML nessa propriedade usando o subconjunto de marcas HTML que recebem suporte do objeto TextField.

Se o valor padrão da propriedade text for alterado no Inspetor de propriedades, esse valor alterado tem precedência sobre qualquer valor no campo da propriedade htmlText, no Inspetor de propriedades. Para usar a propriedade htmlText no Inspetor de propriedades, o campo da propriedade text deve conter o valor Label, exatamente como mostrado. Durante a codificação com o ActionScript, não há necessidade de definir o valor da propriedade text; o valor padrão é Label.

O valor padrão é "".

Elementos da API relacionados

Obtém ou define um valor que indica se o texto pode ser selecionado. Um valor true indica que ele pode ser selecionado; um valor false indica que não é possível fazer isso.

O texto selecionável pode ser copiado do componente Label pelo usuário.

O valor padrão é false.

Obtém ou define o texto sem formatação a ser exibido pelo componente Label.

Observe que os caracteres que representam a marcação HTML não têm significados especiais na string e serão exibidos à medida que são inseridos.

Para exibir o texto que contém as marcas HTML, use a propriedade htmlText. O HTML substitui qualquer texto que você tenha definido usando a propriedade htmlText, e a propriedade text retorna uma versão simples do texto HTML, com as marcas HTML removidas.

Se o valor padrão da propriedade text for alterado no Inspetor de propriedades, esse valor tem precedência sobre a propriedade htmlText, no Inspetor de propriedades.

O valor padrão é "Label".

Elementos da API relacionados

Uma referência ao campo de texto interno do componente Label.

Obtém ou define a largura do componente, em pixels.

Definir esta propriedade faz com que um evento resize seja despachado. Consulte o evento resize para obter informações detalhadas sobre quando ele é despachado.

Se a propriedade scaleX do componente não for 1.0, a largura do componente que é obtido das coordenadas internas não corresponderá ao valor da largura das coordenadas pai. Por exemplo, um componente com uma largura de 100 pixels e scaleX de 2 tem o valor de 100 pixels no pai, mas armazena internamente um valor indicando que a largura é de 50 pixels.

Elementos da API relacionados

Obtém ou define um valor que indica se o campo de texto oferece suporte para quebra de linha. Um valor true indica que sim; um valor false indica que não.

O valor padrão é false.

import fl.controls.Label;

var url:String = "http://www.helpexamples.com/flash/text/lorem.txt";

myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.width = 530;
myLabel.move(10, 10);
myLabel.wordWrap = true;

var ldr:URLLoader = new URLLoader();
ldr.addEventListener(Event.COMPLETE, completeHandler);
ldr.load(new URLRequest(url));

function completeHandler(event:Event):void {
    myLabel.text = URLLoader(event.currentTarget).data;
}

Cria uma nova ocorrência do componente Label.

Recupera o mapa de estilos padrão do componente atual. O mapa de estilos contém o tipo que é apropriado para o componente, de acordo com o estilo que o componente usa. Por exemplo, o estilo disabledTextFormat contém o valor null ou um objeto TextFormat. Você pode usar estes estilos e chamar setStyle() no componente atual. O código a seguir substitui o estilo disabledTextFormat padrão no componente especificado:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Elementos da API relacionados

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Despachado depois que ocorre uma alteração na largura ou altura do componente.

Observação: esse evento não ocorre se o código ActionScript for utilizado para alterar o texto do rótulo.

Esse evento tem as seguintes propriedades:

import fl.controls.Label;
import fl.events.ComponentEvent;

var myLabel:Label = new Label();
myLabel.text = "The quick brown fox jumped over the lazy dog.";
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.wordWrap = true;
myLabel.move(10, 10);
myLabel.addEventListener(ComponentEvent.RESIZE, resizeHandler);
addChild(myLabel);

function resizeHandler(event:ComponentEvent):void {
    var lbl:Label = event.currentTarget as Label;
    trace("width:" + lbl.width, "height:" + lbl.height); // width:100 height:46
}

1. Adicione os componentes Label e Button à biblioteca.
2. Salve esse código como LabelExample.as no mesmo diretório de FLA.
3. Defina DocumentClass em FLA como LabelExample.

package
{
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.display.Sprite;
    import fl.controls.Label;
    import fl.controls.Button;
    
    public class LabelExample extends Sprite
    {
        private var simpleLabel:Label;
        private var b1:Button;
        private var b2:Button;        

        private var htmlData:String = "<br>This label displays <b>bold</b> and <i>italic</i> HTML-formatted text.";
        
        public function LabelExample() {
            setupLabel();
            setupButtons();
        }
        private function setupButtons():void {
            b1 = new Button();
            b2 = new Button();

            b1.move(10,50);
            b2.move(10,80);

            b1.setSize(120,22);
            b2.setSize(120,22);
            
            b1.label = "Make Normal Label";
            b2.label = "Make HTML Label";

            b1.addEventListener(MouseEvent.CLICK,buttonClick);
            b2.addEventListener(MouseEvent.CLICK,buttonClick);

            addChild(b1);
            addChild(b2);
        }
        private function setupLabel():void {
            simpleLabel = new Label();
            simpleLabel.move(10,10);
            simpleLabel.autoSize = TextFieldAutoSize.LEFT;
            addChild(simpleLabel);
        }
                               
        // Event handler function to change the image size.
        private function displayHTML():void {
            simpleLabel.htmlText = htmlData;
        }
      
        // Event handler function to change the image size.
        private function displayText():void {
            simpleLabel.text = "This Label displays plain text.";
        }
        private function buttonClick(e:MouseEvent):void {
            switch(e.target) {
                case b1:
                    displayText();
                    break;
                case b2:
                    displayHTML();
                    break;
                default:
                    break;
            }
        }
    }
}