DisplacementMapFilter  - AS3

Określa wartość przezroczystości alfa, która będzie stosowana do zniekształceń na zewnątrz obiektu. Jest określona jako wartość normalizowana z zakresu od 0,0 do 1,0. Przykład: 0,25 ustawia przezroczystość równą 25%. Wartością domyślną jest 0. Należy użyć tej właściwości, jeśli dla obiektu mode ustawiono DisplacementMapFilterMode.COLOR.

Określa, jakiej wartości koloru użyć dla przemieszczeń wychodzących poza zakres. Poprawne przemieszczenia należą do zakresu od 0,0 do 1,0. Wartości są w formacie szesnastkowym. Wartością domyślną color jest 0. Należy użyć tej właściwości, jeśli dla obiektu mode ustawiono DisplacementMapFilterMode.COLOR.

Określa kanał koloru przeznaczony do użycia na obrazie mapy w celu przemieszczenia wynikowej współrzędnej x. Możliwe wartości to stałe BitmapDataChannel:

• BitmapDataChannel.ALPHA
• BitmapDataChannel.BLUE
• BitmapDataChannel.GREEN
• BitmapDataChannel.RED

Powiązane elementy interfejsu API

Określa kanał koloru przeznaczony do użycia na obrazie mapy w celu przemieszczenia wynikowej współrzędnej y. Możliwe wartości to stałe BitmapDataChannel:

• BitmapDataChannel.ALPHA
• BitmapDataChannel.BLUE
• BitmapDataChannel.GREEN
• BitmapDataChannel.RED

Powiązane elementy interfejsu API

Obiekt BitmapData zawierający dane mapy przeniesień.

Powiązane elementy interfejsu API

Wartość określająca przesunięcie lewego górnego narożnika docelowego obiektu ekranowego względem lewego górnego narożnika mapy.

Powiązane elementy interfejsu API

Tryb filtra. Możliwe wartości to stałe DisplacementMapFilterMode:

• DisplacementMapFilterMode.WRAP — stosuje wartość przemieszczenia do drugiej strony obrazu źródłowego.
• DisplacementMapFilterMode.CLAMP — blokuje wartość przemieszczenia do krawędzi obrazu źródłowego.
• DisplacementMapFilterMode.IGNORE — jeśli wartość przemieszczenia jest poza zakresem, ignoruje przemieszczenia i korzysta ze źródłowych wartości pikseli.
• DisplacementMapFilterMode.COLOR — jeśli wynik przemieszczenia znajduje się poza obrazem, zastępuje wartości właściwości color i alpha.

Powiązane elementy interfejsu API

Mnożnik służący do skalowania wyniku przemieszczenia x z obliczenia mapy.

Mnożnik służący do skalowania wyniku przemieszczenia y z obliczenia mapy.

Inicjuje nowe wystąpienie obiektu DisplacementMapFilter z określonymi parametrami.

Powiązane elementy interfejsu API

Zwraca kopię tego obiektu typu Filter.

1. Klasa definiuje zmienne dla koloru tła, etykiety pola tekstowego oraz dla rozmiaru i przesunięcia, jakie będą używane w różnych funkcjach.
2. Funkcja konstruktora wywołuje metodę draw(), która korzysta z metod klasy Graphics w celu narysowania kwadratu z radialnym wypełnieniem gradientowym. graphics to właściwość obiektu DisplacementMapFilterExample, który rozszerza obiekt Sprite.
3. Funkcja konstruktora wywołuje metodę createLabel(), która tworzy pole tekstowe wyświetlające wartość labelText, a następnie dodaje je do listy wyświetlania.
4. Funkcja konstruktora wywołuje metodę createFilter(), której działanie jest następujące:
   • Tworzy zmienną o nazwie filter dla obiektu filtru.
   • Wywołuje metodę getDisplacementMapFilter() i przypisuje jej wartość zwracaną do zmiennej filter.
   • Przekazuje wartość filter do właściwości filters obiektu DisplacementFilterExample (klasa główna).
5. Metoda getBitmapFilter() tworzy obiekt BitmapData o nazwie mapBitmap i przypisuje jemu wyniki działania metody createBitmapData(). Obiekt mapBitmap, wraz z innymi zmiennymi, definiuje nową klasę przemieszczania.
6. Metoda createBitmapData() tworzy nowy obiekt BitmapData, który jest definiowany na podstawie aktualnej zawartości obiektu DisplacementMapFilterExample. Tworzy nową bitmapę ma podstawie bitmapData i dodaje bitmapę do stołu montażowego.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.BitmapDataChannel;
    import flash.display.GradientType;
    import flash.display.SpreadMethod;
    import flash.display.Sprite;
    import flash.filters.BitmapFilter;
    import flash.filters.DisplacementMapFilter;
    import flash.filters.DisplacementMapFilterMode;
    import flash.geom.Matrix;
    import flash.geom.Point;
    import flash.text.TextField;
    
    public class DisplacementMapFilterExample extends Sprite {
        private var bgColor:uint     = 0xFFCC00;
        private var size:uint        = 200;
        private var offset:uint      = 90;
        private var labelText:String = "Watch the text bend with the displacement map";

        public function DisplacementMapFilterExample() {
            draw();
            createLabel();
            createFilter();
        }

        private function createFilter():void {
            var filter:BitmapFilter = getBitmapFilter();
            filters = new Array(filter);
        }

        private function getBitmapFilter():BitmapFilter {
            var mapBitmap:BitmapData = createBitmapData();
            var mapPoint:Point       = new Point(0, 0);
            var channels:uint        = BitmapDataChannel.RED;
            var componentX:uint      = channels;
            var componentY:uint      = channels;
            var scaleX:Number        = 0.5;
            var scaleY:Number        = -30;
            var mode:String          = DisplacementMapFilterMode.CLAMP;
            var color:uint           = 0;
            var alpha:Number         = 0;
            return new DisplacementMapFilter(mapBitmap,
                                             mapPoint,
                                             componentX,
                                             componentY,
                                             scaleX,
                                             scaleY,
                                             mode,
                                             color,
                                             alpha);
        }

        private function draw():void {
            var matrix:Matrix = new Matrix();
            matrix.createGradientBox(size, size);
            graphics.beginGradientFill(GradientType.RADIAL,
                                       [0xFF0000, 0x0000FF],
                                       [100, 100],
                                       [55, 200],
                                       matrix,
                                       SpreadMethod.PAD);
            graphics.drawRect(0, 0, size, size);
        }

        private function createBitmapData():BitmapData {
            var bitmapData:BitmapData = new BitmapData(size, size, true, bgColor);
            bitmapData.draw(this, new Matrix());
            var bitmap:Bitmap = new Bitmap(bitmapData);
            bitmap.x = size;
            addChild(bitmap);
            return bitmapData;
        }

        private function createLabel():void {
            var tf:TextField = new TextField();
            tf.text = labelText;
            tf.y = offset;
            tf.width = size;
            addChild(tf);
        }
    }
}