ProgressEvent  - AS3

Liczba wczytanych elementów lub bajtów w momencie przetwarzania zdarzenia.

Łączna liczba elementów lub bajtów, które zostaną załadowane w razie pomyślnego zakończenia operacji ładowania. Jeśli zdarzenie postępu jest wywołane/dołączone w obiekcie Socket, właściwość bytesTotal zawsze będzie równa 0, chyba że inna wartość zostanie określona w parametrze bytesTotal konstruktora. Liczba bajtów faktycznie wysłanych lub odebranych nie jest określana, a jej określenie należy do programisty aplikacji.

Tworzy obiekt Event zawierający informacje o zdarzeniach postępu. Obiekty Event są przekazywane jako parametry do detektorów zdarzeń.

Tworzy kopię obiektu ProgressEvent i ustawia wartości poszczególnych właściwości zgodnie z właściwościami oryginału.

Zwraca ciąg znaków, który zawiera wszystkie właściwości obiektu ProgressEvent. Format ciągu znaków jest następujący:

[ProgressEvent type=wartość bubbles=wartość cancelable=wartość bytesLoaded=wartość bytesTotal=wartość]

Definiuje wartość właściwości type obiektu zdarzenia progress.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Definiuje wartość właściwości type obiektu zdarzenia socketData.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Definiuje wartość właściwości type obiektu zdarzenia standardErrorData.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Definiuje wartość właściwości type obiektu zdarzenia standardInputProgress.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Definiuje wartość właściwości type obiektu zdarzenia standardOutputData.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

1. Tworzone są właściwości downloadURL i fileName określające lokalizację i nazwę pobieranego pliku.
2. W konstruktorze ProgressEventExample tworzony jest nowy obiekt FileReference o nazwie file. Następnie obiekt ten jest przekazywany do metody configureListeners().
3. Właściwości downloadURL i fileName są następnie przekazywane do metody file.download(), która wyświetla monit o lokalizację, do której ma zostać pobrany plik.
4. Metoda configureListeners() dodaje siedem detektorów zdarzeń i skojarzone z nimi metody będące subskrybentami:
   1. cancel/cancelHandler() to zdarzenie wywoływane, gdy pobieranie pliku zostanie anulowane.
   2. complete/complereHandler() to zdarzenie wywoływane, gdy proces pobierania zostanie ukończony.
   3. ioError/ioErrorHandler() to zdarzenie wywoływane, gdy pobierany plik jest niedostępny lub nieosiągalny.
   4. open/openHandler() to zdarzenie wywoływane po rozpoczęciu operacji pobierania.
   5. progress/progressHandler() to zdarzenie wywoływane raz, gdy proces pobierania rozpoczyna się, i drugi raz, gdy się kończy.
   6. securityError/securityErrorHandler to zdarzenie wywoływane, gdy ustawienia zabezpieczeń odtwarzania lokalnego nie są zgodne z typem dostępu do danych w pobieranym pliku (lokalnie / z sieci); zobacz poniższe uwagi.
   7. select/selectHandler() to zdarzenie wywoływane po wybraniu obiektu do pobrania.

Uwagi:

• Plik SWF powinien być skompilowany z opcją Zabezpieczenie odtwarzania lokalnego ustawioną na wartość Tylko sieć lokalna.
• Ten przykład do działania wymaga pliku o nazwie SomeFile.pdf.
• Mimo że w przykładzie wykorzystywane są wszystkie zdarzenia dostępne dla obiektu FileReference, w większości sytuacji potrzebny jest tylko podzbiór.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class ProgressEventExample extends Sprite {
        private var downloadURL:String = "http://www.[yourDomain].com/SomeFile.pdf";
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function ProgressEventExample() {
            var request:URLRequest = new URLRequest(downloadURL);
            file = new FileReference();
            configureListeners(file);
            file.download(request, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL);
        }
    }
}