Graphics  - AS3

Wypełnia obszar rysunkowy obrazem bitmapowym. Bitmapa może być powtarzana lub w postaci mozaiki w celu wypełnienia obszaru. Wypełnienie będzie obowiązywało do czasu wywołania metody beginFill(), beginBitmapFill(), beginGradientFill() lub beginShaderFill(). Wywołanie metody clear() powoduje wyczyszczenie zawartości wypełnienia.

Aplikacja renderuje wypełnienie w momencie narysowania trzech lub więcej punktów lub gdy wywołana zostanie metoda endFill().

Parametry

     matrix = new flash.geom.Matrix(); 
     matrix.rotate(Math.PI / 4);
     

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.net.URLRequest;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.geom.Matrix;

    public class Graphics_beginBitmapFillExample extends Sprite {
 
        private var url:String = "image1.jpg";
        private var loader:Loader = new Loader();

        public function Graphics_beginBitmapFillExample() {

            var request:URLRequest = new URLRequest(url);
            
            loader.load(request);
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, drawImage);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function drawImage(event:Event):void {

            var mySprite:Sprite = new Sprite();
            var myBitmap:BitmapData = new BitmapData(loader.width, loader.height, false);
  
            myBitmap.draw(loader, new Matrix());
            
            var matrix:Matrix = new Matrix();
            matrix.rotate(Math.PI/4);
            
            mySprite.graphics.beginBitmapFill(myBitmap, matrix, true);
            mySprite.graphics.drawRect(100, 50, 200, 90);
            mySprite.graphics.endFill();
            
            addChild(mySprite);
        }
 
         private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }   
}

Określa proste wypełnienie jednokolorowe, które będzie używane w kolejnych wywołaniach innych metod klasy Graphics, takich jak lineTo() lub drawCircle(). Wypełnienie będzie obowiązywało do czasu wywołania metody beginFill(), beginBitmapFill(), beginGradientFill() lub beginShaderFill(). Wywołanie metody clear() powoduje wyczyszczenie zawartości wypełnienia.

Aplikacja renderuje wypełnienie w momencie narysowania trzech lub więcej punktów lub gdy wywołana zostanie metoda endFill().

Parametry

Powiązane elementy interfejsu API

Określa wypełnienie gradientowe, które będzie stosowane przy kolejnych wywołaniach metod z klasy Graphics (np. lineTo() i drawCircle()) dla obiektu. Wypełnienie będzie obowiązywało do czasu wywołania metody beginFill(), beginBitmapFill(), beginGradientFill() lub beginShaderFill(). Wywołanie metody clear() powoduje wyczyszczenie zawartości wypełnienia.

Aplikacja renderuje wypełnienie w momencie narysowania trzech lub więcej punktów lub gdy wywołana zostanie metoda endFill().

