LoaderInfo  - AS3

Wersja ActionScript wczytanego pliku SWF. Wersja językowa jest określona przez uporządkowania klasy ActionScriptVersion, jak na przykład ActionScriptVersion.ACTIONSCRIPT2 oraz ActionScriptVersion.ACTIONSCRIPT3.

Uwaga: Ta właściwość zawsze ma wartość ActionScriptVersion.ACTIONSCRIPT2 lub ActionScriptVersion.ACTIONSCRIPT3. Skrypty ActionScript 1.0 i 2.0 są zgłaszane jako wartość ActionScriptVersion.ACTIONSCRIPT2 (wersja 2.0). Ta właściwość odróżnia tylko skrypty ActionScript 1.0 i 2.0 od skryptu ActionScript 3.0.

Powiązane elementy interfejsu API

Gdy ładowany jest zewnętrzny plik SWF, definicje języka ActionScript 3.0 zawarte w załadowanej klasie są przechowywane we właściwości applicationDomain.

Całość kodu zawartego w pliku SWF jest zdefiniowana celu istnienia w domenie aplikacji. Obecna domena aplikacji to ta, w której uruchomiona jest główna aplikacja. Domena systemowa zwiera domeny wszystkich aplikacji, w tym domenę bieżącą, i wszystkie klasy używane przez program Flash Player lub środowisko Adobe AIR.

Wszystkie domeny aplikacji, z wyjątkiem domeny systemu, posiadają skojarzoną domenę nadrzędną. Domeną nadrzędną domeny applicationDomain głównej aplikacji jest domena systemu. Załadowane klasy są definiowane tylko wtedy, gdy nie zostały one już zdefiniowane przez obiekt nadrzędny. Nie jest możliwe nadpisanie definicji załadowanej klasy przy pomocy nowszej definicji.

W celu zapoznania się z przykładami wykorzystania domen aplikacji należy zapoznać się z informacjami zawartymi w rozdziale „Środowisko systemu klienckiego" w publikacji ActionScript 3.0 — Podręcznik dla programistów.

Powiązane elementy interfejsu API

Bajty skojarzone z obiektem LoaderInfo.

Liczba wczytanych bajtów. Gdy ta liczba równa jest wartości właściwości bytesTotal, wówczas wszystkie bajty są ładowane.

Liczba skompresowanych bajtów w całym pliku multimedialnym.

Przed pierwszym wywołaniem zdarzenia progress przez odpowiedni obiekt Loader tego obiektu LoaderInfo, wartość właściwości bytesTotal wynosi 0. Po pierwszym zdarzeniu progress obiektu Loader, właściwość bytesTotal odzwierciedla aktualną liczbę bajtów do pobrania.

Uwaga (tylko system iOS): W przypadku uruchomienia aplikacji w systemie iOS zwracana wartość jest inna niż wartość uzyskiwana na pozostałych platformach.

Powiązane elementy interfejsu API

Wyraża relację zaufania między zawartością (obiekt potomny) i obiektem Loader (obiekt macierzysty). Wartość true, jeżeli obiekt nadrzędny ma dostęp do obiektu podrzędnego; wartość false w innym przypadku. Właściwość ta jest ustawiona na wartość true, jeżeli obiekt podrzędny wywołał metodę allowDomain() w celu nadania pozwolenia domenie nadrzędnej, lub strategia URL jest ładowana na domenie podrzędnej, która nadaje pozwolenia domenie nadrzędnej. Jeżeli obiekt podrzędny i nadrzędny znajdują się w tej samej domenie ta właściwość ma wartość true.

Więcej informacji na temat zabezpieczeń zawiera odpowiedni temat w witrynie Flash Player Developer Center: Bezpieczeństwo.

