TextFormat  - AS3

Określa wyrównanie akapitu. Wartości poprawne to stałe TextFormatAlign.

Wartością domyślną jest TextFormatAlign.LEFT.

Powiązane elementy interfejsu API

Określa wielkość wcięcia bloku tekstowego (w pikselach). Wcięcie bloku tekstowego stosuje się do całego bloku tekstowego, czyli do wszystkich wierszy tekstu. Dla porównania, normalne wcięcie (TextFormat.indent) dotyczy tylko pierwszego wiersza każdego akapitu. Jeśli ta właściwość ma wartość null, obiekt TextFormat nie określa wcięcia bloku tekstowego (wartość wcięcia bloku tekstowego wynosi 0).

Określa, czy tekst jest pogrubiony. Wartość domyślna null oznacza, że nie zastosowano pogrubienia. Wartość true oznacza, że zastosowano pogrubienie.

Określa, czy tekst wchodzi w skład listy wypunktowanej. Na liście wypunktowanej każdy akapit tekstu jest wcięty. Znak wypunktowania jest wyświetlany po lewej stronie pierwszego wiersza każdego akapitu. Wartość domyślna null oznacza, że nie zastosowano listy wykropkowanej.

Określa kolor tekstu. Liczba zawierająca trzy 8-bitowe składniki RGB; na przykład: 0xFF0000 to kolor czerwony, a 0x00FF00 to kolor zielony. Wartość domyślna null oznacza, że użytkownik programu Flash Player używa koloru czarnego (0x000000).

Ciąg znaków reprezentujący nazwę czcionki tekstu. Wartość domyślna null oznacza, że użytkownik programu Flash Player używa dla tekstu czcionki Times New Roman.

Wcięcie mierzone od lewego marginesu do pierwszego znaku akapitu. Wartość domyślna null oznacza, że nie użyto wcięcia.

Powiązane elementy interfejsu API

Określa, czy tekst jest pochylony. Wartość domyślna nulloznacza, że nie użyto kursywy.

Wartość typu Boolean, która wskazuje czy kerning jest włączony (true) czy nie (false). Kerning umożliwia dopasowanie pikseli między pewnymi parami znaków w celu zwiększenia czytelności i powinien być używany tylko w uzasadnionych przypadkach takich jak nagłówki zawierające czcionki o dużym rozmiarze. Kerning jest obsługiwany tylko dla czcionek osadzonych.

Niektóre czcionki takie jak Verdana czy czcionki nieproporcjonalne, jak np. Courier New nie obsługują kerningu.

Wartość domyślna null oznacza, że kerning nie jest włączony.

Liczba całkowita reprezentująca odstęp między wierszami (nazywany leading). Wartość domyślna null oznacza, że wielkości odstępu między wierszami wynosi 0.

Lewy margines akapitu (w pikselach). Wartość domyślna null oznacza, że liczba pikseli dla lewego marginesu wynosi 0.

Liczb reprezentująca wielkość odstępu, który jest równomiernie rozłożony między znakami. Wartość określa liczbę pikseli dodawanych z przodu po każdym znaku. Wartość domyślna null oznacza, że odstęp miedzy literami wynosi 0 pikseli. Dopuszczalne są wartości dziesiętne, jak np. 1,75.

Prawy margines akapitu (w pikselach). Wartość domyślna null oznacza, że liczba pikseli dla prawego marginesu wynosi 0.

Rozmiar tekstu w tym formacie, w pikselach. Wartość domyślna null oznacza, że używany jest rozmiar 12.

Określa położenie niestandardowych tabulatorów (w postaci tablicy całkowitych liczb dodatnich). Każdy punkt tabulacji określony jest za pomocą pikseli. Jeśli niestandardowe punkty tabulacji nie zostały określone (wartość null), domyślną wartością punktu tabulacji jest wartość 4 (średnia szerokość znaku).

Wskazuje docelowe okno, w którym jest wyświetlane hiperłącze. Jeśli okno docelowe stanowi pusty ciąg znaków, tekst jest wyświetlany w domyślnym oknie docelowym _self. Można użyć nazwy niestandardowej lub jednej z następujących czterech nazw: _self określa bieżącą ramkę w bieżącym oknie, _blank określa nowe okno, _parent określa element macierzysty bieżącej ramki, a _top określa ramkę najwyższego poziomu w bieżącym oknie. Jeśli właściwość TextFormat.url stanowi pusty ciąg znaków lub została ustawiona na wartość null, można pobrać lub ustawić tę właściwość, ale nie będzie ona aktywna.

Powiązane elementy interfejsu API

Wskazuje, czy tekst który używa tego formatu tekstowego jest podkreślony (true), czy nie (false). To podkreślenie jest podobne do tego uzyskanego za pomocą znacznika <U>, jednakże to ostatnie podkreślenie nie jest prawdziwe, ponieważ nie pomija poprawnie dolnej części litery. Wartość domyślna null oznacza, że nie użyto podkreślenia.

Wskazuje docelowy adres URL tekstu w tym formacie tekstowym. Jeśli adres url stanowi pusty ciąg znaków, tekst nie posiada odsyłacza hipertekstowego. Wartość domyślna null oznacza, że tekst nie posiada odsyłacza hipertekstowego.

Uwaga: Aby hiperłącze działało poprawnie, dla tekstu z przypisanym formatem tekstowym należy ustawić właściwość htmlText.

Powiązane elementy interfejsu API

Tworzy obiekt TextFormat o określonych właściwościach. Następnie można zmienić właściwości obiektu TextFormat w celu zmiany formatowania pól tekstowych.

