Matrix  - AS3

Wartość wpływająca na położenia pikseli wzdłuż osi x podczas skalowania lub obracania obrazu.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.a);  // 1

myMatrix.a = 2;
trace(myMatrix.a);  // 2

Wartość wpływająca na położenia pikseli wzdłuż osi y podczas obracania lub pochylania obrazu.

import flash.geom.Matrix;
 
var myMatrix:Matrix = new Matrix();
trace(myMatrix.b);  // 0

var degrees:Number = 30;
var radians:Number = (degrees/180) * Math.PI;
myMatrix.b = Math.tan(radians);
trace(myMatrix.b);  // 0.5773502691896257

Wartość wpływająca na położenia pikseli wzdłuż osi x podczas obracania lub pochylania obrazu.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.c);  // 0

var degrees:Number = 30;
var radians:Number = (degrees/180) * Math.PI;
myMatrix.c = Math.tan(radians);
trace(myMatrix.c);  // 0.5773502691896257

Wartość wpływająca na położenia pikseli wzdłuż osi y podczas skalowania lub obracania obrazu.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.d);  // 1

myMatrix.d = 2;
trace(myMatrix.d);  // 2

Odległość, o jaką należy przesunąć każdy punkt wzdłuż osi x.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.tx);  // 0

myMatrix.tx = 50;  // 50
trace(myMatrix.tx);

Odległość, o jaką należy przesunąć każdy punkt wzdłuż osi y.

import flash.geom.Matrix;

var myMatrix:Matrix = new Matrix();
trace(myMatrix.ty);  // 0

myMatrix.ty = 50;
trace(myMatrix.ty);  // 50

Tworzy nowy obiekt Matrix z określonymi parametrami. Oto organizacja właściwości w zapisie macierzowym:

Jeśli do konstruktora new Matrix() nie zostaną przekazane żadne parametry, utworzy on macierz jednostkową z następującymi wartościami:

a = 1

b = 0

c = 0

d = 1

tx = 0

ty = 0

W zapisie macierzowym macierz jednostkowa ma następującą postać:

import flash.geom.Matrix;

var matrix_1:Matrix = new Matrix();
trace(matrix_1);  // (a=1, b=0, c=0, d=1, tx=0, ty=0)

var matrix_2:Matrix = new Matrix(1, 2, 3, 4, 5, 6);
trace(matrix_2);  // (a=1, b=2, c=3, d=4, tx=5, ty=6)

Zwraca nowy obiekt Matrix będący klonem tej macierzy, z dokładną kopią zawartego obiektu.

Konkatenacja danej macierzy z macierzą bieżącą, z graficzną prezentacją wyniku operacji. W kategoriach matematycznych konkatenacja dwóch macierzy jest równoznaczna z połączeniem ich w wyniku mnożenia macierzy.

Na przykład, jeśli macierz m1 skaluje obiekt ze współczynnikiem cztery, a macierz m2 obraca obiekt o 1,5707963267949 radiana (Math.PI/2), to m1.concat(m2) przetransformuje m1 w macierz, która skaluje obiekt ze współczynnikiem cztery i obraca go o Math.PI/2 radiana.

Ta metoda zastępuje macierz źródłową macierzą po konkatenacji. Aby dokonać konkatenacji dwóch macierzy bez zmiany macierzy źródłowych, należy najpierw skopiować macierz źródłową za pomocą metody clone(), tak jak przedstawiono to w sekcji przykładów dla klasy.

Parametry

Kopiuje obiekt Vector3D do określonej kolumny wywołującego obiektu Matrix3D.

Parametry

Kopiuje określoną kolumnę wywołującego obiektu Matrix do obiektu Vector3D. Nie zostanie zmieniony element „w” obiektu Vector3D.

Parametry

Kopiuje wszystkie dane macierzy ze źródłowego obiektu Point do wywołującego obiektu Matrix.

Parametry

Kopiuje obiekt Vector3D do określonego wiersza wywołującego obiektu Matrix.

Parametry

Kopiuje określony wiersz wywołującego obiektu Matrix do obiektu Vector3D. Nie zostanie zmieniony element „w” obiektu Vector3D.

Parametry

Zawiera parametry skalowania, obrotu i translacji. Po zastosowaniu do macierzy ustawia jej wartości na podstawie tych parametrów.

Metoda createBox() umożliwia uzyskanie takiej samej macierzy, jaką uzyskalibyśmy po zastosowaniu kolejno metod identity(), rotate(), scale() i translate(). Na przykład wywołanie mat1.createBox(2,2,Math.PI/4, 100, 100) odniesie ten sam skutek, co:

     import flash.geom.Matrix;
     
     var mat1:Matrix = new Matrix();
     mat1.identity();
     mat1.rotate(Math.PI/4);
     mat1.scale(2,2);
     mat1.translate(10,20);
     