Obiekt może być określony przez kod ładowanej treści w celu udostępnienia właściwości i metod dla kodu w obszarze izolowanym obiektu Loader. Ten most między obszarami izolowanymi umożliwia treści z domeny nieaplikacyjnej uzyskanie kontrolowanego dostępu do skryptów w obszarze izolowanym aplikacji i odwrotnie. Most między obszarami izolowanymi łączy te obszary, pozwalając na jawne interakcje między aplikacyjnymi i nieaplikacyjnymi obszarami izolowanymi zabezpieczeń.

Powiązane elementy interfejsu API

Wczytany obiekt skojarzony z tym obiektem LoaderInfo.

Typ MIME wczytanego pliku. Wartość null, gdy nie została załadowana część pliku wystarczająco duża, by można było określić jego typ. Poniższa lista ilustruje możliwe wartości:

• "application/x-shockwave-flash"
• "image/jpeg"
• "image/gif"
• "image/png"

Liczba klatek na sekundę w ramach wczytanego pliku SWF (liczba ramek na sekundę). Z reguły liczba ta jest liczbą całkowitą, chociaż nie jest to konieczne.

Wartość ta może się różnić od właściwej wykorzystywanej liczby klatek na sekundę. Program Flash Player lub środowisko AIR wykorzystuje tylko jedną częstość klatek dla wszystkich załadowanych plików SWF w danym momencie, która jest określona przez nominalną liczbę klatek na sekundę w głównym pliku SWF. Ponadto osiągnięcie głównej częstości klatek nie zawsze jest możliwe — zależy to od sprzętu, synchronizacji dźwięku i innych czynników.

Nominalna wysokość wczytanego elementu. Wartość ta może się różnić od właściwej wysokości wyświetlanej zawartości, ponieważ załadowana zawartość lub jego nadrzędne obiekty wyświetlane mogą być skalowane.

Wskazuje, czy właściwość LoaderInfo.url została przycięta. Jeśli isURLInaccessible ma wartość true, wówczas wartość LoaderInfo.url jest wyłącznie domeną końcowego adresu URL, z którego załadowano treść. Na przykład: właściwość zostanie przycięta, jeśli treść załadowano z http://www.adobe.com/assets/hello.swf, a właściwość LoaderInfo.url ma wartość http://www.adobe.com. isURLInaccessible ma wartość true tylko wówczas, gdy spełnione są wszystkie następujące warunki:

• Doszło do przekierowania HTTP podczas ładowania treści.
• Plik SWF wywołujący metodę Loader.load() pochodzi z domeny innej niż końcowy adres URL treści.
• Plik SWF wywołujący metodę Loader.load() nie ma uprawnień dostępu do treści. Wydano uprawnienie do uzyskiwania dostępu do treści, a w ten sam sposób wydano uprawnienie do metody BitmapData.draw(): należy wywołać metodę Security.allowDomain(), aby uzyskać dostęp do pliku SWF (w przypadku pliku treści innej niż SWF należy określić plik reguły i użyć właściwości LoaderContext.checkPolicyFile).

Uwaga: Właściwość isURLInaccessible została dodana dla programu Flash Player 10.1 i środowiska AIR 2.0. Jednak ta właściwość jest dostępna dla plików SWF wszystkich wersji, pod warunkiem że środowisko wykonawcze Flash obsługuje tę właściwość. Dlatego stosowanie narzędzi do tworzenia treści w trybie „ścisłym” powoduje błąd kompilacji. W celu obejścia błędu należy użyć składni przekierowania myLoaderInfo["isURLInaccessible"] lub wyłączyć tryb ścisły. Jeśli do tworzenia aplikacji używany jest program Flash Professional CS5 lub środowisko Flex SDK 4.1, można wykorzystywać i kompilować odwołania do tego elementu interfejsu API dla środowisk wykonawczych wydanych wcześniej niż wersje Flash Player 10.1 i AIR 2.

W przypadku treści aplikacji w środowisku AIR ta właściwość ma zawsze wartość false.

Powiązane elementy interfejsu API

