MovieClip  - AS3

Określa numer ramki, którą pokazuje głowica odtwarzania na osi czasu instancji obiektu MovieClip. Jeżeli klip filmowy posiada wiele scen, wówczas ta wartość jest numerem klatki w obecnej scenie.

mc1.gotoAndStop(mc1.currentFrame + 5);

Etykieta w klatce bieżącej na osi czasu instancji MovieClip. Jeśli bieżąca klatka nie ma etykiety, currentLabel ma wartość null.

Etykieta wyznaczona przez bieżące położenie głowicy odtwarzania na osi czasu instancji obiektu MovieClip. Jeżeli obecna klatka nie posiada etykiety, wówczas właściwość currentLabel jest ustawiona na nazwę poprzedniej klatki, która posiada etykietę. Jeżeli poprzednie klatki wraz z obecną nie posiadają etykiet, wówczas właściwość currentLabel zwraca wartość null.

trace(mc1.currentLabel);

Zwraca tablicę obiektów FrameLabel z bieżącej sceny. Jeżeli instancja MovieClip nie wykorzystuje scen, wówczas tablica zawiera wszystkie etykiety klatek całej instancji MovieClip.

Powiązane elementy interfejsu API

import flash.display.FrameLabel;
 
var labels:Array = mc1.currentLabels;

for (var i:uint = 0; i < labels.length; i++) {
    var label:FrameLabel = labels[i];
    trace("frame " + label.frame + ": " + label.name);
}

Scena wyznaczona przez bieżące położenie głowicy odtwarzania na osi czasu wystąpienia obiektu MovieClip.

Powiązane elementy interfejsu API

import flash.display.Scene;
 
var scene:Scene = mc1.currentScene;
trace(scene.name + ": " + scene.numFrames + " frames");

Wartość typu Boolean wskazująca, czy klip filmowy jest aktywny. Wartość domyślna dla właściwości enabled wynosi true. Jeżeli właściwość enabled jest ustawiona na wartość true, wówczas klatki Over, Down i Up klipu filmowego są wyłączone. Klip filmowy wciąż jednak otrzymuje zdarzenia (na przykład mouseDown, mouseUp, keyDown oraz keyUp).

Właściwość enabled zarządza tylko właściwościami klipu filmowego analogicznymi wobec właściwości przycisku. Możliwa jest zmiana właściwości enabled w dowolnym momencie; zmodyfikowany klip filmowy jest natychmiast włączany lub wyłączany. Jeżeli właściwość enabled jest ustawiona na wartość false, wówczas obiekt nie jest włączany do automatycznej kolejności uaktywniania dla klawisza Tab.

mc1.enabled = false;

Liczba klatek wczytanych z pliku SWF. Możliwe jest wykorzystanie właściwości framesLoaded w celu określenia, czy zawartość danej klatki oraz wszystkich wcześniejszych klatek została załadowana i jest dostępna lokalnie w przeglądarce. Można również wykorzystać tę właściwość w celu monitorowania pobierania dużych plików SWF. Na przykład może zajść potrzeba wyświetlenia wiadomości użytkownikom, iż plik SWF jest ładowany do momentu załadowania określonej klatki.

Jeżeli klip filmowy zawiera wiele scen, wówczas właściwość framesLoaded zwraca liczbę klatek załadowanych względem wszystkich scen w klipie filmowym.

Powiązane elementy interfejsu API

if (mc1.framesLoaded == mc1.totalFrames) {
    trace("OK.");
}

Wartość logiczna wskazująca, czy klip filmowy jest obecnie odtwarzany.

Tablica obiektów Scene, z których każdy jest opisany przez nazwę, liczbę klatek i etykiety klatek (w przypadku sceny w wystąpieniu obiektu MovieClip).

Powiązane elementy interfejsu API

import flash.display.Scene;
 
for (var i:uint = 0; i < mc1.scenes.length; i++) {
    var scene:Scene = mc1.scenes[i];
    trace("scene " + scene.name + ": " + scene.numFrames + " frames");
}

Całkowita liczba klatek w tym wystąpieniu obiektu MovieClip.

Jeżeli klip filmowy zawiera wiele klatek, wówczas właściwość totalFrames zwraca liczbę klatek we wszystkich scenach w klipie filmowym.

 trace(mc1.totalFrames);

Wskazuje, czy inne obiekty ekranowe, będące obiektami SimpleButton lub MovieClip, mogą reagować na zdarzenia zwolnienia przycisku myszy lub innego urządzenia wejściowego użytkownika. Właściwość trackAsMenu umożliwia tworzenie menu. Możliwe jest utworzenie właściwości trackAsMenu na dowolnym obiekcie SimpleButton lub MovieClip. Wartość domyślna właściwości trackAsMenu wynosi false.

