Sprite  - AS3

Określa tryb przycisku tej ikonki. Wartość true powoduje, że ikonka zachowuje się jak przycisk, co oznacza, iż wyzwala wyświetlanie wskaźnika w postaci dłoni w momencie przesunięcia wskaźnika nad ikonkę oraz możliwość odebrania zdarzenia click przy wciśnięciu klawiszy enter lub spacji kiedy ikonka jest aktywna. Możliwe jest ograniczenie wyświetlania kursora rączki poprzez ustawienie właściwości useHandCursor na wartość false, co spowoduje wyświetlanie strzałki.

Wprawdzie lepiej jest stosować klasę SimpleButton w celu utworzenia przycisków, możliwe jest wykorzystanie właściwości buttonMode w celu nadania ikonce kilku funkcjonalności przycisku. W celu włączenia ikonki do sekwencji aktywacji klawiszem Tab, należy ustawić właściwość tabEnabled (odziedziczoną z klasy InteractiveObject z wartością domyślną false) na wartość true. Dodatkowo należy rozważyć, czy obiekty podrzędne ikonki mają reagować na interakcje ze strony użytkownika. W przypadku większości przycisków interakcji z użytkownikiem nie należy włączać dla obiektów podrzędnych, gdyż może to zakłócać strumień zdarzeń. W celu wyłączenia interakcji z użytkownikiem dla obiektów podrzędnych należy ustawić właściwość mouseChildren (odziedziczoną z klasy DisplayObjectContainer) na wartość false.

W przypadku wykorzystania właściwości buttonMode z klasą MovieClip (która jest podklasą klasy Sprite), przycisk może mieć dodatkowe funkcje. Przy zawarciu klatek oznaczonych _up, _over i _down moduł Flash Player zapewnia automatyczne zmiany stanu (funkcjonalność podobna do tej zapewnionej przez poprzednie wersje skryptu ActionScript dla klipów filmowych wykorzystanych jako przyciski). Automatyczne zmiany stanów nie są dostępne dla ikonek, gdyż nie posiadają one osi czasu, a zatem nie mają też ramek, którym można nadać etykiety.

Powiązane elementy interfejsu API

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace ("Click!");
}

addChild(circle1);
addChild(circle2);

Określa obiekt wyświetlany, nad którym jest przeciągana ikonka, lub na którą upuszczono ikonkę.

Powiązane elementy interfejsu API

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Określa obiekt Graphics skojarzony z ikonką, której mogą dotyczyć polecenia rysowania kształtów wektorowych.

import flash.display.Sprite;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(40, 40, 40);
addChild(circle);

Określa ikonkę, która ma pełnić funkcję obszaru naciskania innej ikonki. Jeżeli właściwość hitArea nie istnieje lub jej wartością jest null bądź undefined, wówczas sama ikonka jest wykorzystywana jako obszar naciskania. Wartością właściwości hitArea może być odwołanie do obiektu Sprite.

Możliwa jest zmiana właściwości hitArea w dowolnym momencie; zmodyfikowana ikonka natychmiast wykorzystuje nowe zachowanie obszaru naciskania. Ikonka określona jako obszar naciskania nie musi być widoczna; jej kształt graficzny, wprawdzie niewidoczny, jest wciąż wykrywany jako obszar naciskania.

Uwaga: Konieczne jest ustawienie właściwości mouseEnabled na wartość false ikonki określonej jako obszar naciskania. W innym przypadku przycisk ikonki może nie funkcjonować, ponieważ ikonka określona jako obszar naciskania, a nie przycisk, otrzymuje zdarzenia interakcji z użytkownikiem.

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var square:Sprite = new Sprite();
square.graphics.beginFill(0xCCFF00);
square.graphics.drawRect(200, 0, 100, 100);

circle.hitArea = square;
square.mouseEnabled = false;

circle.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void{
    trace(event.target == circle); // true
    trace(event.target == square); // false
}

addChild(circle);
addChild(square);

Kontroluje dźwięki skojarzone z tą ikonką.

Uwaga: Ta właściwość nie ma wpływu na treść HTML w obiekcie HTMLControl (w środowisku Adobe AIR).

Powiązane elementy interfejsu API

import flash.display.Sprite;
import flash.display.Loader;
import flash.events.IOErrorEvent;
import flash.events.MouseEvent;
import flash.net.URLRequest;
import flash.text.TextField;
import flash.media.SoundTransform;

