Sound  - AS3

Zwraca aktualnie dostępną liczbę bajtów tego obiektu dźwiękowego. Ta właściwość jest zazwyczaj użyteczna tylko dla plików ładowanych zewnętrznie.

Zwraca całkowitą liczbę bajtów tego obiektu dźwiękowego.

Zapewnia dostęp do metadanych będących częścią pliku MP3.

Pliki dźwiękowe MP3 mogą zawierać znaczniki ID3, które udostępniają metadane na temat pliku. Jeśli dźwięk w formacie MP3 załadowany za pomocą metody Sound.load() zawiera znaczniki ID3, istnieje możliwość odpytania tych właściwości. Obsługiwane są tylko znaczniki ID3, które korzystają z zestawu znaków standardu UTF-8.

Program Flash Player 9 i późniejsze wersje oraz środowisko AIR obsługują znaczniki ID3 2.0, a w szczególności 2.3 i 2.4. W poniższych tabelach przedstawiono standardowe znaczniki ID3 2.0 oraz typ zawartości, jaką reprezentują te znaczniki. Właściwość Sound.id3 umożliwia dostęp do tych znaczników za pomocą formatu my_sound.id3.COMM, my_sound.id3.TIME itd. Pierwsza tabela opisuje znaczniki, do których można uzyskiwać dostęp za pośrednictwem nazwy właściwości ID3 2.0 lub nazwy właściwości ActionScript. Druga tabela przedstawia znaczniki ID3, które są obsługiwane, ale nie zawierają predefiniowanych właściwości w ActionScript.

Poniższa tabela przedstawia znaczniki ID3, które są obsługiwane, ale nie zawierają predefiniowanych właściwości w klasie Sound. Dostęp do nich uzyskuje się, wywołując mySound.id3.TFLT, mySound.id3.TIME, itd. UWAGA: Żaden z tych znaczników nie jest obsługiwany w programie Flash Lite 4.

Korzystając z tej właściwości, należy wziąć pod uwagę model zabezpieczeń programu Flash Player.

• Właściwość id3 obiektu Sound jest zawsze dozwolona dla plików SWF, które znajdują się w tym samym obszarze izolowanym zabezpieczeń, co plik dźwiękowy. Dla plików z innego obszaru izolowanego sprawdzane są zabezpieczenia.
• Ładując dźwięk za pomocą metody load() klasy Sound, można określić parametr context, którym należy uczynić obiekt SoundLoaderContext. Jeśli dla właściwości checkPolicyFile obiektu SoundLoaderContext zostanie przypisana wartość true, program Flash Player sprawdzi istnienie pliku reguł URL na serwerze, z którego ładowany jest dźwięk. Jeśli plik reguł istnieje i umożliwia dostęp z domeny ładującego pliku SWF, wówczas plik może uzyskiwać dostęp do właściwości id3 obiektu Sound; w przeciwnym wypadku nie może.

Jednak w aplikacji Adobe AIR zawartość obszaru izolowanego application (zawartość instalowana razem z aplikacją AIR) nie jest ograniczana przez te reguły zabezpieczeń.

Więcej informacji na temat zabezpieczeń zawiera odpowiedni temat w Centrum programistów programu Flash Player w kategorii Bezpieczeństwo.

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    import flash.media.Sound;
    import flash.net.URLRequest;
    import flash.media.ID3Info;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.Event;

    public class Sound_id3Example extends Sprite {
        private var snd:Sound = new Sound();       
        private var myTextField:TextField = new TextField();

        public function Sound_id3Example() {
            snd.addEventListener(Event.ID3, id3Handler);
            snd.load(new URLRequest("mySound.mp3"));
        }
    
        private function id3Handler(event:Event):void {
            var id3:ID3Info = snd.id3;

            myTextField.autoSize = TextFieldAutoSize.LEFT;
            myTextField.border = true;

            myTextField.appendText("Received ID3 Info: \n");
              
            for (var propName:String in id3) {
                myTextField.appendText(propName + " = " + id3[propName] + "\n");
            }
 
            myTextField.appendText("\n" + "Artist: " + id3.artist + "\n");
            myTextField.appendText("Song name: " + id3.songName + "\n");
            myTextField.appendText("Album: " + id3.album + "\n\n"); 
 
            this.addChild(myTextField);
        }
    }
}

