DisplayObjectContainer  - AS3

Określa, czy elementy podrzędne obiektu obsługują mysz lub inne urządzenie wejściowe użytkownika. Jeśli obiekt obsługuje takie urządzenia, użytkownik może wchodzić z nim w interakcje za pomocą myszy lub innego urządzenia wejściowego. Wartością domyślną jest true.

Właściwość ta jest pomocna przy utworzeniu przycisku z instancją klasy Sprite (zamiast wykorzystania klasy SimpleButton). Przy wykorzystaniu instancji Sprite w celu utworzenia przycisku możliwa jest dekoracja przycisku przez zastosowanie metody addChild() w celu dodania innych instancji Sprite. Proces ten może wywołać nieoczekiwane zachowanie ze zdarzeniami myszy, ponieważ dodawane instancje Sprite jako elementy podrzędne mogą stać się obiektami docelowymi zdarzeń myszy, zamiast planowanych obiektów nadrzędnych. W celu zapewnienia, iż obiektami docelowymi zdarzeń myszy będą obiekty nadrzędne, należy ustawić właściwość mouseChildren instancji nadrzędnej na wartość false.

Ustawienie tej właściwości nie powoduje wywołania żadnego zdarzenia. Konieczne jest zastosowanie metody addEventListener() w celu utworzenia interaktywnej funkcjonalności.

Powiązane elementy interfejsu API

import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
container.name = "container";
addChild(container);

var circle:Sprite = new Sprite();
circle.name = "circle";
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(40, 40, 40);

container.addChild(circle);

container.mouseChildren = false;

container.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace(event.target.name); // container
}

Zwraca liczbę elementów potomnych tego obiektu.

import flash.display.Sprite;

var container1:Sprite = new Sprite();
var container2:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(80, 40, 40);

container2.addChild(container1);
container1.addChild(circle1);
container1.addChild(circle2);

trace(container1.numChildren); // 2
trace(container2.numChildren); // 1
trace(circle1.numChildren); // 0
trace(circle2.numChildren); // 0

Określa, czy obiekty podrzędne tego obiektu mają reagować na klawisz Tab. Włącza lub wyłącza przechodzenie klawiszem Tab między elementami podrzędnymi obiektu. Wartością domyślną jest true.

Uwaga: Nie należy korzystać z właściwości tabChildren w środowisku Flex. Należy zamiast tego skorzystać z właściwości mx.core.UIComponent.hasFocusableChildren.

import flash.display.Sprite;

var container:Sprite = new Sprite();
container.tabChildren = false;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.tabIndex = 1;

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(120, 40, 40);
circle2.tabIndex = 0;

container.addChild(circle1);
container.addChild(circle2);

Zwraca obiekt TextSnapshot dla tego wystąpienia klasy DisplayObjectContainer.

Powiązane elementy interfejsu API

trace(this.textSnapshot.getText(0, this.textSnapshot.charCount));

Wywoływanie konstruktora new DisplayObjectContainer() powoduje zgłoszenie wyjątku ArgumentError. Jednakże możliwe jest wywołanie konstruktorów następujących podklas obiektu DisplayObjectContainer:

• new Loader()
• new Sprite()
• new MovieClip()

Dodaje potomne wystąpienie klasy DisplayObject do tego wystąpienia klasy DisplayObjectContainer. Obiekt podrzędny jest dodawany na przód (szczyt) pozostałych obiektów podrzędnych w tej instancji DisplayObjectContainer. (W celu dodania obiektu podrzędnego na określony indeks należy wykorzystać metodę addChildAt()).

Dodanie obiektu potomnego, który ma już element macierzysty w postaci innego kontenera obiektów ekranowych, spowoduje usunięcie tego obiektu z listy elementów potomnych tego innego kontenera obiektów ekranowych.

