Array  - AS3

Nieujemna liczba całkowita określająca liczbę elementów tablicy. Aktualizacja tej właściwości przebiega automatycznie podczas dodawania nowych elementów do tablicy. Przypisanie wartości elementowi tablicy (na przykład moja_tablica[indeks] = wartość), gdzie indeks jest liczbą, a indeks+1 jest większy od wartości właściwości length, spowoduje aktualizację właściwości length do wartości indeks+1.

Uwaga: Przypisanie wartości do właściwości length, której wartość jest mniejsza niż wartość aktualnej długości spowoduje, że tablica zostanie przycięta.

var names:Array = new Array("Bill");
names.push("Kyle");
trace(names.length); // 2

names.push("Jeff");
trace(names.length); // 3

names.shift();
names.shift();
trace(names.length); // 1

Pozwala utworzyć tablicę z podanymi elementami. Podane wartości mogą być dowolnego typu. Indeks (lub pozycja) pierwszego elementu tablicy ma zawsze wartość 0.

Uwaga: Dla tej klasy pokazano dwa wpisy dla metody konstruktora, ponieważ konstruktor dopuszcza różne typy argumentów. Zachowanie konstruktora może być różne w zależności od typu i liczby przekazanych argumentów określonych w każdym wpisie. Narzędzie ActionScript 3.0 nie obsługuje przeładowania metod czy konstruktora.

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;

    public class Array_Array_3 extends Sprite {

        public function Array_Array_3() {
            var myArr:Array = new Array("one", "two", "three");
            trace(myArr.length); // 3
            trace(myArr);          // one,two,three
        }
    }
}

Pozwala utworzyć tablicę o określonej liczbie elementów. Jeśli parametry nie zostaną określone, utworzona tablica nie będzie zawierała żadnych elementów. Określenie liczby elementów spowoduje, że liczba elementów w utworzonej tablicy będzie równa wartości numElements.

Uwaga: Dla tej klasy pokazano dwa wpisy dla metody konstruktora, ponieważ konstruktor dopuszcza różne typy argumentów. Zachowanie konstruktora może być różne w zależności o typu i liczby przekazanych argumentów określonych w każdym wpisie. Narzędzie ActionScript 3.0 nie obsługuje przeładowania metod czy konstruktora.

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;

    public class Array_Array extends Sprite {

        public function Array_Array() {
            var myArr:Array = new Array();
            trace(myArr.length); // 0
        }
    }
}

package {
    import flash.display.Sprite;

    public class Array_Array_2 extends Sprite {

        public function Array_Array_2() {
            var myArr:Array = new Array(5);
            trace(myArr.length); // 5
            myArr[0] = "one";
            myArr.push("six");
            trace(myArr);         // one,,,,,six
            trace(myArr.length); // 6
        }
    }
}

Łączy elementy określone za pomocą parametrów z elementami znajdującymi się w tablicy i tworzy nową tablicę. Jeśli parametry określają tablicę, jej elementy zostaną połączone. Jeśli nie zostaną przekazane żadne parametry, nowa tablica będzie stanowić duplikat (jednopoziomowy klon) tablicy oryginalnej.

Parametry

var numbers:Array = new Array(1, 2, 3);
var letters:Array = new Array("a", "b", "c");
var numbersAndLetters:Array = numbers.concat(letters);
var lettersAndNumbers:Array = letters.concat(numbers);

trace(numbers);       // 1,2,3
trace(letters);       // a,b,c
trace(numbersAndLetters); // 1,2,3,a,b,c
trace(lettersAndNumbers); // a,b,c,1,2,3

Wykonuje test funkcji dla poszczególnych elementów tablicy do momentu napotkania elementu, dla którego określona funkcja zwraca wartość false. Ta metoda służy do określenia, czy wszystkie elementy tablicy spełniają dane kryterium, jak np. posiadanie wartości mniejszych niż określona liczba.

Wartość drugiego parametru thisObject dla tej metody musi być równa wartości null, jeśli pierwszy parametr callback stanowi zamknięcie metody. Na przykład, użytkownik w klipie filmowym tworzy funkcję o nazwie me:

     function myFunction(obj:Object):void {
        //your code here
     }
     

