SoundMixer  - AS3

Określa tryb odtwarzania dźwięku dla wszystkich obiektów Sound. Na urządzeniach przenośnych ta właściwość powoduje ustawienie priorytetów i wartości domyślnych dotyczących dźwięku zgodnie z wartościami właściwymi dla danej platformy. Na komputerach i urządzeniach telewizyjnych nie ma różnicy między trybami odtwarzania dźwięku.

Poprawne wartości dla tej właściwości są zdefiniowane w klasie AudioPlaybackMode.

Uwaga: W systemie iOS jeśli aplikacja ustawi tryb audioPlaybackMode=AudioPlaybackMode.VOICE, inne aplikacje nie mogą zmienić trybu AudioPlaybackMode.MEDIA.

W celu umożliwienia innym aplikacjom odtwarzania w trybie multimediów należy jak najkrócej używać trybu AudioPlaybackMode.VOICE i przełączać aplikację do trybu AudioPlaybackMode.MEDIA zaraz po zakończeniu połączenia głosowego.

Zmiana trybu odtwarzania dźwięków w systemie iOS powoduje chwilowe wstrzymanie odtwarzania muzyki w aplikacjach natywnych.

Wartością domyślną jest AudioPlaybackMode.MEDIA.

Powiązane elementy interfejsu API

Czas (w sekundach) wstępnego załadowania osadzonego dźwięku do bufora przed rozpoczęciem generowania strumienia dźwiękowego. Plik, który znajduje się w innej domenie nie może uzyskać dostępu do danych w ładowanym dźwięku (łącznie z jego czasem buforowania), chyba że zostanie zaimplementowany międzydomenowy plik reguł. Więcej informacji o zabezpieczeniach i dźwięku zawiera opis klasy Sound. Kod pliku, który znajduje się w innej domenie nie może uzyskać dostępu do danych w ładowanym dźwięku (łącznie z jego czasem buforowania), chyba że zostanie zaimplementowany międzydomenowy plik reguł. Jednak w obszarze izolowanym aplikacji AIR kod może mieć dostęp do danych plików dźwiękowych z dowolnego źródła. Więcej informacji o zabezpieczeniach i dźwięku zawiera opis klasy Sound.

Właściwość SoundMixer.bufferTime wpływa jedynie na czas buforowania strumieni dźwiękowych osadzonych w pliku SWF i jest niezależna od dynamicznie tworzonych obiektów klasy Sound (tj. obiektów klasy Sound tworzonych w języku ActionScript). Wartość właściwości SoundMixer.bufferTime nie może nadpisywać lub ustawiać wartości domyślnej czasu buforowania określonego w obiekcie SoundLoaderContext, który przekazywany jest do metodySound.load().

Powiązane elementy interfejsu API

Obiekt SoundTransform, który kontroluje globalne właściwości dźwięku. Obiekt SoundTransform zawiera właściwości umożliwiające ustawianie głośności, przesunięcia oraz przypisywanie lewego i prawego głośnika. Użycie obiektu SoundTransform w tej właściwości umożliwia zastosowanie ostatecznych ustawień dźwięku dla wszystkich dźwięków po zastosowaniu indywidualnych ustawień dla każdego z nich.

Powiązane elementy interfejsu API

Włącza lub wyłącza funkcję telefonu głośnomówiącego, gdy urządzenie znajduje się w trybie głosowym. Smartfony domyślnie używają słuchawki telefonu jako wyjścia dźwięku, kiedy właściwość SoundMixer.audioPlaybackMode jest ustawiona na AudioPlaybackMode.VOICE. Właściwość useSpeakerphoneForVoice umożliwia nadpisanie domyślnego wyjścia, dzięki czemu można zaimplementować przycisk telefonu głośnomówiącego w aplikacji na telefonie. Ta właściwość nie ma żadnego znaczenia w przypadku trybów innych niż AudioPlaybackMode.VOICE. Na komputerach i urządzeniach telewizyjnych ta właściwość nie ma żadnego znaczenia.

Uwaga: W systemie iOS jeśli aplikacja ustawiła tryb audioPlaybackMode=VOICE i inna aplikacja również odtwarza w trybie głosowym, nie można ustawić trybu useSpeakerphoneForVoice=true.

