ConvolutionFilter  - AS3

Wartość przezroczystości alfa nowego koloru. Poprawne wartości należą do zakresu od 0 do 1,0. Wartością domyślną jest 0. Przykład: 0,25 powoduje ustawienie przezroczystości równej 25%.

Wartość dodawana do wyniku przekształcenia macierzowego. Odchylenie zwiększa wartość koloru dla każdego kanału, dlatego ciemne kolory są jaśniejsze. Wartością domyślną jest 0.

Wskazuje, czy obraz powinien zostać ściśnięty. Dla pikseli, które znajdują się poza obrazem źródłowym, wartość true oznacza, że obraz wejściowy jest w razie potrzeby wydłużany wzdłuż każdej krawędzi poprzez powielanie wartości kolorów na danej krawędzi obrazu wejściowego. Wartość false oznacza, że powinien być stosowany inny kolor określony przez właściwości color i alpha. Wartością domyślną jest true.

 package {
    import flash.display.Sprite;
    import flash.display.BitmapData;
    import flash.filters.ConvolutionFilter;
    import flash.text.TextField;
    import flash.geom.Rectangle;
    import flash.geom.Point;

    public class ConvolutionClampExample extends Sprite {
        // Variables that affect clamping:
        var clamp:Boolean = false;
        var clampColor:Number = 0xFF0000;
        var clampAlpha:Number = 1;
        
        // For illustration, keep other ConvolutionFilter variables neutral:
        var bias:Number = 0;
        var preserveAlpha:Boolean = false;
        // Also, construct a neutral matrix
        var matrixCols:Number = 3;
        var matrixRows:Number = 3;
        var matrix:Array = [ 1,1,1,
                             1,1,1,
                             1,1,1 ];
        
        var filter:ConvolutionFilter = new ConvolutionFilter(matrixCols, matrixRows, matrix, matrix.length, bias, preserveAlpha, clamp, clampColor, clampAlpha);
        
        var largeBoxWidth:Number = 100;
        var largeBoxHeight:Number = 100;
        var largeBox:BitmapData = new BitmapData(largeBoxWidth, largeBoxWidth, true, 0xCC00FF00);
        var smallBoxWidth:Number = largeBoxWidth / 2;
        var smallBoxHeight:Number = largeBoxHeight / 2;
        var smallBox:BitmapData = new BitmapData(smallBoxWidth, smallBoxWidth, true, 0xCC0000FF);
            
        var mc:MovieClip = this.createEmptyMovieClip("mc", this.getNextHighestDepth());
        mc.attachBitmap(largeBox, this.getNextHighestDepth());
        
        mc.onPress = function() {
            largeBox.applyFilter(smallBox,
                                 new Rectangle(0,0, largeBoxWidth, largeBoxHeight),
                                 new Point(0,0),
                                 filter);
        }
    }
}

Kolor, który ma zastąpić piksele poza obrazem źródłowym (zakodowany szesnastkowo). Jest to wartość RGB bez składnika alpha. Wartością domyślną jest 0.

Dzielnik używany przy transformacji matrycy. Wartością domyślną jest 1. Dzielnik, który jest sumą wszystkich wartości macierzy, wyrównuje intensywność koloru w obiekcie wynikowym. Wartość 0 jest ignorowana i zamiast tego używana jest wartość domyślna.

Tablica wartości używanych do transformacji matrycy. Liczba elementów w macierzy musi być równa matrixX * matrixY.

Splot macierzy jest określony na podstawie macierzy n x m, która określa sposób, w jaki wartość określonego piksela w obrazie wejściowym zostaje połączona z pikselem sąsiednim w celu wygenerowania wartości piksela wynikowego. Każdy piksel wynikowy zostaje określony poprzez zastosowanie macierzy do odpowiedniego piksela źródłowego oraz jego pikseli sąsiednich.

W przypadku splotu macierzy 3 x 3 dla każdego niezależnego kanału koloru stosowana jest następująca formuła:

	dst (x, y) = ((src (x-1, y-1) * a0 + src(x, y-1) * a1....
	                  src(x, y+1) * a7 + src (x+1,y+1) * a8) / divisor) + bias
	

Niektóre specyfikacje filtrów działają szybciej, jeśli są obsługiwane przez procesor, który oferuje obsługę SSE (Streaming SIMD Extensions). Poniżej przedstawiono kryteria szybszego wykonywania operacji splotu:

• Filtr musi być filtrem 3x3.
• Wszystkie pozycje filtrów muszą być wartościami całkowitymi z zakresu od -127 do 127.
• Moduł sumy wszystkich pozycji filtrów nie może być wyższy niż 127.
• Jeśli dowolna pozycja filtru ma wartość ujemną, dzielnik musi należeć do zakresu od 2,00001 do 256.
• Jeśli wszystkie pozycje filtru są dodatnie, dzielnik musi należeć do zakresu od 1,1 do 256.
• Wartość odchylenia musi być całkowita.