Uwaga: Polecenie stage.addChild() może powodować problemy w opublikowanych plikach SWF, a w szczególności problemy z zabezpieczeniami i konflikty z innymi załadowanymi plikami SWF. W danej instancji środowiska wykonawczego Flash istnieje tylko jeden stół montażowy, niezależnie od tego, ile plików SWF jest załadowanych do środowiska. Dlatego co do zasady nie należy nigdy dodawać obiektów bezpośrednio do stołu montażowego. Jedynym obiektem, jaki powinien zawierać stół montażowy, jest obiekt główny hierarchii. Należy utworzyć obiekt DisplayObjectContainer, który będzie zawierał wszystkie elementy listy wyświetlania. Następnie w razie potrzeby należy dodać tę instancję klasy DisplayObjectContainer do stołu montażowego.

Parametry

Powiązane elementy interfejsu API

import flash.display.Sprite;

var container1:Sprite = new Sprite();
var container2:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(80, 40, 40);

container2.addChild(container1);
container1.addChild(circle1);
container1.addChild(circle2);

trace(container1.numChildren); // 2
trace(container2.numChildren); // 1
trace(circle1.numChildren); // 0
trace(circle2.numChildren); // 0

Dodaje instancję obiektu podrzędnego DisplayObject do tej instancji obiektu DisplayObjectContainer. Obiekt podrzędny jest dodawany na następnym określonym indeksie. Indeks równy 0 reprezentuje tył (dół) listy wyświetlania dla tego obiektu DisplayObjectContainer.

Trzy obiekty wyświetlane o etykietach a, b i c znajdują się odpowiednio na indeksach 0, 2 i 1, co widać na poniższym przykładzie:

W przypadku dodania obiektu podrzędnego, który jako obiekt nadrzędny posiada już inny kontener obiektów wyświetlanych, jest on usuwany z listy obiektów podrzędnych tego kontenera.

Parametry

Powiązane elementy interfejsu API

import flash.display.Sprite;

var container:Sprite = new Sprite();

var circle1:Sprite = new Sprite();
var circle2:Sprite = new Sprite();

container.addChild(circle1);
container.addChildAt(circle2, 0);

trace(container.getChildAt(0) == circle2); // true
trace(container.getChildAt(1) == circle1); // true

Wskazuje, czy ograniczenia ze względów bezpieczeństwa mogą spowodować pominięcie obiektów wyświetlanych z listy zwróconej przy wywołaniu metody DisplayObjectContainer.getObjectsUnderPoint() z określonym punktem point. Domyślnie zawartość jednej domeny nie może mieć dostępu do obiektów innej domeny, chyba że zostało to dozwolone poprzez wywołanie metody Security.allowDomain(). Więcej informacji na temat zabezpieczeń zawiera odpowiedni temat w witrynie Flash Player Developer Center: Bezpieczeństwo.

Parametr point jest określony w układzie współrzędnych obiektu Stage, który może różnić się względem układu współrzędnych kontenera obiektów wyświetlanych (chyba że jest nim obiekt Stage). Możliwe jest zastosowanie metod globalToLocal() i localToGlobal() w celu konwersji punktów pomiędzy dwoma układami współrzędnych.

Parametry

Powiązane elementy interfejsu API

import flash.display.Sprite;
import flash.display.Loader;
import flash.system.LoaderContext;
import flash.net.URLRequest;
import flash.events.Event;
import flash.geom.Point;

var container:Sprite = new Sprite();

var urlReq:URLRequest = new URLRequest("http://localhost/RemoteFile.swf");
var ldr:Loader = new Loader();
var context:LoaderContext = new LoaderContext();
context.checkPolicyFile = false;
ldr.load(urlReq, context);

ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, loaded);
ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, urlNotFound);

function loaded(event:Event):void {
    var pt:Point = new Point(1, 1);
    trace(container.areInaccessibleObjectsUnderPoint(pt)); // true
}

function urlNotFound(event:Event):void {
    trace("The URL was not found."); 
}

Decyduje o tym, czy określony obiekt wyświetlany jest obiektem podrzędnym instancji obiektu DisplayObjectContainer, czy też sam jest taką instancją. Przeszukiwanie obejmuje całą listę wyświetlania, włącznie z tą instancją DisplayObjectContainer. Obiekty wnucząt i prawnucząt (itd.) zwracają wartość true.