Parametry

	type:String — Wartość z klasy GradientType, która określa który z typów gradientów należy zastosować: GradientType.LINEAR czy GradientType.RADIAL.
	colors:Array — Tablica wartości kolorów RGB w formacie szesnastkowym do wykorzystania w gradiencie, na przykład: czerwony to 0xFF0000, niebieski to 0x0000FF itd. Możliwe jest określenie maksymalnie 15 kolorów. Dla każdego koloru należy określić odpowiednią wartość w parametrach alpha i proporcji.
	alphas:Array — Tablica wartości alpha dla odpowiednich kolorów w tablicy kolorów; wartości prawidłowe są w zakresie od 0 do 1. Jeżeli wartość wynosi mniej niż 0, wówczas wartość domyślna wynosi 0. Jeżeli wartość wynosi więcej niż 1, wówczas wartość domyślna wynosi 1.
	ratios:Array — Tablica proporcji dystrybucji kolorów; wartości prawidłowe są w zakresie od 0 do 255. Ta wartość definiuje procent szerokości, w której kolor jest próbkowany w 100%. Wartość 0 reprezentuje położenie po lewej stronie pola gradientu, zaś wartość 255 reprezentuje położenie po prawej stronie pola gradientu. Uwaga: Ta wartość reprezentuje położenia w polu gradientu, a nie układu współrzędnych końcowego gradientu, który może być szerszy lub cieńszy od pola gradientu. Należy określić wartość dla każdej wartości parametru colors. Przykładowo dla gradientu liniowego, który zawiera dwa kolory (niebieski i zielony), poniższy przykład ilustruje umiejscowienie kolorów w formie gradientowej według wartości innych niż znajdujące się w tablicy ratios: ratios Gradient [0, 127] [0, 255] [127, 255] Wartości w tablicy muszą zwiększać się w sekwencji; przykładowo: [0, 63, 127, 190, 255].
	matrix:Matrix (default = null) — Macierz przekształceń jest zdefiniowana przez klasę flash.geom.Matrix. Klasa flash.geom.Matrix zawiera metodę createGradientBox(), która pozwala na wygodne ustawienie matrycy do użycia z metodą beginGradientFill().
	spreadMethod:String (default = "pad") — Wartość z klasy SpreadMethod określa którą z metod rysowania należy wykorzystać: SpreadMethod.PAD, SpreadMethod.REFLECT lub SpreadMethod.REPEAT. Przykładowo biorąc pod uwagę prosty gradient liniowy między dwoma barwami: import flash.geom.* import flash.display.* var fillType:String = GradientType.LINEAR; var colors:Array = [0xFF0000, 0x0000FF]; var alphas:Array = [1, 1]; var ratios:Array = [0x00, 0xFF]; var matr:Matrix = new Matrix(); matr.createGradientBox(20, 20, 0, 0, 0); var spreadMethod:String = SpreadMethod.PAD; this.graphics.beginGradientFill(fillType, colors, alphas, ratios, matr, spreadMethod); this.graphics.drawRect(0,0,100,100); W tym przykładzie zastosowano metodę rysowania SpreadMethod.PAD, dzięki czemu wypełnienie gradientu wygląda następująco: W przypadku zastosowania metody rysowania SpreadMethod.REFLECT wypełnienie gradientu wygląda następująco: W przypadku zastosowania metody rysowania SpreadMethod.REPEAT wypełnienie gradientu wygląda następująco:
	interpolationMethod:String (default = "rgb") — Wartość dla klasy InterpolationMethod, która określa wartość do użycia: InterpolationMethod.LINEAR_RGB lub InterpolationMethod.RGB Przykładowo biorąc pod uwagę prosty gradient liniowy między dwoma barwami (przy parametrze spreadMethod ustawionym na wartość SpreadMethod.REFLECT). Różne metody interpolacji wpływają na wygląd w następujący sposób: InterpolationMethod.LINEAR_RGB InterpolationMethod.RGB
	focalPointRatio:Number (default = 0) — Liczba kontrolująca położenie ogniskowej gradientu. 0 oznacza, że ogniskowa znajduje się po środku. 1 oznacza, że ogniskowa znajduje się na jednej z granic okręgu gradientu. -1 oznacza, że ogniskowa znajduje się na drugiej z granic okręgu gradientu. Wartość mniejsza niż -1 lub większa niż 1 jest zaokrąglana do -1 lub 1. Przykład poniżej przedstawia właściwość focalPointRatio ustawioną na wartość 0,75:

Powiązane elementy interfejsu API

Określa wypełnienie dla modułu cieniującego, które będzie stosowane przy kolejnych wywołaniach metod klasy Graphics (np. lineTo() i drawCircle()) dla obiektu. Wypełnienie będzie obowiązywało do czasu wywołania metody beginFill(), beginBitmapFill(), beginGradientFill() lub beginShaderFill(). Wywołanie metody clear() powoduje wyczyszczenie zawartości wypełnienia.

Aplikacja renderuje wypełnienie w momencie narysowania trzech lub więcej punktów lub gdy wywołana zostanie metoda endFill().

Wypełnianie przy użyciu modułów cieniujących nie jest obsługiwane w przypadku renderowania GPU

Parametry

     matrix = new flash.geom.Matrix(); 
     matrix.rotate(Math.PI / 4);
     

Powiązane elementy interfejsu API

Czyści grafikę przypisaną do tego obiektu Graphics, zeruje wypełnienia i style linii.

Kopiuje wszystkie polecenia rysowania ze źródłowego obiektu Graphics do wywołującego obiektu Graphics.

Parametry

Rysuje sześcienną krzywą Beziera z bieżącego położenia rysowania do określonego punktu kotwiczenia. Sześcienne krzywe Beziera składają się z dwóch punktów kotwiczenia oraz dwóch punktów kontrolnych. Krzywa interpoluje oba punkty kotwiczenia i zmienia kształt w kierunku dwóch punktów kontrolnych.

Cztery punkty używane do rysowania sześciennej krzywej Beziera przy użyciu metody cubicCurveTo():

• Bieżące położenie rysowania stanowi pierwszy punkt kotwiczenia.
• Parametry anchorX i anchorY określają drugi punkt kotwiczenia.
• Parametry controlX1 i controlY1 określają pierwszy punkt kontrolny.
• Parametry controlX2 i controlY2 określają drugi punkt kontrolny.

W przypadku wywołania metody cubicCurveTo() przed wywołaniem metody moveTo() krzywa ma początek w punkcie (0, 0).

Jeśli metoda cubicCurveTo() zakończy się powodzeniem, środowisko wykonawcze Flash ustawi bieżące położenie rysowania w punkcie (anchorX, anchorY). Jeśli metoda cubicCurveTo() zakończy się niepowodzeniem, bieżące położenie rysowania pozostanie bez zmian.

Jeśli w klipie filmowym istnieje zawartość utworzona przy użyciu narzędzi do rysowania aplikacji Flash, wówczas rezultaty wywołań metody cubicCurveTo() są rysowane pod tą zawartością.

Parametry