Parametry

Powiązane elementy interfejsu API

package
{
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    import flash.geom.Transform;
    
    public class Matrix_createBox extends Sprite
    {
        public function Matrix_createBox()
        {
             var myMatrix:Matrix = new Matrix();
             trace(myMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
             myMatrix.createBox(1, 2, Math.PI/4, 50, 100);
             trace(myMatrix.toString());  
             // (a=0.7071067811865476, b=1.414213562373095, c=-0.7071067811865475, 
             //  d=1.4142135623730951, tx=50, ty=100)
             
             var rectangleShape:Shape = createRectangle(20, 80, 0xFF0000);   
             addChild(rectangleShape);
              
             var rectangleTrans:Transform = new Transform(rectangleShape);
             rectangleTrans.matrix = myMatrix;
        }
        
        public function createRectangle(w:Number, h:Number, color:Number):Shape 
        {
            var rect:Shape = new Shape();
            rect.graphics.beginFill(color);
            rect.graphics.drawRect(0, 0, w, h);
            addChild(rect);
            return rect;
        }
    }
}

Tworzy macierz specjalną, oczekiwaną w metodach beginGradientFill() i lineGradientStyle() klasy Graphics. Szerokość i wysokość są skalowane zgodnie z parą scaleX/scaleY, a wartości tx/ty są modyfikowane o połowę szerokości i wysokości.

Na przykład weźmy pod uwagę gradient o następujących cechach:

• GradientType.LINEAR
• Dwa kolory, zielony i niebieski, z tablicami współczynników ustawionymi na [0, 255]
• SpreadMethod.PAD
• InterpolationMethod.LINEAR_RGB

Na poniższych ilustracjach przedstawiono gradienty, w których macierz zdefiniowano za pomocą metody createGradientBox() z różnymi parametrami:

Ustawienia metody createGradientBox()	Wynikowy gradient
width = 25; height = 25; rotation = 0; tx = 0; ty = 0;
width = 25; height = 25; rotation = 0; tx = 25; ty = 0;
width = 50; height = 50; rotation = 0; tx = 0; ty = 0;
width = 50; height = 50; rotation = Math.PI / 4; // 45 degrees tx = 0; ty = 0;

Parametry

Powiązane elementy interfejsu API

package
{
    import flash.display.GradientType;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    
    public class Matrix_createGradientBox extends Sprite
    {
        public function Matrix_createGradientBox()
        {
             var myMatrix:Matrix = new Matrix();
             trace(myMatrix.toString());          // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
             myMatrix.createGradientBox(200, 200, 0, 50, 50);
             trace(myMatrix.toString());          // (a=0.1220703125, b=0, c=0, d=0.1220703125, tx=150, ty=150)
             
             var colors:Array = [0xFF0000, 0x0000FF];
             var alphas:Array = [100, 100];
             var ratios:Array = [0, 0xFF];
             
             this.graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, myMatrix);
             this.graphics.drawRect(0, 0, 300, 200);
        }
    }
}

Zwraca nowe współrzędne punktu o podanych współrzędnych początkowych (po dokonaniu przekształcenia). W przeciwieństwie do standardowej transformacji realizowanej przez metodę transformPoint(), transformacja realizowana przez metodę deltaTransformPoint() nie uwzględnia parametrów translacji tx i ty.

Parametry

Ustawia wszystkie wartości macierzy, tak aby wymusić przekształcenie puste. Obiekt przetransformowany poprzez zastosowanie macierzy jednostkowej będzie identyczny z oryginalnym.

Po wywołaniu metody identity() macierz wynikowa ma następujące właściwości : a=1, b=0, c=0, d=1, tx=0, ty=0.

W zapisie macierzowym macierz jednostkowa ma następującą postać:

Stosuje do oryginalnej macierzy przekształcenie odwrotne. W celu wycofania transformacji dokonanych poprzez zastosowanie macierzy, można zastosować do obiektu macierz odwróconą.

