Label  - AS3 Flash

Pobiera lub ustawia ciąg znaków wskazujący sposób wymiarowania i wyrównywania etykiety zgodnie z wartością jej właściwości text. Poniżej podano prawidłowe wartości:

• TextFieldAutoSize.NONE: Wielkość etykiety nie jest zmieniana ani wyrównywana w celu dopasowania do tekstu.
• TextFieldAutoSize.LEFT: Prawa i dolna krawędź etykiety są dostosowywane do wielkości tekstu. Lewa ani górna krawędź nie ulegają zmianie.
• TextFieldAutoSize.CENTER: Lewa i prawa krawędź etykiety są dostosowywane do wielkości tekstu. Oś pozioma etykiety pozostaje zakotwiczona w swoim pierwotnym położeniu, wyśrodkowana w poziomie.
• TextFieldAutoSize.RIGHT: Lewa i dolna krawędź etykiety są dostosowywane do wielkości tekstu. Górna ani prawa krawędź nie ulegają zmianie.

Wartością domyślną jest TextFieldAutoSize.NONE.

Powiązane elementy interfejsu API

import flash.text.TextFieldAutoSize;
import fl.controls.Label;

var testString:String = "Lorem ipsum dolor sit amet.";
var label1:Label = new Label();
var label2:Label = new Label();
var label3:Label = new Label();
label1.move(10,10);
label2.move(10,50);
label3.move(10,90);
label1.width = stage.stageWidth - 20;
label2.width = stage.stageWidth - 20;
label3.width = stage.stageWidth - 20;
label1.text = testString;
label2.text = testString;
label3.text = testString;
label1.autoSize = TextFieldAutoSize.LEFT;
label2.autoSize = TextFieldAutoSize.CENTER;
label3.autoSize = TextFieldAutoSize.RIGHT;
addChild(label1);
addChild(label2);
addChild(label3);

Pobiera lub ustawia wartość wskazującą, czy dodatkowe odstępy, takie jak spacje i podziały wiersza powinny być usuwane ze składnika Label zawierającego tekst HTML. Wartość true wskazuje, że dodatkowe odstępny mają zostać usunięte; wartość false oznacza sytuację przeciwną.

Właściwość condenseWhite ma wpływ wyłącznie na tekst, który ustawiono za pomocą właściwości htmlText, nie zaś za pomocą właściwości text. W przypadku ustawienia tekstu za pomocą właściwości text właściwość condenseWhite jest ignorowana.

W przypadku ustawienia właściwości condenseWhite na wartość true konieczne jest używanie standardowych poleceń HTML, takich jak <br> i <p>, w celu podziału wierszy tekstu w polu tekstowym.

Wartością domyślną jest false.

Powiązane elementy interfejsu API

import fl.controls.Label;

var testString:String = "   Hello World";

var label1:Label = new Label();
label1.move(10,10);
label1.htmlText = testString;
addChild(label1);

var label2:Label = new Label();
label2.move(10,40);
label2.condenseWhite = true;
label2.htmlText = testString;
addChild(label2);

Pobiera lub ustawia wysokość składnika w pikselach.

Ustawienie tej właściwości powoduje wywołanie zdarzenia resize. Szczegółowe informacje o okolicznościach wywoływania zdarzenia resize zawiera opis tego zdarzenia.

Jeśli właściwość scaleY składnika jest różna od 1.0, wysokość składnika uzyskana z jego współrzędnych wewnętrznych będzie różna od wysokości uzyskanej ze współrzędnych obiektu nadrzędnego. Na przykład składnik o wysokości 100 pikseli i wartości scaleY równej 2 ma w obiekcie nadrzędnym wysokość 100 pikseli, ale wewnętrznie jest w nim zapisana wartość wskazująca na wysokość 50 pikseli.

Powiązane elementy interfejsu API

Pobiera lub ustawia tekst do wyświetlenia przez składnik Label, w tym znacznik HTML opisujący style użyte w tym tekście. W tej właściwości można określić tekst HTML, korzystając z podzestawu znaczników HTML obsługiwanych przez obiekt TextField.

Jeśli wartość domyślna właściwości text zostanie zmieniona w Inspektorze właściwości, ta zmieniona wartość zastępuje dowolną wartość w polu właściwości htmlText Inspektora właściwości. W celu użycia właściwości htmlText w Inspektorze właściwości pole właściwości text musi zawierać wartość Label, dokładnie tak, jak pokazano. Podczas kodowania w języku ActionScript nie jest konieczne ustawianie wartości właściwości text; wartość domyślna to Label.

Wartością domyślną jest "".

Powiązane elementy interfejsu API

Pobiera lub ustawia wartość wskazującą, czy tekst można zaznaczyć. Wartość true oznacza, że tekst można zaznaczyć; wartość false oznacza sytuację przeciwną.

Tekst, który można zaznaczyć, może być skopiowany ze składnika Label przez użytkownika.

Wartością domyślną jest false.

Pobiera lub ustawia zwykły tekst do wyświetlania przez składnik Label.

Należy zauważyć, że znaki reprezentujące znaczniki HTML nie mają w ciągu znaków żadnego specjalnego znaczenia i będą wyświetlane tak, jak są wprowadzone.