Załóżmy, że następnie uruchamia metodę every() dla tablicy o nazwie myArray:

     myArray.every(myFunction, me);
     

Ponieważ funkcja myFunction należy do klasy Timeline, której nie można przesłonić za pomocą funkcji me, środowisko wykonawcze Flash Player wygeneruje wyjątek. Aby uniknąć tego błędu czasu wykonywania, należy funkcji przypisać zmienną w następujący sposób:

     var myFunction:Function = function(obj:Object):void {
         //your code here
     };
     myArray.every(myFunction, me);
     

Parametry

function callback(item:*, index:int, array:Array):Boolean;

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    public class Array_every extends Sprite {
        public function Array_every() {
            var arr1:Array = new Array(1, 2, 4);
            var res1:Boolean = arr1.every(isNumeric);
            trace("isNumeric:", res1); // true
 
            var arr2:Array = new Array(1, 2, "ham");
            var res2:Boolean = arr2.every(isNumeric);
            trace("isNumeric:", res2); // false
        }
        private function isNumeric(element:*, index:int, arr:Array):Boolean {
            return (element is Number);
        }
    }
}

Uruchamia funkcję testową dla poszczególnych elementów tablicy i tworzy nową tablicę dla wszystkich elementów, dla których określona funkcja zwróciła wartość true. Jeśli wartość zwrócona dla danego elementu to false, ten element nie zostanie uwzględniony w nowej tablicy.

Wartość drugiego parametru thisObject dla tej metody musi być równa wartości null, jeśli pierwszy parametr callback stanowi zamknięcie metody. Na przykład, użytkownik w klipie filmowym tworzy funkcję o nazwie me:

     function myFunction(obj:Object):void {
        //your code here
     }
     

Załóżmy, że następnie dla tablicy o nazwie myArray uruchamia metodę filter():

 
     myArray.filter(myFunction, me);
     

Ponieważ funkcja myFunction należy do klasy Timeline, której nie można przesłonić za pomocą funkcji me, środowisko wykonawcze Flash Player wygeneruje wyjątek. Aby uniknąć tego błędu czasu wykonywania, należy funkcji przypisać zmienną w następujący sposób:

     var myFunction:Function = function(obj:Object):void {
         //your code here
         };
     myArray.filter(myFunction, me);
     

Parametry

    function callback(item:*, index:int, array:Array):Boolean;

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    public class Array_filter extends Sprite {
        public function Array_filter() {
            var employees:Array = new Array();
            employees.push({name:"Employee 1", manager:false});
            employees.push({name:"Employee 2", manager:true});
            employees.push({name:"Employee 3", manager:false});
            trace("Employees:");
            employees.forEach(traceEmployee);
            
            var managers:Array = employees.filter(isManager);
            trace("Managers:");
            managers.forEach(traceEmployee);
        }
        private function isManager(element:*, index:int, arr:Array):Boolean {
            return (element.manager == true);
        }
        private function traceEmployee(element:*, index:int, arr:Array):void {
            trace("\t" + element.name + ((element.manager) ? " (manager)" : ""));
        }
    }
}

Do każdego z elementów tablicy jest stosowana funkcja.

Wartość drugiego parametru thisObject dla tej metody musi być równa wartości null, jeśli pierwszy parametr callback stanowi zamknięcie metody. Na przykład, użytkownik w klipie filmowym tworzy funkcję o nazwie me:

     function myFunction(obj:Object):void {
        //your code here
     }
     

Załóżmy, że następnie wywołuje metodę forEach() dla tablicy o nazwie myArray:

     myArray.forEach(myFunction, me);
     

Ponieważ funkcja myFunction należy do klasy Timeline, której nie można przesłonić za pomocą funkcji me, środowisko wykonawcze Flash Player wygeneruje wyjątek. Aby uniknąć tego błędu czasu wykonywania, należy funkcji przypisać zmienną w następujący sposób:

     var myFunction:Function = function(obj:Object):void {
         //your code here
         };
     myArray.forEach(myFunction, me);
     

Parametry

    function callback(item:*, index:int, array:Array):void;