Obiekt Loader skojarzony z tym obiektem LoaderInfo. Jeżeli ten obiekt LoaderInfo jest właściwością loaderInfo instancji głównej klasy pliku SWF, wówczas żaden obiekt Loader nie jest skojarzony.

Adres URL pliku SWF, który zainicjował ładowanie danych opisanych przez ten obiekt LoaderInfo. W przypadku instancji głównej klasy pliku SWF, ten adres URL jest taki sam, jaki posiada plik SWF.

Obiekt zawierający pary nazwa-wartość, odpowiadające parametrom przekazywanym do wczytanego pliku SWF.

Możliwe jest wykorzystanie pętli for-in w celu wyodrębnienia wszystkich nazw oraz wartości z obiektu parameters.

Istnieją dwa źródła parametrów: ciąg znaków zapytania w adresie URL głównego pliku SWF oraz wartość właściwości FlashVars parametru HTML (ma to wpływ tylko na główny plik SWF).

Właściwość parameters zastępuje technikę skryptu ActionScript 1.0 i 2.0, polegającą na dostarczaniu parametrów pliku SWF jako właściwości głównej osi czasu.

Wartość właściwości parameters wynosi null dla obiektów Loader zawierających pliki SWF, które wykorzystują skrypt ActionScript 1.0 i 2.0. Ma ona wartość inną niż null tylko w przypadku obiektów Loader zawierających pliki SWF wykorzystujące skrypt ActionScript 3.0.

Wyraża relację zaufania między obiektem Loader (obiekt macierzysty) i zawartością (obiekt potomny). Wartość true, jeżeli obiekt podrzędny ma dostęp do obiektu nadrzędnego; wartość false w innym przypadku. Właściwość ta jest ustawiona na wartość true, jeżeli obiekt nadrzędny wywołał metodę allowDomain() w celu nadania pozwolenia domenie podrzędnej, lub plik reguł URL jest ładowany na domenie nadrzędnej, która nadaje pozwolenia domenie podrzędnej. Jeżeli obiekt podrzędny i nadrzędny znajdują się w tej samej domenie ta właściwość ma wartość true.

Więcej informacji na temat zabezpieczeń zawiera odpowiedni temat w witrynie Flash Player Developer Center: Bezpieczeństwo.

Obiekt może być określony przez kod w obszarze izolowanym obiektu Loader w celu udostępnienia właściwości i metod dla kodu ładowanej treści. Ten most między obszarami izolowanymi umożliwia treści z domeny nieaplikacyjnej uzyskanie kontrolowanego dostępu do skryptów w obszarze izolowanym aplikacji i odwrotnie. Most między obszarami izolowanymi łączy te obszary, pozwalając na jawne interakcje między aplikacyjnymi i nieaplikacyjnymi obszarami izolowanymi zabezpieczeń.

Powiązane elementy interfejsu API

Wyraża relacje między programem ładującym i zawartością: wartość true, jeżeli posiadają one tą samą domenę źródłową; wartość false w innym przypadku.

Instancja obiektu EventDispatcher, która umożliwia wymianę zdarzeń w ramach obowiązujących zabezpieczeń. Nawet gdy obiekt Loader i załadowana treść pochodzą z domen zabezpieczeń, które nawzajem sobie nie ufają, oba te obiekty mają dostęp do obiektu sharedEvents i mogą wysyłać i odbierać zdarzenia przez ten obiekt.

Wersja formatu wczytanego pliku SWF. Format pliku jest określany przez wartość wyliczeniową z klasy SWFVersion, na przykład SWFVersion.FLASH7 oraz SWFVersion.FLASH9.

Powiązane elementy interfejsu API

Obiekt, który wywołuje zdarzenie uncaughtError, gdy w kodzie pliku SWF tego obiektu LoaderInfo wystąpi nieobsłużony błąd. Sytuacja taka ma miejsce, gdy błąd zostanie wywołany poza blokiem try..catch lub gdy zostanie wywołany obiekt zdarzenia ErrorEvent, dla którego nie zarejestrowano żadnych detektorów.

