ColorMatrixFilter  - AS3

Tablica 20-elementowa (o wymiarach 4 x 5) reprezentująca macierzowe przekształcenie kolorów. Właściwości matrix nie można zmienić poprzez bezpośrednie modyfikowanie jej wartości (na przykład: myFilter.matrix[2] = 1;). Zamiast tego należy użyć odwołania do tablicy, zmienić odwołanie, a następnie wyzerować wartość.

Filtr macierzy kolorów rozdziela każdy piksel źródłowy na jego składniki: czerwony, niebieski i alpha — tj. srcR, srcG, srcB, srcA. W celu obliczenia wyniku dla każdego z czterech kanałów wartość każdego piksela na obrazie zostaje przemnożona przez wartości w macierzy transformacji. Do każdego wyniku (piąty element w każdym wierszu macierzy) może zostać dodane opcjonalne przesunięcie (z zakresu od -255 do 255). Filtr łączy każdy składnik koloru z pojedynczym pikselem, a następnie zapisuje wynik. W poniższej formule wartości od a[0] do a[19] odpowiadają wpisom od 0 do 19 w tablicy 20-elementowej, która jest przekazywana do właściwości matrix:

	redResult   = (a[0]  * srcR) + (a[1]  * srcG) + (a[2]  * srcB) + (a[3]  * srcA) + a[4]
	greenResult = (a[5]  * srcR) + (a[6]  * srcG) + (a[7]  * srcB) + (a[8]  * srcA) + a[9]
	blueResult  = (a[10] * srcR) + (a[11] * srcG) + (a[12] * srcB) + (a[13] * srcA) + a[14]
	alphaResult = (a[15] * srcR) + (a[16] * srcG) + (a[17] * srcB) + (a[18] * srcA) + a[19]
	

Dla każdej wartości koloru w tablicy wartość 1 jest równa 100% kanału wysyłanego do wyjścia, co zapewnia zachowanie wartości kanału koloru.

Obliczenia są wykonywane na wartościach kolorów przed mnożeniem. Jeśli grafika wejściowa zawiera wartości wstępnie przemnożonego koloru, te wartości są automatycznie konwertowane na nieprzemnożone wartości koloru dla danej operacji.

Dostępne są dwa zoptymalizowane tryby:

Tylko Alpha. Po przekazaniu do filtra macierzy, która dostosowuje tylko składnik alpha, jak w tym przykładzie, filtr optymalizuje jej działanie:

	    1 0 0 0 0
	    0 1 0 0 0
	    0 0 1 0 0
	    0 0 0 N 0  (where N is between 0.0 and 1.0)
	

Wersja szybsza. Dostępna tylko w procesorach, w których aktywny jest akcelerator SSE/AltiVec — takich jak Intel^® Pentium^® 3 i późniejsze oraz Apple^® G4 i późniejsze. Akcelerator jest używany wówczas, gdy mnożnik należy do zakresu od -15,99 do 15,99, a elementy dodawane a[4], a[9], a[14] i a[19] należą do zakresu od -8000 do 8000.

Inicjuje nowe wystąpienie klasy ColorMatrixFilter z określonymi parametrami.

Zwraca kopię tego obiektu typu Filter.

Funkcja buildChild() tworzy nowy obiekt Loader o nazwie loader. Dla każdego wywołania metody buildChild() należy dołączyć detektor zdarzeń do obiektu Loader w celu wykrywania zdarzeń complete, które są obsługiwane przez funkcję przekazaną do metody buildChild().

Funkcje applyRed(), applyGreen() i applyBlue() korzystają z różnych wartości dla tablicy matrix, dzięki czemu zapewniają osiąganie różnych wyników.

Uwaga: w celu osiągnięcia najlepszych wyników należy korzystać z obrazów o szerokości około 80 pikseli. Nazwa i lokalizacja pliku obrazu powinna być zgodna z wartością wprowadzoną do właściwości url. Przykład: wartość wprowadzona do właściwości url w przykładzie wskazuje na plik obrazu o nazwie „Image.jpg”, który znajduje się w tym samym katalogu, co plik SWF.

package {
    import flash.display.DisplayObject;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.filters.ColorMatrixFilter;
    import flash.net.URLRequest;

    public class ColorMatrixFilterExample extends Sprite {
        private var size:uint  = 140;
        private var url:String = "Image.jpg";

        public function ColorMatrixFilterExample() {
            buildChild(null);
            buildChild(applyRed);
            buildChild(applyGreen);
            buildChild(applyBlue);
        }

        private function buildChild(loadHandler:Function):void {
            var loader:Loader = new Loader();
            loader.x = numChildren * size;
            loader.y = size;
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            if (loadHandler != null) {
                loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadHandler);
            }

            var request:URLRequest = new URLRequest(url);
            loader.load(request);
            addChild(loader);
        }

        private function applyRed(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            var matrix:Array = new Array();
            matrix = matrix.concat([1, 0, 0, 0, 0]); // red
            matrix = matrix.concat([0, 0, 0, 0, 0]); // green
            matrix = matrix.concat([0, 0, 0, 0, 0]); // blue
            matrix = matrix.concat([0, 0, 0, 1, 0]); // alpha

            applyFilter(child, matrix);
        }

        private function applyGreen(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            var matrix:Array = new Array();
            matrix = matrix.concat([0, 0, 0, 0, 0]); // red
            matrix = matrix.concat([0, 1, 0, 0, 0]); // green
            matrix = matrix.concat([0, 0, 0, 0, 0]); // blue
            matrix = matrix.concat([0, 0, 0, 1, 0]); // alpha

            applyFilter(child, matrix);
        }

        private function applyBlue(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            var matrix:Array = new Array();
            matrix = matrix.concat([0, 0, 0, 0, 0]); // red
            matrix = matrix.concat([0, 0, 0, 0, 0]); // green
            matrix = matrix.concat([0, 0, 1, 0, 0]); // blue
            matrix = matrix.concat([0, 0, 0, 1, 0]); // alpha

            applyFilter(child, matrix);
        }

        private function applyFilter(child:DisplayObject, matrix:Array):void {
            var filter:ColorMatrixFilter = new ColorMatrixFilter(matrix);
            var filters:Array = new Array();
            filters.push(filter);
            child.filters = filters;
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}