Parametry

import flash.display.Sprite;

var sprite1:Sprite = new Sprite();
var sprite2:Sprite = new Sprite();
var sprite3:Sprite = new Sprite();
var sprite4:Sprite = new Sprite();

sprite1.addChild(sprite2);
sprite2.addChild(sprite3);

trace(sprite1.contains(sprite1)); // true
trace(sprite1.contains(sprite2)); // true
trace(sprite1.contains(sprite3)); // true
trace(sprite1.contains(sprite4)); // false

Zwraca wystąpienie potomnego obiektu ekranowego o podanym indeksie.

Parametry

Powiązane elementy interfejsu API

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
var sprite2:Sprite = new Sprite();
var sprite3:Sprite = new Sprite();

container.addChild(sprite1);
container.addChild(sprite2);
container.addChildAt(sprite3, 0);

trace(container.getChildAt(0) == sprite3); // true
trace(container.getChildAt(1) == sprite1); // true
trace(container.getChildAt(2) == sprite2); // true

Zwraca instancję podrzędnego obiektu wyświetlanego o podanej nazwie. Jeżeli więcej niż jeden podrzędny obiekt wyświetlany nosi tę określoną nazwę, metoda zwraca pierwszy obiekt z listy obiektów podrzędnych.

Metoda getChildAt() jest szybsza niż metoda getChildByName(). Metoda getChildAt() uzyskuje dostęp do obiektu podrzędnego wprost z buforowanej tablicy, zaś metoda getChildByName() musi w tym celu przejść przez powiązaną listę.

Parametry

Powiązane elementy interfejsu API

import flash.display.Sprite;
import flash.display.DisplayObject;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

var target:DisplayObject = container.getChildByName("sprite1"); 
trace(container.getChildIndex(target)); // 0

Zwraca indeks instancji child DisplayObject.

Parametry

import flash.display.Sprite;
import flash.display.DisplayObject;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

var target:DisplayObject = container.getChildByName("sprite1"); 
trace(container.getChildIndex(target)); // 0

Zwraca tablicę obiektów, które leżą poniżej określonego punktu i są obiektami podrzędnymi tej instancji obiektu DisplayObjectContainer. Obiekty niedostępne ze względów bezpieczeństwa są pominięte w zwróconej tablicy. W celu określenia, czy ograniczenia ze względów bezpieczeństwa mają wpływ na zwracaną tablicę, należy wywołać metodę areInaccessibleObjectsUnderPoint().

Parametr point jest określony w układzie współrzędnych obiektu Stage, który może różnić się względem układu współrzędnych kontenera obiektów wyświetlanych (chyba że jest nim obiekt Stage). Możliwe jest zastosowanie metod globalToLocal() i localToGlobal() w celu konwersji punktów pomiędzy dwoma układami współrzędnych.

Parametry

Powiązane elementy interfejsu API

import flash.display.Sprite;
import flash.geom.Point;

var container:Sprite = new Sprite();

var square1:Sprite = new Sprite();
square1.graphics.beginFill(0xFFCC00);
square1.graphics.drawRect(0, 0, 40, 40);

var square2:Sprite = new Sprite();
square2.graphics.beginFill(0x00CCFF);
square2.graphics.drawRect(20, 0, 30, 40);

container.addChild(square1);
container.addChild(square2);

var pt:Point = new Point(10, 20);
var objects:Array = container.getObjectsUnderPoint(pt); 
trace(objects.length); // 1

pt = new Point(35, 20);
objects = container.getObjectsUnderPoint(pt);
trace(objects.length);  // 2

Usuwa określoną instancję child DisplayObject z listy obiektów podrzędnych instancji DisplayObjectContainer. Właściwość parent usuniętego obiektu podrzędnego jest ustawiona na wartość null, zaś obiekt jest usuwany jako element zbędny, jeżeli nie ma do niego innych odwołań. Indeksy dowolnych obiektów wyświetlanych znajdujących się ponad obiektem podrzędnym w obiekcie DisplayObjectContainer są zmniejszane o 1.