Zwraca stan buforowania zewnętrznych plików MP3. Jeśli jej wartością jest true aktualnie odtwarzany dźwięk zostanie wstrzymany, w momencie oczekiwania na większą ilość danych.

Wskazuje, czy właściwość Sound.url została przycięta. Gdy właściwość isURLInaccessible ma wartość true, wartość Sound.url jest wyłącznie domeną adresu URL, spod którego ostatecznie dźwięk został załadowany. Na przykład: właściwość zostanie przycięta, jeśli treść załadowano z http://www.adobe.com/assets/hello.mp3, a właściwość Sound.url ma wartość http://www.adobe.com. Właściwość isURLInaccessible ma wartość true tylko wówczas, gdy spełnione są wszystkie następujące warunki:

• Doszło do przekierowania HTTP podczas ładowania pliku dźwiękowego.
• Plik SWF wywołujący metodę Sound.load() pochodzi z domeny innej niż ostateczny adres URL pliku dźwiękowego.
• Plik SWF wywołujący metodę Sound.load() nie ma uprawnień dostępu do pliku dźwiękowego. Zezwolenie na dostęp do pliku dźwiękowego udzielane jest na tej samej zasadzie, jak w przypadku właściwości Sound.id3: należy ustanowić plik reguł i skorzystać z właściwości SoundLoaderContext.checkPolicyFile.

Uwaga: Właściwość isURLInaccessible została dodana dla programu Flash Player 10.1 i środowiska AIR 2.0. Jednak ta właściwość jest dostępna dla plików SWF wszystkich wersji, pod warunkiem że środowisko wykonawcze Flash obsługuje tę właściwość. Dlatego stosowanie narzędzi do tworzenia treści w trybie „ścisłym” powoduje błąd kompilacji. W celu obejścia błędu należy użyć składni przekierowania mySound["isURLInaccessible"] lub wyłączyć tryb ścisły. Jeśli do tworzenia aplikacji używany jest program Flash Professional CS5 lub środowisko Flex SDK 4.1, można wykorzystywać i kompilować odwołania do tego elementu interfejsu API dla środowisk wykonawczych wydanych wcześniej niż wersje Flash Player 10.1 i AIR 2.

W przypadku treści aplikacji w środowisku AIR ta właściwość ma zawsze wartość false.

Powiązane elementy interfejsu API

Długość bieżącego dźwięku w milisekundach.

Adres URL strony, z której załadowano dźwięk. Tę właściwość należy stosować jedynie do obiektów Sound, które zostały załadowane za pomocą metody Sound.load(). Dla obiektów Sound, które są skojarzone z dźwiękami z biblioteki pliku SWF, wartość właściwości url jest równa null.

Przy pierwszym wywołaniu metody Sound.load(), właściwość url ma wartość początkową null, ponieważ ostateczny adres URL nie jest jeszcze znany. Właściwość url będzie miała wartość różną od null tuż po wywołaniu zdarzenia open z obiektu Sound.

Właściwość url zawiera ostateczny, bezwzględny adres URL, z którego został załadowany dźwięk. Wartością właściwości url jest zazwyczaj ta sama wartość, która przekazywana jest do parametru stream metody Sound.load(). Jeśli jednak do metody Sound.load()przekazany zostanie względny adres URL, wartość właściwości url będzie reprezentowała bezwzględny adres URL. Ponadto, jeśli oryginalny adres URL zostanie przekierowany przez serwer HTTP, wartość właściwości url będzie odzwierciedlać ostateczny adres URL z którego faktycznie pobrany został plik dźwiękowy. Zgłoszenie ostatecznego, bezwzględnego adresu URL jest równoważne z działaniem właściwości LoaderInfo.url.

W niektórych przypadkach wartość właściwości url jest przycięta; szczegółowe informacje zawiera opis właściwości isURLInaccessible.