package {
    import flash.display.Sprite;
    import flash.display.Shape;
    
    public class Graphics_cubicCurveToExample extends Sprite
    {
        public function Graphics_cubicCurveToExample():void
        {
            var rounderObject:Shape = new Shape();

            rounderObject.graphics.beginFill(0x0000FF);
            rounderObject.graphics.moveTo(250, 0);
            rounderObject.graphics.cubicCurveTo(275, 0, 300, 25, 300, 50);
            rounderObject.graphics.cubicCurveTo(300, 75, 275, 100, 250, 100);
            rounderObject.graphics.cubicCurveTo(225, 100, 200, 75, 200, 50);
            rounderObject.graphics.cubicCurveTo(200, 25, 225, 0, 250, 0);
            rounderObject.graphics.endFill();
            
            this.addChild(rounderObject);
        }
    }
}

Rysuje kwadratową krzywą Beziera przy użyciu bieżącego stylu linii z bieżącego położenia rysowania do punktu (anchorX, anchorY) zgodnie z punktem kontrolnym o współrzędnych (controlX, controlY). Obecna pozycja rysowania jest ustawiona na (anchorX, anchorY). W przypadku, gdy klip filmowy w którym przeprowadzane jest rysowanie posiada zawartość, która została utworzona przy pomocy narzędzi rysowania aplikacji Flash, wówczas wywołania metody curveTo() są rysowane pod zawartością. W sytuacji gdy zostanie wywołana metoda curveTo() przed wywołaniami metody moveTo(), wówczas domyślną pozycją obecnego rysowania jest (0,0). Jeżeli brak jest któregoś z parametrów ta metoda kończy się niepowodzeniem, zaś obecna pozycja rysowania nie jest zmieniana.

Narysowana krzywa jest kwadratową krzywą Beziera. Kwadratowe krzywe Beziera składają się z dwóch punktów kotwiczenia oraz jednego punktu kontrolnego. Krzywa interpoluje oba punkty kotwiczenia i krzywi się w kierunku punktu kontrolnego.

Parametry

package {
    import flash.display.Sprite;
    import flash.display.Shape;
    
    public class Graphics_curveToExample1 extends Sprite
    {
        public function Graphics_curveToExample1():void
        {
            var roundObject:Shape = new Shape();

            roundObject.graphics.beginFill(0x00FF00);
            roundObject.graphics.moveTo(250, 0);
            roundObject.graphics.curveTo(300, 0, 300, 50);
            roundObject.graphics.curveTo(300, 100, 250, 100);
            roundObject.graphics.curveTo(200, 100, 200, 50);
            roundObject.graphics.curveTo(200, 0, 250, 0);
            roundObject.graphics.endFill();
            
            this.addChild(roundObject);
        }
    }
}

package {
    import flash.display.Sprite;
    import flash.display.Shape;

    public class Graphics_curveToExample2 extends Sprite
    {
        public function Graphics_curveToExample2() {
            var newMoon:Shape = new Shape();
            
            newMoon.graphics.lineStyle(1, 0);
            newMoon.graphics.beginFill(0xFFFFFF);
            newMoon.graphics.moveTo(100, 100); 
            newMoon.graphics.curveTo(30, 150, 100, 200);    
            newMoon.graphics.curveTo(50, 150, 100, 100);
            graphics.endFill();
            
            this.addChild(newMoon);
        }
    }
}

Rysuje okrąg. Należy ustawić styl linii, wypełnienie lub obie te właściwości przed wywołaniem metody drawCircle(), poprzez wywołanie metody linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() lub beginBitmapFill().

Parametry

Powiązane elementy interfejsu API

Rysuje elipsę. Należy ustawić styl linii, wypełnienie lub obie te właściwości przed wywołaniem metody drawEllipse(), poprzez wywołanie metody linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() lub beginBitmapFill().

Parametry

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    import flash.display.Shape;

    public class Graphics_drawEllipseExample extends Sprite
    {
        public static const SMALL:uint = 0;
        public static const MEDIUM:uint = 1;
        public static const LARGE:uint = 2;

        public function Graphics_drawEllipseExample()
        {
            drawEgg(SMALL, 0, 100);
            drawEgg(MEDIUM, 100, 60);
            drawEgg(LARGE, 250, 35);    
        }

        public function drawEgg(eggSize:uint, x:Number, y:Number):void  {
            
            var myEgg:Shape = new Shape();
            
            myEgg.graphics.beginFill(0xFFFFFF);
            myEgg.graphics.lineStyle(1);

            switch(eggSize) {
                case SMALL:
                    myEgg.graphics.drawEllipse(x, y, 60, 70);
                    break;
                case MEDIUM:
                    myEgg.graphics.drawEllipse(x, y, 120, 150);    
                    break;
                case LARGE:
                    myEgg.graphics.drawEllipse(x, y, 150, 200);
                    break;
                default:
                    trace ("Wrong size! There is no egg.");
                break;            
            }
            
            myEgg.graphics.endFill();
    
            this.addChild(myEgg);
        }
    }
}

