BevelFilter  - AS3

Kąt fazy. Poprawne wartości należą do zakresu od 0 do 360°. Wartością domyślną jest 45°.

Wartość kąta reprezentuje kąt padania światła z teoretycznego źródła światła oświetlającego obiekt oraz określa położenie efektu względem obiektu. Jeśli dla właściwości distance zostanie ustawiona wartość 0, efekt nie zostanie przesunięty z obiektu i dlatego właściwość angle nie będzie miała żadnego efektu.

Intensywność rozmycia poziomego (w pikselach). Poprawne wartości należą do zakresu od 0 do 255 (wielkość zmiennoprzecinkowa). Wartością domyślną jest 4. Wartości, które są potęgami 2 (dwójki 2, 4, 8, 16 i 32) są zoptymalizowane i są renderowane szybciej niż inne wartości.

Intensywność rozmycia pionowego (w pikselach). Poprawne wartości należą do zakresu od 0 do 255 (wielkość zmiennoprzecinkowa). Wartością domyślną jest 4. Wartości, które są potęgami 2 (dwójki 2, 4, 8, 16 i 32) są zoptymalizowane i są renderowane szybciej niż inne wartości.

Odległość przesunięcia fazy. Poprawne wartości w pikselach (zmiennoprzecinkowe). Wartością domyślną jest 4.

Wartość przezroczystości alfa koloru podświetlenia. Wartość jest określona jako znormalizowana wartość od 0 do 1. Przykład: 0,25 powoduje ustawienie przezroczystości równej 25%. Wartością domyślną jest 1.

Kolor światła w fazie. Poprawne wartości są w formacie szesnastkowym 0xRRGGBB. Wartością domyślną jest: 0xFFFFFF.

Pozwala zastosować efekt odcięcia (true), który sprawia, że wypełnienie obiektu staje się przezroczyste i widać przez nie tło dokumentu. Wartością domyślną jest false (brak odcięcia).

Liczba operacji zastosowania filtra. Wartością domyślną jest BitmapFilterQuality.LOW, która jest równoważna jednorazowemu zastosowaniu filtra. Wartość BitmapFilterQuality.MEDIUM powoduje dwukrotne zastosowanie filtra; wartość BitmapFilterQuality.HIGH powoduje trzykrotne zastosowanie filtra. Filtry o niższych wartościach są renderowane szybciej.

W większości zastosowań wystarczające są następujące wartości quality: low, medium i high. Mimo że w celu osiągnięcia różnych efektów można stosować dodatkowe wartości liczbowe (aż do 15), wyższe wartości są renderowane wolniej. Zamiast zwiększać wartość quality — w celu uzyskania podobnego efektu przy krótszym czasie renderowania — można po prostu zwiększać wartości właściwości blurX i blurY.

Za pomocą następujących stałych BitmapFilterQuality można określać wartości właściwości quality:

• BitmapFilterQuality.LOW
• BitmapFilterQuality.MEDIUM
• BitmapFilterQuality.HIGH

Wartość przezroczystości alfa koloru cienia. Wartość jest określona jako znormalizowana wartość od 0 do 1. Przykład: 0,25 powoduje ustawienie przezroczystości równej 25%. Wartością domyślną jest 1.

Kolor cienia w fazie. Poprawne wartości są w formacie szesnastkowym 0xRRGGBB. Wartość domyślna: 0x000000.

Siła odciskania lub zalewkowania. Poprawne wartości należą do zakresu od 0 do 255. Im wyższa jest wartość, tym więcej koloru zostaje odciśnięte, co powoduje również wzmocnienie kontrastu między fazą i tłem. Wartością domyślną jest 1.

Umiejscowienie fazy w obiekcie. Fazy wewnętrzne i zewnętrzne są umieszczane na krawędzi wewnętrznej i zewnętrznej; pełna faza jest umieszczana na całym obiekcie. Poprawne wartości są stałymi BitmapFilterType:

• BitmapFilterType.INNER
• BitmapFilterType.OUTER
• BitmapFilterType.FULL

Inicjuje nowe wystąpienie obiektu BevelFilter z określonymi parametrami.

Powiązane elementy interfejsu API

Zwraca kopię tego obiektu typu Filter.

1. Zaimportuj wymagane klasy.
2. Zadeklaruj trzy właściwości używane w funkcji draw(), która rysuje obiekt, do którego zostanie zastosowany filtr fazy.
3. Utwórz funkcję konstruktora BevelFilterExample(), którego działanie jest następujące:
   • Wywołuje funkcję draw(), która zostanie zadeklarowana później.
   • Deklaruje zmienną filter jako obiekt BitmapFilter i przypisuje ją do wartości zwracanej przez wywołanie metody getBitmapFilter().
   • Tworzy nowy obiekt tablicy myFilters i stosuje filtr filter do tablicy, a nstępnie przypiusuje myFilters do własciwości filters obiektu BevelFilterExample. To spowoduje zastosowanie wszystkich filtrów zalezionych w obiekcie myFilters — w tym przykładzie jest to filtr filter.
4. Utwórz funkcję getBitmapFilter w celu utworzenia i ustawienia właściwości dla filtru.
5. Utwórz funkcję draw(). W tej funkcji stosowane są metody klasy Graphics, do której dostęp uzyskuje się za pośrednictwem właściwości graphics klasy Sprite, w celu rysowania kwadratu.

package {
    import flash.display.Sprite;
    import flash.filters.BevelFilter;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BitmapFilterType;

    public class BevelFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function BevelFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var distance:Number       = 5;
            var angleInDegrees:Number = 45;
            var highlightColor:Number = 0xFFFF00;
            var highlightAlpha:Number = 0.8;
            var shadowColor:Number    = 0x0000FF;
            var shadowAlpha:Number    = 0.8;
            var blurX:Number          = 5;
            var blurY:Number          = 5;
            var strength:Number       = 5;
            var quality:Number        = BitmapFilterQuality.HIGH;
            var type:String           = BitmapFilterType.INNER;
            var knockout:Boolean      = false;

            return new BevelFilter(distance,
                                   angleInDegrees,
                                   highlightColor,
                                   highlightAlpha,
                                   shadowColor,
                                   shadowAlpha,
                                   blurX,
                                   blurY,
                                   strength,
                                   quality,
                                   type,
                                   knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}