NumericStepper  - AS3 Flash

Obtém ou define um valor que indica se o componente pode aceitar a interação do usuário. O valor true indica que o componente pode aceitar interação do usuário; o valor false indica que ele não pode aceitar.

Se você definir a propriedade enabled como false, a cor do contêiner ficará esmaecia e a entrada do usuário será bloqueada (com exceção dos componentes Label e ProgressBar).

O valor padrão é true.

Obtém ou define o modo do editor de métodos de entrada (IME). IME torna possível o uso de um teclado QWERTY pelos usuários, para inserir caracteres do conjunto de caracteres chineses, japoneses e coreanos.

O Flash define o IME como o modo especificado quando o componente obtém o foco e o restaura para o valor original, depois que o componente perde o foco.

A classe flash.system.IMEConversionMode define constantes para os valores válidos para essa propriedade. Defina essa propriedade como null para impedir o uso do IME com o componente.

Obtém ou define o valor máximo na sequência de valores numéricos.

O valor padrão é 10.

Obtém ou define o número mínimo na sequência de valores numéricos.

O valor padrão é 0.

Obtém o próximo valor na sequência de valores.

Obtém o valor anterior na sequência de valores.

Obtém ou define um número diferente de zero que descreve a unidade de alteração entre valores. A propriedade value é um múltiplo desse número menos o mínimo. O componente NumericStepper arredonda o valor resultante ao tamanho de etapa mais próximo.

O valor padrão é 1.

Obtém uma referência ao componente TextInput que o componente NumericStepper contém. Use essa propriedade para acessar e manipular o componente TextInput subjacente. Por exemplo, é possível usar essa propriedade para alterar a seleção atual na caixa de texto ou restringir os caracteres aceitos pela caixa de texto.

Obtém ou define o valor atual do componente NumericStepper.

O valor padrão é 1.

Cria uma nova ocorrência do componente NumericStepper.

Mostra ou oculta o indicador de foco neste componente.

A classe UIComponent implementa este método criando e posicionando uma ocorrência da classe que é especificada pelo estilo focusSkin.

Parâmetros

Recupera o mapa de estilos padrão do componente atual. O mapa de estilos contém o tipo que é apropriado para o componente, de acordo com o estilo que o componente usa. Por exemplo, o estilo disabledTextFormat contém o valor null ou um objeto TextFormat. Você pode usar estes estilos e chamar setStyle() no componente atual. O código a seguir substitui o estilo disabledTextFormat padrão no componente especificado:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Elementos da API relacionados

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Define o foco da ocorrência do componente

Despachado quando o usuário altera o valor do componente NumericStepper.

Observação: esse evento não é despachado, se o ActionScript for usado para alterar o valor.

Esse evento tem as seguintes propriedades:

1. Adicione o componente NumericStepper à biblioteca.
2. Salve esse código como NumericStepperExample.as no mesmo diretório de FLA.
3. Defina DocumentClass em FLA como NumericStepperExample.

package 
{
    import flash.display.Sprite
    import flash.text.TextField;
    import flash.events.Event;
    import fl.controls.NumericStepper;
    
    public class NumericStepperExample extends Sprite
    {
        private var ns1:NumericStepper;
        private var ns2:NumericStepper;
        private var tf1:TextField;
        private var tf2:TextField;
        private var rowHeight1:Number = 10;
        private var rowHeight2:Number = 50;
        
        public function NumericStepperExample() {        
            setupSteppers();
            setupTextFields();
        }
        private function setupTextFields():void {
            tf1 = new TextField();
            tf1.text = "This stepper increments by 1 between 0 and 5. Disables if it reaches 0.";
            tf1.autoSize = "left";
            tf1.x = 100;
            tf1.y = rowHeight1;
            addChild(tf1);
            
            tf2 = new TextField();
            tf2.text = "This stepper increments by 0.01 between 0 and 20. Disables if it reaches 0.";
            tf2.autoSize = "left";
            tf2.x = 100;
            tf2.y = rowHeight2;
            addChild(tf2);
        }
        private function setupSteppers():void {    
            ns1 = new NumericStepper();
            ns1.stepSize = 1;
            ns1.maximum = 5;
            ns1.minimum = 0;
            ns1.addEventListener(Event.CHANGE,changeOccurred);
            ns1.move(10,rowHeight1);
            addChild(ns1);

            ns2 = new NumericStepper();
            ns2.stepSize = 0.01;
            ns2.maximum = 20;
            ns2.minimum = 0;
            ns2.value = 10;
            ns2.addEventListener(Event.CHANGE,changeOccurred);
            ns2.move(10,rowHeight2);
            addChild(ns2);
        }
        private function changeOccurred(e:Event):void {
            var nsTarget:NumericStepper = e.target as NumericStepper;
            if(nsTarget.value == 0) nsTarget.enabled = false;
        }
    }
}