TextFormat  - AS3

Indica o alinhamento do parágrafo. Os valores válidos são as constantes TextFormatAlign.

O valor padrão é TextFormatAlign.LEFT.

Elementos da API relacionados

Indica o recuo do bloco em pixels. O recuo de bloco é aplicado a um bloco inteiro de texto, ou seja, a todas as linhas do texto. Em contraste, o recuo normal (TextFormat.indent) afeta somente a primeira linha de cada parágrafo. Se essa propriedade for null, o objeto TextFormat não especificará o recuo do bloco (recuo do bloco é 0).

Especifica se o texto está em negrito. O valor padrão é null, o que significa que não está sendo utilizado o negrito. Se o valor for true, o texto estará em negrito.

Indica que o texto faz parte de uma lista com marcadores. Em uma lista com marcadores, cada parágrafo de texto é recuado. É exibido um símbolo de marcador à esquerda da primeira linha de cada parágrafo. O valor padrão é null, o que significa que nenhuma lista com marcadores está sendo utilizada.

Indica a cor do texto. Um número que contém três componentes RGB de 8 bits; por exemplo, 0xFF0000 é vermelho, enquanto 0x00FF00 é verde. O valor padrão é null, o que significa que o Flash Player usa a cor preta (0x000000).

O nome da fonte para o texto neste formato de texto, como uma string. O valor padrão é null, o que significa que o Flash Player usa a fonte Times New Roman para o texto

Indica o recuo da margem esquerda para o primeiro caractere no parágrafo. O valor padrão é null, o que indica que nenhum recuo é utilizado.

Elementos da API relacionados

Indica se o texto neste formato de texto pode ser formato em itálico. O valor padrão é null, o que significa que itálico não é utilizado.

Um valor booliano que indica se kerning está ativado (true) ou desativado (false). O kerning ajusta os pixels entre determinados pares de caracteres para aprimorar a legibilidade e deve ser utilizado somente quando necessário, como ocorre em cabeçalhos com fontes grandes. O kerning é suportado somente para fontes incorporadas.

Determinadas fontes, como Verdana, e fontes de espaço único, como Courier New, não oferecem suporte a kerning.

O valor padrão é null, o que significa que kerning não está ativado.

Um inteiro que representa a quantidade de espaço vertical (denominado leading) entre linhas. O valor padrão é null, o que indica que a quantidade de entrelinhas utilizada é 0.

A margem esquerda do parágrafo, em pixels. O valor padrão é null, o que indica que a margem esquerda é de 0 pixel.

Um número que representa a quantidade de espaço uniformemente distribuída entre todos os caracteres. O valor especifica o número de pixels adicionados à frente após cada caractere. O valor padrão é null, o que significa que 0 pixel será utilizado para o espaçamento entre letras. É possível utilizar valores decimais, como 1,75.

A margem direita do parágrafo, em pixels. O valor padrão é null, o que indica que a margem direita é de 0 pixel.

O tamanho do texto em pixels nesse formato de texto. O valor padrão é null, significando que o tamanho 12 será usado.

Especifica paradas de tabulação personalizadas como uma matriz de inteiros não negativos. Cada parada de tabulação é especificada em pixels. Se paradas de tabulação personalizadas não forem especificadas (null), a parada de tabulação padrão será 4 (largura média de caractere).

Indica a janela de destino na qual o hiperlink é exibido. Se a janela de destino for uma string vazia, o texto será exibido na janela de destino padrão, _self. É possível selecionar um nome personalizado ou um dos quatro seguintes nomes: _self especifica o quadro atual na janela atual, _blank especifica uma nova janela, _parent especifica o pai do quadro atual e _top especifica o quadro de nível superior na janela atual. Se a propriedade TextFormat.url for uma string vazia ou null, é possível obter ou definir essa propriedade, mas ela não surtirá efeito.

Elementos da API relacionados

Indica se o texto que usa esse formato de texto está sublinhado (true) ou não (false). O sublinhado é similar ao produzido pela marca <U>, mas esta não é um sublinhado verdadeiro, já que não ignora descendentes corretamente. O valor padrão é null, o que indica que nenhum sublinhado é utilizado.

Indica o URL de destino do texto neste formato de texto. Se a propriedade url for uma string vazia, o texto não terá um hiperlink. O valor padrão é null, o que indica que o texto não tem um hiperlink.

Observação: o texto com o formato de texto atribuído deve ser definido com a propriedade htmlText para que o hiperlink funcione.

Elementos da API relacionados

Cria um objeto TextFormat com as propriedades especificadas. É possível alterar as propriedades do objeto TextFormat para alterar a formatação de campos de texto.