Wysyła serię instancji IGraphicsData dla rysunku. Ta metoda akceptuje wektor zawierający obiekty, łącznie ze ścieżkami, wypełnieniami i obrysami, które implementują interfejs IGraphicsData. W celu renderowania pełnego kształtu wektor instancji IGraphicsData może odwoływać się do części kształtu lub złożonego, w pełni zdefiniowanego zestawu danych.

Ścieżki Graphics mogą zawierać inne ścieżki graficzne. Jeśli wektor graphicsData zawiera ścieżkę, podczas tej operacji będzie renderowana ścieżka i wszystkie jej ścieżki podrzędne.

Parametry

Powiązane elementy interfejsu API

package
{
    import flash.display.*;
    import flash.geom.*;

    public class DrawGraphicsDataExample extends Sprite
    {
        public function DrawGraphicsDataExample()
        {
            // establish the fill properties
            var myFill:GraphicsGradientFill = new GraphicsGradientFill();
            myFill.colors = [0xEEFFEE, 0x0000FF];
            myFill.matrix = new Matrix();
            myFill.matrix.createGradientBox(100, 100, 0);
            
            // establish the stroke properties
            var myStroke:GraphicsStroke = new GraphicsStroke(2);
            myStroke.fill = new GraphicsSolidFill(0x000000);
            
            // establish the path properties
            var pathCommands = new Vector.<int>(5, true);
            pathCommands[0] = GraphicsPathCommand.MOVE_TO;
            pathCommands[1] = GraphicsPathCommand.LINE_TO;
            pathCommands[2] = GraphicsPathCommand.LINE_TO;
            pathCommands[3] = GraphicsPathCommand.LINE_TO;
            pathCommands[4] = GraphicsPathCommand.LINE_TO;
            
            var pathCoordinates:Vector.<Number> = new Vector.<Number>(10, true);
            pathCoordinates.push(10,10, 10,100, 100,100, 100,10, 10,10);
            
            var myPath:GraphicsPath = new GraphicsPath(pathCommands, pathCoordinates);
            
            // populate the IGraphicsData Vector array
            var myDrawing:Vector.<IGraphicsData> = new Vector.<IGraphicsData>(3, true);
            myDrawing[0] = myFill;
            myDrawing[1] = myStroke;
            myDrawing[2] = myPath;
            
            // render the drawing
            graphics.drawGraphicsData(myDrawing);
        }
    }
}

Wysyła serię poleceń dla rysunku. Metoda drawPath() przyjmuje w jednym wywołaniu obiekt Vector zawierający połączone polecenia rysowania moveTo(), lineTo() i curveTo(). Parametry metody drawPath() łączą polecenia rysowania z parami wartości x i y oraz kierunkiem rysowania. Polecenia rysowania są reprezentowane przez liczby całkowite — stałe zdefiniowane w klasie GraphicsPathCommand. Pary współrzędnych x- i y- są liczbami w tablicy, w której każda para definiuje miejsce w układzie współrzędnych. Kierunek rysowania jest wartością z klasy GraphicsPathWinding.

Zwykle rysunki są renderowane szybciej w przypadku użycia metody drawPath() niż kolejnych wywołań metod lineTo() i curveTo().

Metoda drawPath() korzysta z obliczeń zmiennoprzecinkowych, dzięki czemu rotacje i skalowanie kształtów jest bardziej dokładne i zapewnia lepsze wyniki. Jednak krzywe wprowadzone za pośrednictwem metody drawPath() mogą zawierać niewielkie błędy na poziomie wyrównania pikseli, gdy metoda będzie używana łącznie z metodami lineTo() oraz curveTo().

Metoda drawPath() korzysta również z innych reguł wypełniania i rysowania linii. Reguły są następujące:

• Gdy do renderowania ścieżki stosowane jest wypełnienie:
  • Ścieżka podrzędna zawierająca mniej niż 3 punkty nie jest renderowana. (Należy jednak pamiętać o tym, że dojdzie do renderowania obrysu, co jest spójne z regułami dla obrysów, które zostały przedstawione poniżej).
  • Ścieżka podrzędna, która nie jest zamknięta (punkt końcowy nie jest równy punktowi początkowemu), jest zamknięta niejawnie.
• Gdy do renderowania ścieżki stosowany jest obrys:
  • Ścieżki podrzędne mogą być złożone z dowolnej liczby punktów.
  • Ścieżka podrzędna nigdy nie jest zamknięta niejawnie.

Parametry

Powiązane elementy interfejsu API

