Bitmap  - AS3

Obiekt BitmapData, do którego odwołuje się funkcja.

Decyduje o tym, czy obiekt Bitmap jest przyciągany do najbliższego piksela. Klasa PixelSnapping zawiera następujące możliwe wartości:

• PixelSnapping.NEVER—Nie występuje przyciąganie pikseli.
• PixelSnapping.ALWAYS—Obraz zawsze jest przyciągany do najbliższego pikseli, bez względu na transformację.
• PixelSnapping.AUTO—Obraz jest przyciągany do najbliższego piksela, jeżeli jest rysowany bez obrotu lub pochylenia oraz przy współczynniku skali od 99.9% do 100.1%. Przy spełnieniu tych warunków obraz bitmapowy jest rysowany w skali 100%, przyciągany do najbliższego piksela. Wewnętrznie ta wartość zezwala na rysowanie obrazu tak szybko, jak jest to możliwe przy wykorzystaniu mechanizmu renderowania wektorów.

Decyduje o tym, czy podczas skalowania bitmapa jest wygładzana. Jeżeli wartość true, wówczas bitmapa jest wygładzana przy skalowaniu. Jeżeli wartość false, wówczas bitmapa nie jest wygładzana przy skalowaniu.

Inicjuje obiekt Bitmap odwołujący się do określonego obiektu BitmapData.

	bitmapData:BitmapData (default = null) — Obiekt BitmapData, do którego odwołuje się funkcja.
	pixelSnapping:String (default = "auto") — Określa, czy obiekt Bitmap jest przyciągany do najbliższego piksela, czy też nie.
	smoothing:Boolean (default = false) — Określa, czy bitmapa jest wygładzana w trakcie skalowania, czy też nie. Poniższe przykłady ilustrują wygląd bitmapy skalowanej przy współczynniku równym 3, z właściwością smoothing ustawioną na wartość false (lewo) oraztrue (prawo):

const IMAGE_URL:String = "http://www.helpexamples.com/flash/images/logo.png";
 
var ldr:Loader = new Loader();
ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, ldr_complete);
ldr.load(new URLRequest(IMAGE_URL));
 
var bitmap1:Bitmap;
var bitmap2:Bitmap;
var bitmap3:Bitmap;
var bitmap4:Bitmap;
 
function ldr_complete(evt:Event):void {
    var bmp:Bitmap = ldr.content as Bitmap;
 
    bitmap1 = new Bitmap(bmp.bitmapData);
    bitmap1.x = 100;
    bitmap1.y = 100;
    bitmap1.rotation = 0;
    addChild(bitmap1);
 
    bitmap2 = new Bitmap(bmp.bitmapData);
    bitmap2.x = 200;
    bitmap2.y = 100;
    bitmap2.rotation = 90;
    addChild(bitmap2);
 
    bitmap3 = new Bitmap(bmp.bitmapData);
    bitmap3.x = 300;
    bitmap3.y = 100;
    bitmap3.rotation = 180;
    addChild(bitmap3);
 
    bitmap4 = new Bitmap(bmp.bitmapData);
    bitmap4.x = 400;
    bitmap4.y = 100;
    bitmap4.rotation = 270;
    addChild(bitmap4);
}