Powiązane elementy interfejsu API

Tworzy nowy obiekt Sound. Przekazanie poprawnego obiektu URLRequest do konstruktora Sound powoduje automatyczne wywołanie funkcji load() dla obiektu Sound. Nie przekazanie poprawnego obiektu URLRequest do konstruktora Sound powoduje, że użytkownik jest zmuszony do samodzielnego wywołania funkcji load() dla obiektu Sound, w przeciwnym razie strumień nie zostanie załadowany.

Po wywołaniu funkcji load() na obiekcie Sound nie istnieje możliwość załadowania w późniejszym czasie innego pliku dźwiękowego do tego obiektu. Aby załadować inny plik dźwiękowy, należy utworzyć nowy obiekt Sound.

Zamyka strumień, powodując zakończenie ładowania wszelkich danych. Żadne dane nie zostaną odczytane ze strumienia po wywołaniu metody close().

 
package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;    
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.errors.IOError;
    import flash.events.IOErrorEvent;

    public class Sound_closeExample extends Sprite {
        private var snd:Sound = new Sound();
        private var button:TextField = new TextField();
        private var req:URLRequest = new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3");
        
        public function Sound_closeExample() {
            button.x = 10;
            button.y = 10;
            button.text = "START";
            button.border = true;
            button.background = true;
            button.selectable = false;
            button.autoSize = TextFieldAutoSize.LEFT;

            button.addEventListener(MouseEvent.CLICK, clickHandler);

            this.addChild(button);
        }

        private function clickHandler(e:MouseEvent):void {

            if(button.text == "START") {

                snd.load(req);
                snd.play();        

                snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);

                button.text = "STOP";
            }
            else if(button.text == "STOP") {
                    
                try {
                    snd.close();
                    button.text = "Wait for loaded stream to finish.";
                }
                catch (error:IOError) {
                    button.text = "Couldn't close stream " + error.message;    
                }
            }
        }
        
        private function errorHandler(event:IOErrorEvent):void {
                button.text = "Couldn't load the file " + event.text;
        }
    }
}

Wyodrębnia nieprzetworzone dane dźwiękowe z obiektu Sound.

Ta metoda jest przeznaczona do pracy z dźwiękiem generowanym dynamicznie, przy użyciu funkcji przypisanej do zdarzenia sampleData dla innego obiektu Sound. Oznacza to, że metody tej można używać do wyodrębniania danych dźwięku z obiektu Sound. Można wówczas zapisać dane do tablicy bajtowej, której inny obiekt Sound używa do strumieniowania dynamicznych danych audio.

Dane audio są umieszczane w docelowej tablicy bajtowej począwszy od bieżącej pozycji tablicy bajtowej. Dane audio są zawsze udostępniane jako dane stereofoniczne o częstotliwości próbkowania 44100 Hz. Typem przykładowym jest wartość 32-bitowa zmiennoprzecinkowa, którą można konwertować na format liczbowy za pomocą metody ByteArray.readFloat().

Parametry

Powiązane elementy interfejsu API

var sourceSnd:Sound = new Sound();
var outputSnd:Sound = new Sound();
var urlReq:URLRequest = new URLRequest("test.mp3");

sourceSnd.load(urlReq);
sourceSnd.addEventListener(Event.COMPLETE, loaded);

function loaded(event:Event):void
{
    outputSnd.addEventListener(SampleDataEvent.SAMPLE_DATA, processSound);
    outputSnd.play();
}

function processSound(event:SampleDataEvent):void
{
    var bytes:ByteArray = new ByteArray();
    sourceSnd.extract(bytes, 4096);
    event.data.writeBytes(upOctave(bytes));
}

function upOctave(bytes:ByteArray):ByteArray
{
    var returnBytes:ByteArray = new ByteArray();
    bytes.position = 0;
    while(bytes.bytesAvailable > 0)
    {
        returnBytes.writeFloat(bytes.readFloat());
        returnBytes.writeFloat(bytes.readFloat());
        if (bytes.bytesAvailable > 0)
        {
            bytes.position += 8;
        }
    }
    return returnBytes;
}