Proces czyszczenia pamięci ponownie przydziela niewykorzystane miejsce w pamięci. Jeżeli zmienna lub obiekt nie są już aktywnie używane lub aktywnie przechowywane, wówczas proces czyszczenia pamięci zwalnia zajmowaną przez nie pamięć, o ile nie istnieją odwołania do nich.

Parametry

 
import flash.display.DisplayObject;
import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
addChild(container);

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00CCFF);
circle2.graphics.drawCircle(120, 40, 40);

container.addChild(circle1);
container.addChild(circle2);

container.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    container.removeChild(DisplayObject(event.target)); 
}

Usuwa obiekt potomny DisplayObject z określonej pozycji index z listy obiektów potomnych instancji DisplayObjectContainer. Właściwość parent usuniętego obiektu potomnego jest ustawiona na wartość null, zaś obiekt jest usuwany jako element zbędny, jeżeli nie ma do niego innych odwołań. Indeksy dowolnych obiektów wyświetlanych znajdujących się ponad obiektem podrzędnym w obiekcie DisplayObjectContainer są zmniejszane o 1.

Proces czyszczenia pamięci ponownie przydziela niewykorzystane miejsce w pamięci. Jeżeli zmienna lub obiekt nie są już aktywnie używane lub aktywnie przechowywane, wówczas proces czyszczenia pamięci zwalnia zajmowaną przez nie pamięć, o ile nie istnieją odwołania do nich.

Parametry

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

trace(container.numChildren) // 2
container.removeChildAt(0); 
trace(container.numChildren) // 1
trace(container.getChildAt(0).name); // sprite2

Powoduje usunięcie wszystkich obiektów DisplayObject o właściwości child z listy obiektów potomnych wystąpienia klasy DisplayObjectContainer. Dla właściwości parent usuniętych obiektów potomnych zostaje ustawiona wartość null, zaś obiekty są usuwane jako elementy zbędne, jeżeli nie ma do nich innych odniesień.

Proces czyszczenia pamięci ponownie przydziela niewykorzystane miejsce w pamięci. Jeżeli zmienna lub obiekt nie są już aktywnie używane lub aktywnie przechowywane, wówczas proces czyszczenia pamięci zwalnia zajmowaną przez nie pamięć, o ile nie istnieją odwołania do nich.

Parametry

Zmienia położenie istniejącego potomka w kontenerze obiektu ekranowego. Ma to wpływ na warstwowanie obiektów podrzędnych. Trzy obiekty wyświetlane o etykietach a, b i c znajdują się odpowiednio na indeksach 0, 1 i 2, co widać na poniższym przykładzie:

Przy wykorzystaniu metody setChildIndex() i określeniu indeksu, który jest już zajęty, jedynymi pozycjami ulegającymi zmianie są stara i nowa pozycja obiektu wyświetlanego. Wszystkie inne pozycje pozostają bez zmian. Jeżeli obiekt podrzędny jest przesunięty na index NIŻSZY niż obecny, wówczas wszystkie obiekty w przestrzeni zmiany pozycji ZWIĘKSZAJĄ swoje odwołanie indeksowe o 1. Jeżeli obiekt potomny jest przesunięty na index WYŻSZY niż obecny, wówczas wszystkie obiekty w przestrzeni zmiany pozycji ZMNIEJSZAJĄ swoje odwołanie indeksowe o 1. Przykładowo jeżeli kontener obiektów wyświetlania nosi nazwę container (z poprzedniego przykładu), wówczas możliwa jest zamiana pozycji obiektów wyświetlania nazwanych a i b poprzez wywołanie następującego kodu:

container.setChildIndex(container.getChildAt(1), 0);

Kod ten skutkuje ułożeniem obiektów w sposób przedstawiony poniżej:

Parametry

Powiązane elementy interfejsu API

import flash.display.Sprite;
import flash.events.MouseEvent;