package
{
    import flash.display.*;
        
    public class DrawPathExample extends Sprite
    {
        public function DrawPathExample()
        {
            var star_commands:Vector.<int> = new Vector.<int>(5, true);
            
            star_commands[0] = GraphicsPathCommand.MOVE_TO;
            star_commands[1] = GraphicsPathCommand.LINE_TO;
            star_commands[2] = GraphicsPathCommand.LINE_TO;
            star_commands[3] = GraphicsPathCommand.LINE_TO;
            star_commands[4] = GraphicsPathCommand.LINE_TO;
            
            var star_coord:Vector.<Number> = new Vector.<Number>(10, true);
            star_coord[0] = 66; //x
            star_coord[1] = 10; //y 
            star_coord[2] = 23; 
            star_coord[3] = 127; 
            star_coord[4] = 122; 
            star_coord[5] = 50; 
            star_coord[6] = 10; 
            star_coord[7] = 49; 
            star_coord[8] = 109; 
            star_coord[9] = 127;
            
            graphics.beginFill(0x003366);
            graphics.drawPath(star_commands, star_coord);
        }
    }
}

 graphics.drawPath(star_commands, star_coord, GraphicsPathWinding.NON_ZERO);
 

Rysuje prostokąt. Należy ustawić styl linii, wypełnienie lub obie te właściwości przed wywołaniem metody drawRect(), poprzez wywołanie metody linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() lub beginBitmapFill().

Parametry

Powiązane elementy interfejsu API

var movieClip:MovieClip = new MovieClip();
movieClip.graphics.beginFill(0xFF0000);
movieClip.graphics.drawRect(0, 0, 100, 80);
movieClip.graphics.endFill();
movieClip.x = 10;
movieClip.y = 10;
addChild(movieClip);

Rysuje zaokrąglony prostokąt. Należy ustawić styl linii, wypełnienie lub obie te właściwości przed wywołaniem metody drawRoundRect(), poprzez wywołanie metody linestyle(), lineGradientStyle(), beginFill(), beginGradientFill() lub beginBitmapFill().

Parametry

Powiązane elementy interfejsu API

Renderuje zbiór trójkątów, zwykle w celu odkształcenia bitmap i nadania im wyglądu trójwymiarowego. Metoda drawTriangles() odwzorowuje bieżące wypełnienie lub wypełnienie bitmapy na powierzchnie trójkątów, stosując zestaw współrzędnych (u,v).

Można użyć dowolnego typu wypełnienia, ale jeśli wypełnienie ma macierz transformacji, jest ona ignorowana.

Parametr uvtData poprawia odwzorowywanie tekstury, gdy używane jest wypełnienie bitmapy.

Parametry

Powiązane elementy interfejsu API

Stosuje wypełnienie linii oraz krzywych, które zostały dodane od momentu ostatniego wywołania metod beginFill()beginGradientFill()beginBitmapFill(). Aplikacja Flash stosuje wypełnienie, które zostało określone przy poprzednim wywołaniu metod beginFill(), beginGradientFill(), beginBitmapFill(). W sytuacji, gdy obecna pozycja rysowania nie jest równa poprzedniej pozycji określonej w metodzie moveTo() oraz zdefiniowane jest wypełnienie, wówczas ścieżka jest zamknięta linią a następnie wypełniana.

Powiązane elementy interfejsu API

Określa bitmapę, jaka będzie używana dla obrysu podczas rysowania linii.

Styl linii bitmapy będzie używany dla kolejnych wywołań metod Graphics, takich jak lineTo() lub drawCircle(). Styl linii będzie obowiązywał do czasu wywołania metod lineStyle() lub lineGradientStyle() albo ponownego wywołania metody lineBitmapStyle() z innymi parametrami.

Metodę lineBitmapStyle() można wywołać w trakcie rysowania ścieżki w celu określenia innych stylów dla różnych segmentów linii w ścieżce.

Aby aktywować obrys, należy wywołać metodę lineStyle() przed wywołaniem metody lineBitmapStyle() — w przeciwnym wypadku styl linii będzie następujący: undefined.

Wywołania metody clear() powodują ponowne ustawienie stylu linii: undefined.

Parametry

Powiązane elementy interfejsu API

Określa gradient, jaki będzie używany dla obrysu podczas rysowania linii.

Styl linii gradientowej będzie używany dla kolejnych wywołań metod Graphics, takich jak lineTo() lub drawCircle(). Linia będzie obowiązywała do czasu wywołania metod lineStyle() lub lineBitmapStyle(), albo ponownie metody lineGradientStyle() z innymi parametrami.

Możliwe jest wywołanie metody lineGradientStyle() w trakcie rysowania ścieżki w celu określenia różnych stylów dla odrębnych segmentów linii w ścieżce.

Aby aktywować obrys, należy wywołać metodę lineStyle() przed wywołaniem metody lineGradientStyle() — w przeciwnym wypadku styl linii będzie następujący: undefined.

Wywołania metody clear() powodują ponowne ustawienie stylu linii: undefined.

