GlowFilter  - AS3

Wartość przezroczystości alfa koloru. Poprawne wartości należą do zakresu od 0 do 1. Przykład: 0,25 powoduje ustawienie przezroczystości równej 25%. Wartością domyślną jest 1.

Intensywność rozmycia w poziomie. Poprawne wartości należą do zakresu od 0 do 255 (wielkość zmiennoprzecinkowa). Wartością domyślną jest 6. Wartości, które są potęgami 2 (dwójki 2, 4, 8, 16 i 32) są zoptymalizowane i są renderowane szybciej niż inne wartości.

Intensywność rozmycia w pionie. Poprawne wartości należą do zakresu od 0 do 255 (wielkość zmiennoprzecinkowa). Wartością domyślną jest 6. Wartości, które są potęgami 2 (na przykład liczby 2, 4, 8, 16 i 32), są zoptymalizowane i są renderowane szybciej niż inne wartości.

Kolor blasku. Poprawne wartości są w formacie szesnastkowym 0xRRGGBB. Wartością domyślną jest 0xFF0000.

Określa, czy blask jest blaskiem wewnętrznym. Wartość true określa poświatę wewnętrzną. Wartością domyślną jest false — poświata zewnętrzna (poświata wokół zewnętrznych krawędzi obiektu).

Określa, czy z tym obiektem skojarzono ramkę odcięcia. Wartość true sprawia, że wypełnienie obiektu jest przezroczyste i ujawnia kolor tła dokumentu. Wartością domyślną jest false (brak odcięcia).

Liczba operacji zastosowania filtra. Wartością domyślną jest BitmapFilterQuality.LOW, która jest równoważna jednorazowemu zastosowaniu filtra. Wartość BitmapFilterQuality.MEDIUM powoduje dwukrotne zastosowanie filtra; wartość BitmapFilterQuality.HIGH powoduje trzykrotne zastosowanie filtra. Filtry o niższych wartościach są renderowane szybciej.

W większości zastosowań wystarczające są następujące wartości quality: low, medium i high. Mimo że w celu osiągnięcia różnych efektów można stosować dodatkowe wartości liczbowe (aż do 15), wyższe wartości są renderowane wolniej. Zamiast zwiększać wartość quality — w celu uzyskania podobnego efektu przy krótszym czasie renderowania — można po prostu zwiększać wartości właściwości blurX i blurY.

Powiązane elementy interfejsu API

Siła odciskania lub zalewkowania. Im wyższa jest wartość, tym więcej koloru zostaje odciśnięte, co powoduje również wzmocnienie kontrastu między poświatą i tłem. Poprawne wartości należą do zakresu od 0 do 255. Wartością domyślną jest 2.

Inicjuje nową instancję obiektu GlowFilter z określonymi parametrami.

Powiązane elementy interfejsu API

Zwraca kopię tego obiektu typu Filter.

1. Zaimportuj wymagane klasy.
2. Zadeklaruj trzy właściwości w metodzie draw, która korzysta z metod klasy Graphics, do których uzyskuje dostęp za pośrednictwem właściwości graphics Sprite w celu narysowania pomarańczowego kwadratu.
3. Utwórz funkcję konstruktora, którego działanie jest następujące:
   • Wywołuje funkcję draw w celu utworzenia prostokąta.
   • Tworzy obiekt glowFilter klasy BitmapFilter i przypisuje do niego wartości zwrócone przez funkcję getBitmapFilter().
   • Przypisuje tablicę wartości z obiektu glowFilter do właściwości filters głównego obiektu ekranowego. W tym przypadku wszystkie elementy podrzędne głównego obiektu ekranowego dziedziczą właściwości filtru poświaty. Oznacza to, że prostokąt utworzony za pomocą funkcji draw() jest wyświetlany z zastosowaniem właściwości filtru poświaty.

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.GlowFilter;

    public class GlowFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function GlowFilterExample() {
        //draw the rectangle using the draw() function below
            draw();
            
        //assign the values from getBitmapFilter function below
        //to a BitmapFilter object "glowFilter"
            var glowFilter:BitmapFilter = getBitmapFilter();
            
        //populate the filters property of the root display object with the array of values
        //from the glowFilter object.
            filters = [ glowFilter ];
        }

        private function getBitmapFilter():BitmapFilter {
            var color:Number = 0x33CCFF;
            var alpha:Number = 0.8;
            var blurX:Number = 35;
            var blurY:Number = 35;
            var strength:Number = 2;
            var inner:Boolean = false;
            var knockout:Boolean = false;
            var quality:Number = BitmapFilterQuality.HIGH;

            return new GlowFilter(color,
                                  alpha,
                                  blurX,
                                  blurY,
                                  strength,
                                  quality,
                                  inner,
                                  knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}