BitmapData  - AS3

Wysokość obrazu bitmapowego w pikselach.

Prostokąt definiujący wymiary i położenie obrazu bitmapowego. Góra i lewa strona prostokąta mają wartość 0; szerokość i wysokość są równe szerokości i wysokości obiektu BitmapData.

Określa, czy obraz bitmapowy obsługuje przezroczystość poszczególnych pikseli. Możliwe jest ustawienie tej wartości tylko w przypadku konstruowania obiektu BitmapData przez podanie wartości true dla parametru transparent konstruktora. Następnie, po utworzeniu obiektu BitmapData, możliwe jest sprawdzenie obsługi przezroczystości na poziomie poszczególnych pikseli. W tym celu należy sprawdzić, czy właściwość transparent ma wartość true.

Szerokość obrazu bitmapowego w pikselach.

Tworzy obiekt BitmapData o określonej wysokości i szerokości. W przypadku określenia wartości parametru fillColor każdy piksel bitmapy zostanie ustawiony na ten kolor.

Domyślnie bitmapa jest tworzona jako przezroczysta, chyba że zostanie podana wartość false dla parametru transparent. Po utworzeniu nieprzezroczystej bitmapy nie jest możliwa zmiana jej na bitmapę przezroczystą. Każdy piksel na bitmapie nieprzezroczystej wykorzystuje tylko 24 bity informacji kanałów kolorów. Po zdefiniowaniu bitmapy jako przezroczystej każdy piksel wykorzystuje 32 bity informacji kanałów kolorów, włącznie z kanałem przezroczystości alpha.

W środowisku AIR 1.5 i programie Flash Player 10 maksymalna szerokość i wysokość obiektu BitmapData wynosi 8191, a łączna liczba pikseli nie może przekroczyć 16 777 215. (A zatem, jeśli obiekt BitmapData ma szerokość 8,191 pikseli, nie może być wyższy niż 2048 pikseli). W programie Flash Player 9 lub nowszym i środowisku AIR 1.1 lub nowszym obowiązuje ograniczenie do 2880 pikseli wysokości i szerokości. Przy określeniu wartości szerokości lub wysokości większej niż 2880 nowa instancja nie zostanie utworzona.

Pobiera obraz źródłowy i filtr, a następnie generuje obraz filtrowany.

Ta metoda opiera się na zachowaniu wbudowanych obiektów filtra, które określa prostokąt docelowy, na który ma wpływ prostokąt źródła wprowadzania.

Po zastosowaniu filtra obraz wynikowy może być większy niż obraz wejściowy. Na przykład przy użyciu klasy BlurFilter w celu rozmycia prostokąta źródłowego o współrzędnych (50, 50,100,100) oraz punkcie docelowym (10, 10), obszar który ulega zmianie w obrazie docelowym jest większy niż (10, 10, 60, 60) ze względu na rozmycie. Dzieje się to wewnętrznie w trakcie wywołania metody applyFilter().

Jeżeli parametrsourceRect parametru sourceBitmapData jest obszarem wewnętrznym, jak na przykład (50, 50, 100, 100) w obrazie wielkości 200 x 200, wówczas filtr wykorzystuje piksele spoza parametru sourceRect w celu wygenerowania prostokąta docelowego.

Jeżeli obiekt BitmapData oraz obiekt określony jako parametr sourceBitmapData są tym samym obiektem, wówczas aplikacja wykorzystuje tymczasową kopię obiektu w celu przeprowadzenia filtrowania. Najlepiej jest nie dopuszczać do takiej sytuacji.

Parametry

Powiązane elementy interfejsu API

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.filters.BlurFilter;

var bmd:BitmapData = new BitmapData(80, 30, false, 0xFFCC00);
var rect:Rectangle = new Rectangle(10, 10, 40, 10);
bmd.fillRect(rect, 0xFF0000);

var pt:Point = new Point(10, 10);
var filter:BlurFilter = new BlurFilter();
bmd.applyFilter(bmd, rect, pt, filter);

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Zwraca nowy obiekt BitmapData, który jest klonem oryginalnej instancji z dokładną kopią zawartej bitmapy.

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd1:BitmapData = new BitmapData(100, 80, false, 0x00000000);
var bmd2:BitmapData = bmd1.clone();

bmd1.setPixel32(1, 1, 0xFFFFFFFF);

trace(bmd1.getPixel32(1, 1).toString(16)); // ffffffff
trace(bmd2.getPixel32(1, 1).toString(16)); // ff000000

var bm1:Bitmap = new Bitmap(bmd1);
this.addChild(bm1);

var bm2:Bitmap = new Bitmap(bmd2);
bm2.x = 110;
this.addChild(bm2);

Dopasowuje wartości kolorów w określonym obszarze obrazu bitmapowego poprzez wykorzystanie obiektu ColorTransform. Jeżeli prostokąt pasuje pod względem granic do obrazu bitmapowego, wówczas ta metoda transformuje wartości kolorów dla całego obrazu.

Parametry

Powiązane elementy interfejsu API

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.ColorTransform;

var bmd:BitmapData = new BitmapData(80, 30, false, 0xFF0000);

var cTransform:ColorTransform = new ColorTransform();
cTransform.alphaMultiplier = 0.5
var rect:Rectangle = new Rectangle(0, 0, 40, 30);
bmd.colorTransform(rect, cTransform);

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Porównuje dwa obiekty BitmapData. Jeżeli dwa obiekty BitmapData mają te same wymiary (szerokość i wysokość), wówczas metoda zwraca nowy obiekt BitmapData, w którym każdy piksel jest "różnicą" pomiędzy pikselami dwóch obiektów źródłowych:

• Jeżeli oba piksele są równe, piksel różnicy ma wartość 0x00000000.
• Jeżeli oba piksele mają różne wartości RGB (pomijając wartość alpha), wówczas piksel różnicy ma wartość 0xRRGGBB, gdzie RR/GG/BB są indywidualnymi wartościami różnicy między kanałami koloru czerwonego, zielonego i niebieskiego (wartość pikseli w obiekcie źródłowym minus wartość pikseli w obiekcie otherBitmapData). Różnice dotyczące kanału alpha są w tym przypadku pomijane.
• Jeżeli tylko wartość kanału alpha się różni, wówczas wartość pikseli wynosi 0xZZFFFFF, gdzie ZZ jest różnicą wartości alpha (wartość alpha w obiekcie źródłowym minus wartość alpha w obiekcie otherBitmapData).