Możliwa jest zmiana właściwości trackAsMenu w dowolnym momencie; zmodyfikowany klip filmowy natychmiast wykorzystuje nowe zachowanie.

 mc1.trackAsMenu = true;

Tworzy nową instancję klasy MovieClip. Po utworzeniu obiektu MovieClip należy wywołać metodę addChild() lub addChildAt() kontenera obiektów wyświetlanych, który znajduje się na stole montażowym.

Zaczyna odtwarzanie pliku SWF od określonej klatki. Dzieje się to po zakończeniu wykonywania wszystkich operacji w danej klatce. W celu wybrania sceny jak i klatki, należy określić wartość dla parametru scene.

Parametry

mc1.gotoAndPlay(mc1.currentFrame + 5);

mc1.gotoAndPlay("intro", "Scene 12");

Przesuwa głowicę odtwarzania do określonej klatki klipu filmowego i zatrzymuje ją. Dzieje się to po zakończeniu wykonywania wszystkich akcji w danej klatce. W celu wybrania sceny jak i klatki, należy określić wartość dla parametru scene.

Parametry

mc1.gotoAndStop(mc1.currentFrame + 5);

mc1.gotoAndStop("finale", "Scene 12");

Przesuwa głowicę odtwarzania do następnej klatki i zatrzymuje ją. Dzieje się to po zakończeniu wykonywania wszystkich akcji w danej klatce.

Powiązane elementy interfejsu API

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

Przesuwa głowicę do następnej sceny instancji obiektu MovieClip. Dzieje się to po zakończeniu wykonywania wszystkich akcji w danej klatce.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

Przesuwa głowicę odtwarzania na osi czasu klipu filmowego.

Powiązane elementy interfejsu API

import flash.text.TextField;
import flash.events.MouseEvent;

var continueText:TextField = new TextField();
continueText.text = "Play movie...";
addChild(continueText);

mc1.stop();
continueText.addEventListener(MouseEvent.CLICK, resumeMovie);

function resumeMovie(event:MouseEvent):void {
    mc1.play();
}

Przesuwa głowicę odtwarzania do poprzedniej klatki i zatrzymuje ją. Dzieje się to po zakończeniu wykonywania wszystkich akcji w danej klatce.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevFrame();
}

function goForward(event:MouseEvent):void {
    mc1.nextFrame();
}

Przesuwa głowicę do poprzedniej sceny instancji obiektu MovieClip. Dzieje się to po zakończeniu wykonywania wszystkich akcji w danej klatce.

import flash.events.MouseEvent;

mc1.stop();
prevBtn.addEventListener(MouseEvent.CLICK, goBack);
nextBtn.addEventListener(MouseEvent.CLICK, goForward);

function goBack(event:MouseEvent):void {
    mc1.prevScene();
}

function goForward(event:MouseEvent):void {
    mc1.nextScene();
}

Zatrzymuje głowicę odtwarzania w klipie filmowym.

1. Funkcja konstruktora definiuje pole tekstowe, które jest wykorzystywane w celu wyświetlania wartości właściwości obiektu MovieClipExample (który rozszerza obiekt MovieClip).
2. Wartość zwrotna metody getPropertiesString() jest wykorzystywana jako tekst dla pola tekstowego outputText. Metoda getPropertiesString() zwraca ciąg znaków, który jest zapełniany wartościami następujących właściwości klipu filmowego:currentFrame, currentLabel, currentScene, framesLoaded, totalFrames oraz trackAsMenu.
3. Dwie linie kodu w funkcji konstruktora dopasowują właściwości width i height pola tekstowego outputText.
4. Ostatnia linia funkcji konstruktora dodaje pole tekstowe outputText do listy wyświetlania.

package {
    import flash.display.MovieClip;
    import flash.text.TextField;

    public class MovieClipExample extends MovieClip {

        public function MovieClipExample() {
            var outputText:TextField = new TextField();
            outputText.text = getPropertiesString();
            outputText.width = stage.stageWidth;
            outputText.height = outputText.textHeight;
            addChild(outputText);
        }

        private function getPropertiesString():String {
            var str:String = ""
                + "currentFrame: " + currentFrame + "\n"
                + "currentLabel: " + currentLabel + "\n"
                + "currentScene: " + currentScene + "\n"
                + "framesLoaded: " + framesLoaded + "\n"
                + "totalFrames: " + totalFrames + "\n"
                + "trackAsMenu: " + trackAsMenu + "\n";
            return str;
        }
    }
}