Jeśli na przykład blok try zawiera obiekt wywołujący zdarzenie jego modułu obsługi zdarzeń, blok catch nie przechwytuje błędu w przypadku wygenerowania błędu przez ten moduł. Każdy błąd wygenerowany później może zostać przechwycony przez wykrywanie zdarzenia LoaderInfo.uncaughtErrorEvents.

Ta właściwość jest tworzona po zakończeniu ładowania pliku przez ten obiekt LoaderInfo. Do tego czasu właściwość uncaughtErrorEvents jest równa null. (Tylko w projektach ActionScript) Dostęp do tej właściwości można uzyskać podczas wykonywania funkcji konstruktora klasy głównej pliku SWF lub po jej wykonaniu. W przypadku projektów Flex właściwość uncaughtErrorEvents staje się dostępna po wywołaniu zdarzenia applicationComplete.

Powiązane elementy interfejsu API

package
{
    import flash.display.Sprite;
    import flash.events.ErrorEvent;
    import flash.events.MouseEvent;
    import flash.events.UncaughtErrorEvent;

    public class UncaughtErrorEventExample extends Sprite
    {
        public function UncaughtErrorEventExample()
        {
            loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
            
            drawUI();
        }
        
        private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
        {
            if (event.error is Error)
            {
                var error:Error = event.error as Error;
                // do something with the error
            }
            else if (event.error is ErrorEvent)
            {
                var errorEvent:ErrorEvent = event.error as ErrorEvent;
                // do something with the error
            }
            else
            {
                // a non-Error, non-ErrorEvent type was thrown and uncaught
            }
        }
        
        private function drawUI():void
        {
            var btn:Sprite = new Sprite();
            btn.graphics.clear();
            btn.graphics.beginFill(0xFFCC00);
            btn.graphics.drawRect(0, 0, 100, 50);
            btn.graphics.endFill();
            addChild(btn);
            btn.addEventListener(MouseEvent.CLICK, clickHandler);
        }
        
        private function clickHandler(event:MouseEvent):void
        {
            throw new Error("Gak!");
        }
    }
}

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
                       xmlns:s="library://ns.adobe.com/flex/spark" 
                       xmlns:mx="library://ns.adobe.com/flex/halo"
                       applicationComplete="applicationCompleteHandler();">
    
    <fx:Script>
        <![CDATA[
            import flash.events.ErrorEvent;
            import flash.events.MouseEvent;
            import flash.events.UncaughtErrorEvent;
            
            private function applicationCompleteHandler():void
            {
                loaderInfo.uncaughtErrorEvents.addEventListener(UncaughtErrorEvent.UNCAUGHT_ERROR, uncaughtErrorHandler);
            }
    
            private function uncaughtErrorHandler(event:UncaughtErrorEvent):void
            {
                if (event.error is Error)
                {
                    var error:Error = event.error as Error;
                    // do something with the error
                }
                else if (event.error is ErrorEvent)
                {
                    var errorEvent:ErrorEvent = event.error as ErrorEvent;
                    // do something with the error
                }
                else
                {
                    // a non-Error, non-ErrorEvent type was thrown and uncaught
                }
            }
            
            private function clickHandler(event:MouseEvent):void
            {
                throw new Error("Gak!");
            }
        ]]>
    </fx:Script>
      
    <s:Button label="Cause Error" click="clickHandler(event);"/>
</s:WindowedApplication>

Adres URL ładowanych danych.

Przed wywołaniem pierwszego zdarzenia progress przez odpowiedni obiekt Loader tego obiektu LoaderInfo możliwe jest, że wartość właściwości url odzwierciedla tylko początkowy adres URL określony w wywołaniu do metody load() obiektu Loader. Po pierwszym wywołaniu zdarzenia progress, właściwość url odzwierciedla ostateczny adres URL nośnika, po rozpoznaniu przekierowań i względnych adresów URL.