Inicjuje wczytywanie zewnętrznego pliku MP3 spod określonego adresu URL. Zapewnienie poprawnego obiektu URLRequest dla konstruktora Sound powoduje wywołanie funkcji Sound.load() za użytkownika. Funkcję Sound.load() należy wywołać samodzielnie, jeśli do konstruktora Sound nie zostanie przekazany poprawny obiekt URLRequest lub przekazana zostanie wartość null.

Po wywołaniu funkcji load() na obiekcie Sound nie istnieje możliwość załadowania w późniejszym czasie innego pliku dźwiękowego do tego obiektu. Aby załadować inny plik dźwiękowy, należy utworzyć nowy obiekt Sound.

Korzystając z tej metody, należy wziąć pod uwagę model zabezpieczeń:

• Wywołanie metody Sound.load() jest niedozwolone, jeśli plik wywołujący znajduje się w lokalnym obszarze izolowanym systemu plików, a dźwięk znajduje się w obszarze izolowanym sieci.
• Dostęp z lokalnego zaufanego obszaru izolowanego lub lokalnego obszaru izolowanego z dostępem do sieci wymaga uprawnień udzielonych przez witrynę sieci Web (za pośrednictwem pliku reguł URL).
• Nie można połączyć się z portem, który zazwyczaj jest zastrzeżony. Pełną listę zablokowanych portów zawiera sekcja „Ograniczanie sieciowych interfejsów API” w publikacji ActionScript 3.0 — podręcznik dla programistów.
• Można zapobiec korzystaniu z tej metody przez plik SWF, ustawiając parametr allowNetworking znaczników object i embed na stronie HTML z zawartością SWF.

W programie Flash Player 10 i nowszych wersjach, jeśli użyty zostanie wieloczęściowy nagłówek Content-Type (np. "multipart/form-data"), w którym przesyłane są pliki (wskazywane przez parametr "filename" w nagłówku "content-disposition" w treści operacji POST), wówczas operacja POST podlega regułom zabezpieczeń zastosowanym do wysyłania plików:

• Operację POST należy wykonać w odpowiedzi na działanie zainicjowane przez użytkownika, np. kliknięcie myszy lub naciśnięcie klawisza.
• Jeśli operacja POST jest operacją międzydomenową (cel operacji POST nie znajduje się na tym samym serwerze, co plik SWF, który wysyła żądanie POST), docelowy serwer musi dostarczyć plik reguł URL, który zezwoli na międzydomenowy dostęp.

Dla dowolnego wieloczęściowego nagłówka Content-Type również składnia musi być poprawna (zgodnie ze standardami RFC2046). Jeśli składnia okaże się niepoprawna, operacja POST będzie podlegać regułom zabezpieczeń stosowanym do wysyłania plików.

W aplikacji Adobe AIR zawartość obszaru izolowanego application (zawartość instalowana razem z aplikacją AIR) nie jest ograniczana przez te reguły zabezpieczeń.

Więcej informacji na temat zabezpieczeń zawiera odpowiedni temat w Centrum programistów programu Flash Player w kategorii Bezpieczeństwo.

Parametry

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.ProgressEvent;
    import flash.events.IOErrorEvent;
    
    public class Sound_loadExample extends Sprite {
        private var snd:Sound = new Sound();
        private var statusTextField:TextField  = new TextField();

        public function Sound_loadExample(){

            statusTextField.autoSize = TextFieldAutoSize.LEFT;
            var req:URLRequest = new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3");
            
            try {
            snd.load(req);
            
            snd.play();
            }
            catch (err:Error) {
                trace(err.message);
            }
 
            snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            snd.addEventListener(ProgressEvent.PROGRESS, progressHandler);
                     
            this.addChild(statusTextField);
        }
    
        private function progressHandler(event:ProgressEvent):void {
            var loadTime:Number = event.bytesLoaded / event.bytesTotal;
            var LoadPercent:uint = Math.round(100 * loadTime);
              
            statusTextField.text = "Sound file's size in bytes: " + event.bytesTotal + "\n" 
                                 + "Bytes being loaded: " + event.bytesLoaded + "\n" 
                                 + "Percentage of sound file that is loaded " + LoadPercent + "%.\n";
        }
 
        private function errorHandler(errorEvent:IOErrorEvent):void {
            statusTextField.text = "The sound could not be loaded: " + errorEvent.text;
        }
    }
}

