BlurFilter  - AS3

Intensywność rozmycia w poziomie. Poprawne wartości należą do zakresu od 0 do 255 (wielkość zmiennoprzecinkowa). Wartością domyślną jest 4. Wartości, które są potęgami 2 (na przykład liczby 2, 4, 8, 16 i 32), są zoptymalizowane i są renderowane szybciej niż inne wartości.

Intensywność rozmycia w pionie. Poprawne wartości należą do zakresu od 0 do 255 (wielkość zmiennoprzecinkowa). Wartością domyślną jest 4. Wartości, które są potęgami 2 (na przykład liczby 2, 4, 8, 16 i 32), są zoptymalizowane i są renderowane szybciej niż inne wartości.

Wykonywana liczba operacji rozmycia. Wartością domyślną jest BitmapFilterQuality.LOW, która jest równoważna jednorazowemu zastosowaniu filtra. Wartość BitmapFilterQuality.MEDIUM powoduje dwukrotne zastosowanie filtra; wartość BitmapFilterQuality.HIGH powoduje trzykrotne zastosowanie filtra i umożliwia uzyskanie rozmycia gaussowskiego. Filtry o niższych wartościach są renderowane szybciej.

W większości zastosowań wystarczające są następujące wartości quality: low, medium i high. Mimo że w celu zwiększenia wielokrotności stosowania rozmycia można stosować dodatkowe wartości liczbowe (aż do 15), należy pamiętać o tym, że wyższe wartości są renderowane wolniej. Zamiast zwiększać wartość quality — w celu uzyskania podobnego efektu przy krótszym czasie renderowania — można po prostu zwiększać wartości właściwości blurX i blurY.

Za pomocą następujących stałych BitmapFilterQuality można określać wartości właściwości quality:

• BitmapFilterQuality.LOW
• BitmapFilterQuality.MEDIUM
• BitmapFilterQuality.HIGH

Inicjuje filtr z zadanymi parametrami. Wartość domyślna powoduje wygenerowanie nieostrego obrazu.

Zwraca kopię tego obiektu typu Filter.

1. Zaimportuj wymagane klasy.
2. Zadeklaruj trzy właściwości używane w funkcji draw(), która rysuje obiekt, do którego zostanie zastosowany filtr rozmycia.
3. Utwórz funkcję konstruktora BlurFilterExample(), którego działanie jest następujące:
   • Wywołuje funkcję draw(), która zostanie zadeklrawowana później.
   • Deklaruje zmienną filter jako obiekt BitmapFilter i przypisuje ją do wartości zwracanej przez wywołanie metody getBitmapFilter().
   • Tworzy nowy obiekt tablicy myFilters i dodaje filtr filter do tablicy, a następnie przypisuje myFilters do własciwości filters obiektu BlurFilterExample. To spowoduje zastosowanie wszystkich filtrów zalezionych w obiekcie myFilters — w tym przykładzie jest to filtr filter.
4. Utwórz funkcję getBitmapFilter() w celu utworzenia i ustawienia właściwości dla filtru.
5. Utwórz funkcję draw(). W tej funkcji stosowane są metody klasy Graphics, do której dostęp uzyskuje się za pośrednictwem właściwości graphics klasy Sprite, w celu rysowania kwadratu.

package {
    import flash.display.Sprite;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BlurFilter;

    public class BlurFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function BlurFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var blurX:Number = 30;
            var blurY:Number = 30;
            return new BlurFilter(blurX, blurY, BitmapFilterQuality.HIGH);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}