package {
    import flash.display.Sprite;
    public class Array_forEach extends Sprite {
        public function Array_forEach() {
            var employees:Array = new Array();
            employees.push({name:"Employee 1", manager:false});
            employees.push({name:"Employee 2", manager:true});
            employees.push({name:"Employee 3", manager:false});
            trace(employees);
            employees.forEach(traceEmployee);
        }
        private function traceEmployee(element:*, index:int, arr:Array):void {
            trace(element.name + " (" + element.manager + ")");
        }
    }
}

package {
    import flash.display.Sprite;
    public class Array_forEach_2 extends Sprite {
        public function Array_forEach_2() {
            var employeeXML:XML = <employees>
                    <employee name="Steven" manager="false" />
                    <employee name="Bruce" manager="true" />
                    <employee name="Rob" manager="false" />
                </employees>;
            var employeesList:XMLList = employeeXML.employee;
            var employeesArray:Array = new Array();
            for each (var tempXML:XML in employeesList) {
                employeesArray.push(tempXML);
            }
            employeesArray.sortOn("@name");
            employeesArray.forEach(traceEmployee);
        }
        private function traceEmployee(element:*, index:Number, arr:Array):void {
            trace(element.@name + ((element.@manager == "true") ? " (manager)" : ""));
        }
    }
}

Wyszukuje element tablicy za pomocą operatora ścisłej równości (===) i zwraca indeks znalezionego elementu.

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    public class Array_indexOf extends Sprite {
        public function Array_indexOf() {
            var arr:Array = new Array(123,45,6789);
            arr.push("123-45-6789");
            arr.push("987-65-4321");
            
            var index:int = arr.indexOf("123");
            trace(index); // -1
            
            var index2:int = arr.indexOf(123);
            trace(index2); // 0
        }
    }
}

Wstawia pojedynczy element do tablicy. Ta metoda modyfikuje tablicę i nie tworzy jej kopii.

Parametry

Konwertuje elementy tablicy na ciągi znaków, wstawia między elementy określony separator, łączy je i zwraca ciąg wynikowy. Tablice zagnieżdżone są zawsze oddzielone przecinkiem (,), a nie separatorem przekazanym za pośrednictwem metody join().

Parametry

Powiązane elementy interfejsu API

var myArr:Array = new Array("one", "two", "three");
var myStr:String = myArr.join(" and ");
trace(myArr); // one,two,three
trace(myStr); // one and two and three

var phoneString:String = "(888) 867-5309";

var specialChars:Array = new Array("(", ")", "-", " ");
var myStr:String = phoneString;

var ln:uint = specialChars.length;
for(var i:uint; i < ln; i++) {
    myStr = myStr.split(specialChars[i]).join("");
}

var phoneNumber:Number = new Number(myStr);

trace(phoneString); // (888) 867-5309
trace(phoneNumber); // 8888675309

Wyszukuje element tablicy wstecz, rozpoczynając od ostatniego elementu i za pomocą operatora ścisłej równości (===) zwraca indeks zgodnego elementu.

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    public class Array_lastIndexOf extends Sprite {
        public function Array_lastIndexOf() {
            var arr:Array = new Array(123,45,6789,123,984,323,123,32);
            
            var index:int = arr.indexOf(123);
            trace(index); // 0
            
            var index2:int = arr.lastIndexOf(123);
            trace(index2); // 6
        }
    }
}

Określona funkcja jest stosowana do wszystkich elementów tablicy. Dla każdego elementu jest tworzona nowa tablica elementów będących wartościami użytej funkcji.

Wartość drugiego parametru thisObject dla tej metody musi być równa wartości null, jeśli pierwszy parametr callback stanowi zamknięcie metody. Na przykład, użytkownik w klipie filmowym tworzy funkcję o nazwie me:

     function myFunction(obj:Object):void {
        //your code here
     }
     

Załóżmy, że następnie użyje metody map() dla tablicy o nazwie myArray:

     myArray.map(myFunction, me);
     

Ponieważ funkcja myFunction należy do klasy Timeline, której nie można przesłonić za pomocą funkcji me, środowisko wykonawcze Flash Player wygeneruje wyjątek. Aby uniknąć tego błędu czasu wykonywania, należy funkcji przypisać zmienną w następujący sposób:

     var myFunction:Function = function(obj:Object):void {
         //your code here
         };
     myArray.map(myFunction, me);
     