Wczytuje dane dźwięku MP3 z obiektu ByteArray do obiektu Sound. Dane są odczytywane od bieżącego położenia obiektu ByteArray, a po zakończeniu operacji dla obiektu ByteArray jest ustawiane końcowe położenie zakresu o podanej długości w bajtach. Jeśli dane dźwięku MP3 zawierają dane ID3, podczas wywołania tej funkcji są wywoływane zdarzenia ID3. Ta funkcja wygeneruje wyjątek, jeśli obiekt ByteArray nie zawiera wystarczającej ilości danych.

Parametry

Wczytuje dane dźwięku PCM (32-bitowe wartości zmiennoprzecinkowe) z obiektu ByteArray do obiektu Sound. Dane są odczytywane od bieżącego położenia w obiekcie ByteArray, a po zakończeniu operacji dla obiektu ByteArray jest ustawiane końcowe położenie próbki o podanej długości w bajtach pomnożonej przez liczbę kanałów (1 lub 2 w przypadku ustawienia flagi dźwięku stereo).

Od wersji Flash Player 11.8 wprowadzono ograniczenie ilości danych dźwiękowych, jakie można przekazać do tej funkcji. W plikach SWF o wersji co najmniej 21 ta funkcja generuje wyjątek, jeśli ilość przekazanych do niej danych dźwiękowych obejmuje ponad 1800 sekund. Oznacza to, że stosunek liczby próbek do częstotliwości próbkowania nie powinien przekraczać 1800. W plikach SWF o wersji niższej niż 21 środowisko wykonawcze przestaje pracować, nie zgłaszając błędu, jeśli ilość przekazanych danych dźwiękowych obejmuje ponad 12 000 sekund. Ta funkcja jest dostępna tylko w celu zachowania zgodności wstecz.

Ta funkcja generuje wyjątek, jeśli obiekt ByteArray nie zawiera wystarczającej ilości danych.

Parametry

Generuje nowy obiekt SoundChannel, umożliwiający odtwarzanie dźwięku. Metoda zwraca obiekt SoundChannel, który umożliwia zatrzymanie dźwięku i kontrolowanie głośności po uzyskaniu do niego dostępu. (Aby kontrolować głośność, przesunięcie oraz balans, należy uzyskać dostęp do obiektu SoundTransform skojarzonego z kanałem dźwiękowym).

Parametry

Powiązane elementy interfejsu API

 
package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.MouseEvent;
    import flash.media.Sound;;
    import flash.net.URLRequest;
    import flash.media.SoundChannel;
    import flash.events.ProgressEvent;
    import flash.events.Event;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.IOErrorEvent;
    
    public class Sound_playExample1 extends Sprite {
        private var snd:Sound = new Sound();
        private var channel:SoundChannel = new SoundChannel();
        private var infoTextField:TextField = new TextField();
    
        public function Sound_playExample1() {

            var req:URLRequest = new URLRequest("MySound.mp3");
            
            infoTextField.autoSize = TextFieldAutoSize.LEFT;
            infoTextField.text = "Please wait for the file to be loaded.\n" 
                                + "Then select from the bar to decide where the file should start.";
            
            snd.load(req);               
            channel = snd.play();

            snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            snd.addEventListener(Event.COMPLETE, completeHandler);


            this.addChild(infoTextField);
        }

        private function completeHandler(event:Event):void {                
            infoTextField.text = "File is ready.";

            var bar:Sprite = new Sprite();

            bar.graphics.lineStyle(5, 0xFF0000);
            bar.graphics.moveTo(100, 100);
            bar.graphics.lineTo(200, 100);

            bar.addEventListener(MouseEvent.CLICK, clickHandler);

            this.addChild(bar);
        }
    
        private function clickHandler(event:MouseEvent):void {
            
                var position:uint = event.localX;
                var percent:uint = Math.round(position) - 100;   
                var cue:uint = (percent / 100) * snd.length;

                channel.stop();
                channel = snd.play(cue);    
        }

        private function errorHandler(errorEvent:IOErrorEvent):void {
            infoTextField.text = "The sound could not be loaded: " + errorEvent.text;
        }
    }
}