Parametry

	type:String — Wartość z klasy GradientType określająca, który z typów gradientu należy zastosować — GradientType.LINEAR czy też GradientType.RADIAL.
	colors:Array — Tablica wartości kolorów RGB w formacie szesnastkowym do wykorzystania w gradiencie (na przykład czerwony to 0xFF0000, niebieski to 0x0000FF itd.).
	alphas:Array — Tablica wartości alpha dla odpowiednich kolorów w tablicy kolorów; wartości prawidłowe są w zakresie od 0 do 1. Jeżeli wartość wynosi mniej niż 0, wówczas wartość domyślna wynosi 0. Jeżeli wartość wynosi więcej niż 1, wówczas wartość domyślna wynosi 1.
	ratios:Array — Tablica proporcji dystrybucji kolorów; wartości prawidłowe są w zakresie od 0 do 255. Ta wartość definiuje procent szerokości, w której kolor jest próbkowany w 100%. Wartość 0 reprezentuje położenie po lewej stronie pola gradientu, zaś wartość 255 reprezentuje położenie po prawej stronie pola gradientu. Ta wartość reprezentuje położenia w polu gradientu, a nie współrzędne w układzie współrzędnych końcowego gradientu, który może być szerszy lub cieńszy od pola gradientu. Należy określić wartość dla każdej wartości parametru colors. Przykładowo dla gradientu liniowego, który zawiera dwa kolory (niebieski i zielony), poniższa figura ilustruje umiejscowienie kolorów w formie gradientowej według wartości innych niż znajdujące się w tablicy ratios: ratios Gradient [0, 127] [0, 255] [127, 255] Wartości w tablicy muszą zwiększać się w sekwencji; przykładowo: [0, 63, 127, 190, 255].
	matrix:Matrix (default = null) — Matryca transformacyjna jest zdefiniowana przez klasę flash.geom.Matrix. Klasa flash.geom.Matrix zawiera metodę createGradientBox(), która pozwala na wygodne ustawienie matrycy do użycia z metodą lineGradientStyle().
	spreadMethod:String (default = "pad") — Wartość z klasy SpreadMethod, określająca którą z metod należy zastosować: SpreadMethod.PAD SpreadMethod.REFLECT SpreadMethod.REPEAT
	interpolationMethod:String (default = "rgb") — Wartość z klasy InterpolationMethod, określająca którą z wartości należy zastosować. Przykładowo biorąc pod uwagę prosty gradient liniowy między dwoma barwami (przy parametrze spreadMethod ustawionym na wartość SpreadMethod.REFLECT). Różne metody interpolacji wpływają na wygląd w następujący sposób: InterpolationMethod.LINEAR_RGB InterpolationMethod.RGB
	focalPointRatio:Number (default = 0) — Liczba kontrolująca położenie ogniskowej gradientu. Wartość równa 0 oznacza, że ogniskowa znajduje się po środku. Wartość równa 1 oznacza, że ogniskowa znajduje się na jednej z granic okręgu gradientu. Wartość równa -1 oznacza, że ogniskowa znajduje się na drugiej z granic okręgu gradientu. Wartości mniejsze niż -1 lub większe niż 1 są zaokrąglane do -1 lub 1. Poniższy obraz przedstawia gradient z właściwością focalPointRatio o wartości -0,75:

Powiązane elementy interfejsu API

package {
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.geom.Matrix; 
    import flash.display.GradientType;
    
    public class Graphics_lineGradientStyleExample extends Sprite
    {
        public function Graphics_lineGradientStyleExample()
        {
            var myShape:Shape = new Shape();
            var gradientBoxMatrix:Matrix = new Matrix();
  
            gradientBoxMatrix.createGradientBox(200, 40, 0, 0, 0);  
            
            myShape.graphics.lineStyle(5);
  
            myShape.graphics.lineGradientStyle(GradientType.LINEAR, [0xFF0000,
            0x00FF00, 0x0000FF], [1, 1, 1], [0, 128, 255], gradientBoxMatrix);
            
            myShape.graphics.drawRect(0, 0, 200, 40);
            myShape.graphics.drawCircle(100, 120, 50);  
             
            this.addChild(myShape);
    
        }
    }
}

Określa moduł cieniujący, jaki będzie używany dla obrysu podczas rysowania linii.

Styl linii modułu cieniującego będzie używany dla kolejnych wywołań metod Graphics, takich jak lineTo() lub drawCircle(). Styl linii będzie obowiązywał do czasu wywołania metod lineStyle() lub lineGradientStyle(), albo ponownie metody lineBitmapStyle() z innymi parametrami.

Metodę lineShaderStyle() można wywołać w trakcie rysowania ścieżki w celu określenia innych stylów dla różnych segmentów linii w ścieżce.

Aby aktywować obrys, należy wywołać metodę lineStyle() przed wywołaniem metody lineShaderStyle() — w przeciwnym wypadku styl linii będzie następujący: undefined.

Wywołania metody clear() powodują ponowne ustawienie stylu linii: undefined.

Parametry

Powiązane elementy interfejsu API

Określa styl linii, jaki będzie używany dla kolejnych wywołań metod Graphics, takich jak lineTo() lub drawCircle(). Styl linii będzie obowiązywał do czasu wywołania metody lineGradientStyle(), metodylineBitmapStyle() lub metody lineStyle() z innymi parametrami.

Metodę lineStyle() można wywołać w trakcie rysowania ścieżki w celu określenia innych stylów dla różnych segmentów linii w ścieżce.