Parametry

    function callback(item:*, index:int, array:Array):String;

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    public class Array_map extends Sprite {
        public function Array_map() {
            var arr:Array = new Array("one", "two", "Three");
            trace(arr); // one,two,Three

            var upperArr:Array = arr.map(toUpper);
            trace(upperArr); // ONE,TWO,THREE
        }
        private function toUpper(element:*, index:int, arr:Array):String {
            return String(element).toUpperCase();
        }
    }
}

Usuwa ostatni element tablicy i zwraca jego wartość.

Powiązane elementy interfejsu API

var letters:Array = new Array("a", "b", "c");
trace(letters); // a,b,c
var letter:String = letters.pop();
trace(letters); // a,b
trace(letter);     // c

Dodaje na końcu tablicy co najmniej jeden nowy element i zwraca nową długość tablicy.

Parametry

Powiązane elementy interfejsu API

var letters:Array = new Array();

letters.push("a");
letters.push("b");
letters.push("c");

trace(letters.toString()); // a,b,c

var letters:Array = new Array("a");
var count:uint = letters.push("b", "c");

trace(letters); // a,b,c
trace(count);   // 3

Usuwa pojedynczy element z tablicy. Ta metoda modyfikuje tablicę i nie tworzy jej kopii.

Parametry

Tablica jest odwracana.

var letters:Array = new Array("a", "b", "c");
trace(letters); // a,b,c
letters.reverse();
trace(letters); // c,b,a

Usuwa pierwszy element tablicy i zwraca jego wartość. Pozostałe elementy tablicy zostają przeniesione z oryginalnego położenia „i” do położenia „i-1”.

Powiązane elementy interfejsu API

var letters:Array = new Array("a", "b", "c");
var firstLetter:String = letters.shift();
trace(letters);     // b,c
trace(firstLetter); // a

Zwraca nową tablicę składającą się z zakresu elementów tablicy oryginalnej bez jej modyfikacji. Zwrócona tablica zawiera element startIndex oraz wszystkie poprzedzające go elementy, z wyłączeniem elementu endIndex.

Jeśli nie zostaną przekazane żadne parametry, nowa tablica będzie stanowić duplikat (jednopoziomowy klon) tablicy oryginalnej.

Parametry

var letters:Array = new Array("a", "b", "c", "d", "e", "f");
var someLetters:Array = letters.slice(1,3);

trace(letters);     // a,b,c,d,e,f
trace(someLetters); // b,c

var letters:Array = new Array("a", "b", "c", "d", "e", "f");
var someLetters:Array = letters.slice(2);

trace(letters);     // a,b,c,d,e,f
trace(someLetters); // c,d,e,f

var letters:Array = new Array("a", "b", "c", "d", "e", "f");
var someLetters:Array = letters.slice(-2);

trace(letters);     // a,b,c,d,e,f
trace(someLetters); // e,f

Uruchamia funkcję testową dla poszczególnych elementów tablicy do momentu napotkania elementu, dla którego zwracana jest wartość true. Ta metoda służy do określenia, czy dowolny element tablicy spełnia dane kryterium, jak np. posiadanie wartości mniejszej niż określona liczba.

Wartość drugiego parametru thisObject dla tej metody musi być równa wartości null, jeśli pierwszy parametr callback stanowi zamknięcie metody. Na przykład, użytkownik w klipie filmowym tworzy funkcję o nazwie me:

     function myFunction(obj:Object):void {
        //your code here
     }
     

Załóżmy, że wywoła następnie metodę some() dla tablicy o nazwie myArray:

     myArray.some(myFunction, me);
     

Ponieważ funkcja myFunction należy do klasy Timeline, której nie można przesłonić za pomocą funkcji me, środowisko wykonawcze Flash Player wygeneruje wyjątek. Aby uniknąć tego błędu czasu wykonywania, należy funkcji przypisać zmienną w następujący sposób:

     var myFunction:Function = function(obj:Object):void {
         //your code here
         };
     myArray.some(myFunction, me);
     

