| Pakiet | flash.net |
| Klasa | public final class URLRequestHeader |
| Dziedziczenie | URLRequestHeader  Object |
| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | AIR 1.0, Flash Player 9, Flash Lite 4 |
requestHeaders klasy URLRequest.
W środowisku Adobe® AIR® treść w obszarze izolowanym zabezpieczeń aplikacji (np. treść instalowana z aplikacją AIR) może korzystać z dowolnych nagłówków żądań i nie spowoduje to błędu. Jednak w przypadku treści działającej w środowisku Adobe AIR, która znajduje się w innym obszarze izolowanym, lub w przypadku treści działającej w programie Flash® Player użycie następujących nagłówków żądań spowoduje wygenerowanie błędu podczas wykonywania; w zastrzeżonych elementach nie jest rozróżniana wielkość liter (na przykład żądania Get, get i GET nie są dozwolone):
W programie Flash Player i w treści Adobe AIR działającej poza obszarem izolowanym zabezpieczeń aplikacji nie można używać następujących nagłówków żądań; w zastrzeżonych elementach nie jest rozróżniana wielkość liter (na przykład żądania Get, get i GET nie są dozwolone). Ograniczenia dotyczą również terminów dwuczłonowych, jeśli są rozdzielone podkreśleniem (np. oba terminy Content-Length i Content_Length są niedozwolone):
Accept-Charset, Accept-Encoding, Accept-Ranges, Age, Allow, Allowed, Authorization, Charge-To, Connect, Connection, Content-Length, Content-Location, Content-Range, Cookie, Date, Delete, ETag, Expect, Get, Head, Host, If-Modified-Since, Keep-Alive, Last-Modified, Location, Max-Forwards, Options, Origin, Post, Proxy-Authenticate, Proxy-Authorization, Proxy-Connection, Public, Put, Range, Referer, Request-Range, Retry-After, Server, TE, Trace, Trailer, Transfer-Encoding, Upgrade, URI, User-Agent, Vary, Via, Warning, WWW-Authenticate, x-flash-version.
Obiekty URLRequestHeader mają ograniczoną długość. Jeśli sumaryczna długość obiektu URLRequestHeader (długość właściwości name i właściwości value) lub tablicy obiektów URLRequestHeader użytej we właściwości URLRequest.requestHeaders przekracza dopuszczalną długość, zostanie wygenerowany wyjątek.
Treść działająca w środowisku Adobe AIR ustawia nagłówek ACCEPT w następujący sposób, chyba że ustawienie nagłówka ACCEPT zostanie określone we właściwości requestHeaders klasy URLRequest:
text/xml, application/xml, application/xhtml+xml, text/html;q=0.9, text/plain;q=0.8, image/png, application/x-shockwave-flash, video/mp4;q=0.9, flv-application/octet-stream;q=0.8, video/x-flv;q=0.7, audio/mp4, */*;q=0.5
Nie wszystkie metody, które akceptują parametry obiektu URLRequest, obsługują właściwość requestHeaders, dlatego należy zapoznać się z dokumentacją wywoływanych metod. Na przykład metody FileReference.upload() i FileReference.download() nie obsługują właściwości URLRequest.requestHeaders.
Z powodu ograniczeń przeglądarki, niestandardowe nagłówki żądań HTTP są obsługiwane jedynie przez żądania POST, nie przez GET.
Powiązane elementy interfejsu API
Ukryj dziedziczone właściwości publiczne
Pokaż dziedziczone właściwości publiczne| Właściwość | Zdefiniowane przez | ||
|---|---|---|---|
 | constructor : Object
Odwołanie do obiektu klasy lub funkcji konstruktora, dotyczące danej instancji obiektu. | Object | |
| name : String
Nazwa nagłówka żądania HTTP (np. Content-Type lub SOAPAction). | URLRequestHeader | ||
| value : String
Wartość skojarzona z nazwą (np. tekst/zwykły). | URLRequestHeader | ||
| Metoda | Zdefiniowane przez | ||
|---|---|---|---|
Tworzy nowy obiekt URLRequestHeader, który mieści w sobie nagłówek jednego żądania HTTP. | URLRequestHeader | ||
|
Wskazuje, czy dla obiektu zdefiniowano określoną właściwość. | Object | |
|
Wskazuje, czy instancja klasy Object należy do łańcucha prototypów obiektu określonego jako parametr. | Object | |
|
Wskazuje, czy określona właściwość istnieje i jest przeliczalna. | Object | |
|
Ustawia dostępność właściwości dynamicznej używanej w pętlach. | Object | |
|
Zwraca ciąg reprezentujący obiekt — sformatowany zgodnie z konwencjami właściwymi dla ustawień regionalnych. | Object | |
|
Zwraca ciąg reprezentujący określony obiekt. | Object | |
|
Zwraca pierwotną wartość dla określonego obiektu. | Object | |
name | właściwość |
public var name:String| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Nazwa nagłówka żądania HTTP (na przykład Content-Type lub SOAPAction).
value | właściwość |
public var value:String| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Wartość skojarzona z właściwością name (na przykład text/plain).
URLRequestHeader | () | Konstruktor |
public function URLRequestHeader(name:String = "", value:String = "")| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | AIR 1.0, Flash Player 9, Flash Lite 4 |
Tworzy nowy obiekt URLRequestHeader, który mieści w sobie nagłówek jednego żądania HTTP. Obiekty URLRequestHeader są używane we właściwości requestHeaders klasy URLRequest.
name:String (default = "Content-Type lub SOAPAction).
| |
value:String (default = "name (np. text/plain).
|
header do tablicy właściwości requestHeaders. Nagłówek wskazuje, że aplikacja przesyła żądanie do oryginalnego serwera, nawet jeśli posiada zbuforowaną kopię żądanych danych.
package {
import flash.display.Sprite;
import flash.events.*;
import flash.net.URLLoader;
import flash.net.URLRequest;
import flash.net.URLRequestHeader;
import flash.net.URLRequestMethod;
import flash.net.URLVariables;
public class URLRequestHeaderExample extends Sprite {
private var loader:URLLoader;
public function URLRequestHeaderExample() {
loader = new URLLoader();
configureListeners(loader);
var header:URLRequestHeader = new URLRequestHeader("pragma", "no-cache");
var request:URLRequest = new URLRequest("http://www.[yourdomain].com/greeting.cfm");
request.data = new URLVariables("name=John+Doe");
request.method = URLRequestMethod.POST;
request.requestHeaders.push(header);
try {
loader.load(request);
} catch (error:Error) {
trace("Unable to load requested document.");
}
}
private function configureListeners(dispatcher:IEventDispatcher):void {
dispatcher.addEventListener(Event.COMPLETE, completeHandler);
dispatcher.addEventListener(Event.OPEN, openHandler);
dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
}
private function completeHandler(event:Event):void {
var loader:URLLoader = URLLoader(event.target);
trace("completeHandler: " + loader.data);
}
private function openHandler(event:Event):void {
trace("openHandler: " + event);
}
private function progressHandler(event:ProgressEvent):void {
trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
}
private function securityErrorHandler(event:SecurityErrorEvent):void {
trace("securityErrorHandler: " + event);
}
private function httpStatusHandler(event:HTTPStatusEvent):void {
trace("httpStatusHandler: " + event);
}
private function ioErrorHandler(event:IOErrorEvent):void {
trace("ioErrorHandler: " + event);
}
}
}
Tue Jun 12 2018, 12:06 PM Z