W celu wyświetlenia tekstu zawierającego znaczniki HTML należy użyć właściwości htmlText. Tekst HTML zastępuje dowolny tekst ustawiony przez użytkownika za pomocą właściwości htmlText, zaś właściwość text zwraca wersję ze zwykłym tekstem wygenerowaną na podstawie tekstu w formacie HTML przez usunięcie znaczników HTML.

W przypadku zmiany właściwości text z wartości domyślnej w inspektorze właściwości zmiana ta ma priorytet wobec właściwości htmlText w inspektorze właściwości.

Wartością domyślną jest "Label".

Powiązane elementy interfejsu API

Odniesienie do wewnętrznego pola tekstowego składnika Label.

Pobiera lub ustawia szerokość składnika w pikselach.

Ustawienie tej właściwości powoduje wywołanie zdarzenia resize. Szczegółowe informacje o okolicznościach wywoływania zdarzenia resize zawiera opis tego zdarzenia.

Jeśli właściwość scaleX składnika jest różna od 1,0, szerokość składnika uzyskana z jego współrzędnych wewnętrznych będzie różna od szerokości uzyskanej ze współrzędnych obiektu nadrzędnego. Na przykład składnik o szerokości 100 pikseli i wartości scaleX równej 2 ma w obiekcie nadrzędnym szerokość 100 pikseli, ale wewnętrznie jest w nim zapisana wartość wskazująca na szerokość 50 pikseli.

Powiązane elementy interfejsu API

Pobiera lub ustawia wartość wskazującą, czy tekst może być zawijany. Wartość true oznacza, że tekst można zawijać; wartość false oznacza sytuację przeciwną.

Wartością domyślną jest false.

import fl.controls.Label;

var url:String = "http://www.helpexamples.com/flash/text/lorem.txt";

myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.width = 530;
myLabel.move(10, 10);
myLabel.wordWrap = true;

var ldr:URLLoader = new URLLoader();
ldr.addEventListener(Event.COMPLETE, completeHandler);
ldr.load(new URLRequest(url));

function completeHandler(event:Event):void {
    myLabel.text = URLLoader(event.currentTarget).data;
}

Tworzy nowe wystąpienie składnika Label.

Pobiera domyślną mapę stylów dla bieżącego składnika. Mapa stylów zawiera typ odpowiedni dla składnika, w zależności od stylu składnika. Na przykład dla stylu disabledTextFormat wartość jest równa null lub jest obiektem TextFormat. Można używać tych stylów w wywołaniach metody setStyle() dla bieżącego składnika. Poniższy kod przesłania domyślny styl disabledTextFormat dla określonego składnika:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Powiązane elementy interfejsu API

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Wywoływane po zmianie szerokości lub wysokości składnika.

Uwaga: To zdarzenie nie występuje w przypadku użycia kodu ActionScript do zmiany tekstu etykiety.

To zdarzenie ma następujące właściwości:

import fl.controls.Label;
import fl.events.ComponentEvent;

var myLabel:Label = new Label();
myLabel.text = "The quick brown fox jumped over the lazy dog.";
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.wordWrap = true;
myLabel.move(10, 10);
myLabel.addEventListener(ComponentEvent.RESIZE, resizeHandler);
addChild(myLabel);

function resizeHandler(event:ComponentEvent):void {
    var lbl:Label = event.currentTarget as Label;
    trace("width:" + lbl.width, "height:" + lbl.height); // width:100 height:46
}

1. Dodaj składniki Label i Button do biblioteki.
2. Zapisz ten kod pod nazwą LabelExample.as w tym samym katalogu, co plik FLA.
3. Ustaw właściwość DocumentClass w pliku FLA na wartość LabelExample.

package
{
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.display.Sprite;
    import fl.controls.Label;
    import fl.controls.Button;
    
    public class LabelExample extends Sprite
    {
        private var simpleLabel:Label;
        private var b1:Button;
        private var b2:Button;        

        private var htmlData:String = "<br>This label displays <b>bold</b> and <i>italic</i> HTML-formatted text.";
        
        public function LabelExample() {
            setupLabel();
            setupButtons();
        }
        private function setupButtons():void {
            b1 = new Button();
            b2 = new Button();

            b1.move(10,50);
            b2.move(10,80);

            b1.setSize(120,22);
            b2.setSize(120,22);
            
            b1.label = "Make Normal Label";
            b2.label = "Make HTML Label";

            b1.addEventListener(MouseEvent.CLICK,buttonClick);
            b2.addEventListener(MouseEvent.CLICK,buttonClick);

            addChild(b1);
            addChild(b2);
        }
        private function setupLabel():void {
            simpleLabel = new Label();
            simpleLabel.move(10,10);
            simpleLabel.autoSize = TextFieldAutoSize.LEFT;
            addChild(simpleLabel);
        }
                               
        // Event handler function to change the image size.
        private function displayHTML():void {
            simpleLabel.htmlText = htmlData;
        }
      
        // Event handler function to change the image size.
        private function displayText():void {
            simpleLabel.text = "This Label displays plain text.";
        }
        private function buttonClick(e:MouseEvent):void {
            switch(e.target) {
                case b1:
                    displayText();
                    break;
                case b2:
                    displayHTML();
                    break;
                default:
                    break;
            }
        }
    }
}