URLLoader  - AS3

Ukazuje liczbę bajtów, które zostały pobrane od rozpoczęcia operacji wczytywania.

Ukazuje całkowitą liczbę bajtów pobranych danych. Ta właściwość ma wartość 0, jeśli w danym momencie wykonywana jest operacja load; właściwość zostanie wypełniona po zakończeniu tej operacji. Brak nagłówka Content-Length będzie powodował, że właściwość bytesTotal będzie nieokreślona.

Dane uzyskane w wyniku ładowania. Ta właściwość jest wypełniania dopiero po zakończeniu operacji load. Format danych zależy od ustawienia właściwości dataFormat:

Jeśli wartością właściwości dataFormat jest URLLoaderDataFormat.TEXT, odebranymi danymi jest ciąg znaków zawierający tekst załadowanego pliku.

Jeśli wartością właściwości dataFormat jest URLLoaderDataFormat.BINARY, odebranymi danymi jest obiekt ByteArray zawierający nieprzetworzone dane binarne.

Jeśli wartością właściwościdataFormat jest URLLoaderDataFormat.VARIABLES, odebranymi danymi jest obiekt URLVariables zawierający zmienne zakodowane w postaci URL.

Powiązane elementy interfejsu API

//params.txt is a local file that includes: firstName=Tom&lastName=Jones
var lbl:TextField = new TextField();
var urlRequest:URLRequest = new URLRequest("params.txt");
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.VARIABLES;
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    lbl.text = urlLoader.data.lastName + "," + urlLoader.data.firstName;
    addChild(lbl);
}

Decyduje o tym, czy pobierane dane mają postać tekstu (URLLoaderDataFormat.TEXT), nieprzetworzonych danych (URLLoaderDataFormat.BINARY), czy też zmiennych zakodowanych w postaci URL (URLLoaderDataFormat.VARIABLES).

Jeśli wartością właściwości dataFormat jest URLLoaderDataFormat.TEXT, odebranymi danymi jest ciąg znaków zawierający tekst załadowanego pliku.

Jeśli wartością właściwości dataFormat jest URLLoaderDataFormat.BINARY, odebranymi danymi jest obiekt ByteArray zawierający nieprzetworzone dane binarne.

Jeśli wartością właściwościdataFormat jest URLLoaderDataFormat.VARIABLES, odebranymi danymi jest obiekt URLVariables zawierający zmienne zakodowane w postaci URL.

Wartością domyślną jest URLLoaderDataFormat.TEXT.

Powiązane elementy interfejsu API

var PATH:String = "lorem.txt";
var urlRequest:URLRequest = new URLRequest(PATH);
var urlLoader:URLLoader = new URLLoader();
urlLoader.dataFormat = URLLoaderDataFormat.TEXT; // default
urlLoader.addEventListener(Event.COMPLETE, urlLoader_complete);
urlLoader.load(urlRequest);
 
function urlLoader_complete(evt:Event):void {
    textArea.text = urlLoader.data;
}

Tworzy nowy obiekt URLLoader.

Powiązane elementy interfejsu API

Rejestruje obiekt detektora zdarzenia w obiekcie EventDispatcher, dzięki czemu detektor będzie otrzymywał powiadomienia o zdarzeniu. We wszystkich węzłach listy wyświetlania można rejestrować detektory zdarzeń reagujące na zdarzenia konkretnego typu, znajdujące się w określonej fazie i mające określony priorytet.

Po pomyślnym zarejestrowaniu detektora zdarzeń nie można zmienić jego priorytetu poprzez dodatkowe wywołania metody addEventListener(). Aby zmienić priorytet detektora, należy najpierw wywołać metodę removeListener(). Następnie można ponownie zarejestrować detektor z nowym poziomem priorytetu.

Należy pamiętać, że po zarejestrowaniu detektora późniejsze wywołania metody addEventListener() z różnymi wartościami type albo useCapture powodują rejestrowanie odrębnych detektorów. Na przykład detektor zarejestrowany z parametrem useCapture ustawionym na true wykrywa tylko zdarzenia w fazie przechwytywania. Po ponownym wywołaniu metody addEventListener() z tym samym obiektem detektora, ale z parametrem useCapture ustawionym na false będą istniały dwa odrębne detektory: jeden wykrywający zdarzenia w fazie przechwytywania, a drugi wykrywający zdarzenia w fazach miejsca docelowego i propagacji.

Nie można zarejestrować detektora zdarzeń, który wykrywałby tylko zdarzenia w fazie miejsca docelowego lub tylko zdarzenia w fazie propagacji. Te fazy są sprzężone podczas rejestracji, ponieważ propagacja zachodzi tylko w przodkach węzła miejsca docelowego.