Qualquer parâmetro pode ser definido como null para indicar que não foi definido. Todos os parâmetros são opcionais; qualquer parâmetro omitido é tratado como null.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFormat;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.text.TextFormatAlign;
    
    public class TextFormat_constructorExample extends Sprite {
        private var contentTextField:TextField = new TextField();
        private var formatTextField:TextField = new TextField();
        private var newFormat:TextFormat = new TextFormat();
        
        public function TextFormat_constructorExample() {
            contentTextField.x = 10;
            contentTextField.y = 10;
            contentTextField.background = true;
            contentTextField.border = true;
            contentTextField.multiline = true;
            contentTextField.wordWrap = true;
            contentTextField.selectable = false;
            contentTextField.width = 250;
            contentTextField.height = 120; 
  
            contentTextField.htmlText = "<p>The TextFormat class represents character formatting "
                + "information. Use the TextFormat class to create specific text formatting "
                + "for text fields." + 
                " </p><br>" + "\tTab One" + "\tTab Two<br>";
              
            formatTextField.x = 10;
            formatTextField.y = 140;
            formatTextField.background = true;
            formatTextField.border = true;
            formatTextField.autoSize = TextFieldAutoSize.LEFT;
            
            formatTextField.text = "align: right\n" + "blockIndent: 10 pixels\n" + "bold:\n" + "bullet:\n" + "color: red\n"
                                + "font: Arial\n" + "indent: 20 pixels\n" + "italic:\n" + "leading: 5 spaces\n" 
                                + "leftMargin: 20 pixels\n" + "letterSpacing: 4 pixels\n" + "rightMargin: 20 pixels\n" 
                                + "size: 16 point\n" + "target: new window\n" + "tabStops: 50 and 150 pixel\n" 
                                + "underline:\n" + "url: Adobe Flex page\n";

            formatTextField.addEventListener(MouseEvent.CLICK, formatTextFieldClickHandler);
            
            contentTextField.addEventListener(MouseEvent.CLICK, contentTextFieldClickHandler);
            
            this.addChild(contentTextField);
            this.addChild(formatTextField);
        }

        private function formatTextFieldClickHandler(e:MouseEvent):void {
                var value:String= "";
                var i:uint = 0;
                var index:int = formatTextField.getLineIndexAtPoint(e.localX, e.localY);
                var line:String = formatTextField.getLineText(index);;

                line = line.substr(0, (line.indexOf(":")));

                switch(line) {
                    case "align":
                        newFormat.align = TextFormatAlign.RIGHT;
                        break;
                    case "blockIndent":
                        newFormat.blockIndent = 10;
                        break;
                    case "bold":
                        newFormat.bold = true;
                        break;
                    case "bullet":
                        newFormat.bullet = true;
                        break;
                    case "color":
                        newFormat.color = 0xFF0000;        
                        break;
                    case "font":
                        newFormat.font = "Arial";
                        break;
                    case "indent":
                        newFormat.indent = 20;
                        break;
                    case "italic":
                        newFormat.italic = true;
                        break;
                    case "leading":
                        newFormat.leading = 5;
                        break;
                    case "leftMargin":
                        newFormat.leftMargin = 20;
                        break;
                    case "letterSpacing":
                        newFormat.letterSpacing = 4;
                        break;
                    case "rightMargin":
                        newFormat.rightMargin = 20;
                        break;
                    case "size":
                        newFormat.size = 16;
                        break;
                    case "tabStops":                
                        newFormat.tabStops = [50, 150];
                        break;
                    case "target":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        newFormat.target = "_blank";
                        break;    
                    case "underline":
                        newFormat.underline = true;
                        break;
                    case "url":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        break;
                }    

                contentTextField.setTextFormat(newFormat);
        }

        private function contentTextFieldClickHandler(e:MouseEvent):void {
            contentTextField.setTextFormat(contentTextField.defaultTextFormat);
            newFormat = contentTextField.defaultTextFormat;
        }
    }
}

1. Uma propriedade label do tipo TextField é criada.
2. O construtor de classe chama a função configureLabel().
3. Primeiramente, a função configureLabel() cria um novo objeto TextField e o atribui a label e, em seguida, define seus parâmetros como
   • Justifica à esquerda o campo de texto.
   • Ativa o preenchimento do plano de fundo.
   • Ativa a borda.
4. Em seguida, configureLabel() cria a variável local, format, e a atribui a uma nova ocorrência TextFormat com seus parâmetros definidos como:
   • Tipo de fonte = Verdana
   • Cor da fonte = solid red
   • Tamanho da fonte = 10
   • Fonte sublinhada = true.
5. A propriedade defaultTextFormat de label é definida como format e a ocorrência de label é adicionada à lista de exibição, a qual exibe inicialmente um campo de texto sem texto (como uma pequena caixa com um plano de fundo branco) no palco.
6. Finalmente (de volta ao construtor), o texto de label é definido para exibir "Hello World and welcome to the show", nas coordenadas x = 0, y = 0, chamando setLabel().

 package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;


    public class TextFormatExample extends Sprite {
        private var label:TextField;

        public function TextFormatExample() {
            configureLabel();
            setLabel("Hello World and welcome to the show");
        }

        public function setLabel(str:String):void {
            label.text = str;
        }

        private function configureLabel():void {
            label = new TextField();
            label.autoSize = TextFieldAutoSize.LEFT;
            label.background = true;
            label.border = true;

            var format:TextFormat = new TextFormat();
            format.font = "Verdana";
            format.color = 0xFF0000;
            format.size = 10;
            format.underline = true;

            label.defaultTextFormat = format;
            addChild(label);
        }
    }
}