Uwaga: Jeśli instancja ConvolutionFilter jest tworzona za pomocą konstruktora bez parametrów, kolejność, w jakiej wartości są przypisywane do właściwości macierzy, wpływa na działanie filtru. W poniższym przypadku przypisana jest tablica macierzy, a właściwości matrixX i matrixY mają wartości 0 (domyślne):

    public var myfilter:ConvolutionFilter = new ConvolutionFilter();
    myfilter.matrix = [0, 0, 0, 0, 1, 0, 0, 0, 0];
    myfilter.matrixX = 3;
    myfilter.matrixY = 3;
    

W poniższym przypadku przypisana jest tablica macierzy, a właściwości matrixX i matrixY mają wartości 3:

    public var myfilter:ConvolutionFilter = new ConvolutionFilter();
    myfilter.matrixX = 3;
    myfilter.matrixY = 3;
    myfilter.matrix = [0, 0, 0, 0, 1, 0, 0, 0, 0];
    

Wymiar x macierzy (liczba kolumn macierzy). Wartością domyślną jest 0.

Wymiar y macierzy (liczba wierszy macierzy). Wartością domyślną jest 0.

Wskazuje, czy kanał alfa ma pozostać poza zasięgiem filtra, czy też filtr splotu ma być stosowany i do kanału alfa i do kanałów kolorów. Wartość false wskazuje, że splot jest stosowany do wszystkich kanałów, również do kanału alpha. Wartość true oznacza, że splot jest stosowany tylko dla kanałów kolorów. Wartością domyślną jest true.

Inicjuje nowe wystąpienie klasy ConvolutionFilter z określonymi parametrami.

Zwraca kopię tego obiektu typu Filter.

Funkcja buildChild() tworzy nowy obiekt Loader o nazwie loader. Dla każdego wywołania metody buildChild() należy dołączyć detektor zdarzeń do obiektu Loader w celu wykrywania zdarzeń complete, które są obsługiwane przez funkcję przekazaną do metody buildChild().

Funkcje applyBrightness(), applySharpness() i applyOutline() korzystają z innych wartości dla tablicy matrix w celu uzyskania innych efektów ConvolutionFilter.

Uwaga: w celu osiągnięcia najlepszych wyników należy korzystać z obrazów o szerokości około 80 pikseli. Nazwa i lokalizacja pliku obrazu powinna być zgodna z wartością wprowadzoną do właściwości url. Przykład: wartość wprowadzona do właściwości url w przykładzie wskazuje na plik obrazu o nazwie „Image.jpg”, który znajduje się w tym samym katalogu, co plik SWF.

package {
    import flash.display.DisplayObject;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.filters.BitmapFilter;
    import flash.filters.ConvolutionFilter;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;

    public class ConvolutionFilterExample extends Sprite {
        private var size:uint = 140;
        private var url:String = "Image.jpg";

        public function ConvolutionFilterExample() {
            buildChild(applyNothing);
            buildChild(applyBrightness);
            buildChild(applySharpness);
            buildChild(applyOutline);
        }

        private function buildChild(loadHandler:Function):void {
            var loader:Loader = new Loader();
            loader.x = numChildren * size;
            loader.y = size;
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            if(loadHandler != null) {
                loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadHandler);
            }

            var request:URLRequest = new URLRequest(url);
            loader.load(request);
            addChild(loader);
        }

        private function applyNothing(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            applyLabel(child, "no filter");
        }

        private function applyBrightness(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            var matrix:Array = [5, 5, 5,
                                5, 0, 5,
                                5, 5, 5];
            applyFilter(child, matrix);
            applyLabel(child, "brightness");
        }

        private function applySharpness(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            var matrix:Array = [0, -1, 0,
                               -1, 20, -1,
                                0, -1, 0];
            applyFilter(child, matrix);
            applyLabel(child, "sharpness");
        }

        private function applyOutline(event:Event):void {
            var child:DisplayObject = DisplayObject(event.target.loader);
            var matrix:Array = [-30, 30, 0,
                                -30, 30, 0,
                                -30, 30, 0];
            applyFilter(child, matrix);
            applyLabel(child, "outline");
        }

        private function applyFilter(child:DisplayObject, matrix:Array):void {
            var matrixX:Number = 3;
            var matrixY:Number = 3;
            var divisor:Number = 9;
            var filter:BitmapFilter = new ConvolutionFilter(matrixX, matrixY, matrix, divisor);
            var filters:Array = new Array();
            filters.push(filter);
            child.filters = filters;
        }

        private function applyLabel(child:DisplayObject, label:String):void {
            var tf:TextField = new TextField();
            tf.x = child.x;
            tf.y = child.height;
            tf.autoSize = TextFieldAutoSize.LEFT;
            tf.text = label;
            addChild(tf);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}