Parametry

    function callback(item:*, index:int, array:Array):Boolean;

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    public class Array_some extends Sprite {
        public function Array_some() {
            var arr:Array = new Array();
            arr[0] = "one";
            arr[1] = "two";
            arr[3] = "four";
            var isUndef:Boolean = arr.some(isUndefined);
            if (isUndef) {
                trace("array contains undefined values: " + arr);
            } else {
                trace("array contains no undefined values.");
            }
        }
        private function isUndefined(element:*, index:int, arr:Array):Boolean {
            return (element == undefined);
        }
    }
}

Sortuje elementy tablicy. Ta metoda sortuje według wartości Unicode. (Wartości ASCII stanowią podzbiór wartości Unicode.)

Domyślnie Array.Metoda sort() działa w następujący sposób:

• Wielkość liter jest w sortowaniu uwzględniania (Z poprzedza a).
• Sortowanie jest rosnące (a poprzedza b).
• Zmodyfikowana tablica odzwierciedla porządek sortowania; elementy złożone o identycznych polach sortowania zostały dowolnie umieszczone w sortowanej tablicy jedno po drugim.
• Wszystkie elementy bez względu na typ danych są sortowane jak ciągi znaków, tak więc 100 poprzedza 99, ponieważ „1” stanowi wartość ciągu niższą od „9”.

Sortowanie tablicy za pomocą ustawień innych niż domyślne można przeprowadzić za pomocą jednej z opcji sortowania opisanej we fragmencie dotyczącym argumentu sortOptions parametru ...args lub za pomocą własnej niestandardowej funkcji sortowania. Aby utworzyć funkcję niestandardową, należy wywołać metodę sort() i użyć nazwy funkcji niestandardowej jako pierwszego argumentu (funkcja compareFunction)

Parametry

Powiązane elementy interfejsu API

var vegetables:Array = new Array("spinach",
                 "green pepper",
                 "cilantro",
                 "onion",
                 "avocado");

trace(vegetables); // spinach,green pepper,cilantro,onion,avocado
vegetables.sort();
trace(vegetables); // avocado,cilantro,green pepper,onion,spinach

var vegetables:Array = new Array("spinach",
                 "green pepper",
                 "Cilantro",
                 "Onion",
                 "Avocado");

vegetables.sort();
trace(vegetables); // Avocado,Cilantro,Onion,green pepper,spinach
vegetables.sort(Array.CASEINSENSITIVE);
trace(vegetables); // Avocado,Cilantro,green pepper,Onion,spinach

var vegetables:Array = new Array();
vegetables.push(new Vegetable("lettuce", 1.49));
vegetables.push(new Vegetable("spinach", 1.89));
vegetables.push(new Vegetable("asparagus", 3.99));
vegetables.push(new Vegetable("celery", 1.29));
vegetables.push(new Vegetable("squash", 1.44));

trace(vegetables);
// lettuce:1.49, spinach:1.89, asparagus:3.99, celery:1.29, squash:1.44

vegetables.sort();

trace(vegetables);
// asparagus:3.99, celery:1.29, lettuce:1.49, spinach:1.89, squash:1.44

//The following code defines the Vegetable class
class Vegetable {
    private var name:String;
    private var price:Number;

    public function Vegetable(name:String, price:Number) {
        this.name = name;
        this.price = price;
    }

    public function toString():String {
        return " " + name + ":" + price;
    }
}

var vegetables:Array = new Array();
vegetables.push(new Vegetable("lettuce", 1.49));
vegetables.push(new Vegetable("spinach", 1.89));
vegetables.push(new Vegetable("asparagus", 3.99));
vegetables.push(new Vegetable("celery", 1.29));
vegetables.push(new Vegetable("squash", 1.44));

trace(vegetables);
// lettuce:1.49, spinach:1.89, asparagus:3.99, celery:1.29, squash:1.44

vegetables.sort(sortOnPrice);

trace(vegetables);
// celery:1.29, squash:1.44, lettuce:1.49, spinach:1.89, asparagus:3.99

function sortOnPrice(a:Vegetable, b:Vegetable):Number {
    var aPrice:Number = a.getPrice();
    var bPrice:Number = b.getPrice();

    if(aPrice > bPrice) {
        return 1;
    } else if(aPrice < bPrice) {
        return -1;
    } else  {
        //aPrice == bPrice
        return 0;
    }
}