var container:Sprite = new Sprite();
addChild(container);

var ldr:Loader = new Loader;
var urlReq:URLRequest = new URLRequest("SoundPlayer.swf");
ldr.load(urlReq);

container.addChild(ldr);
ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, urlNotFound);
            
var tf:TextField = new TextField();
tf.htmlText = "<a href = 'event:Mute'>Mute / Unmute</a>";
addChild(tf);

var mySoundTransform:SoundTransform = new SoundTransform();
mySoundTransform.volume = 1;

tf.addEventListener(MouseEvent.CLICK, mute);

function mute(event:MouseEvent):void {    
    if (mySoundTransform.volume == 0) {
        mySoundTransform.volume = 1;
    } else {
        mySoundTransform.volume = 0;        
    }
    container.soundTransform = mySoundTransform;
}

function urlNotFound(event:IOErrorEvent):void {
    trace("The URL was not found."); 
}

Wartość typu Boolean wskazuje czy wskaźnik dłoni pojawia się w momencie, gdy wskaźnik jest przesuwany nad ikonką, której właściwość buttonMode jest ustawiona na wartość true. Wartość domyślna dla właściwości useHandCursor wynosi true. W przypadku ustawienia właściwości useHandCursor na wartość true, w momencie przesunięcia wskaźnika nad ikonkę przycisku pojawia się wskaźnik w kształcie dłoni. W przypadku ustawienia właściwości useHandCursor na wartość false wykorzystywany jest kursor strzałki.

Możliwa jest zmiana właściwości useHandCursor w dowolnym momencie; zmodyfikowana ikonka natychmiast wykorzystuje nowy wygląd kursora.

Uwaga: Jeśli we Flex lub Flash Builder ikonka zawiera ikonki podrzędne, wówczas właściwość mouseChildren można ustawić na wartość false. Na przykład, jeśli kursor w kształcie rączki ma być wyświetlany nad elementem sterującym Flex <mx:Label>, należy ustawić właściwości useHandCursor i buttonMode na wartość true oraz właściwość mouseChildren na wartość false.

Powiązane elementy interfejsu API

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.useHandCursor = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = true;
circle2.useHandCursor = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace ("Click!");
}

addChild(circle1);
addChild(circle2);

Tworzy nową instancję klasy Sprite. Po utworzeniu instancji Sprite należy wywołać metodę DisplayObjectContainer.addChild() lub DisplayObjectContainer.addChildAt() w celu dodania instancji do nadrzędnego obiektu DisplayObjectContainer.

Pozwala użytkownikowi przeciągnąć określoną ikonkę. Przeciągnięcie ikonki jest możliwe do momentu jawnego zatrzymania poprzez wywołanie do metody Sprite.stopDrag() lub do momentu, możliwe stanie się przeciągnięcie innej ikonki. W danym momencie możliwe jest przeciągnięcie tylko jednej ikonki.

Trójwymiarowe obiekty wyświetlane podążają za ruchem wskaźnika, a metoda Sprite.startDrag() przesuwa obiekt po trójwymiarowej płaszczyźnie zdefiniowanej przez obiekt wyświetlany. Jeśli jednak obiekt wyświetlany jest obiektem dwuwymiarowym oraz elementem podrzędnym obiektu trójwymiarowego, wówczas obiekt dwuwymiarowy jest przesuwany po płaszczyźnie trójwymiarowej zdefiniowanej przez nadrzędny obiekt trójwymiarowy.

Parametry

Powiązane elementy interfejsu API

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Umożliwia użytkownikowi przeciąganie określonej ikonki na urządzeniu z ekranem dotykowym. Ikonka jest możliwa do przeciągnięcia do momentu jawnego zatrzymania poprzez wywołanie do metody Sprite.stopTouchDrag() lub momentu, gdy inna ikonka staje się możliwa do przeciągnięcia. W danym momencie możliwe jest przeciągnięcie tylko jednej ikonki.

Trójwymiarowe obiekty wyświetlane podążają za ruchem wskaźnika, a metoda Sprite.startTouchDrag() przesuwa obiekt po trójwymiarowej płaszczyźnie zdefiniowanej przez obiekt wyświetlany. Jeśli obiekt ekranowy jest dwuwymiarowy i jest elementem potomnym obiektu trójwymiarowego, to obiekt dwuwymiarowy przemieszcza się w obrębie płaszczyzny trójwymiarowej zdefiniowanej przez macierzysty obiekt trójwymiarowy.