Gdy detektor zdarzeń przestanie być potrzebny, należy go usunąć, wywołując metodę removeEventListener(); w przeciwnym razie mogą wystąpić problemy w zarządzaniu pamięcią. Detektory zdarzeń nie są automatycznie usuwane z pamięci, ponieważ proces czyszczenia pamięci nie usuwa detektora, pod warunkiem że istnieje obiekt wywołujący (o ile dla parametru useWeakReference ustawiona jest wartość true).

Skopiowanie instancji klasy EventDispatcher nie powoduje skopiowania detektorów zdarzeń dołączonych do tej instancji. (Jeśli utworzono nowy węzeł, dla którego potrzebny jest detektor zdarzeń, należy dołączyć detektor po utworzeniu węzła). Jednak przeniesienie instancji klasy EventDispatcher powoduje również przeniesienia dołączonych do niej detektorów zdarzeń

Jeśli detektor zdarzeń jest rejestrowany w węźle w momencie, gdy ten węzeł przetwarza zdarzenie, detektor nie zostanie wywołany w bieżącej fazie, ale może być wywołany w późniejszej fazie przepływu zdarzeń, np. w fazie propagacji.

Jeśli detektor zdarzeń zostanie usunięty z węzła w momencie, gdy ten węzeł przetwarza zdarzenie, zostanie wywołany przez bieżące operacje. Raz usunięty detektor zdarzeń nie jest nigdy ponownie wywoływany (chyba że zostanie ponownie zarejestrowany na potrzeby dalszego etapu wykonania programu).

Parametry

function(evt:Event):void

Kończy trwającą operację ładowania. Wszystkie operacje load wykonywane w danym momencie zostaną natychmiast zakończone. Jeśli żaden adres URL nie jest strumieniowany, zgłoszony zostanie błąd niepoprawnego strumienia.

Wysyła dane i ładuje je spod określonego adresu URL. W zależności od wartości przekazanej do właściwości dataFormat odebranymi danymi mogą być tekst, nieprzetworzone dane binarne lub zmienne zakodowane w postaci URL. Należy zauważyć, że wartością domyślną właściwości dataFormat jest text. Jeśli dane mają być wysyłane do określonego adresu URL, należy ustawić właściwość data w obiekcie URLRequest.

Uwaga: jeśli ładowany plik zawiera znaki, które nie są znakami ASCII (co zdarza się w wielu językach innych niż angielski), zalecane jest zapisanie pliku z kodowaniem w systemie UTF-8 lub UTF-16.

Plik SWF w lokalnym obszarze izolowanym z dostępem do systemu plików nie może wczytywać danych z, i dostarczać danych do, zasobu znajdującego się w obszarze izolowanym sieci.

Domyślnie wywołujący plik SWF oraz ładowany URL muszą być w tej samej domenie. Na przykład plik SWF na stronie www.adobe.com może ładować dane jedynie ze źródeł, które również znajdują się na stronie www.adobe.com. Aby ładować dane z różnych domen, należy umieścić plik reguł URL na serwerze przechowującym dane.

Nie można połączyć się z portem, który zazwyczaj jest zastrzeżony. Pełną listę zablokowanych portów zawiera sekcja „Ograniczanie sieciowych interfejsów API” w publikacji ActionScript 3.0 — podręcznik dla programistów.

W programie Flash Player 10 i nowszych wersjach, jeśli użyty zostanie wieloczęściowy nagłówek Content-Type (np. "multipart/form-data"), w którym przesyłane są pliki (wskazywane przez parametr "filename" w nagłówku "content-disposition" w treści operacji POST), wówczas operacja POST podlega regułom zabezpieczeń zastosowanym do wysyłania plików:

• Operację POST należy wykonać w odpowiedzi na działanie zainicjowane przez użytkownika, np. kliknięcie myszy lub naciśnięcie klawisza.
• Jeśli operacja POST jest operacją międzydomenową (cel operacji POST nie znajduje się na tym samym serwerze, co plik SWF, który wysyła żądanie POST), docelowy serwer musi dostarczyć plik reguł URL, który zezwoli na międzydomenowy dostęp.

Dla dowolnego wieloczęściowego nagłówka Content-Type również składnia musi być poprawna (zgodnie ze standardami RFC2046). Jeśli składnia okaże się niepoprawna, operacja POST będzie podlegać regułom zabezpieczeń stosowanym do wysyłania plików.