Dowolny parametr może posiadać wartość null, która będzie oznaczać, że dany parametr nie został ustawiony. Wszystkie parametry są opcjonalne; każdy pominięty parametr jest traktowany jako parametr o wartości null.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFormat;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.text.TextFormatAlign;
    
    public class TextFormat_constructorExample extends Sprite {
        private var contentTextField:TextField = new TextField();
        private var formatTextField:TextField = new TextField();
        private var newFormat:TextFormat = new TextFormat();
        
        public function TextFormat_constructorExample() {
            contentTextField.x = 10;
            contentTextField.y = 10;
            contentTextField.background = true;
            contentTextField.border = true;
            contentTextField.multiline = true;
            contentTextField.wordWrap = true;
            contentTextField.selectable = false;
            contentTextField.width = 250;
            contentTextField.height = 120; 
  
            contentTextField.htmlText = "<p>The TextFormat class represents character formatting "
                + "information. Use the TextFormat class to create specific text formatting "
                + "for text fields." + 
                " </p><br>" + "\tTab One" + "\tTab Two<br>";
              
            formatTextField.x = 10;
            formatTextField.y = 140;
            formatTextField.background = true;
            formatTextField.border = true;
            formatTextField.autoSize = TextFieldAutoSize.LEFT;
            
            formatTextField.text = "align: right\n" + "blockIndent: 10 pixels\n" + "bold:\n" + "bullet:\n" + "color: red\n"
                                + "font: Arial\n" + "indent: 20 pixels\n" + "italic:\n" + "leading: 5 spaces\n" 
                                + "leftMargin: 20 pixels\n" + "letterSpacing: 4 pixels\n" + "rightMargin: 20 pixels\n" 
                                + "size: 16 point\n" + "target: new window\n" + "tabStops: 50 and 150 pixel\n" 
                                + "underline:\n" + "url: Adobe Flex page\n";

            formatTextField.addEventListener(MouseEvent.CLICK, formatTextFieldClickHandler);
            
            contentTextField.addEventListener(MouseEvent.CLICK, contentTextFieldClickHandler);
            
            this.addChild(contentTextField);
            this.addChild(formatTextField);
        }

        private function formatTextFieldClickHandler(e:MouseEvent):void {
                var value:String= "";
                var i:uint = 0;
                var index:int = formatTextField.getLineIndexAtPoint(e.localX, e.localY);
                var line:String = formatTextField.getLineText(index);;

                line = line.substr(0, (line.indexOf(":")));

                switch(line) {
                    case "align":
                        newFormat.align = TextFormatAlign.RIGHT;
                        break;
                    case "blockIndent":
                        newFormat.blockIndent = 10;
                        break;
                    case "bold":
                        newFormat.bold = true;
                        break;
                    case "bullet":
                        newFormat.bullet = true;
                        break;
                    case "color":
                        newFormat.color = 0xFF0000;        
                        break;
                    case "font":
                        newFormat.font = "Arial";
                        break;
                    case "indent":
                        newFormat.indent = 20;
                        break;
                    case "italic":
                        newFormat.italic = true;
                        break;
                    case "leading":
                        newFormat.leading = 5;
                        break;
                    case "leftMargin":
                        newFormat.leftMargin = 20;
                        break;
                    case "letterSpacing":
                        newFormat.letterSpacing = 4;
                        break;
                    case "rightMargin":
                        newFormat.rightMargin = 20;
                        break;
                    case "size":
                        newFormat.size = 16;
                        break;
                    case "tabStops":                
                        newFormat.tabStops = [50, 150];
                        break;
                    case "target":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        newFormat.target = "_blank";
                        break;    
                    case "underline":
                        newFormat.underline = true;
                        break;
                    case "url":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        break;
                }    

                contentTextField.setTextFormat(newFormat);
        }

        private function contentTextFieldClickHandler(e:MouseEvent):void {
            contentTextField.setTextFormat(contentTextField.defaultTextFormat);
            newFormat = contentTextField.defaultTextFormat;
        }
    }
}

1. Utworzona zostaje właściwość label typu TextField.
2. Konstruktor klasy wywołuje funkcję configureLabel().
3. Funkcja configureLabel() najpierw tworzy obiekt TextField i przypisuje mu właściwość label, a ustawia parametry w następujący sposób:
   • Wyrównanie pole tekstowego do lewej.
   • Włączenie wypełnienie tła.
   • Włącz obramowanie.
4. Następnie, metoda configureLabel() tworzy lokalną zmienną, format i przypisuje ją do nowej instancji TextFormat wraz z parametrami ustawionymi w następujący sposób:
   • Typ czcionki = Verdana
   • Kolor czcionki = czerwony kryjący
   • Rozmiar czcionki = 10
   • Podkreślenie = prawda
5. Właściwość defaultTextFormat etykiety zostaje ustawiona na wartośćformat, a instancja label zostaje dodana do listy wyświetlania, która początkowo wyświetla pole tekstowe bez tekstu (jako małe pole o białym tle) na stole montażowym.
6. Na końcu (z powrotem w konstruktorze), etykieta wyświetla tekst „Hello World and welcome to the show”, o położeniu określonym przez współrzędne x = 0, y = 0 za pomocą metody setLabel().

 package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;


    public class TextFormatExample extends Sprite {
        private var label:TextField;

        public function TextFormatExample() {
            configureLabel();
            setLabel("Hello World and welcome to the show");
        }

        public function setLabel(str:String):void {
            label.text = str;
        }

        private function configureLabel():void {
            label = new TextField();
            label.autoSize = TextFieldAutoSize.LEFT;
            label.background = true;
            label.border = true;

            var format:TextFormat = new TextFormat();
            format.font = "Verdana";
            format.color = 0xFF0000;
            format.size = 10;
            format.underline = true;

            label.defaultTextFormat = format;
            addChild(label);
        }
    }
}