Można na przykład przeanalizować poniższe dwa obiekty BitmapData:

     var bmd1:BitmapData = new BitmapData(50, 50, true, 0xFFFF8800);
     var bmd2:BitmapData = new BitmapData(50, 50, true, 0xCCCC6600);
     var diffBmpData:BitmapData = bmd1.compare(bmd2) as BitmapData;
     trace ("0x" + diffBmpData.getPixel(0,0).toString(16); // 0x332200
     

Uwaga: Kolory wykorzystane do wypełnienia dwóch obiektów BitmapData mają nieco inne wartości RGB (0xFF0000 i 0xFFAA00). Wynikiem metody compare() jest nowy obiekt BitmapData, gdzie każdy piksel wykazuje różnicę w wartościach RGB między dwoma bitmapami.

Biorąc pod uwagę poniższe dwa obiekty BitmapData, w których kolory RGB są takie same, ale różne są wartości alpha:

     var bmd1:BitmapData = new BitmapData(50, 50, true, 0xFFFFAA00);
     var bmd2:BitmapData = new BitmapData(50, 50, true, 0xCCFFAA00);
     var diffBmpData:BitmapData = bmd1.compare(bmd2) as BitmapData;
     trace ("0x" + diffBmpData.getPixel32(0,0).toString(16); // 0x33ffffff
     

Wynikiem metody compare() jest nowy obiekt BitmapData, gdzie każdy piksel wykazuje różnicę w wartościach właściwości alpha między dwoma bitmapami.

Jeżeli obiekty BitmapData są swoimi odpowiednikami (ta sama szerokość i wysokość oraz identyczne wartości pikseli), wówczas metoda zwraca liczbę 0.

Jeżeli szerokości obiektów BitmapData nie są równe, wówczas metoda zwraca liczbę -3.

Jeżeli wysokości obiektów BitmapData nie są równe, ale szerokości są takie same, wówczas metoda zwraca liczbę -4.

Poniższy przykład ilustruje porównanie dwóch obiektów Bitmap o różnych szerokościach (50 i 60):

     var bmd1:BitmapData = new BitmapData(100, 50, false, 0xFFFF0000);
     var bmd2:BitmapData = new BitmapData(100, 60, false, 0xFFFFAA00);
     trace(bmd1.compare(bmd2)); // -4
     

Parametry

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd1:BitmapData = new BitmapData(50, 50, true, 0xFFFFAA00);
var bmd2:BitmapData = new BitmapData(50, 50, true, 0xCCFFAA00);
var diffBmpData:BitmapData = BitmapData(bmd1.compare(bmd2));
var diffValue:String = diffBmpData.getPixel32(1, 1).toString(16);
trace (diffValue); // 33ffffff

var bm1:Bitmap = new Bitmap(bmd1);
addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
addChild(bm2);
bm2.x = 60;

Przenosi dane z jednego kanału innego obiektu BitmapData lub bieżącego obiektu BitmapData na kanał w bieżącym obiekcie BitmapData. Wszelkie dane z innych kanałów w obiekcie docelowym BitmapData są zachowane.

Źródłowe wartości kanałów oraz docelowe wartości kanałów mogą mieć następujące wartości:

• BitmapDataChannel.RED
• BitmapDataChannel.GREEN
• BitmapDataChannel.BLUE
• BitmapDataChannel.ALPHA

Parametry

Powiązane elementy interfejsu API

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var bmd:BitmapData = new BitmapData(100, 80, false, 0x00FF0000);

var rect:Rectangle = new Rectangle(0, 0, 20, 20);
var pt:Point = new Point(10, 10);
bmd.copyChannel(bmd, rect, pt, BitmapDataChannel.RED, BitmapDataChannel.BLUE);

var bm:Bitmap = new Bitmap(bmd);
this.addChild(bm);    

Zapewnia szybką procedurę do manipulowania pikselami między różnymi obrazami, bez rozciągania, obrotu ani efektów kolorystycznych. Ta metoda kopiuje prostokątny obszar obrazu źródłowego do obszaru prostokątnego o tym samym rozmiarze w punkcie docelowym obiektu BitmapData.

W przypadku zawarcia parametrów alphaBitmap oraz alphaPoint możliwe jest wykorzystanie drugorzędnego obrazu jako źródła właściwości alpha dla obrazu źródłowego. Jeżeli obraz źródłowy posiada dane alpha, wówczas oba zestawy tych danych są wykorzystywane do składania pikseli z obrazu źródłowego do obrazu docelowego. Parametr alphaPoint jest punktem w obrazie alpha, który odpowiada górnemu lewemu narożnikowi prostokąta źródłowego. Wszelkie piksele znajdujące się poza przecięciem obrazu źródłowego i obrazu alpha nie są kopiowane do obrazu docelowego.

Właściwość mergeAlpha kontroluje, czy kanał alpha jest lub nie jest wykorzystywany przy kopiowaniu jednego przezroczystego obrazu na drugi. W celu skopiowania pikseli z danymi kanału alpha należy ustawić właściwość mergeAlpha na wartość true. Domyślnie właściwość mergeAlpha ma wartość false.

Parametry

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var bmd1:BitmapData = new BitmapData(40, 40, false, 0x000000FF);
var bmd2:BitmapData = new BitmapData(80, 40, false, 0x0000CC44);

var rect:Rectangle = new Rectangle(0, 0, 20, 20);
var pt:Point = new Point(10, 10);
bmd2.copyPixels(bmd1, rect, pt);

var bm1:Bitmap = new Bitmap(bmd1);
this.addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
this.addChild(bm2);
bm2.x = 50;

Wypełnia tablicę bajtów na podstawie prostokątnego obszaru pikseli. Ta metoda zapisuje w tablicy bajtów liczbę całkowitą bez znaku (32-bitową niepomnożoną wartość pikseli) dla każdego piksela, rozpoczynając od indeksu position obiektu ByteArray. Jeśli jest to niezbędne, rozmiar tablicy bajtów zostaje zwiększony do liczby bajtów wymaganej w celu zapisania wszystkich danych pikseli.

Parametry

Powiązane elementy interfejsu API

Zwalnia pamięć używaną do przechowywania danego obiektu typu BitmapData.

W przypadku wywołania metody dispose() na obrazie, jego szerokość i wysokość zostają ustawione na 0. Wszelkie kolejne wywołania do metod lub właściwości tej instancji BitmapData zakończą się niepowodzeniem oraz zgłoszone zostaną wyjątki.

Metoda BitmapData.dispose() niezwłocznie zwalnia pamięć zajętą przez faktyczne dane bitmapowe (jedna bitmapa może zajmować maksymalnie 64 MB pamięci). Po użyciu metody BitmapData.dispose() obiekt BitmapData nie może być już używany, środowisko wykonawcze Flash wygeneruje wyjątek przy próbie wywołania funkcji tego obiektu. Jednak metoda BitmapData.dispose() nie porządkuje pamięci po obiekcie BitmapData (pozostawiając około 128 bajtów); pamięć zajęta przez obiekt BitmapData jest zwalniana w momencie usunięcia tego obiektu przez proces porządkowania pamięci.

Powiązane elementy interfejsu API

import flash.display.BitmapData;

var myBitmapData:BitmapData = new BitmapData(100, 80, false, 0x000000FF);
trace(myBitmapData.getPixel(1, 1)); // 255 == 0xFF

myBitmapData.dispose();
try {
    trace(myBitmapData.getPixel(1, 1));
} catch (error:Error) {
    trace(error); // ArgumentError
}

Rysuje obiekt wyświetlany source na obrazie bitmapowym za pomocą wektorowego mechanizmu renderującego środowiska wykonawczego Flash. Możliwe jest określenie parametrów matrix, colorTransform, blendMode oraz docelowego parametru clipRect w celu kontrolowania wydajności renderowania. Opcjonalnie możliwe jest określenie, czy bitmapa powinna być wygładzana w trakcie skalowania (jest to możliwe tylko, gdy obiektem źródłowym jest obiekt BitmapData).

Uwaga: Metoda drawWithQuality() działa analogicznie do metody draw(), ale zamiast określać jakość renderowania grafiki wektorowej na podstawie właściwości Stage.quality, umożliwia podanie przy wywołaniu parametru quality.

Ta metoda odpowiada bezpośrednio za sposób, w jaki obiekty są rysowane przy pomocy mechanizmu renderującego wektory standardowe dla obiektów w interfejsie narzędzi autoryzacyjnych.

Źródłowy obiekt wyświetlany nie wykorzystuje żadnych zastosowanych transformacji dla tego wywołania. Jest on traktowany jakby istniał w bibliotece lub pliku, bez transformacji macierzy, transformacji kolorów czy trybu mieszania. W celu narysowania obiektu wyświetlanego (jak na przykład klip filmowy) przy wykorzystaniu jego własnych właściwości transformacji, możliwe jest skopiowanie jego obiektu właściwości transform do właściwości transform obiektu Bitmap korzystającego z obiektu BitmapData.

Ta metoda jest obsługiwana przy użyciu protokołu RTMP w programie Flash Player 9.0.115.0 i nowszych wersjach oraz w środowisku Adobe AIR. Istnieje możliwość sterowania dostępem do strumieni na serwerze z oprogramowaniem Flash Media Server za pomocą skryptu po stronie serwera. Więcej informacji na ten temat zawierają opisy właściwości Client.audioSampleAccess oraz Client.videoSampleAccess w publikacji Dokumentacja języka ActionScript po stronie serwera dla programu Flash Media Server.

Jeśli obiekt źródłowy oraz (w przypadku obiektu Sprite lub MovieClip) wszystkie jego obiekty podrzędne nie pochodzą z tej samej domeny, co treść wywołująca, lub nie należą do treści udostępnionej dla treści wywołującej za pomocą metody Security.allowDomain(), wywołanie metody draw() spowoduje wygenerowanie wyjątku SecurityError. To ograniczenie nie ma zastosowania do zawartości AIR w obszarze izolowanym aplikacji.

Obowiązują także ograniczenia w wykorzystaniu załadowanego obrazu bitmapowego jako obiektu source. Wywołanie metody draw() kończy się powodzeniem, jeśli załadowany obraz pochodzi z tej samej domeny, co treść wywołująca. Ponadto międzydomenowy plik zasad na serwerze obrazu może nadać uprawnienia domenie treści SWF wywołującej metodę draw(). W tym przypadku należy ustawić właściwość checkPolicyFile obiektu LoaderContext i użyć tego obiektu jako parametru context w wywołaniu metody load() obiektu Loader wykorzystywanego do załadowania obrazu. Te ograniczenia nie ma zastosowania do treści AIR w obszarze izolowanym zabezpieczeń aplikacji.

W systemie Windows metoda draw() nie umożliwia przechwytywania treści SWF osadzonej w stronie HTML w obiekcie HTMLLoader w środowisku Adobe AIR.

Metoda draw() nie umożliwia przechwytywania treści PDF w środowisku Adobe AIR. Nie umożliwia także przechwytywania treści SWF osadzonej w kodzie HTML, gdy atrybut wmode jest ustawiony "window" (w środowisku Adobe AIR).

Parametry

Powiązane elementy interfejsu API

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.text.TextField;

var tf:TextField = new TextField();
tf.text = "bitmap text";

var myBitmapData:BitmapData = new BitmapData(80, 20);
myBitmapData.draw(tf);
var bmp:Bitmap = new Bitmap(myBitmapData);
this.addChild(bmp);

Rysuje obiekt wyświetlany source na obrazie bitmapowym za pomocą wektorowego mechanizmu renderującego środowiska wykonawczego Flash. Możliwe jest określenie parametrów matrix, colorTransform, blendMode oraz docelowego parametru clipRect w celu kontrolowania wydajności renderowania. Opcjonalnie możliwe jest określenie, czy bitmapa powinna być wygładzana w trakcie skalowania (jest to możliwe tylko, gdy obiektem źródłowym jest obiekt BitmapData).

Uwaga: Metoda drawWithQuality() działa analogicznie do metody draw(), ale zamiast określać jakość renderowania grafiki wektorowej na podstawie właściwości Stage.quality, umożliwia podanie przy wywołaniu parametru quality.

Ta metoda odpowiada bezpośrednio za sposób, w jaki obiekty są rysowane przy pomocy mechanizmu renderującego wektory standardowe dla obiektów w interfejsie narzędzi autoryzacyjnych.

Źródłowy obiekt wyświetlany nie wykorzystuje żadnych zastosowanych transformacji dla tego wywołania. Jest on traktowany jakby istniał w bibliotece lub pliku, bez transformacji macierzy, transformacji kolorów czy trybu mieszania. W celu narysowania obiektu wyświetlanego (jak na przykład klip filmowy) przy wykorzystaniu jego własnych właściwości transformacji, możliwe jest skopiowanie jego obiektu właściwości transform do właściwości transform obiektu Bitmap korzystającego z obiektu BitmapData.

Ta metoda jest obsługiwana przy użyciu protokołu RTMP w programie Flash Player 9.0.115.0 i nowszych wersjach oraz w środowisku Adobe AIR. Istnieje możliwość sterowania dostępem do strumieni na serwerze z oprogramowaniem Flash Media Server za pomocą skryptu po stronie serwera. Więcej informacji na ten temat zawierają opisy właściwości Client.audioSampleAccess i Client.videoSampleAccess znajdujące się na stronie Dokumentacja języka ActionScript po stronie serwera dla programu Flash Media Server.

Jeśli obiekt źródłowy oraz (w przypadku obiektu Sprite lub MovieClip) wszystkie jego obiekty podrzędne nie pochodzą z tej samej domeny co element wywołujący albo nie należą do zawartości udostępnionej dla elementu wywołującego za pomocą metody Security.allowDomain(), wywołanie metody drawWithQuality() powoduje wygenerowanie wyjątku SecurityError. To ograniczenie nie ma zastosowania do zawartości AIR w obszarze izolowanym aplikacji.

Obowiązują także ograniczenia w wykorzystaniu załadowanego obrazu bitmapowego jako obiektu source. Wywołanie metody drawWithQuality() kończy się powodzeniem, jeśli wczytany obraz pochodzi z tej samej domeny co element wywołujący. Ponadto plik zasad międzydomenowych na serwerze obrazu może nadać uprawnienia domenie zawartości SWF wywołującej metodę drawWithQuality(). W tym przypadku należy ustawić właściwość checkPolicyFile obiektu LoaderContext i użyć tego obiektu jako parametru context w wywołaniu metody load() obiektu Loader wykorzystywanego do załadowania obrazu. Te ograniczenia nie ma zastosowania do treści AIR w obszarze izolowanym zabezpieczeń aplikacji.

W systemie Windows metoda drawWithQuality() nie umożliwia przechwytywania zawartości SWF osadzonej na stronie HTML w obiekcie HTMLLoader w środowisku Adobe AIR.

Metoda drawWithQuality() nie umożliwia przechwytywania zawartości PDF w środowisku Adobe AIR. Nie umożliwia także przechwytywania treści SWF osadzonej w kodzie HTML, gdy atrybut wmode jest ustawiony "window" (w środowisku Adobe AIR).

Parametry

Powiązane elementy interfejsu API

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.text.TextField;

var tf:TextField = new TextField();
tf.text = "bitmap text";

var myBitmapData:BitmapData = new BitmapData(80, 20);
myBitmapData.drawWithQuality(tf, , , , , , StageQuality.LOW);
var bmp:Bitmap = new Bitmap(myBitmapData);
this.addChild(bmp);

Kompresuje ten obiekt BitmapData przy użyciu wybranego algorytmu kompresji i zwraca nowy obiekt ByteArray. Opcjonalnie zapisuje dane wynikowe w podanym obiekcie ByteArray. Argument compressor określa algorytm kodowania. Może mieć wartość PNGEncoderOptions, JPEGEncoderOptions lub JPEGXREncoderOptions.

Poniższy przykładowy kod kompresuje obiekt BitmapData przy użyciu parametru JPEGEncoderOptions:

     // Compress a BitmapData object as a JPEG file.
     var bitmapData:BitmapData = new BitmapData(640,480,false,0x00FF00);
     var byteArray:ByteArray = new ByteArray();
     bitmapData.encode(new Rectangle(0,0,640,480), new flash.display.JPEGEncoderOptions(), byteArray); 

Parametry

Powiązane elementy interfejsu API

Wypełnia obszar prostokątny pikselami o określonym kolorze ARGB.

Parametry

Powiązane elementy interfejsu API

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;

var myBitmapData:BitmapData = new BitmapData(40, 40, false, 0x0000FF00);

var rect:Rectangle = new Rectangle(0, 0, 20, 20);
myBitmapData.fillRect(rect, 0x0000FF);

var bm:Bitmap = new Bitmap(myBitmapData);
addChild(bm);

Przeprowadza operację wypełniania jednolitego, zaczynając od punktu na współrzędnych (x, y) i wypełniając wybranym kolorem. Metoda floodFill() jest podobna do narzędzia wiadra z farbą, wykorzystywanego w różnych programach graficznych. Kolorem jest kolor ARGB zawierający informacje dotyczące wartości parametru alpha.

Parametry

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;

var myBitmapData:BitmapData = new BitmapData(40, 40, false, 0x0000FF00);

var rect:Rectangle = new Rectangle(0, 0, 20, 20);
myBitmapData.fillRect(rect, 0x000000FF);
rect = new Rectangle(15, 15, 25, 25);
myBitmapData.fillRect(rect, 0x000000FF);

myBitmapData.floodFill(10, 10, 0x00FF0000);

var bm:Bitmap = new Bitmap(myBitmapData);
addChild(bm);

Określa prostokąt docelowy, na który ma wpływ wywołanie metody applyFilter(), jeżeli jest podany obiekt BitmapData, prostokąt źródłowy oraz obiekt filtra.

Na przykład filtr rozmycia ma wpływ na obszar większy niż rozmiar oryginalnego obrazu. Obraz wielkości 100 x 200 pikseli filtrowany przez domyślną instancję BlurFilter, gdzie blurX = blurY = 4 generuje prostokąt docelowy o współrzędnych (-2, -2, 104, 204). Metoda generateFilterRect() pozwala na wczesne poznanie rozmiaru prostokąta docelowego, aby możliwe było określenie rozmiaru obrazu docelowego przed przeprowadzaniem operacji filtrowania.

Niektóre filtry przycinają prostokąt docelowy w oparciu o rozmiar obrazu źródłowego. Na przykład wewnętrzna właściwość DropShadow nie generuje wyniku większego niż jego obraz źródłowy. W przypadku tego API obiekt BitmapData jest wykorzystywany jako granice źródłowe a nie jako parametr źródłowy rect.

Parametry

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.filters.BlurFilter;

var bmd:BitmapData = new BitmapData(80, 30, false, 0xFFCC00);
var rect:Rectangle = new Rectangle(10, 10, 40, 10);
bmd.fillRect(rect, 0xFF0000);

var pt:Point = new Point(10, 10);
var filter:BlurFilter = new BlurFilter();

trace(bmd.generateFilterRect(rect, filter));
// (x=8, y=8, w=44, h=14)

bmd.applyFilter(bmd, rect, pt, filter);
var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Określa obszar prostokątny, który albo w pełni pokrywa wszelkie piksele określonego koloru wewnątrz obrazu bitmapowego (jeżeli parametr findColor jest ustawiony na wartość true), lub w pełni pokrywa wszelkie piksele, które nie zawierają określonego koloru (jeżeli parametr findColor jest ustawiony na wartość false).

Przykładowo, jeżeli konieczne jest określenie prostokąta posiadanego obrazu źródłowego, który zawiera kanał alpha inny niż zero, należy przekazać (mask: 0xFF000000, kolor: 0x00000000 jako parametry. Jeżeli parametr findColor jest ustawiony na wartośćtrue, wówczas w całym obrazie poszukiwane są piksele, których parametr (value & mask) == color (gdzie właściwość value jest wartością koloru pikseli). Jeżeli parametr findColor jest ustawiony na wartość false, wówczas w całym obrazie poszukiwane są granice pikseli, których właściwość (value & mask) != color (gdzie właściwość value jest wartością koloru pikseli). W celu określenia białej przestrzeni wokół obrazu należy podać parametry {mask: 0xFFFFFFFF, color: 0xFFFFFFFF} w celu odnalezienia granic pikseli innych niż białe.

Parametry

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;

var bmd:BitmapData = new BitmapData(80, 40, false, 0xFFFFFF);
var rect:Rectangle = new Rectangle(0, 0, 80, 20);
bmd.fillRect(rect, 0xFF0000);

var maskColor:uint = 0xFFFFFF; 
var color:uint = 0xFF0000;  
var redBounds:Rectangle = bmd.getColorBoundsRect(maskColor, color, true);
trace(redBounds); // (x=0, y=0, w=80, h=20)

var notRedBounds:Rectangle = bmd.getColorBoundsRect(maskColor, color, false);
trace(notRedBounds); // (x=0, y=20, w=80, h=20)

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Zwraca liczbę całkowitą, która reprezentuje wartość RGB piksela z obiektu BitmapData w określonym punkcie (x, y). Metoda getPixel() zwraca nieprzemnożoną wartość piksela. Nie jest zwracana informacja dotycząca wartości parametru alpha.

Wszystkie piksele obiektu BitmapData są przechowywane jako wstępnie przemnożone wartości kolorów. Wartość wstępnie przemnożona koloru jest wartością kanałów koloru czerwonego, zielonego i niebieskiego przemnożoną przez wartość alpha. Na przykład jeżeli wartość alhpa wynosi 0, wówczas wartości kanałów RGB również wynoszą 0, niezależnie od ich wartości nieprzemnożonych. Tego rodzaju utrata danych może spowodować problemy w trakcie wykonywania operacji. Wszystkie metody BitmapData pobierają i zwracają wartości nieprzemnożone. Reprezentacja pikseli wewnętrznych jest konwertowana z wartości wstępnie przemnożonych do wartości nieprzemnożonych przed zwróceniem jako wartość. W trakcie operacji ustawiania wartość piksela jest wstępnie przemnażana przed ustawieniem surowego piksela obrazu.

Parametry

Powiązane elementy interfejsu API

import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(80, 40, false, 0xFF0000);

var pixelValue:uint = bmd.getPixel(0, 0);
trace(pixelValue.toString(16)); // ff0000;

Zwraca wartość koloru ARGB, która zawiera dane kanału alfa i dane RGB. Ta metoda jest podobna do metody getPixel(), która zwraca kolor RGB bez wartości kanału alpha.

Wszystkie piksele obiektu BitmapData są przechowywane jako wstępnie przemnożone wartości kolorów. Wartość wstępnie przemnożona koloru jest wartością kanałów koloru czerwonego, zielonego i niebieskiego przemnożoną przez wartość alpha. Na przykład jeżeli wartość alhpa wynosi 0, wówczas wartości kanałów RGB również wynoszą 0, niezależnie od ich wartości nieprzemnożonych. Tego rodzaju utrata danych może spowodować problemy w trakcie wykonywania operacji. Wszystkie metody BitmapData pobierają i zwracają wartości nieprzemnożone. Reprezentacja pikseli wewnętrznych jest konwertowana z wartości wstępnie przemnożonych do wartości nieprzemnożonych przed zwróceniem jako wartość. W trakcie operacji ustawiania wartość piksela jest wstępnie przemnażana przed ustawieniem surowego piksela obrazu.

Parametry

Powiązane elementy interfejsu API

import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(80, 40, true, 0xFF44AACC);

var pixelValue:uint = bmd.getPixel32(0, 0);
var alphaValue:uint = pixelValue >> 24 & 0xFF;
var red:uint = pixelValue >> 16 & 0xFF;
var green:uint = pixelValue >> 8 & 0xFF;
var blue:uint = pixelValue & 0xFF;

trace(alphaValue.toString(16)); // ff
trace(red.toString(16)); // 44
trace(green.toString(16)); // aa
trace(blue.toString(16)); // cc

Generuje tablicę bajtów na podstawie prostokątnego obszaru pikseli. Zapisuje liczbę całkowitą bez znaku (32-bitową wartość nieprzemnożoną pikseli) dla każdego piksela w tablicy bajtów.

Parametry

Powiązane elementy interfejsu API

import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.utils.ByteArray;

var bmd:BitmapData = new BitmapData(80, 40, true);
var seed:int = int(Math.random() * int.MAX_VALUE);
bmd.noise(seed);

var bounds:Rectangle = new Rectangle(0, 0, bmd.width, bmd.height);
var pixels:ByteArray = bmd.getPixels(bounds);

Generuje tablicę wektorów na podstawie prostokątnego obszaru pikseli. Zwraca obiekt Vector zawierający liczby całkowite bez znaku (32-bitowe nieprzemnożone wartości pikseli) dla określonego prostokąta.

Parametry

Oblicza histogram 256 wartości binarnych obiektu BitmapData. Metoda zwraca obiekt Vector zawierający cztery obiekty Vector.Instancje <Number> (cztery obiekty Vector, które zawierają obiekty Number). Cztery instancje Vector reprezentują w kolejności składnik czerwony, zielony, niebieski i kanał alfa. Każda instancja Vector zawiera 256 wartości, które reprezentują liczbę wystąpień dla pojedynczej wartości składnika (z zakresu od 0 do 255).

Parametry

Uaktywnia wykrywanie pikseli między obrazem bitmapowym a punktem, prostokątem lub innym obrazem bitmapowym. Do wykrycia dochodzi, gdy punkt lub prostokąt pokrywa piksel nieprzezroczysty lub dwa nachodzące na siebie nieprzezroczyste piksele. Rozciąganie, obracanie oraz żadne inne transformacje żadnego z obiektów nie są brane pod uwagę przy przeprowadzaniu testu trafień.

Jeżeli obraz jest nieprzezroczysty, wówczas jest uznawany w tej metodzie za prostokąt w pełni nieprzezroczysty. Oba obrazy muszą być przezroczyste przy przeprowadzaniu testowania trafień na poziomie pikseli przy rozważaniu przezroczystości. Przy testowaniu dwóch obrazów przezroczystych, progowe parametry alpha kontrolują które wartości kanału alpha (z zakresu od 0 do 255) są uważane za nieprzezroczyste.

Parametry

import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var bmd1:BitmapData = new BitmapData(80, 80, true, 0x00000000);
var rect:Rectangle = new Rectangle(20, 20, 40, 40);
bmd1.fillRect(rect, 0xFF0000FF);

var pt1:Point = new Point(1, 1);
trace(bmd1.hitTest(pt1, 0xFF, pt1)); // false
var pt2:Point = new Point(40, 40);
trace(bmd1.hitTest(pt1, 0xFF, pt2)); // true

Blokuje obraz, co powoduje, że wszelkie obiekty odwołujące się do obiektu BitmapData, np. obiekty Bitmap, nie są aktualizowane w odpowiedzi na zmiany obiektu BitmapData. W celu podwyższenia wydajności należy stosować tą metodę wraz z metodą unlock() przed i po wielokrotnych wywołaniach do metody setPixel() i setPixel32().

Powiązane elementy interfejsu API

import flash.display.BitmapData;

var bitmapData:BitmapData = picture.bitmapData;
bitmapData.lock();
bitmapData = complexTransformation(bitmapData);
bitmapData.unlock();
picture.bitmapData = bitmapData;

Wykonuje mieszanie poszczególnych kanałów z obrazu źródłowego do obrazu docelowego. Dla każdego kanału i każdego piksela nowa wartość jest obliczana na podstawie wartości kanałów pikseli źródłowych i docelowych. Przykładowo w kanale koloru czerwonego, nowa wartość jest obliczana w następujący sposób (gdzie właściwość redSrc jest wartością kanału koloru czerwonego w obrazie źródłowym, zaś właściwość redDest jest wartością kanału czerwonego na odpowiadającym pikselu obrazu docelowego):

nowy redDest = [(redSrc * redMultiplier) + (redDest * (256 - redMultiplier))] / 256;

Wartości właściwości redMultiplier, greenMultiplier, blueMultiplier oraz alphaMultiplier są przelicznikami wykorzystywanymi względem każdego kanału kolorów. Należy zastosować wartość szesnastkową w graniach od 0 do 0x100 (256), gdzie 0 określa pełną wartość ze źródła wykorzystaną końcowo, 0x100 określa wykorzystanie pełnej wartości ze źródła, zaś liczby pomiędzy określają wykorzystanie mieszania (jak na przykład 0x80 dla wartości 50%).

Parametry

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var bmd1:BitmapData = new BitmapData(100, 80, true, 0xFF00FF00);
var bmd2:BitmapData = new BitmapData(100, 80, true, 0xFFFF0000);
var rect:Rectangle = new Rectangle(0, 0, 20, 20);
var pt:Point = new Point(20, 20);
var mult:uint = 0x80; // 50% 
bmd1.merge(bmd2, rect, pt, mult, mult, mult, mult);

var bm1:Bitmap = new Bitmap(bmd1);
addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
addChild(bm2);
bm2.x = 110;

Wypełnia obraz pikselami stanowiącymi losowy szum.

Parametry

Powiązane elementy interfejsu API

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.BitmapDataChannel;

var bmd1:BitmapData = new BitmapData(80, 80);
var bmd2:BitmapData = new BitmapData(80, 80);

var seed:int = int(Math.random() * int.MAX_VALUE);
bmd1.noise(seed, 0, 0xFF, BitmapDataChannel.RED, false);
bmd2.noise(seed, 0, 0xFF, BitmapDataChannel.RED, true);

var bm1:Bitmap = new Bitmap(bmd1);
this.addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
this.addChild(bm2);
bm2.x = 90;

Ponownie odwzorowuje wartości kanałów kolorów w obrazie zawierającym maksymalnie cztery tablice dotyczące kolorów — po jednej na każdy kanał.

Środowisko wykonawcze Flash realizuje poniższe kroki w celu generowania obrazu wynikowego:

1. Po obliczeniu wartości koloru czerwonego, niebieskiego oraz wartości alpha są dodawane razem przy zastosowaniu standardowej arytmetyki 32-bitowych liczb całkowitych.
2. Wartości kanałów kolorów czerwonego, zielonego, niebieskiego oraz wartość alpha są wyodrębniane do oddzielnych wartości z zakresu 0 do 255. Te wartości są wykorzystywane przy wyszukiwaniu nowych wartości kolorów w odpowiedniej tablicy: redArray, greenArray, blueArray oraz alphaArray. Każda z tych tablic powinna zawierać 256 wartości.
3. Po pobraniu wszystkich czterech nowych wartości kanałów, są one łączone w standardową wartość ARGB, która będzie zastosowana względem pikseli.

Efekty międzykanałowe są obsługiwane przez tą metodę. Każda tablica wejścia może zawierać pełne 32-bitowe wartości i nie dochodzi do przesuwania gdy wartości są dodawane do siebie. Ta procedura nie obsługuje ściśnięcia poszczególnych kanałów.

Jeżeli nie została wybrana tablica dla kanału, wówczas kanał koloru jest kopiowany z obrazu źródłowego do obrazu docelowego.

Możliwe jest wykorzystanie tej metody do realizacji szerokiej gamy efektów, jak na przykład ogólnego odwzorowywania palety (pobieranie jednego kanału i jego konwersja do obrazu z zafałszowanymi kolorami). Możliwe jest również wykorzystanie tej metody w celu zastosowania różnych zaawansowanych algorytmów manipulacji kolorami, jak na przykład korekcja gamma, krzywe, poziomy oraz kwantyfikacja.

Parametry

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;

var myBitmapData:BitmapData = new BitmapData(80, 80, false, 0x00FF0000);
myBitmapData.fillRect(new Rectangle(20, 20, 40, 40), 0x0000FF00);

var redArray:Array = new Array(256);
var greenArray:Array = new Array(256);

for(var i:uint = 0; i < 255; i++) {
    redArray[i] = 0x00000000;
    greenArray[i] = 0x00000000;
}

redArray[0xFF] = 0x0000FF00;
greenArray[0xFF] = 0x00FF0000;

var bottomHalf:Rectangle = new Rectangle(0, 0, 100, 40);
var pt:Point = new Point(0, 0);
myBitmapData.paletteMap(myBitmapData, bottomHalf, pt, redArray, greenArray);

var bm1:Bitmap = new Bitmap(myBitmapData);
addChild(bm1);

Generuje obraz szumu Perlina.

Algorytm generacji szumu Perlina interpoluje oraz łączy indywidualne funkcje szumu losowego (zwane oktawami) w pojedynczą funkcję tworzącą bardziej naturalny szum losowy. Tak jak w przypadku oktaw muzycznych, każda funkcja oktawy ma podwójną częstotliwość poprzedniej. Szum Perlina został opisany jako „suma fraktali szumu", ponieważ łączy on wiele zestawów danych szumu o różnych stopniach uszczegółowienia.

Możliwe jest wykorzystanie funkcji szumu Perlina w celu symulacji zjawisk naturalnych i krajobrazów, jak na przykład struktura drewna, chmury oraz stoki górskie. W większości przypadków efekt wyjściowy funkcji szumu Perlina nie jest wyświetlana bezpośrednio, lecz wykorzystywana do udoskonalenia obrazów oraz nadania im pseudo-losowych wariacji.

Proste funkcje cyfrowego szumu losowego często generują obrazy o ostrych, kontrastujących punktach. Tego typu ostry kontrast nie jest często spotykany w naturze. Algorytm szumu Perlina miesza wiele funkcji szumu, które operują na różnych stopniach szczegółowości. Algorytm powoduje mniejsze wariacje wśród wartości pikseli sąsiadujących.

Parametry

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(200, 200, false, 0x00CCCCCC);

var seed:Number = Math.floor(Math.random() * 10);
var channels:uint = BitmapDataChannel.RED | BitmapDataChannel.BLUE;
bmd.perlinNoise(100, 80, 6, seed, false, true, channels, false, null);

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Przeprowadza operację rozpuszczania na poziomie pikseli - albo z obrazu źródłowego do obrazu docelowego, albo przy użyciu jednego obrazu. Środowisko wykonawcze Flash wykorzystuje wartość randomSeed w celu wygenerowania operacji losowego rozpuszczania pikseli. Wartość zwrotna funkcji musi zostać podana w kolejnych wywołaniach w celu kontynuowania operacji rozpuszczania pikseli aż do zakończenia.

Jeżeli obraz źródłowy nie równa się obrazowi docelowemu, wówczas piksele są kopiowane ze źródła do celu przez wykorzystanie wszelkich właściwości. Proces ten pozwala na rozpuszczanie z pustego obrazu do obrazu w całości zapełnionego.

Jeżeli obrazy źródłowy i docelowy są takie same, wówczas piksele są wypełniane zgodnie z parametrem color. Proces ten pozwala na rozpuszczanie z dala od obrazu w całości zapełnionego. W tym trybie docelowy parametr point jest ignorowany.

Parametry

import flash.display.BitmapData;
import flash.display.Bitmap;
import flash.geom.Point;
import flash.geom.Rectangle;
import flash.utils.Timer;
import flash.events.TimerEvent;

var bmd:BitmapData = new BitmapData(100, 80, false, 0x00CCCCCC);
var bitmap:Bitmap = new Bitmap(bmd);
addChild(bitmap);

var tim:Timer = new Timer(20);
tim.start();
tim.addEventListener(TimerEvent.TIMER, timerHandler);
 
function timerHandler(event:TimerEvent):void {
    var randomNum:Number = Math.floor(Math.random() * int.MAX_VALUE);
    dissolve(randomNum);
}

function dissolve(randomNum:Number):void {
    var rect:Rectangle = bmd.rect;
    var pt:Point = new Point(0, 0);
    var numberOfPixels:uint = 100;
    var red:uint = 0x00FF0000;
    bmd.pixelDissolve(bmd, rect, pt, randomNum, numberOfPixels, red);
    var grayRegion:Rectangle = bmd.getColorBoundsRect(0xFFFFFFFF, 0x00CCCCCC, true);
    if(grayRegion.width == 0 && grayRegion.height == 0 ) {
        tim.stop();
    }
}

Przewija obraz o określoną ilość (x, y) pikseli. Obszary krawędzi poza polem przewijania są pozostawione bez zmian.

Parametry

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.Rectangle;

var bmd:BitmapData = new BitmapData(80, 80, true, 0xFFCCCCCC);
var rect:Rectangle = new Rectangle(0, 0, 40, 40);
bmd.fillRect(rect, 0xFFFF0000);
            
var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

trace (bmd.getPixel32(50, 20).toString(16)); // ffcccccccc

bmd.scroll(30, 0); 

trace (bmd.getPixel32(50, 20).toString(16)); // ffff0000

Ustawia pojedynczy piksel obiektu BitmapData. Obecna wartość kanału alpha pikseli obrazu jest zachowana w trakcie tej operacji. Parametr wartości RGB koloru jest traktowany jako wartość nieprzemnożona koloru.

Uwaga: W celu podwyższenia wydajności w trakcie wielokrotnego korzystania z metod setPixel() i setPixel32() pomocne jest wywołanie metody lock() przed wywołaniem metody setPixel() i setPixel32() oraz wywołanie unlock() po dokonaniu zmian piksela. Proces ten zapobiega aktualizacji obiektów odwołujących się do instancji BitmapData zanim nie zostanie zakończone wprowadzanie zmian piksela.

Parametry

Powiązane elementy interfejsu API

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(80, 80, false, 0xCCCCCC);

for (var i:uint = 0; i < 80; i++) {
    var red:uint = 0xFF0000;
    bmd.setPixel(i, 40, red);
}

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Ustawia wartości koloru i przezroczystości alfa jednego piksela w obiekcie typu BitmapData. Metoda ta jest podobna do metody setPixel(); główną różnicą jest fakt, iż metoda setPixel32() pobiera wartość ARGB koloru, która zawiera informację dotyczącą kanału alpha.

Wszystkie piksele obiektu BitmapData są przechowywane jako wstępnie przemnożone wartości kolorów. Wartość wstępnie przemnożona koloru jest wartością kanałów koloru czerwonego, zielonego i niebieskiego przemnożoną przez wartość alpha. Na przykład jeżeli wartość alhpa wynosi 0, wówczas wartości kanałów RGB również wynoszą 0, niezależnie od ich wartości nieprzemnożonych. Tego rodzaju utrata danych może spowodować problemy w trakcie wykonywania operacji. Wszystkie metody BitmapData pobierają i zwracają wartości nieprzemnożone. Reprezentacja pikseli wewnętrznych jest konwertowana z wartości wstępnie przemnożonych do wartości nieprzemnożonych przed zwróceniem jako wartość. W trakcie operacji ustawiania wartość piksela jest wstępnie przemnażana przed ustawieniem surowego piksela obrazu.

Uwaga: W celu podwyższenia wydajności w trakcie wielokrotnego korzystania z metod setPixel() i setPixel32() pomocne jest wywołanie metody lock() przed wywołaniem metody setPixel() i setPixel32() oraz wywołanie unlock() po dokonaniu zmian piksela. Proces ten zapobiega aktualizacji obiektów odwołujących się do instancji BitmapData zanim nie zostanie zakończone wprowadzanie zmian piksela.

Parametry

Powiązane elementy interfejsu API

import flash.display.Bitmap;
import flash.display.BitmapData;

var bmd:BitmapData = new BitmapData(80, 80, true, 0xFFCCCCCC);

for (var i:uint = 0; i < 80; i++) {
    var red:uint = 0x60FF0000;
    bmd.setPixel32(i, 40, red);
}

var bm:Bitmap = new Bitmap(bmd);
addChild(bm);

Konwertuje tablicę bajtów na prostokątny obszar pikseli. Dla każdego piksela metoda ByteArray.readUnsignedInt() jest wywoływana, zaś zwrócona wartość jest zapisana w pikselu. Jeżeli tablica bajtów kończy się przed zapisaniem całego prostokąta, wówczas funkcja jest zwracana. Dane w tablicy bajtów powinny być 32-bitowymi wartościami ARGB pikseli. Wyszukiwanie nie jest przeprowadzane na tablicy bajtów przed lub po odczytaniu pikseli.

Parametry

Powiązane elementy interfejsu API

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.utils.ByteArray;
import flash.geom.Rectangle;

var bmd1:BitmapData = new BitmapData(100, 100, true, 0xFFCCCCCC);
var bmd2:BitmapData = new BitmapData(100, 100, true, 0xFFFF0000);

var rect:Rectangle = new Rectangle(0, 0, 100, 100);
var bytes:ByteArray = bmd1.getPixels(rect);

bytes.position = 0;
bmd2.setPixels(rect, bytes);

var bm1:Bitmap = new Bitmap(bmd1);
addChild(bm1);
var bm2:Bitmap = new Bitmap(bmd2);
addChild(bm2);
bm2.x = 110;

Przekształca obiekt Vector w prostokątny region danych pikselowych. Dla każdego piksela odczytywany jest element tablicy Vector, który następnie zapisywany jest do piksela w obiekcie BitmapData. Dane w tablicy Vector powinny być 32-bitowymi wartościami ARGB pikseli.

Parametry

Testuje wartości pikseli obrazu ze względu na określony próg i określa nowe wartości kolorów pikseli zweryfikowanych pozytywnie. Poprzez zastosowanie metody threshold() możliwe jest izolowanie oraz zamiana zakresów kolorów w obrazie oraz przeprowadzenie innych operacji logicznych na pikselach obrazu.

Logika testów metody threshold() przedstawia się następująco:

1. Jeżeli ((pixelValue & maska) operacja (próg & maska)), wówczas piksel jest ustawiany zgodnie z właściwością color;
2. W innym przypadku, gdy copySource == true, wówczas piksel jest ustawiany na odpowiadającą wartość pikseli z właściwości sourceBitmap.

Parametr operation określa operatora porównania do wykorzystania w teście progowym. Przykładowo, zastosowanie operatora "==" jako parametru operation możliwa jest izolacja określonej wartości koloru na obrazie. Również poprzez wykorzystanie parametru {operation: "<", mask: 0xFF000000, threshold: 0x7F000000, color: 0x00000000} możliwe jest ustawienie wszystkich pikseli docelowych na pełną przezroczystość w przypadku, gdy wartość alpha pikseli obrazu źródłowego wynosi mniej niż 0x7F. Można wykorzystać tą technikę przy przejściach animowanych i innych efektach.

Parametry

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.BitmapDataChannel;
import flash.geom.Point;
import flash.geom.Rectangle;

var bmd1:BitmapData = new BitmapData(200, 200, true, 0xFFCCCCCC);

var seed:int = int(Math.random() * int.MAX_VALUE);
var channels:uint = BitmapDataChannel.RED | BitmapDataChannel.BLUE;
bmd1.perlinNoise(100, 80, 12, seed, false, true, channels, false, null);

var bitmap1:Bitmap = new Bitmap(bmd1);
addChild(bitmap1);

var bmd2:BitmapData = new BitmapData(200, 200, true, 0xFFCCCCCC);
var pt:Point = new Point(0, 0);
var rect:Rectangle = new Rectangle(0, 0, 200, 200);
var threshold:uint =  0x00800000; 
var color:uint = 0x20FF0000;
var maskColor:uint = 0x00FF0000;
bmd2.threshold(bmd1, rect, pt, ">", threshold, color, maskColor, true);

var bitmap2:Bitmap = new Bitmap(bmd2);
bitmap2.x = bitmap1.x + bitmap1.width + 10;
addChild(bitmap2);

Odblokowuje obraz, co powoduje, że wszelkie obiekty odwołujące się do obiektu BitmapData, np. obiekty Bitmap, są aktualizowane w odpowiedzi na zmiany obiektu BitmapData. W celu podwyższenia wydajności należy stosować tą metodę wraz z metodą lock() przed i po wielokrotnych wywołaniach do metody setPixel() i setPixel32().

Parametry

Powiązane elementy interfejsu API

import flash.display.BitmapData;

var bitmapData:BitmapData = picture.bitmapData;
bitmapData.lock();
bitmapData = complexTransformation(bitmapData);
bitmapData.unlock();
picture.bitmapData = bitmapData;

1. Tworzona jest właściwość url, która jest miejscem położenia oraz nazwą pliku obrazu.
2. Konstruktor klas tworzy obiekt Loader, który z kolei tworzy instancję detektora zdarzeń, zaś ten jest wywoływany gdy metoda completeHandler() zakończy manipulację obrazu.
3. Obiekt URLRequest request jest następnie przekazywany do metody loader.load(), który ładuje obraz poprzez wykorzystanie obiektu wyświetlania.
4. Obraz jest wówczas umieszczany na liście wyświetlania, która wyświetla obraz na ekranie na współrzędnych x = 0, y = 0.
5. Metoda completeHandler() przeprowadza wówczas następujące zadania.
   • Tworzy drugi obiekt Loader, wraz z obiektem Bitmap, który jest inicjalizowany przy pomocy obiektu Loader.
   • Tworzy dugi obiekt Bitmap duplicate, który z kolei wywołuje metodę duplicateImage(), tworzącą duplikat oryginalnego obrazu.
   • Tworzy obiekt BitmapData, który jest powiązany z obiektem duplicate obiektu BitmapData.
   • Tworzy nowy obiekt Rectangle inicjalizowany z tymi samymi współrzędnymi, szerokością i wysokością jak obraz oryginalny.
   • Tworzy nowy obiekt Point, którego współrzędne domyślne to x = 0, y = 0.
   • Tworzy następujące zmienne:
     • operation — Stosuje nowy kolor, gdy wartość progowa jest większa lub równa oryginałowi.
     • threshold — Wartość, wobec której każdy piksel jest porównywany (w tym przykładzie jest ustawiona na kolor jasnoszary z wartością alpha 0xCC).
     • color — kolor, na który zostaną ustawione piksele spełniające warunek progowy; w tym wypadku jest to jednolity kolor żółty.
     • mask — Kolor dokładnie przeciwny (przezroczysty kolor niebieski).
     • copySource — Ustawiona na wartość false wskazuje, iż wartości pikseli nie są kopiowane w przypadku, gdy wartość progowa nie zostanie zweryfikowana pozytywnie. Ta wartość nie ma znaczenia, ponieważ obraz jest zduplikowany i wyłącznie piksele które zostały pozytywnie zweryfikowane w teście progowym są zmieniane.
   • Wywołuje metodę threshold() wykorzystując powyższe zmienne. Końcowe równanie progowe wygląda następująco: jeżeli (obecna wartość pikseli & 0x000000FF) >= (0xCCCCCCCC & 0x000000FF) wówczas ustaw wartość pikseli na 0xFFFFFF00.

Uwagi:

• Plik SWF musi być skompilowany z zabezpieczeniem odtwarzania lokalnego ustawionym na tylko do pliki dostępne lokalnie.
• Dla zilustrowania tego przykładu konieczne jest umieszczenie pliku o nazwie Image.gif w tym samym katalogu, w którym znajduje się plik SWF.
• Zalecane jest wykorzystanie obrazu o szerokości do 80 pikseli.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.geom.Point;
    import flash.geom.Rectangle;
    import flash.net.URLRequest;

    public class BitmapDataExample extends Sprite {
        private var url:String = "Image.gif";
        private var size:uint = 80;

        public function BitmapDataExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

            var request:URLRequest = new URLRequest(url);
            loader.x = size * numChildren;
            loader.load(request);
            addChild(loader);
        }

        private function duplicateImage(original:Bitmap):Bitmap {
            var image:Bitmap = new Bitmap(original.bitmapData.clone());
            image.x = size * numChildren;
            addChild(image);
            return image;
        }

        private function completeHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var image:Bitmap = Bitmap(loader.content);

            var duplicate:Bitmap = duplicateImage(image);
            var bitmapData:BitmapData = duplicate.bitmapData;
            var sourceRect:Rectangle = new Rectangle(0, 0, bitmapData.width, bitmapData.height);
            var destPoint:Point = new Point();
            var operation:String = ">=";
            var threshold:uint = 0xCCCCCCCC;
            var color:uint = 0xFFFFFF00;
            var mask:uint = 0x000000FF;
            var copySource:Boolean = true;

            bitmapData.threshold(bitmapData,
                                 sourceRect,
                                 destPoint,
                                 operation,
                                 threshold,
                                 color,
                                 mask,
                                 copySource);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}