UIComponent  - AS3 Flash

Pobiera lub ustawia wartość wskazującą, czy składnik akceptuje interakcje ze strony użytkownika. Wartość true oznacza, że składnik może akceptować interakcje ze strony użytkownika; wartość false oznacza sytuację przeciwną.

Ustawienie właściwości enabled na false powoduje, że kolor kontenera zostanie wyszarzony, a akceptowanie interakcji ze strony użytkownika będzie zablokowane (z wyjątkiem składników Label i ProgressBar).

Wartością domyślną jest true.

Pobiera lub ustawia wartość Boolean określającą, czy składnik może stawać się aktywny, gdy użytkownik go kliknie. Wartość true oznacza, że składnik może stawać się aktywny; wartość false oznacza sytuację przeciwną.

Gdy ta właściwość jest równa false, aktywność zostanie przeniesiona do pierwszego obiektu nadrzędnego, którego właściwość mouseFocusEnabled będzie ustawiona na true.

Wartością domyślną jest true.

Powiązane elementy interfejsu API

Pobiera lub ustawia obiekt FocusManager sterujący aktywnością tego składnika i jego składników równorzędnych. Każdy składnik podręczny ma własną pętlę aktywności i instancję obiektu FocusManager. Ta właściwość umożliwia dostęp do obiektu FocusManager właściwego dla tego składnika.

Pobiera lub ustawia wysokość składnika w pikselach.

Ustawienie tej właściwości powoduje wywołanie zdarzenia resize. Szczegółowe informacje o okolicznościach wywoływania zdarzenia resize zawiera opis tego zdarzenia.

Jeśli właściwość scaleY składnika jest różna od 1.0, wysokość składnika uzyskana z jego współrzędnych wewnętrznych będzie różna od wysokości uzyskanej ze współrzędnych obiektu nadrzędnego. Na przykład składnik o wysokości 100 pikseli i wartości scaleY równej 2 ma w obiekcie nadrzędnym wysokość 100 pikseli, ale wewnętrznie jest w nim zapisana wartość wskazująca na wysokość 50 pikseli.

Pobiera lub ustawia wartość określającą, czy składnik może stawać się aktywny, gdy użytkownik go kliknie. Wartość true oznacza, że składnik może stawać się aktywny; wartość false oznacza sytuację przeciwną.

Gdy ta właściwość jest równa false, aktywność zostanie przeniesiona do pierwszego obiektu nadrzędnego, którego właściwość mouseFocusEnabled będzie ustawiona na true.

Wartością domyślną jest true.

Powiązane elementy interfejsu API

Mnoży bieżącą szerokość składnika przez współczynnik skalowania.

Powiązane elementy interfejsu API

Mnoży bieżącą wysokość składnika przez współczynnik skalowania.

Powiązane elementy interfejsu API

Pobiera lub ustawia wartość wskazującą, czy bieżąca instancja składnika jest widoczna. Wartość true oznacza, że bieżący składnik jest widoczny; wartość false oznacza, że nie jest.

Gdy ta wartość zostanie ustawiona na true, obiekt wywoła zdarzenie show. Gdy ta wartość zostanie ustawiona na false, obiekt wywoła zdarzenie hide. W obu przypadkach składniki podrzędne obiektu nie generują zdarzenia show ani hide, chyba że obiekt jawnie implementuje takie zachowanie.

Wartością domyślną jest true.

Powiązane elementy interfejsu API

Pobiera lub ustawia szerokość składnika w pikselach.

Ustawienie tej właściwości powoduje wywołanie zdarzenia resize. Szczegółowe informacje o okolicznościach wywoływania zdarzenia resize zawiera opis tego zdarzenia.

Jeśli właściwość scaleX składnika jest różna od 1,0, szerokość składnika uzyskana z jego współrzędnych wewnętrznych będzie różna od szerokości uzyskanej ze współrzędnych obiektu nadrzędnego. Na przykład składnik o szerokości 100 pikseli i wartości scaleX równej 2 ma w obiekcie nadrzędnym szerokość 100 pikseli, ale wewnętrznie jest w nim zapisana wartość wskazująca na szerokość 50 pikseli.

Powiązane elementy interfejsu API

Pobiera lub ustawia współrzędną x reprezentującą pozycję składnika wzdłuż osi x w jego kontenerze nadrzędnym. Wartość jest wyrażona w pikselach i liczona od lewej strony.

Ustawienie tej właściwości powoduje wywołanie zdarzenia ComponentEvent.MOVE.

Wartością domyślną jest 0.

Powiązane elementy interfejsu API

Pobiera lub ustawia współrzędną y reprezentującą pozycję składnika wzdłuż osi y w jego kontenerze nadrzędnym. Wartość jest wyrażona w pikselach i liczona od góry.

Ustawienie tej właściwości powoduje wywołanie zdarzenia move.

Powiązane elementy interfejsu API

Tworzy nową instancję składnika UIComponent.

Usuwa właściwość stylu z tej instancji składnika.