package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.media.Sound;
    import flash.net.URLRequest;

    public class Sound_playExample2 extends Sprite {
        private var button:Sprite = new Sprite(); 
        private var snd:Sound = new Sound();
            
        public function Sound_playExample2() {

            var req:URLRequest = new URLRequest("click.mp3");
            snd.load(req);               
     
            button.graphics.beginFill(0x00FF00);
            button.graphics.drawRect(10, 10, 50, 30);
            button.graphics.endFill();
     
            button.addEventListener(MouseEvent.CLICK, clickHandler);
            button.addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
     
            this.addChild(button);
        }

        private function clickHandler(event:MouseEvent):void {
            snd.play();            
        }

        private function doubleClickHandler(event:MouseEvent):void {
            snd.play(0, 2);        
        }
    }
}

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    
    public class Sound_playExample3 extends Sprite {
        private var snd:Sound = new Sound();
        private var channel:SoundChannel;
        private var statusTextField:TextField  = new TextField();

        public function Sound_playExample3(){

            statusTextField.autoSize = TextFieldAutoSize.LEFT;

           var req:URLRequest = new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3");
            
            try {
                snd.load(req);
            
                channel = snd.play();
            }
            catch (err:Error) {
                trace(err.message);
            }
                    
            snd.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            addEventListener(Event.ENTER_FRAME, enterFrameHandler);
            channel.addEventListener(Event.SOUND_COMPLETE, soundCompleteHandler);
                    
            this.addChild(statusTextField);
        }
    
        private function enterFrameHandler(event:Event):void {    
            var loadTime:Number = snd.bytesLoaded / snd.bytesTotal;
            var loadPercent:uint = Math.round(100 * loadTime);
            var estimatedLength:int = Math.ceil(snd.length / (loadTime));
            var playbackPercent:uint = Math.round(100 * (channel.position / estimatedLength));
      
            statusTextField.text = "Sound file's size is " + snd.bytesTotal + " bytes.\n" 
                                   + "Bytes being loaded: " + snd.bytesLoaded + "\n" 
                                   + "Percentage of sound file that is loaded " + loadPercent + "%.\n"
                                   + "Sound playback is " + playbackPercent + "% complete.";     
        }
 
        private function errorHandler(errorEvent:IOErrorEvent):void {
            statusTextField.text = "The sound could not be loaded: " + errorEvent.text;
        }

        private function soundCompleteHandler(event:Event):void {
            statusTextField.text = "The sound has finished playing.";
            removeEventListener(Event.ENTER_FRAME, enterFrameHandler);
        }
    }
}

Wywoływane po pomyślnym wczytaniu danych.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane przez obiekt Sound, gdy są dostępne dane ID3 dotyczące dźwięku MP3.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływana, gdy wystąpi błąd wejścia lub wyjścia uniemożliwiający wczytywanie danych.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane po rozpoczęciu ładowania.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane w trakcie stopniowego wczytywania danych.

To zdarzenie ma następujące właściwości:

Powiązane elementy interfejsu API

Wywoływane, gdy środowisko wykonawcze zażąda nowych danych audio.

To zdarzenie ma następujące właściwości:

var mySound:Sound = new Sound();
function sineWaveGenerator(event:SampleDataEvent):void {
    for ( var c:int=0; c<8192; c++ ) {
        event.data.writeFloat(Math.sin((Number(c+event.position)/Math.PI/2))*0.25);
        event.data.writeFloat(Math.sin((Number(c+event.position)/Math.PI/2))*0.25);
    }
}

mySound.addEventListener(SampleDataEvent.SAMPLE_DATA,sineWaveGenerator);
mySound.play();

Powiązane elementy interfejsu API