Uwaga: Aby ta wartość była uwzględniana w systemie Android, należy ustawić parametr android.permission.MODIFY_AUDIO_SETTINGS deskryptora aplikacji AIR. To ustawienie obowiązuje globalnie na urządzeniu. Inne aplikacje działające na urządzeniu mogą w każdej chwili zmienić to ustawienie.

Wartością domyślną jest false.

Powiązane elementy interfejsu API

Wskazuje, czy ze względów bezpieczeństwa pewne dźwięki są niedostępne. Przykład: dźwięk ładowany z domeny innej, niż domena zawierająca treść, która wywołuje tę metodę, jest niedostępny, jeśli serwer tego dźwięku nie posiada pliku reguł URL, który przyznaje dostęp do domeny dla tej domeny. Dźwięk można nadal załadować i odtworzyć, lecz operacje niskiego poziomu takie, jak pobieranie metadanych ID3, nie będą wykonywane na niedostępnych dźwiękach.

Dla treści aplikacji AIR w obszarze izolowanym aplikacji wywołanie tej metody zawsze powoduje zwrócenie wartości false. Wszystkie dźwięki, łącznie z tymi załadowanymi z innych domen, są dostępne dla treści w obszarze izolowanym aplikacji.

Powiązane elementy interfejsu API

Pozwala zarejestrować bieżącą falę dźwiękową i umieścić ją w określonym obiekcie ByteArray. Wartości są formatowane do postaci znormalizowanych wartości zmiennoprzecinkowych z zakresu od -1,0 do 1,0. Obiekt ByteArray przekazany do parametru outputArray jest nadpisywany nowymi wartościami. Rozmiar utworzonego obiektu ByteArray jest stały i wynosi 512 wartości zmiennoprzecinkowych, z których pierwsze 256 wartości reprezentuje lewy kanał, a kolejne 256 kanał prawy.

Uwaga: Metoda podlega ograniczeniom wynikającym z zabezpieczeń plików lokalnych oraz ograniczeń ładowania międzydomenowego. Pracując z lokalnymi plikami lub dźwiękami ładowanymi z serwera z innej domeny, niż ta z której są wywoływane, użytkownik może być zmuszony do rozwiązania kwestii ograniczeń obszaru izolowanego za pomocą międzydomenowego pliku reguł. Aby uzyskać więcej informacji na ten temat, należy zapoznać się z opisem klasy Sound. Ponadto ta metoda nie może zostać użyta do wyodrębnienia danych ze strumieni RTMP, nawet jeśli zostanie wywołana przez treść, która znajduje się w tej samej domenie co serwer RTMP.

Ta metoda jest obsługiwana przez protokół RTMP w programie Flash Player 9.0.115.0 i nowszych wersjach oraz w środowisku Adobe AIR. Istnieje możliwość sterowania dostępem do strumieni na serwerze z oprogramowaniem Flash Media Server za pomocą skryptu po stronie serwera. Aby uzyskać·więcej informacji na ten temat, należy zapoznać się z właściwościami Client.audioSampleAccess oraz Client.videoSampleAccess znajdującymi się w publikacji Server-Side ActionScript Language Reference for Adobe Flash Media Server.

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.Event;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.net.URLRequest;
    import flash.utils.ByteArray;
    import flash.text.TextField;

    public class SoundMixer_computeSpectrumExample extends Sprite {

        public function SoundMixer_computeSpectrumExample() {
            var snd:Sound = new Sound();
            var req:URLRequest = new URLRequest("Song1.mp3");
            snd.load(req);
            
            var channel:SoundChannel;
            channel = snd.play();
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
            channel.addEventListener(Event.SOUND_COMPLETE, onPlaybackComplete);
        }

        private function onEnterFrame(event:Event):void {
            var bytes:ByteArray = new ByteArray();
            const PLOT_HEIGHT:int = 200;
            const CHANNEL_LENGTH:int = 256;

            SoundMixer.computeSpectrum(bytes, false, 0);
            
            var g:Graphics = this.graphics;
            
            g.clear();
       
            g.lineStyle(0, 0x6600CC);
            g.beginFill(0x6600CC);
            g.moveTo(0, PLOT_HEIGHT);
            
            var n:Number = 0;
            
            for (var i:int = 0; i < CHANNEL_LENGTH; i++) {
                n = (bytes.readFloat() * PLOT_HEIGHT);
                g.lineTo(i * 2, PLOT_HEIGHT - n);
            }

            g.lineTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
            g.endFill();
 
            g.lineStyle(0, 0xCC0066);
            g.beginFill(0xCC0066, 0.5);
            g.moveTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
            
            for (i = CHANNEL_LENGTH; i > 0; i--) {
                n = (bytes.readFloat() * PLOT_HEIGHT);
                g.lineTo(i * 2, PLOT_HEIGHT - n);
            }
  
            g.lineTo(0, PLOT_HEIGHT);
            g.endFill();
        }
        
        private function onPlaybackComplete(event:Event):void {
            removeEventListener(Event.ENTER_FRAME, onEnterFrame);
        }
    }
}