package
{
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.geom.Matrix;
    import flash.geom.Transform;
    
    public class Matrix_invert extends Sprite
    {
        public function Matrix_invert()
        {
            var rect0:Shape = createRectangle(20, 80, 0xFF0000);   
            var rect1:Shape = createRectangle(20, 80, 0x00FF00);   
            var rect2:Shape = createRectangle(20, 80, 0x0000FF);
            var rect3:Shape = createRectangle(20, 80, 0x000000);
            
            var trans0:Transform = new Transform(rect0);
            var trans1:Transform = new Transform(rect1);
            var trans2:Transform = new Transform(rect2);
            var trans3:Transform = new Transform(rect3);
             
            var doubleScaleMatrix:Matrix = new Matrix(2, 0, 0, 2, 0, 0);
            trans0.matrix = doubleScaleMatrix;
            trace(doubleScaleMatrix.toString());  // (a=2, b=0, c=0, d=2, tx=0, ty=0)
             
            var noScaleMatrix:Matrix = new Matrix(1, 0, 0, 1, 0, 0);
            trans1.matrix = noScaleMatrix;
            rect1.x = 50;
            trace(noScaleMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)
             
            var halfScaleMatrix:Matrix = doubleScaleMatrix.clone();
            halfScaleMatrix.invert();
            trans2.matrix = halfScaleMatrix;
            rect2.x = 100;
            trace(halfScaleMatrix.toString());  // (a=0.5, b=0, c=0, d=0.5, tx=0, ty=0)
             
            var originalAndInverseMatrix:Matrix = doubleScaleMatrix.clone();
            originalAndInverseMatrix.concat(halfScaleMatrix);
            trans3.matrix = originalAndInverseMatrix;
            rect3.x = 150;
            trace(originalAndInverseMatrix.toString());  // (a=1, b=0, c=0, d=1, tx=0, ty=0)            
        }
        
        public function createRectangle(w:Number, h:Number, color:Number):Shape 
        {
            var rect:Shape = new Shape();
            rect.graphics.beginFill(color);
            rect.graphics.drawRect(0, 0, w, h);
            addChild(rect);
            return rect;
        }
    }
}

Powala obrócić obiekt Matrix.

Metoda rotate() modyfikuje właściwości a, b, c, i d obiektu Matrix. W zapisie macierzowym operacja ta jest równoważna konkatenacji bieżącej macierzy z następującą:

Parametry

Powala przeskalować obiekt Matrix. Wartości na osi x są mnożone przez sx, a wartości na osi y są mnożone przez sy.

Metoda scale() modyfikuje właściwości a i d obiektu Matrix. W zapisie macierzowym operacja ta jest równoważna konkatenacji bieżącej macierzy z następującą:

Parametry

Ustawia określone wartości elementów obiektu Matrix.

Parametry

Zwraca wartość tekstową zawierającą listę właściwości obiektu Matrix.

Zwraca wynik zastosowania przekształcenia geometrycznego reprezentowanego przez obiekt Matrix do określonego punktu.

Parametry

Dokonuje translacji macierzy wzdłuż osi x i y, zgodnie z parametrami dx i dy.

Parametry

1. Aplikacja tworzy nowy obiekt Matrix myMatrix i za pomocą metody trace() wyświetla domyślne wartości właściwości dla obiektu myMatrix.
2. Aplikacja wywołuje metodę createGradientBox() z parametrami width i height ustawionymi na 200 pikseli, bez obrotu i z przesunięciem wzdłuż osi x oraz y ustawionym na 50 pikseli.
3. Aplikacja ponownie wyświetla obiekt myMatrix, aby uwidocznić zmiany po wywołaniu metody createGradientBox().
4. Aplikacja konfiguruje trzy zmienne sterujące sposobem wypełniania gradientowego:
   • colors: Ustawia zakres kolorów gradientu między litym czerwonym a litym niebieskim.
   • alphas: Ustawia lite krycie.
   • ratios: Ustawia taki sam rozkład kolorów na identyczny dla czerwonego i niebieskiego.
5. Aplikacja wywołuje metodę graficzną beginGradientFill(), która operuje na obiekcie myMatrix, i wywołuje metodę lineTo(), co powoduje gradientowe wypełnienie prostokąta.

package {
    import flash.geom.Matrix;
    import flash.display.Sprite;
    import flash.display.GradientType;

    public class MatrixExample extends Sprite {

        public function MatrixExample() {
            var myMatrix:Matrix = new Matrix();
            trace(myMatrix.toString());    // (a=1, b=0, c=0, d=1, tx=0, ty=0)

            myMatrix.createGradientBox(200, 200, 0, 50, 50);
            trace(myMatrix.toString());    // (a=0.1220703125, b=0, c=0, d=0.1220703125, tx=150, ty=150)

            var colors:Array = [0xFF0000, 0x0000FF];
            var alphas:Array = [1, 1];
            var ratios:Array = [0, 0xFF];
            graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, myMatrix);
            graphics.lineTo(0, 300);
            graphics.lineTo(300, 300);
            graphics.lineTo(300, 0);
            graphics.lineTo(0, 0);
        }
    }
}