Więcej informacji na temat zabezpieczeń zawiera odpowiedni temat w Centrum programistów programu Flash Player w kategorii Bezpieczeństwo.

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.xml.*;
    import flash.events.IOErrorEvent;
  
    public class URLLoader_loadExample extends Sprite {
        private var xmlTextField:TextField = new TextField();
        private var externalXML:XML;    
        private var loader:URLLoader;

        public function URLLoader_loadExample() {
            var request:URLRequest = new URLRequest("xmlFile.xml");

            loader = new URLLoader();
            
            try {
                loader.load(request);
            }
            catch (error:SecurityError)
            {
                trace("A SecurityError has occurred.");
            }

             loader.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            loader.addEventListener(Event.COMPLETE, loaderCompleteHandler);

            xmlTextField.x = 10;
            xmlTextField.y = 10;
            xmlTextField.background = true;
            xmlTextField.autoSize = TextFieldAutoSize.LEFT;

            addChild(xmlTextField);
        }

        private function loaderCompleteHandler(event:Event):void {

                try {
                    externalXML = new XML(loader.data);
                    readNodes(externalXML);    
                } catch (e:TypeError) {
                    trace("Could not parse the XML file.");
                }
        }

        private function readNodes(node:XML):void {

                for each (var element:XML in node.elements()) {
                    xmlTextField.appendText(element.attributes()[0] + "\n");

                    readNodes(element);
                }    
        }

        private function errorHandler(e:IOErrorEvent):void {
            xmlTextField.text = "Had problem loading the XML File.";
        }
    }
}

Wywoływane, gdy wszystkie odebrane dane zostały zdekodowane i związane z właściwością danych obiektu URLLoader. Dostęp do odebranych danych można uzyskać po wywołaniu tego zdarzenia.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane, jeśli wywołanie metody load() skutkuje próbą uzyskania dostępu do danych za pomocą protokołu HTTP i aplikacja Adobe AIR ma możliwość wykrycia i zwrócenia kodu stanu żądania.

Stała HTTPStatusEvent.HTTP_RESPONSE_STATUS definiuje wartość właściwości type obiektu zdarzenia httpResponseStatus.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane, jeśli wywołanie URLLoader.load() skutkuje próbą dostępu do danych za pośrednictwem protokołu HTTP. W przypadku treści działającej w programie Flash Player to zdarzenie jest wywoływane tylko wtedy, gdy bieżące środowisko Flash Player jest w stanie wykryć i zwrócić kod statusu dla żądania. (Niektóre środowiska przeglądarek mogą nie być w stanie zapewnić tych informacji). Należy zauważyć, że ewentualne zdarzenie httpStatus zostanie wysłane przed (i oprócz) wszelkich zdarzeń complete luberror.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane, gdy wywołanie metody URLLoader.load() skutkuje błędem krytycznym, który kończy pobieranie danych.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane, gdy operacja pobierania rozpoczyna się od wywołania metody URLLoader.load()

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane w trakcie stopniowego wczytywania danych.

Należy zauważyć, że korzystając z obiektu URLLoader, nie jest możliwe uzyskanie dostępu do danych, dopóki nie zostaną one całkowicie odebrane. Dlatego zdarzenie progress służy jedynie do powiadamiania o postępie pobierania. Aby uzyskać dostęp do danych przed ich całkowitym pobraniem, należy użyć obiektu URLStream.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane, jeśli wywołanie metody URLLoader.load() skutkuje próbą pobrania danych z serwera na zewnątrz obszaru izolowanego. Wywoływane również, gdy wywołanie metody URLLoader.load() skutkuje próbą załadowania pliku SWZ, a certyfikat jest nieważny lub skrót jest niezgodny ze składnikiem.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Uwaga: aby uruchomić ten przykład, należy umieścić plik o nazwie urlLoaderExample.txt w tym samym katalogu, co plik SWF. Plik powinien zawierać tylko następujący wiersz tekstu: answer=42&question=unknown

Przykładowy kod realizuje następujące zadania:

1. Funkcja konstruktora tworzy instancję URLLoader o nazwie loader oraz instancję URLRequest o nazwie request, która zawiera lokalizację i nazwę pliku do ładowania.
2. Obiekt loader przekazywany jest do metody configureListeners(), która dodaje detektory dla każdego z obsługiwanych zdarzeń URLLoader:
3. Następnie obiekt request jest przekazywany do metody loader.load(), która ładuje plik tekstowy.
4. Po zakończeniu ładowania przez obiekt URLLoader pliku tekstowego, wywoływane jest zdarzenie Event.COMPLETE, które powoduje wywołanie metody completeHandler(). Metoda completeHandler() tworzy obiekt URLVariables z tekstu załadowanego z pliku. Obiekt URLVariables przekształca pary nazwa/wartość zakodowane w postaci URL na właściwości ActionScript, aby ułatwić sterowanie załadowanymi danymi.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLLoaderExample extends Sprite {
        
        private loader:URLoader;
        public function URLLoaderExample() {
            loader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("urlLoaderExample.txt");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
    
            var vars:URLVariables = new URLVariables(loader.data);
            trace("The answer is " + vars.answer);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}