Nie musi powodować zwrócenie przez metodę getStyle() wartości undefined.

Parametry

Powiązane elementy interfejsu API

Wyświetla lub ukrywa wskaźnik aktywności tego składnika.

Klasa UIComponent implementuje tę metodę poprzez utworzenie i ustawienie położenia instancji klasy określonej przez styl focusSkin.

Parametry

Inicjuje natychmiastową operację rysowania bez unieważniania wszystkich składników i właściwości, co odróżnia ją od metody invalidateNow.

Pobiera obiekt, który jest w danej chwili aktywny.

Ta metoda nie zawsze zwraca składnik, który jest aktywny. Może zwrócić wewnętrzny składnik podrzędny aktywnego składnika. Aby pobrać aktywny składnik, należy skorzystać z właściwości focusManager.focus.

Pobiera właściwość stylu ustawioną w łańcuchu wyszukiwania stylów danego składnika.

Typ wartości zwracanej przez tę metodę zależy od pobranej właściwości stylu. Do możliwych typów należą: Boolean; String; Number; int; uint w przypadku koloru RGB; Class w przypadku karnacji; oraz wszelkiego rodzaju obiekty.

Wywołanie tej metody w celu pobrania właściwości określonego stylu, zwrócona zostanie wartość znanego typu, którą można zapisać w zmiennej tego samego typu. Nie jest wymagane rzutowanie stylów. Wystarczy prosta instrukcja przypisania, taka jak poniższa:

var backgroundColor:uint = getStyle("backgroundColor");

Jeśli właściwość stylu nie jest ustawiona w łańcuchu wyszukiwania stylów, ta metoda zwraca wartość undefined. Należy zwrócić uwagę, że undefined jest wartością specjalną, różną od false, "", NaN, 0, lub null. Żadna poprawna wartość stylu nie jest nigdy równa undefined. Można użyć metody statycznej StyleManager.isValidStyleValue() w celu przetestowania, czy wartość została ustawiona.

Parametry

Powiązane elementy interfejsu API

import fl.controls.ComboBox;
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var myComboBox:ComboBox = new ComboBox();
myComboBox.setStyle("textPadding", 6);
myComboBox.setStyle("disabledAlpha", 0.8);

var styleObject:Object = ComboBox.getStyleDefinition();
var styleDP:DataProvider = new DataProvider();
var styleName:String;
var styleDefaultValue:String;
var styleCurrentValue:String;

for (styleName in styleObject) {
    styleDefaultValue = String(styleObject[styleName]);
    styleCurrentValue = String(myComboBox.getStyle(styleName));
    styleDP.addItem({name:styleName, defaultValue:styleDefaultValue, currentValue:styleCurrentValue});
}
styleDP.sortOn("name", Array.CASEINSENSITIVE);

var c1:DataGridColumn = new DataGridColumn("name");
c1.headerText = "Style name:";
var c2:DataGridColumn = new DataGridColumn("defaultValue");
c2.headerText = "Default style value:";
var c3:DataGridColumn = new DataGridColumn("currentValue");
c3.headerText = "Current style value:"

var styleDataGrid:DataGrid = new DataGrid();
styleDataGrid.addColumn(c1); // name
styleDataGrid.addColumn(c2); // defaultValue
styleDataGrid.addColumn(c3); // currentValue
styleDataGrid.dataProvider = styleDP;
styleDataGrid.setSize(stage.stageWidth - 20, stage.stageHeight - 20);
styleDataGrid.move(10, 10);
addChild(styleDataGrid);

Pobiera domyślną mapę stylów dla bieżącego składnika. Mapa stylów zawiera typ odpowiedni dla składnika, w zależności od stylu składnika. Na przykład dla stylu disabledTextFormat wartość jest równa null lub jest obiektem TextFormat. Można używać tych stylów w wywołaniach metody setStyle() dla bieżącego składnika. Poniższy kod przesłania domyślny styl disabledTextFormat dla określonego składnika:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Powiązane elementy interfejsu API

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Zwraca określony styl dla składnika po uwzględnieniu wszystkich stylów ustawionych na poziomie globalnym, poziomie składnika i instancji.

Przykład: jeśli składnik ma styl ustawiony na poziomie globalnym jako myStyle, a użytkownik wywoła getStyle("myStyle") dla instancji, która nie zawiera ustawienia instancji, metoda zwróci wartość null. Metoda getStyleValue("myStyle") zwraca "myStyle", ponieważ jest aktywna na poziomie globalnym.

Parametry

Oznacza właściwość jako nieważną i ponownie rysuje składnik w następnej klatce, o ile nie określono innego zachowania.

Parametry

Scala style z wielu klas w jeden obiekt. Jeśli styl jest zdefiniowany w wielu obiektach, używane jest pierwsze napotkane wystąpienie.

Parametry

Przemieszcza składnik do określonej pozycji w jego obiekcie nadrzędnym. Odnosi ten sam skutek, co zmiana położenia składnika poprzez ustawienie jego właściwości x i y. Wywołanie tej metody powoduje wywołanie zdarzenia ComponentEvent.MOVE.