Powoduje zatrzymanie odtwarzania wszystkich aktualnych dźwięków.

>W programie Flash Professional ta metoda nie powoduje zatrzymania głowicy odtwarzania. Odtwarzanie dźwięków umieszczonych w strumieniu zostanie wznowione, gdy głowica odtwarzania przesunie się do klatek, w których są umieszczone.

Korzystając z tej właściwości, należy wziąć pod uwagę następujący model zabezpieczeń:

• Domyślnie wywołanie metody SoundMixer.stopAll() zatrzymuje odtwarzanie dźwięków jedynie w tym samym obszarze izolowanym, co obiekt wywołujący metodę. Dźwięki, których odtwarzanie nie zostało rozpoczęte z tego samego obszaru izolowanego, co obiekt, nie zostaną zatrzymane.
• Wczytując dźwięk za pomocą metody load() klasy Sound, można określić parametr context, który jest obiektem SoundLoaderContext. Jeśli właściwości checkPolicyFile obiektu SoundLoaderContext zostanie przypisana wartość true, program Flash Player lub środowisko AIR sprawdzi istnienie międzydomenowego pliku reguł na serwerze, z którego jest ładowany dźwięk. Jeśli na serwerze znajduje się międzydomenowy plik reguł i plik zezwala na dostęp domenie zawierającej treść wywołującą, wtedy plik może zatrzymać ładowany dźwięk za pomocą metody SoundMixer.stopAll(); w innym przypadku nie może.

Jednak w aplikacji Adobe AIR zawartość obszaru izolowanego application (zawartość instalowana razem z aplikacją AIR) nie jest ograniczana przez te reguły zabezpieczeń.

Więcej informacji na temat zabezpieczeń zawiera odpowiedni temat w Centrum programistów programu Flash Player w kategorii Bezpieczeństwo.

package {
    import flash.display.Sprite;
    import flash.net.URLRequest;
    import flash.media.Sound;
    import flash.media.SoundLoaderContext;
    import flash.media.SoundChannel;
    import flash.media.SoundMixer;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.events.IOErrorEvent;

    public class SoundMixer_stopAllExample extends Sprite  {
        private var firstSound:Sound = new Sound();
        private var secondSound:Sound = new Sound();
        private var muteButton:TextField = new TextField();
        private var channel1:SoundChannel = new SoundChannel();
        
        public function SoundMixer_stopAllExample() {
            firstSound.load(new URLRequest("mySound.mp3"));
            secondSound.load(new URLRequest("http://av.adobe.com/podcast/csbu_dev_podcast_epi_2.mp3"));

            firstSound.addEventListener(IOErrorEvent.IO_ERROR, firstSoundErrorHandler);
            secondSound.addEventListener(IOErrorEvent.IO_ERROR, secondSoundErrorHandler);
            
            channel1 = firstSound.play();
            secondSound.play();
            
            muteButton.autoSize = TextFieldAutoSize.LEFT;
            muteButton.border = true;
            muteButton.background = true;
            muteButton.text = "MUTE";
        
            muteButton.addEventListener(MouseEvent.CLICK, muteButtonClickHandler);         
        
            this.addChild(muteButton);
        }

        private function muteButtonClickHandler(event:MouseEvent):void {

            if(muteButton.text == "MUTE") {        
  
                if(SoundMixer.areSoundsInaccessible() == false) {
                    SoundMixer.stopAll();
                    muteButton.text = "click to play only one of sound.";
                }
                else {
                    muteButton.text = "The sounds are not accessible.";
                }
            }
           else {
                firstSound.play();        
                muteButton.text = "MUTE";
           }
        } 

        private function firstSoundErrorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }

        private function secondSoundErrorHandler(errorEvent:IOErrorEvent):void {
            trace(errorEvent.text);
        }
    }
}