W niektórych przypadkach wartość właściwości url jest przycięta; szczegółowe informacje zawiera opis właściwości isURLInaccessible.

Powiązane elementy interfejsu API

Nominalna szerokość wczytanego elementu. Wartość ta może się różnić od właściwej szerokości wyświetlanej zawartości, ponieważ załadowana zawartość lub jego nadrzędne obiekty wyświetlane mogą być skalowane.

Zwraca obiekt LoaderInfo skojarzony z plikiem SWF zdefiniowanym jako obiekt.

Parametry

Wywoływane po pomyślnym załadowaniu danych. Innymi słowy: zdarzenie jest wywoływane po załadowaniu całej zawartości i zakończeniu ładowania. Zdarzenie complete jest zawsze wywoływane po zdarzeniu init. Zdarzenie init jest wywoływane, gdy możliwe jest uzyskanie dostępu do obiektu, nawet jeśli nadal trwa pobieranie zawartości.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane, gdy generowane jest żądanie sieciowe za pośrednictwem protokołu HTTP i możliwe jest wykrycie kodu stanu HTTP.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane, gdy właściwości i metody załadowanego pliku SWF są dostępne i gotowe do użycia. Zawartość może być jednak nadal pobierana. Obiekt LoaderInfo wywołuje zdarzenie init przy wystąpieniu następujących warunków:

• Wszystkie właściwości i metody skojarzone z ładowanym obiektem oraz te skojarzone z obiektem LoaderInfo są dostępne.
• Konstruktorzy wszystkich obiektów podrzędnych zakończyły pracę.
• Cały kod ActionScript w pierwszej klatce głównej linii czasu załadowanego pliku SWF został wykonany.

Przykład: zdarzenie Event.INIT jest wywoływane po załadowaniu pierwszej klatki filmu lub animacji. Następnie film jest dostępny i może być dodawany do listy wyświetlania. Pobieranie całego filmu może jednak trwać dłużej. Zdarzenie Event.COMPLETE jest wywoływane po załadowaniu całego filmu.

Zdarzenie init zawsze uprzedza zdarzenie complete.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane, gdy wystąpi błąd wejścia lub wyjścia uniemożliwiający ładowanie danych.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane po rozpoczęciu ładowania.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane w trakcie stopniowego wczytywania danych.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane przez obiekt LoaderInfo za każdym razem, gdy załadowany obiekt jest usuwany za pomocą metody unload() obiektu Loader, a także wtedy, gdy ten sam obiekt Loader uaktywnia drugą operację ładowania i przed jej rozpoczęciem są usuwane oryginalne dane.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

1. Tworzona jest właściwość url, która jest miejscem położenia oraz nazwą pliku obrazu.
2. Konstruktor klas tworzy obiekt Loader o nazwie loader.
3. Obiekt loader tworzy instancję detektora zdarzeń w celu zapewnienia poprawnego ładowania obrazu.
4. Konstruktor tworzy nową instancję obiektu URLRequest request z przekazaną właściwością url, aby nazwa pliku i lokacja były znane.
5. Obiekt request jest wówczas przekazywany do metody load() obiektu loader, który ładuje obraz do listy wyświetlania.

Ważne: Dla zilustrowania tego przykładu konieczne jest umieszczenie pliku o nazwie Image.gif w tym samym katalogu, co skompilowany plik SWF. Należy korzystać z obrazu, którego obszar mieści się w granicy wymiarów głównego pliku SWF.

package {
    import flash.display.Loader;
    import flash.display.LoaderInfo;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderInfoExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderInfoExample() {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.INIT, initHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            var request:URLRequest = new URLRequest(url);
            loader.load(request);
            addChild(loader);
        }

        private function initHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var info:LoaderInfo = LoaderInfo(loader.contentLoaderInfo);
            trace("initHandler: loaderURL=" + info.loaderURL + " url=" + info.url);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}