Aby przesłonić metodę updateDisplayList() w składniku niestandardowym, należy użyć metody move() zamiast ustawiania właściwości x i y. Wynika to z faktu, że wywołanie metody move() powoduje wywołanie zdarzenia move natychmiast po ukończeniu operacji przemieszczania. Natomiast zmiana położenia składnika poprzez ustawienie jego właściwości x i y powoduje, że obiekt zdarzenia zostanie wywołany dopiero przy następnym odświeżeniu ekranu.

Parametry

Powiązane elementy interfejsu API

Ustawia ten składnik jako aktywny. Składnik może przekazać aktywność do składnika podrzędnego.

Uwaga: Po ustawieniu aktywności przez tę metodę wskaźniki aktywności są wyświetlane tylko dla składników TextInput i TextArea. Wskaźnik aktywności jest wyświetlany dla wszystkich składników, gdy użytkownik przekaże aktywność za pomocą klawisza Tab.

Ustawia szerokość i wysokość składnika na określone wartości.

Parametry

Ustawia właściwość stylu tej instancji składnika. Styl może przesłonić styl ustawiony globalnie.

Wywołanie tej metody może spowodować pogorszenie wydajności. Należy jej używać wyłącznie wtedy, gdy jest to niezbędne.

Parametry

Powiązane elementy interfejsu API

import fl.controls.Button;

var myFormat:TextFormat = new TextFormat();
myFormat.font = "Georgia";

var b:Button = new Button();
b.label = "Hello World";
b.setStyle("textFormat", myFormat);
addChild(b);

import fl.controls.Button;

var flashIcon:Loader = new Loader();
flashIcon.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
flashIcon.load(new URLRequest("http://www.helpexamples.com/flash/images/logo.png"));

var myButton:Button = new Button();
myButton.label = "Flash";
myButton.move(10, 10);
addChild(myButton);

function completeHandler(event:Event):void {
    flashIcon.width = 16;
    flashIcon.height = 16;
    myButton.setStyle("icon", flashIcon);
}

Sprawdza ważność i aktualizuje właściwości oraz układ tego obiektu, w razie potrzeby rysując go ponownie.

Właściwości wymagające intensywnych obliczeń zwykle nie są przetwarzane do czasu zakończenia wykonywania skryptu. Wynika to z faktu, że ustawienie jednej właściwości mogłoby wymagać przetworzenia pozostałych. Na przykład ustawienie właściwości width może wymagać ponownego obliczenia szerokości obiektów podrzędnych i obiektu nadrzędnego. A jeśli skrypt przelicza szerokość obiektu więcej niż jeden raz, każda z tych zależnych właściwości również mogłaby wymagać przeliczenia. Ta metoda umożliwia ręczne przesłonięcie opisanego zachowania.

Wywoływane po zmianie stanu widoczności składnika z widocznego na niewidoczny.

To zdarzenie ma następujące właściwości:

import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

Powiązane elementy interfejsu API

Wywoływane po przemieszczeniu składnika.

To zdarzenie ma następujące właściwości:

import fl.controls.Slider;
import fl.containers.UILoader;
import fl.events.ComponentEvent;
import fl.events.SliderEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
myUILoader.move(10, 20); 
myUILoader.addEventListener(ComponentEvent.MOVE, moveHandler);
addChild(myUILoader);

var mySlider:Slider = new Slider();
mySlider.liveDragging = true;
mySlider.minimum = myUILoader.x;
mySlider.maximum = myUILoader.x + 200;
mySlider.snapInterval = 1;
mySlider.tickInterval = 10;
mySlider.move(10, 10);
mySlider.addEventListener(SliderEvent.CHANGE, changeHandler);
addChild(mySlider);

function changeHandler(event:SliderEvent):void {
    myUILoader.x = event.value;
}

function moveHandler(event:ComponentEvent):void {
    trace("[move] x:" + event.currentTarget.x + ", y:" + event.currentTarget.y);
}

Wywoływane po zmianie rozmiaru składnika.

To zdarzenie ma następujące właściwości:

import fl.containers.UILoader;
import fl.events.ComponentEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.scaleContent = false;
myUILoader.addEventListener(ComponentEvent.RESIZE, resizeHandler);
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
addChild(myUILoader);

function resizeHandler(event:ComponentEvent):void {
    var myImg:UILoader = event.currentTarget as UILoader;
    var newX:uint = (stage.stageWidth - myImg.width) / 2;
    var newY:uint = (stage.stageHeight - myImg.height) / 2;
    myImg.move(newX, newY);
}

Wywoływane po zmianie stanu widoczności składnika z niewidocznego na widoczny.

To zdarzenie ma następujące właściwości:

import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

Powiązane elementy interfejsu API

Numer wersji składników.

import fl.controls.CheckBox;

var myCheckBox:CheckBox = new CheckBox();
trace(myCheckBox.version);