Uwaga: Wywołania metody clear() ustawiają styl linii na z powrotem na wartość undefined.

Uwaga: Program Flash Lite 4 obsługuje jedynie trzy pierwsze parametry (thickness, color oraz alpha).

Parametry

Powiązane elementy interfejsu API

Rysuje linię przy wykorzystaniu obecnego stylu linii z obecnej pozycji rysowania do (x, y); wówczas obecna pozycja rysowania jest ustawiana na (x,y). W przypadku, gdy obiekt wyświetlania w którym przeprowadzane jest rysowanie posiada zawartość, która została utworzona przy pomocy narzędzi rysowania aplikacji Flash, wówczas wywołania metody lineTo() są rysowane pod zawartością. W sytuacji gdy zostanie wywołana metoda lineTo() przed wywołaniami metody moveTo(), wówczas domyślną pozycją obecnego rysowania jest (0, 0). Jeżeli brakuje któregoś z parametrów, ta metoda kończy działanie niepowodzeniem, zaś obecna pozycja rysowania nie ulega zmianie.

Parametry

package {
    import flash.display.Sprite;
    import flash.display.LineScaleMode;
    import flash.display.CapsStyle;
    import flash.display.JointStyle;
    import flash.display.Shape;


    public class Graphics_lineToExample extends Sprite {

        public function Graphics_lineToExample() {

            var trapezoid:Shape = new Shape();    

            trapezoid.graphics.lineStyle(10, 0xFFD700, 1, false, LineScaleMode.VERTICAL,
                               CapsStyle.NONE, JointStyle.MITER, 10);

            trapezoid.graphics.moveTo(100, 100);
 
            trapezoid.graphics.lineTo(120, 50);
            trapezoid.graphics.lineTo(200, 50);
            trapezoid.graphics.lineTo(220, 100);
            trapezoid.graphics.lineTo(100, 100); 

            this.addChild(trapezoid);
        }
    }
}

Przenosi obecną pozycję rysowania na: (x,y). Jeżeli brakuje któregoś z parametrów, ta metoda kończy działanie niepowodzeniem, zaś obecna pozycja rysowania nie ulega zmianie.

Parametry

package {
    import flash.display.Sprite;
    import flash.display.CapsStyle;
    import flash.display.LineScaleMode;

    public class Graphics_moveToExample extends Sprite
    {
        public function Graphics_moveToExample() {
            
            graphics.lineStyle(3, 0x990000, 0.25, false, 
                            LineScaleMode.NONE, CapsStyle.SQUARE);

            graphics.moveTo(10, 20);
            graphics.lineTo(20, 20);
            graphics.moveTo(30, 20);
            graphics.lineTo(50, 20);
            graphics.moveTo(60, 20);
            graphics.lineTo(80, 20);
            graphics.moveTo(90, 20);
            graphics.lineTo(110, 20);            
            graphics.moveTo(120, 20);
            graphics.lineTo(130, 20);           
        }
    }
}

Pobiera zawartość grafiki wektorowej obiektu Sprite lub Shape (opcjonalnie jego elementów potomnych). Wynikiem jest wektor obiektów IGraphicsData. Przed zapytaniem do obiektów ekranowych są stosowane przekształcenia, dzięki czemu wszystkie zwracane ścieżki znajdują się w tej samej przestrzeni współrzędnych. Współrzędne w wynikowym zestawie danych są podane względem stołu montażowego, a nie próbkowanego obiektu ekranowego.

Wynik zawiera obiekty następujących typów z wymienionymi ograniczeniami:

• GraphicsSolidFill
• GraphicsGradientFill
  • Metoda readGraphicsData() zwraca wszystkie właściwości wypełnienia gradientem.
  • Zwracana macierz jest zbliżona do macierzy wejściowej, ale nie jest taka sama.
• GraphicsEndFill
• GraphicsBitmapFill
  • Zwracana macierz jest zbliżona do macierzy wejściowej, ale nie jest taka sama.
  • Właściwość repeat zawsze ma wartość true.
  • Właściwość smooth zawsze ma wartość false.
• GraphicsStroke
  • Jest obsługiwana właściwość thickness.
  • Właściwość fill obsługuje wartości GraphicsSolidFill, GraphicsGradientFill i GraphicsBitmapFill zgodnie z opisem powyżej.
  • Wszystkie pozostałe właściwości mają wartości domyślne.
• GraphicsPath
  • Są obsługiwane tylko polecenia MOVE_TO, CURVE_TO i LINE_TO.

Wynik nie zawiera następujących elementów wizualnych i przekształceń, gdyż nie można ich odwzorować:

• Maski
• Tekst z wyjątkiem tekstu statycznego zdefiniowanego z opcją „Wygładź dla animacji”, który jest renderowany jako kształty wektorowe i zawarty w wyniku.
• Wypełnienia z cieniowaniem
• Tryby mieszania
• Skalowanie z podziałem na obszary
• Trójkąty (utworzone przy użyciu metody drawTriangles())
• Nieprzezroczyste tło
• Ustawienia scrollrect
• Przekształcenia 2,5D
• Niewidoczne obiekty (z właściwością visible o wartości false)