var container:Sprite = new Sprite();
addChild(container);

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFF0000);
circle1.graphics.drawCircle(40, 40, 40);
circle1.addEventListener(MouseEvent.CLICK, clicked);
 
var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0x00FF00);
circle2.graphics.drawCircle(100, 40, 40);
circle2.addEventListener(MouseEvent.CLICK, clicked);
 
var circle3:Sprite = new Sprite();
circle3.graphics.beginFill(0x0000FF);
circle3.graphics.drawCircle(70, 80, 40);
circle3.addEventListener(MouseEvent.CLICK, clicked);
 
container.addChild(circle1);
container.addChild(circle2);
container.addChild(circle3);
addChild(container);
 
function clicked(event:MouseEvent):void {
    var circle:Sprite = Sprite(event.target);
    var topPosition:uint = container.numChildren - 1;
    container.setChildIndex(circle, topPosition);
}

Rekurencyjnie zatrzymuje wykonywanie osi czasu wszystkich obiektów MovieClip, dla których ten obiekt jest obiektem głównym.

Potomne obiekty ekranowe należące do obszaru izolowanego, do którego wykonywany kod nie ma dostępu, są ignorowane.

Uwaga: Nie zostanie zatrzymane strumieniowe odtwarzanie multimediów sterowane obiektem NetStream.

Zamienia kolejność dwóch określonych obiektów podrzędnych. Wszelkie pozostałe obiekty potomne w kontenerze obiektów ekranowych pozostają na tych samych indeksach.

Parametry

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";

container.addChild(sprite1);
container.addChild(sprite2);

trace(container.getChildAt(0).name); // sprite1
trace(container.getChildAt(1).name); // sprite2

container.swapChildren(sprite1, sprite2);

trace(container.getChildAt(0).name); // sprite2
trace(container.getChildAt(1).name); // sprite1

Zamienia miejscami na liście dwa różne obiekty podrzędne o podanych indeksach. Wszelkie pozostałe obiekty podrzędne w kontenerze obiektów wyświetlanych pozostają na tych samych indeksach.

Parametry

import flash.display.Sprite;

var container:Sprite = new Sprite();

var sprite1:Sprite = new Sprite();
sprite1.name = "sprite1";
var sprite2:Sprite = new Sprite();
sprite2.name = "sprite2";
var sprite3:Sprite = new Sprite();
sprite3.name = "sprite3";

container.addChild(sprite1);
container.addChild(sprite2);
container.addChild(sprite3);

trace(container.getChildAt(0).name); // sprite1
trace(container.getChildAt(1).name); // sprite2
trace(container.getChildAt(2).name); // sprite3

container.swapChildrenAt(0, 2);

trace(container.getChildAt(0).name); // sprite3
trace(container.getChildAt(1).name); // sprite2
trace(container.getChildAt(2).name); // sprite1

1. Konstruktor wywołuje metodę configureAssets().
2. Metoda configureAssets() tworzy obiekty Sprite child oraz lastChild.
3. Pętla for tworzy pięć pomarańczowych kwadratów oraz umieszcza je jeden obok drugiego.
4. Za każdym razem, gdy tworzony jest obiekt CustomSprite, jego konstruktor wywołuje metodę draw() dla obiektu CustomSprite, która tworzy kwadrat 50 x 50 pikseli poprzez wywołanie metod beginFill(), drawRect() i endFill() klasy Graphics. Metoda addChild() dodaje każdy z tych kwadratów do listy wyświetlania.

package {
    import flash.display.DisplayObject;
    import flash.display.Sprite;

    public class DisplayObjectContainerExample extends Sprite {
        private var gutter:uint     = 5;
        private var childCount:uint = 5;

        public function DisplayObjectContainerExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var child:Sprite = new CustomSprite();
            var lastChild:Sprite = child;
            for (var i:uint = 1; i <= childCount; i++) {
                child = new CustomSprite();
                child.x = lastChild.x + lastChild.width + gutter;
                addChild(child);
                lastChild = child;
            }
        }
    }
}

import flash.display.Sprite;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0xFFCC00;

    public function CustomSprite() {
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }
}