Parametry

Powiązane elementy interfejsu API

MySprite.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
MySprite.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);

function onTouchBegin(e:TouchEvent) {
     e.target.startTouchDrag(e.touchPointID, false, bg.getRect(this));
     trace("touch begin");
 
 }
function onTouchEnd(e:TouchEvent) {
     e.target.stopTouchDrag(e.touchPointID);
     trace("touch end");
}

Kończy metodę startDrag(). Ikonka, której przeciągnięcie stało się możliwe w wyniku wywołania metody startDrag(), utrzymuje ten stan do momentu dodania metody stopDrag() lub gdy stanie się możliwe przeciągnięcie innej ikonki. W danym momencie możliwe jest przeciągnięcie tylko jednej ikonki.

Powiązane elementy interfejsu API

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown) 

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Kończy działanie metody startTouchDrag(); używana z urządzeniami wyposażonymi w ekran dotykowy. Ikonka, której przeciągnięcie stało się możliwe w wyniku wywołania metody startTouchDrag(), utrzymuje ten stan do momentu dodania metody stopTouchDrag() lub gdy stanie się możliwe przeciągnięcie innej ikonki. W danym momencie możliwe jest przeciągnięcie tylko jednej ikonki.

Parametry

Powiązane elementy interfejsu API

MySprite.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
MySprite.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);

function onTouchBegin(e:TouchEvent) {
     e.target.startTouchDrag(e.touchPointID, false, bg.getRect(this));
     trace("touch begin");
 
 }
function onTouchEnd(e:TouchEvent) {
     e.target.stopTouchDrag(e.touchPointID);
     trace("touch end");
}

1. Należy zadeklarować właściwość size (100 x 100 pikseli) oraz kolor tła (pomarańczowy) dla późniejszego wykorzystania przy rysowaniu kwadratu.
2. Wówczas konstruktor tworzy nowy obiekt Sprite child oraz wykorzystuje go w celu dodania dwóch detektorów zdarzeń i powiązanych z nimi metod mouseDownHandler() oraz mouseUpHandler().
3. Obiekt Sprite child jest następnie przekazywany do metody draw(), która rysuje pomarańczowy kwadrat.
4. Obiekt podrzędny jest wówczas umieszczany na liście wyświetlania poprzez wywołanie do metody addChild().
5. Detektory zdarzeń funkcjonują w następujący sposób:
   • mouseDownHandler(): w momencie kliknięcia obiektu Sprite przez użytkownika metoda dodaje detektor zdarzeń mouseMove - metodę mouseMoveHandler() - która przetwarza ruchy myszy. Następnie wywoływana jest metoda startDrag(), która umożliwia przeciąganie obiektu Sprite.
   • mouseUpHandler(): w momencie zwolnienia przycisku myszy detektor zdarzeń mouseMove jest usuwany oraz wywoływana jest metoda stopDrag(), która unieruchamia pomarańczowy kwadrat.
   • mouseMoveHandler: ta metoda nakazuje odtwarzaczowi ciągłe przerysowywanie pomarańczowego kwadratu przez cały okres czasu, kiedy przyciśnięty jest lewy przycisk myszy.

Uwaga: Każda z metod detektora zdarzeń deklaruje lokalną zmienną sprite, która jest powiązana z właściwością target zdarzenia.

package {
    import flash.display.Sprite;
    import flash.events.*;

    public class SpriteExample extends Sprite {
        private var size:uint    = 100;
        private var bgColor:uint = 0xFFCC00;

        public function SpriteExample() {
            var child:Sprite = new Sprite();
            child.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            child.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
            draw(child);
            addChild(child);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            trace("mouseDownHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.startDrag();
        }

        private function mouseUpHandler(event:MouseEvent):void {
            trace("mouseUpHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.stopDrag();
        }

        private function mouseMoveHandler(event:MouseEvent):void {
            trace("mouseMoveHandler");
            event.updateAfterEvent();
        }

        private function draw(sprite:Sprite):void {
            sprite.graphics.beginFill(bgColor);
            sprite.graphics.drawRect(0, 0, size, size);
            sprite.graphics.endFill();
        }
    }
}