Parametry

Powiązane elementy interfejsu API

package
{
    import flash.display.GraphicsPathCommand;
    import flash.display.IGraphicsData;
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    
    public class ReadGraphicsDataExample extends Sprite
    {
        private var original:Shape;
        private var copy:Shape;
        
        public function ReadGraphicsDataExample()
        {
            original = new Shape();
            original.x = 50;
            original.y = 100;
            addChild(original);
            
            drawSquare();
            
            copy = new Shape();
            copy.x = 250;
            copy.y = 100;
            addChild(copy);
            
            stage.addEventListener(MouseEvent.CLICK, drawCopyOnClick);
        }
        
        private function drawCopyOnClick(event:MouseEvent):void
        {
            // reset
            copy.graphics.clear();
            
            // Sample the vector data. Move the original to 0,0
            // before sampling so that the coordinates match the 
            // relative coordinates of the original.
            var xPos:Number = original.x;
            var yPos:Number = original.y;
            original.x = 0;
            original.y = 0;
            var result:Vector.<IGraphicsData> = original.graphics.readGraphicsData(false);
            original.x = xPos;
            original.y = yPos;
            
            // re-draw
            copy.graphics.drawGraphicsData(result);
        }
        
        private function drawSquare():void
        {
            var squareCommands:Vector.<int> = new Vector.<int>(5, true);
            
            squareCommands[0] = GraphicsPathCommand.MOVE_TO;
            squareCommands[1] = GraphicsPathCommand.LINE_TO;
            squareCommands[2] = GraphicsPathCommand.LINE_TO;
            squareCommands[3] = GraphicsPathCommand.LINE_TO;
            
            var squareCoordinates:Vector.<Number> = new Vector.<Number>(8, true);
            squareCoordinates[0] = 0;
            squareCoordinates[1] = 0; 
            squareCoordinates[2] = 50; 
            squareCoordinates[3] = 0; 
            squareCoordinates[4] = 50; 
            squareCoordinates[5] = 50; 
            squareCoordinates[6] = 0; 
            squareCoordinates[7] = 50; 
            
            original.graphics.beginFill(0x003366);
            original.graphics.drawPath(squareCommands, squareCoordinates);
        }
    }
}

1. Deklaruje właściwość size do późniejszego użytku przy określaniu rozmiaru każdej figury.
2. Należy zadeklarować właściwości w celu ustawienia tła na kolor pomarańczowy, barwę obramowania na kolor szary, rozmiar obramowania na 0 pikseli, promień kąta na 9 pikseli oraz ustawić przestrzeń pomiędzy krawędzią stołu montażowego i innych obiektów na 5 pikseli.
3. Należy wykorzystać właściwości zadeklarowane w poprzednich krokach wraz z wbudowanymi metodami klasy Graphics w celu narysowania okręgu, zaokrąglonego prostokąta oraz kwadratu na współrzędnych x = 0, y = 0.
4. Narysuj ponownie figury wzdłuż górnej części stołu montażowego, rozpoczynając na współrzędnych x = 5, y = 5, przy 5-pikselowej przerwie między figurami.

package {
    import flash.display.DisplayObject;
    import flash.display.Graphics;
    import flash.display.Shape;
    import flash.display.Sprite;

    public class GraphicsExample extends Sprite {
        private var size:uint         = 80;
        private var bgColor:uint      = 0xFFCC00;
        private var borderColor:uint  = 0x666666;
        private var borderSize:uint   = 0;
        private var cornerRadius:uint = 9;
        private var gutter:uint       = 5;

        public function GraphicsExample() {
            doDrawCircle();
            doDrawRoundRect();
            doDrawRect();
            refreshLayout();
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject;
            var lastChild:DisplayObject = getChildAt(0);
            lastChild.x = gutter;
            lastChild.y = gutter;
            for (var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = gutter + lastChild.x + lastChild.width;
                child.y = gutter;
                lastChild = child;
            }
        }

        private function doDrawCircle():void {
            var child:Shape = new Shape();
            var halfSize:uint = Math.round(size / 2);
            child.graphics.beginFill(bgColor);
            child.graphics.lineStyle(borderSize, borderColor);
            child.graphics.drawCircle(halfSize, halfSize, halfSize);
            child.graphics.endFill();
            addChild(child);
        }

        private function doDrawRoundRect():void {
            var child:Shape = new Shape();
            child.graphics.beginFill(bgColor);
            child.graphics.lineStyle(borderSize, borderColor);
            child.graphics.drawRoundRect(0, 0, size, size, cornerRadius);
            child.graphics.endFill();
            addChild(child);
        }

        private function doDrawRect():void {
            var child:Shape = new Shape();
            child.graphics.beginFill(bgColor);
            child.graphics.lineStyle(borderSize, borderColor);
            child.graphics.drawRect(0, 0, size, size);
            child.graphics.endFill();
            addChild(child);
        }
    }
}