// The following code defines the Vegetable class and should be in a separate package.
class Vegetable {
    private var name:String;
    private var price:Number;

    public function Vegetable(name:String, price:Number) {
        this.name = name;
        this.price = price;
    }

    public function getPrice():Number {
        return price;
    }

    public function toString():String {
        return " " + name + ":" + price;
    }
}

var numbers:Array = new Array(3,5,100,34,10);

trace(numbers); // 3,5,100,34,10
numbers.sort();
trace(numbers); // 10,100,3,34,5
numbers.sort(Array.NUMERIC);
trace(numbers); // 3,5,10,34,100

Sortuje elementy tablicy według określonych pól. Tablica powinna mieć następujące cechy:

• Tablica jest tablicą indeksowaną, a nie skojarzoną.
• Każdy element tablicy posiada obiekt o przynajmniej jednej właściwości.
• Wszystkie obiekty mają przynajmniej jedną wspólną właściwość, których wartości można używać do sortowania tablicy. Taka właściwość nosi nazwę field.

W przypadku przekazania wielu parametrów fieldName pierwsze pole stanowi pierwszorzędne pole sortowania, drugie — drugorzędne pole sortowania itd. Program Flash sortuje według wartości Unicode. (Wartości ASCII stanowią podzbiór wartości Unicode.) Jeśli którykolwiek z dwóch porównywanych elementów nie zawiera pola określonego parametrem fieldName, przyjmuje się, że to pole zostało ustawione na wartość undefined, a elementy sortowanej tablicy są dowolnie umieszczane jeden po drugim.

Domyślnie Array.Metoda sortOn() działa w następujący sposób:

• Wielkość liter jest w sortowaniu uwzględniania (Z poprzedza a).
• Sortowanie jest rosnące (a poprzedza b).
• Zmodyfikowana tablica odzwierciedla porządek sortowania; elementy złożone o identycznych polach sortowania zostały dowolnie umieszczone w sortowanej tablicy jedno po drugim.
• Pola numeryczne są sortowane jak ciągi znaków, tak więc 100 poprzedza 99, ponieważ „1” stanowi wartość ciągu niższą od „9”.

W programie Flash Player 7 dodano parametr options, który służy do nadpisywania domyślnego sposobu sortowania. Aby przeprowadzić sortowanie prostej tablicy (na przykład, tablicy zawierającej tylko jedno pole), lub określić porządek sortowania nieobsługiwany przez parametr options, należy użyć metody Array.sort().

Aby przekazać wiele flag, należy rozdzielić je operatorem bitowym OR (|):

     my_array.sortOn(someFieldName, Array.DESCENDING | Array.NUMERIC);
     

W programie Flash Player 8 dodano możliwość określania różnych opcji sortowania dla każdego pola w przypadku sortownia według więcej niż jednego pola. W programie Flash Player 8 i jego późniejszych wersjach, parametr options akceptuje tabelę wysortowanych opcji w taki sposób, że każda opcja sortowania odpowiada polu sortowania określonego przez parametr fieldName. Poniższy przykład ilustruje sortowanie malejące według pierwszorzędnego pola sortowania a; sortowanie numeryczne według drugorzędnego pola sortowania, b oraz sortowanie według trzeciorzędnego pola sortowania c uwzględniającego wielkość liter:

     Array.sortOn (["a", "b", "c"], [Array.DESCENDING, Array.NUMERIC, Array.CASEINSENSITIVE]);
     

Uwaga: Tablice fieldName oraz options muszą posiadać tę sama liczbę elementów; w przeciwnym razie tablica options zostanie pominięta. Opcji Array.UNIQUESORT i Array.RETURNINDEXEDARRAY można użyć jedynie jako pierwszych elementów tablicy, w przeciwnym razie zostaną one pominięte.

Parametry

Powiązane elementy interfejsu API

var vegetables:Array = new Array();
vegetables.push(new Vegetable("lettuce", 1.49));
vegetables.push(new Vegetable("spinach", 1.89));
vegetables.push(new Vegetable("asparagus", 3.99));
vegetables.push(new Vegetable("celery", 1.29));
vegetables.push(new Vegetable("squash", 1.44));