1. Tworzona jest właściwość url, która jest miejscem położenia oraz nazwą pliku obrazu.
2. Klasa konstruktora wywołuje metodę configureAssets(), która z kolei wywołuje metodę completeHandler().
3. Metoda configureAssets() tworzy obiekt Loader, który z kolei tworzy instancję detektora zdarzeń, zaś ten jest wywoływany gdy metoda completeHandler() zakończy manipulację obrazu.
4. Następnie metoda buildChild() tworzy nową instancję obiektu URLRequest request z przekazaną właściwością url, aby nazwa pliku i lokacja były znane.
5. Obiekt request jest przekazywany do metody loader.load(), która ładuje obraz do pamięci poprzez obiekt wyświetlania.
6. Obraz jest wówczas umieszczany na liście wyświetlania, która prędko wyświetla obraz na ekranie na współrzędnych x = 0, y = 0.
7. Metoda completeHandler() przeprowadza wówczas następujące zadania:
   1. Tworzy drugi obiekt Loader, wraz z obiektem Bitmap, który jest inicjalizowany z obiektem Loader.
   2. Tworzy dugi obiekt Bitmap duplicate, który z kolei wywołuje metodę duplicateImage(), tworzącą duplikat oryginalnego obrazu.
   3. Tworzy obiekt BitmapData, który jest powiązany z obiektem duplicate obiektu BitmapData.
   4. Tworzy nowy obiekt Rectangle inicjalizowany z tymi samymi współrzędnymi, szerokością i wysokością jak obraz oryginalny.
   5. Tworzy nowy obiekt Point, którego współrzędne domyślne to x = 0, y = 0.
   6. Tworzy następujące zmienne:
      • operation: stosuje nowy kolor gdy wartość progowa jest >= w porównaniu do oryginału.
      • threshold: wartość wobec której każdy piksel jest porównywany jest ustawiona na kolor jasno szary z wartością alpha 0xCC.
      • color: kolor, na który zostaną ustawione piksele które zostały pozytywnie zweryfikowane przy teście progowym; w tym wypadku jest to jednolity kolor żółty.
      • mask: ustawiona na kolor dokładnie przeciwny (przezroczysty kolor niebieski).
      • copySource: ustawiona na wartość false, wskazuje, iż wartości pikseli nie są kopiowane w przypadku, gdy wartość progowa nie zostanie zweryfikowana pozytywnie. Ta wartość nie ma znaczenia, ponieważ obraz jest zduplikowany i wyłącznie piksele, które zostały pozytywnie zweryfikowane w teście progowym, są zmieniane.
   7. Wywołuje metodę threshold() poprzez wykorzystanie powyższych zmiennych. Końcowe równanie progowe wygląda następująco: jeżeli (obecna wartość pikseli & 0x000000FF) >= (0xCCCCCCCC & 0x000000FF) wówczas ustaw wartość pikseli na 0xFFFFFF00.

Uwagi:

• Należy skompilować plik SWF z opcją „Bezpieczeństwo odtwarzania lokalnego” ustawioną na wartość „Tylko pliki dostępne lokalnie”.
• Dla zilustrowania tego przykładu konieczne jest umieszczenie pliku o nazwie Image.gif w tym samym katalogu, co plik SWF.
• Zalecane jest wykorzystanie obrazu o szerokości do 80 pikseli.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.geom.Point;
    import flash.geom.Rectangle;
    import flash.net.URLRequest;

    public class BitmapExample extends Sprite {
        private var url:String = "Image.gif";
        private var size:uint = 80;

        public function BitmapExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

            var request:URLRequest = new URLRequest(url);
            loader.x = size * numChildren;
            loader.load(request);
            addChild(loader);
        }

        private function duplicateImage(original:Bitmap):Bitmap {
            var image:Bitmap = new Bitmap(original.bitmapData.clone());
            image.x = size * numChildren;
            addChild(image);
            return image;
        }

        private function completeHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var image:Bitmap = Bitmap(loader.content);

            var duplicate:Bitmap = duplicateImage(image);
            var bitmapData:BitmapData = duplicate.bitmapData;
            var sourceRect:Rectangle = new Rectangle(0, 0, bitmapData.width, bitmapData.height);
            var destPoint:Point = new Point();
            var operation:String = ">=";
            var threshold:uint = 0xCCCCCCCC;
            var color:uint = 0xFFFFFF00;
            var mask:uint = 0x000000FF;
            var copySource:Boolean = true;

            bitmapData.threshold(bitmapData,
                                 sourceRect,
                                 destPoint,
                                 operation,
                                 threshold,
                                 color,
                                 mask,
                                 copySource);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}