DropShadowFilter  - AS3

Wartość przezroczystości alfa koloru cienia. Poprawne wartości należą do zakresu od 0,0 do 1,0. Przykład: 0,25 powoduje ustawienie przezroczystości 25%. Wartością domyślną jest 1.0.

Kąt cienia. Poprawne wartości należą do zakresu od 0 do 360 stopni (wielkość zmiennoprzecinkowa). Wartością domyślną jest 45.

Intensywność rozmycia w poziomie. Poprawne wartości należą do zakresu od 0 do 255,0 (wielkość zmiennoprzecinkowa). Wartością domyślną jest 4,0.

Intensywność rozmycia w pionie. Poprawne wartości należą do zakresu od 0 do 255,0 (wielkość zmiennoprzecinkowa). Wartością domyślną jest 4,0.

Kolor cienia. Poprawne wartości są w formacie szesnastkowym 0xRRGGBB. Wartość domyślna: 0x000000.

Przesunięcie cienia (w pikselach). Wartością domyślną jest 4,0 (wielkość zmiennoprzecinkowa).

Decyduje, czy obiekt jest widoczny czy nie. Wartość true wskazuje, że obiekt nie jest rysowany; widoczny jest tylko cień. Wartością domyślną jest false (obiekt jest widoczny).

Decyduje, czy cień jest cieniem wewnętrznym czy nie. Wartość true określa cień wewnętrzny. Wartością domyślną jest false — cień zewnętrzny (cień wokół zewnętrznych krawędzi obiektu).

Pozwala zastosować efekt odcięcia (true), który sprawia, że wypełnienie obiektu staje się przezroczyste i widać przez nie tło dokumentu. Wartością domyślną jest false (brak odcięcia).

Liczba operacji zastosowania filtra. Wartością domyślną jest BitmapFilterQuality.LOW, która jest równoważna jednorazowemu zastosowaniu filtra. Wartość BitmapFilterQuality.MEDIUM powoduje dwukrotne zastosowanie filtra; wartość BitmapFilterQuality.HIGH powoduje trzykrotne zastosowanie filtra. Filtry o niższych wartościach są renderowane szybciej.

W większości zastosowań wystarczające są następujące wartości jakości: low, medium i high. Mimo że w celu osiągnięcia różnych efektów można stosować dodatkowe wartości liczbowe (aż do 15), wyższe wartości są renderowane wolniej. Zamiast zwiększać wartość quality — w celu uzyskania podobnego efektu przy krótszym czasie renderowania — można po prostu zwiększać wartości właściwości blurX i blurY.

Powiązane elementy interfejsu API

Siła odciskania lub zalewkowania. Im wyższa jest wartość, tym więcej koloru zostaje odciśnięte, co powoduje również wzmocnienie kontrastu między cieniem i tłem. Poprawne wartości należą do zakresu od 0 do 255,0. Wartością domyślną jest 1,0.

Tworzy nowe wystąpienie obiektu DropShadowFilter z określonymi parametrami.

Powiązane elementy interfejsu API

Zwraca kopię tego obiektu typu Filter.

1. Zadeklaruj trzy właściwości, które posłużą do narysowania kwadratu, do którego zostanie zastosowany filtr.
2. Utwórz funkcję konstruktora. Konstruktor wywoła metodę draw(), która korzysta z metod klasy Graphics, do których uzyskuje dostęp za pośrednictwem właściwości graphics Sprite w celu narysowania pomarańczowego kwadratu.
3. W konsturktorze zadeklaruj zmienną filter jako obiekt BitmapFilter i przypisz ją do wartości zwracanej przez wywołanie metody getBitmapFilter(). Metoda getBitmapFilter() definiuje używany filtr.
4. Utwórz nowy obiekt myFilters tablicy i dodaj filtr (filter) do tablicy. Przypisz tablicę myFilters do właściwości filters obiektu DropShadowFilterExample. To spowoduje zastosowanie wszystkich filtrów zalezionych w obiekcie myFilters — w tym przykładzie jest to filtr filter.

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.DropShadowFilter;

    public class DropShadowFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function DropShadowFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var color:Number = 0x000000;
            var angle:Number = 45;
            var alpha:Number = 0.8;
            var blurX:Number = 8;
            var blurY:Number = 8;
            var distance:Number = 15;
            var strength:Number = 0.65;
            var inner:Boolean = false;
            var knockout:Boolean = false;
            var quality:Number = BitmapFilterQuality.HIGH;
            return new DropShadowFilter(distance,
                                        angle,
                                        color,
                                        alpha,
                                        blurX,
                                        blurY,
                                        strength,
                                        quality,
                                        inner,
                                        knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}