trace(vegetables);
// lettuce:1.49, spinach:1.89, asparagus:3.99, celery:1.29, squash:1.44

vegetables.sortOn("name");
trace(vegetables);
// asparagus:3.99, celery:1.29, lettuce:1.49, spinach:1.89, squash:1.44

vegetables.sortOn("price", Array.NUMERIC | Array.DESCENDING);
trace(vegetables);
// asparagus:3.99, spinach:1.89, lettuce:1.49, squash:1.44, celery:1.29

class Vegetable {
    public var name:String;
    public var price:Number;

    public function Vegetable(name:String, price:Number) {
        this.name = name;
        this.price = price;
    }

    public function toString():String {
        return " " + name + ":" + price;
    }
}

var records:Array = new Array();
records.push({name:"john", city:"omaha", zip:68144});
records.push({name:"john", city:"kansas city", zip:72345});
records.push({name:"bob", city:"omaha", zip:94010});

for(var i:uint = 0; i < records.length; i++) {
    trace(records[i].name + ", " + records[i].city);
}
// Results:
// john, omaha
// john, kansas city
// bob, omaha

trace("records.sortOn('name', 'city');");
records.sortOn(["name", "city"]);
for(var i:uint = 0; i < records.length; i++) {
    trace(records[i].name + ", " + records[i].city);
}
// Results:
// bob, omaha
// john, kansas city
// john, omaha

trace("records.sortOn('city', 'name');");
records.sortOn(["city", "name"]);
for(var i:uint = 0; i < records.length; i++) {
    trace(records[i].name + ", " + records[i].city);
}
// Results:
// john, kansas city
// bob, omaha
// john, omaha

class User {
    public var name:String;
    public var age:Number;
    public function User(name:String, age:uint) {
        this.name = name;
        this.age = age;
    }

    public function toString():String {
        return this.name + ":" + this.age;
    }
}

var users:Array = new Array();
users.push(new User("Bob", 3));
users.push(new User("barb", 35));
users.push(new User("abcd", 3));
users.push(new User("catchy", 4));

trace(users); // Bob:3,barb:35,abcd:3,catchy:4

users.sortOn("name");
trace(users); // Bob:3,abcd:3,barb:35,catchy:4

users.sortOn("name", Array.CASEINSENSITIVE);
trace(users); // abcd:3,barb:35,Bob:3,catchy:4

users.sortOn("name", Array.CASEINSENSITIVE | Array.DESCENDING);
trace(users); // catchy:4,Bob:3,barb:35,abcd:3

users.sortOn("age");
trace(users); // abcd:3,Bob:3,barb:35,catchy:4

users.sortOn("age", Array.NUMERIC);
trace(users); // Bob:3,abcd:3,catchy:4,barb:35

users.sortOn("age", Array.DESCENDING | Array.NUMERIC);
trace(users); // barb:35,catchy:4,Bob:3,abcd:3

var indices:Array = users.sortOn("age", Array.NUMERIC | Array.RETURNINDEXEDARRAY);
var index:uint;
for(var i:uint = 0; i < indices.length; i++) {
    index = indices[i];
    trace(users[index].name, ": " + users[index].age);
}

// Results:
// Bob : 3
// abcd : 3
// catchy : 4
// barb : 35

Dodaje i usuwa elementy tablicy. Ta metoda modyfikuje tablicę i nie tworzy jej kopii.

Uwaga: Aby nadpisać te metodę w podklasie Array, należy użyć parametrów w postaci ...args, jak pokazano w poniższym przykładzie:

     public override function splice(...args) {
       // your statements here
     }
     

Parametry

var vegetables:Array = new Array("spinach",
                 "green pepper",
                 "cilantro",
                 "onion",
                 "avocado");

var spliced:Array = vegetables.splice(2, 2);
trace(vegetables); // spinach,green pepper,avocado
trace(spliced);    // cilantro,onion

vegetables.splice(1, 0, spliced);
trace(vegetables); // spinach,cilantro,onion,green pepper,avocado

 
var vegetables:Array = new Array("spinach",
                 "green pepper",
                 "cilantro",
                 "onion",
                 "avocado");
 
 var spliced:Array = vegetables.splice(2, 2);
 trace(vegetables); // spinach,green pepper,avocado
 trace(spliced);    // cilantro,onion
 
 vegetables.splice(1, 0, "cilantro", "onion");
 trace(vegetables); // spinach,cilantro,onion,green pepper,avocado

Zwraca ciąg znaków reprezentujący elementy określonej tablicy. Każdy element tablicy, począwszy od elementu o indeksie 0 aż po najwyższy indeks jest konwertowany do łączonego ciągu i oddzielany przecinkami. W narzędziu ActionScript 3.0 ta metoda zwraca te same wartości co metoda Array.toString().

Powiązane elementy interfejsu API

Zwraca ciąg znaków reprezentujący elementy określonej tablicy. Każdy element tablicy, począwszy od elementu o indeksie 0 aż po najwyższy indeks jest konwertowany do łączonego ciągu i oddzielany przecinkami. Aby określić separator niestandardowy, należy użyć metody Array.join().

Powiązane elementy interfejsu API

var vegetables:Array = new Array();
vegetables.push(1);
vegetables.push(2);
vegetables.push(3);
vegetables.push(4);
vegetables.push(5);
var vegnums:String = vegetables.toString();
trace(vegnums+",6");
// 1,2,3,4,5,6

Dodaje na początku tablicy co najmniej jeden element i zwraca nową długość tablicy. Pozostałe elementy tablicy zostają przesunięte z oryginalnego położenia „i” do położenia „i+1”.

Parametry

Powiązane elementy interfejsu API

var names:Array = new Array();
names.push("Bill");
names.push("Jeff");

trace(names); // Bill,Jeff

names.unshift("Alfred");
names.unshift("Kyle");

trace(names); // Kyle,Alfred,Bill,Jeff

W ramach metod sortowania klasy Array określa sortowanie z uwzględnieniem wielkości liter. Tej stałej używa się dla parametru options w przypadku metody sort() lub sortOn().

Wartością tej stałej jest liczba 1.

Powiązane elementy interfejsu API

W ramach metod sortowania klasy Array określa sortowanie w porządku malejącym. Tej stałej używa się dla parametru options w przypadku metody sort() lub sortOn().

Wartością tej stałej jest liczba 2.

Powiązane elementy interfejsu API

W ramach metod sortowania klasy Array określa sortowanie numeryczne (a nie alfabetyczne). Zastosowane tej stałej do parametru options spowoduje, że sortowanie liczb za pomocą metod sort() i sortOn() będzie się odbywać według ich wartości liczbowych, a nie ciągu znaków numerycznych. Jeśli stała NUMERIC nie zostanie ujęta, podczas sortowania każdy element tablicy będzie traktowany jako ciąg znaków, a rezultat takiego sortowania zostanie przedstawiony w porządku Unicode.

Na przykład, jeśli dla danej tablicy wartości [2005, 7, 35] stała NUMERIC nie zostanie włączona do parametru options, porządek elementów w wysortowanej tablicy będzie następujący: [2005, 35, 7]. Jeśli jednak stała NUMERIC zostanie do niego włączona, tablica wyświetli elementy w następującym porządku [7, 35, 2005].

Ta stała ma zastosowanie tylko do liczb w tablicy; nie można jej stosować do ciągów, które zawierają dane liczbowe, jak np. [„23”, „5”].

Wartością tej stałej jest liczba 16.

Powiązane elementy interfejsu API

Określa, że sortowanie ma zwracać tablicę indeksów. Tej stałej używa się dla parametru options w przypadku zastosowania metod sort() lub sortOn(). Stała umożliwia uzyskanie dostępu do wielu widoków elementów tablicy bez konieczności modyfikacji oryginalnej tablicy.

Wartością tej stałej jest liczba 8.

Powiązane elementy interfejsu API

W ramach metod sortowania klasy Array określa niepowtarzalne kryterium sortowania. Tej stałej używa się dla parametru options w przypadku metody sort() lub sortOn(). Unikalna opcja sortowania przerywa sortowanie, jeśli dowolne dwa sortowane elementy lub pola posiadają identyczne wartości.

Wartością tej stałej jest liczba 4.

Powiązane elementy interfejsu API